Debian Codegraph @

texmf-dist/fonts/source/public/fdsymbol/fdoperators.mf

raw
1 %
2 % Copyright (c) 2011-2025, Michael Ummels <[email protected]>
3 %
4 % This Font Software is licensed under the SIL Open Font License,
5 % Version 1.1. This license is in the accompanying file OFL.txt, and
6 % is also available with a FAQ at: http://scripts.sil.org/OFL
7 %
8
9 for scale = 1, 1.4:
10 beginsquarebigop(scale, scale); "big plus";
11 draw_line(centre + op_height/2 * right, centre + op_height/2 * left, false);
12 draw_line(centre + op_height/2 * up, centre + op_height/2 * down, false);
13 endchar;
14 endfor;
15 charlist current_char - 1: current_char;
16
17 for scale = 1, 1.4:
18 beginsquarebigop(scale, scale); "big times";
19 z1 - z0 = z3 - z2 = (op_width - line_thickness / sqrt(2)) * right;
20 z2 - z0 = (op_width - line_thickness / sqrt(2)) * up;
21 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
22
23 draw_line(z0, z3, false);
24 draw_line(z1, z2, false);
25 endchar;
26 endfor;
27 charlist current_char - 1: current_char;
28
29 for sign = 1, -1:
30 for scale = 1, 1.4:
31 beginbigop(scale, scale); "big wedge";
32 draw_less(a, centre + sign * op_height/2 * up, centre - sign * op_height/2 * up, op_width - line_thickness, line_thickness, false);
33 endchar;
34 endfor;
35 charlist current_char - 1: current_char;
36 endfor;
37
38 for sign = 1, -1:
39 for scale = 1, 1.4:
40 beginbigop(scale, scale); "big wedge dot";
41 draw_less(a, centre + sign * op_height/2 * up, centre - sign * op_height/2 * up, op_width - line_thickness, line_thickness, false);
42 fill dot(centre - sign * 1/4op_height * up, dot_size);
43 endchar;
44 endfor;
45 charlist current_char - 1: current_char;
46 endfor;
47
48 for sign = 1, -1:
49 for scale = 1, 1.4:
50 beginbigop(4/3scale, scale); "double big wedge";
51 z0 = centre - 1/8op_width * right;
52 z1 = centre + 1/8op_width * right;
53
54 draw_less(a, z0 + sign * op_height/2 * up, z0 - sign * op_height/2 * up, 3/4op_width - line_thickness, line_thickness, false);
55 draw_less(b, z1 + sign * op_height/2 * up, z1 - sign * op_height/2 * up, 3/4op_width - line_thickness, line_thickness, false);
56 endchar;
57 endfor;
58 charlist current_char - 1: current_char;
59 endfor;
60
61 for sign = 1, -1:
62 for scale = 1, 1.4:
63 beginbigop(scale, scale); "big curly wedge";
64 draw_prec(a, centre + sign * op_height/2 * up, centre - sign * op_height/2 * up, op_width - line_thickness, line_thickness, false);
65 endchar;
66 endfor;
67 charlist current_char - 1: current_char;
68 endfor;
69
70 for sign = 1, -1:
71 for scale = 1, 1.4:
72 beginbigop(scale, scale); "big union";
73 draw_subset(a, centre + sign * op_height/2 * up, centre - sign * op_height/2 * up, op_width - line_thickness, line_thickness);
74 endchar;
75 endfor;
76 charlist current_char - 1: current_char;
77 endfor;
78
79 for sign = 1, -1:
80 for scale = 1, 1.4:
81 beginbigop(scale, scale); "big union dot";
82 draw_subset(a, centre + sign * op_height/2 * up, centre - sign * op_height/2 * up, op_width - line_thickness, line_thickness);
83 fill dot(centre - sign * 1/8op_height * up, dot_size);
84 endchar;
85 endfor;
86 charlist current_char - 1: current_char;
87 endfor;
88
89 for sign = 1, -1:
90 for scale = 1, 1.4:
91 beginbigop(scale, scale); "big union plus";
92 draw_subset(a, centre + sign * op_height/2 * up, centre - sign * op_height/2 * up, op_width - line_thickness, line_thickness);
93
94 r := 1/4op_width;
95
96 draw_line(centre - sign * 1/8op_width * up + r * right, centre - sign * 1/8op_width * up + r * left, false);
97 draw_line(centre + (r - sign * 1/8op_width) * up, centre + (r + sign * 1/8op_width) * down, false);
98 endchar;
99 endfor;
100 charlist current_char - 1: current_char;
101 endfor;
102
103 for sign = 1, -1:
104 for scale = 1, 1.4:
105 beginbigop(scale, scale); "big square union";
106 z3 - z0 = z2 - z1 = (op_width - line_thickness) * right;
107 z1 - z0 = sign * (op_height - line_thickness) * up;
108 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
109
110 draw_line(z0, z1, true);
111 draw_line(z1, z2, true);
112 draw_line(z2, z3, true);
113 endchar;
114 endfor;
115 charlist current_char - 1: current_char;
116 endfor;
117
118 for sign = 1, -1:
119 for scale = 1, 1.4:
120 beginbigop(scale, scale); "big square union dot";
121 z3 - z0 = z2 - z1 = (op_width - line_thickness) * right;
122 z1 - z0 = sign * (op_height - line_thickness) * up;
123 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
124
125 draw_line(z0, z1, true);
126 draw_line(z1, z2, true);
127 draw_line(z2, z3, true);
128 fill dot(centre - sign * 1/8op_height * up, dot_size);
129 endchar;
130 endfor;
131 charlist current_char - 1: current_char;
132 endfor;
133
134 for sign = 1, -1:
135 for scale = 1, 1.4:
136 beginbigop(scale, scale); "big square union plus";
137 z3 - z0 = z2 - z1 = (op_width - line_thickness) * right;
138 z1 - z0 = sign * (op_height - line_thickness) * up;
139 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
140
141 draw_line(z0, z1, true);
142 draw_line(z1, z2, true);
143 draw_line(z2, z3, true);
144
145 r := 1/4op_width;
146
147 draw_line(centre - sign * 1/8op_width * up + r * right, centre - sign * 1/8op_width * up + r * left, false);
148 draw_line(centre + (r - sign * 1/8op_width) * up, centre + (r + sign * 1/8op_width) * down, false);
149 endchar;
150 endfor;
151 charlist current_char - 1: current_char;
152 endfor;
153
154 for alpha = 0, 45:
155 for scale = 1, 1.4:
156 beginsquarebigop(scale, scale); "big circle plus";
157 r := (op_height - line_thickness)/2;
158
159 draw_circle(centre, r, line_thickness);
160 draw_line(centre - r * dir alpha, centre + r * dir alpha, false);
161 draw_line(centre - r * dir (alpha + 90), centre + r * dir (alpha + 90), false);
162 endchar;
163 endfor;
164 charlist current_char - 1: current_char;
165 endfor;
166
167 for scale = 1, 1.4:
168 beginsquarebigop(scale, scale); "big circle dot";
169 draw_circle(centre, (op_height - line_thickness)/2, line_thickness);
170 fill dot(centre, dot_size);
171 endchar;
172 endfor;
173 charlist current_char - 1: current_char;
174
175 for scale = 1, 1.4:
176 beginsquarebigop(scale, scale); "big circle asterisk";
177 thick := line_thickness;
178 r := (op_height - line_thickness)/2;
179
180 draw_circle(centre, r, line_thickness);
181
182 penpos a0(4/3thick, 0);
183 penpos a1(4/3thick, 60);
184 penpos a2(4/3thick, 120);
185 penpos a3(4/3thick, 180);
186 penpos a4(4/3thick, 240);
187 penpos a5(4/3thick, 300);
188
189 penpos b0(thick, 0);
190 penpos b1(thick, 60);
191 penpos b2(thick, 120);
192 penpos b3(thick, 180);
193 penpos b4(thick, 240);
194 penpos b5(thick, 300);
195
196 reg_poly_points(a)(6, centre, r, 90);
197
198 z.b0 = z.b1 = z.b2 = z.b3 = z.b4 = z.b5 = centre;
199
200 fill stroke z.a0e -- z.b0e;
201 fill stroke z.a1e -- z.b1e;
202 fill stroke z.a2e -- z.b2e;
203 fill stroke z.a3e -- z.b3e;
204 fill stroke z.a4e -- z.b4e;
205 fill stroke z.a5e -- z.b5e;
206 endchar;
207 endfor;
208 charlist current_char - 1: current_char;
209
210 for sign = 1, -1:
211 for serifs = true, false:
212 for scale = 1, 1.4:
213 beginbigop(5/4scale, scale); "product";
214 draw_product(centre, op_width, op_height, sign, line_thickness * sqrt sqrt scale, serifs);
215 endchar;
216 endfor;
217 charlist current_char - 1: current_char;
218 endfor;
219 endfor;
220
221 for serifs = true, false:
222 for scale = 1, 1.4:
223 beginbigop(scale, scale); "sum";
224 draw_sum(a)(centre, op_width, op_height, line_thickness * sqrt sqrt scale, serifs);
225 endchar;
226 endfor;
227 charlist current_char - 1: current_char;
228 endfor;
229
230 for serifs = true, false:
231 for scale = 1, 1.4:
232 beginbigop(scale, scale); "sum modulo two";
233 draw_sum(a)(centre, op_width, op_height, line_thickness * sqrt sqrt scale, serifs);
234 draw_circle(z12a, sqrt scale * 1/4op_width, line_thickness * sqrt sqrt scale);
235 endchar;
236 endfor;
237 charlist current_char - 1: current_char;
238 endfor;
239
240 for number = 0, 1, 2, 3:
241 for scale = 1, 1.8:
242 beginsymbol(scale * (5number + 4) * u# + (sqrt scale) * 3/4line_thickness# + 2side_bearing#, vcentre(scale * 1.6asc_height#)); "integral";
243 italcorr scale * 3u# - (sqrt scale) * 3/4line_thickness#; % kerning between upper limit and lower limit
244
245 pair centre;
246
247 for i = 0 upto number:
248 centre := (side_bearing + scale * (5i + 7/2) * u, (h - d)/2);
249 draw_integral([i])(scale, centre, line_thickness * sqrt sqrt scale);
250 endfor;
251 endchar;
252 endfor;
253 charlist current_char - 1: current_char;
254 endfor;
255
256 for scale = 1, 1.8:
257 beginsymbol(scale * 9u# + 4(equal_spread# + dot_size#) + (sqrt scale) * 3/4line_thickness# + 2side_bearing#, vcentre(scale * 1.6asc_height#)); "integral dots";
258 italcorr scale * 3u# - (sqrt scale) * 3/4line_thickness#; % kerning between upper limit and lower limit
259
260 pair centre;
261 centre := (side_bearing + scale * 7/2u, (h - d)/2);
262
263 draw_integral([0])(scale, centre, line_thickness * sqrt sqrt scale);
264
265 centre := (side_bearing + scale * 6u + 4(equal_spread + dot_size), (h - d)/2);
266
267 draw_integral([1])(scale, centre, line_thickness * sqrt sqrt scale);
268
269 z0 = 1/4[z0[0],z0[1]];
270 z1 = 2/4[z0[0],z0[1]];
271 z2 = 3/4[z0[0],z0[1]];
272
273 fill dot(z0, dot_size);
274 fill dot(z1, dot_size);
275 fill dot(z2, dot_size);
276 endchar;
277 endfor;
278 charlist current_char - 1: current_char;
279
280 for sign = 1, -1:
281 for scale = 1, 1.8:
282 beginsymbol(scale * 6u# + if scale > 1: (sqrt scale) * 3/4line_thickness# else: scale * 3u# fi + 2side_bearing#, vcentre(scale * 1.6asc_height#)); "oriented integral";
283 if scale > 1:
284 italcorr scale * 3u# - (sqrt scale) * 3/4line_thickness#; % kerning between upper limit and lower limit
285 fi
286
287 pair centre;
288 centre := (side_bearing + scale * 9/2u, (h - d)/2);
289
290 draw_integral(a)(scale, centre, line_thickness * sqrt sqrt scale);
291
292 thick := line_thickness * sqrt sqrt scale;
293 r := 4u;
294
295 penpos0(thick, 135);
296 penpos1(thick, 90);
297 penpos2(thick, 45);
298
299 z0 = z0a + sign * scale * (-r, -1/4r);
300 z1 = z0a + sign * scale * (0, 1/4r);
301 z2 = z0a + sign * scale * (r, -1/4r);
302
303 if sign > 0:
304 fill stroke z0.e{dir 45} .. {dir 0}z1.e .. {dir -45}z2.e;
305 draw_arrowhead(z2, -40, 2/3scale * arrow_spread, 5/6thick);
306 else:
307 fill stroke z0.e{dir -135} .. {dir 180}z1.e .. {dir 135}z2.e;
308 draw_arrowhead(z0, 40, 2/3scale * arrow_spread, 5/6thick);
309 fi
310
311 penlabels(0,1,2);
312 endchar;
313 endfor;
314 charlist current_char - 1: current_char;
315 endfor;
316
317 for scale = 1, 1.8:
318 beginsymbol(scale * 4u# + if scale > 1: (sqrt scale) * 3/4line_thickness# else: scale * 3u# fi + 2side_bearing#, vcentre(scale * 1.6asc_height#)); "integral with horizontal bar";
319 if scale > 1:
320 italcorr scale * 3u# - (sqrt scale) * 3/4line_thickness#; % kerning between upper limit and lower limit
321 fi
322
323 pair centre;
324 centre := (side_bearing + scale * 7/2u, (h - d)/2);
325
326 draw_integral(a)(scale, centre, line_thickness * sqrt sqrt scale);
327
328 r := scale * 5/2u;
329 thick := line_thickness * sqrt sqrt scale;
330
331 draw_straight(z0a + r * left, z0a + r * right, thick, true);
332 endchar;
333 endfor;
334 charlist current_char - 1: current_char;
335
336 for scale = 1, 1.8:
337 beginsymbol(scale * 4u# + if scale > 1: (sqrt scale) * 3/4line_thickness# else: scale * 3u# fi + 2side_bearing#, vcentre(scale * 1.6asc_height#)); "integral with double horizontal bar";
338 if scale > 1:
339 italcorr scale * 3u# - (sqrt scale) * 3/4line_thickness#; % kerning between upper limit and lower limit
340 fi
341
342 pair centre;
343 centre := (side_bearing + scale * 7/2u, (h - d)/2);
344
345 draw_integral(a)(scale, centre, line_thickness * sqrt sqrt scale);
346
347 z1 - z0 = equal_spread * up;
348 1/2[z0, z1] = z0a;
349
350 r := scale * 5/2u;
351 thick := line_thickness * sqrt sqrt scale;
352
353 draw_straight(z0 + r * left, z0 + r * right, thick, true);
354 draw_straight(z1 + r * left, z1 + r * right, thick, true);
355 endchar;
356 endfor;
357 charlist current_char - 1: current_char;
358
359 for scale = 1, 1.8:
360 beginsymbol(scale * 4u# + (sqrt scale) * 3/4line_thickness# + 2side_bearing#, vcentre(scale * 1.6asc_height#)); "stroked integral";
361 italcorr scale * 3u# - (sqrt scale) * 3/4line_thickness#; % kerning between upper limit and lower limit
362
363 pair centre;
364 centre := (side_bearing + scale * 7/2u, (h - d)/2);
365
366 draw_integral(a)(scale, centre, line_thickness * sqrt sqrt scale);
367
368 r := scale * 7/2u;
369 thick := line_thickness * sqrt sqrt scale;
370
371 draw_straight(z0a - r * dir 35, z0a + r * dir 35, thick, true);
372 endchar;
373 endfor;
374 charlist current_char - 1: current_char;
375
376 for number = 0, 1, 2:
377 for scale = 1, 1.8:
378 beginsymbol(scale * (5number + 5) * u# + if scale > 1: (sqrt scale) * 3/4line_thickness# else: scale * 3u# fi + 2side_bearing#, vcentre(scale * 1.6asc_height#)); "contour integral";
379 if scale > 1:
380 italcorr scale * 3u# - (sqrt scale) * 3/4line_thickness#; % kerning between upper limit and lower limit
381 fi
382
383 pair centre;
384
385 centre := (side_bearing + scale * (5number/2 + 4) * u, (h - d)/2);
386 thick := line_thickness * sqrt sqrt scale;
387 r := scale * 4u;
388 s := scale * (5number + 8)/2 * u;
389
390 if number = 0:
391 fill circle(centre, r);
392 unfill circle(centre, r - thick);
393 else:
394 fill superellipse(centre + s * dir 0, centre + r * dir 90, centre - s * dir 0, centre - r * dir 90, 3/4);
395 unfill superellipse(centre + (s - thick) * dir 0, centre + (r - thick) * dir 90, centre - (s - thick) * dir 0, centre - (r - thick) * dir 90, 3/4);
396 fi
397
398 % Integral must come after unfill when processed with MetaPost!
399 for i = 0 upto number:
400 centre := (side_bearing + scale * (5i + 4) * u, (h - d)/2);
401 draw_integral([i])(scale, centre, line_thickness * sqrt sqrt scale);
402 endfor;
403 endchar;
404 endfor;
405 charlist current_char - 1: current_char;
406 endfor;
407
408 for alpha = 0, 180:
409 for sign = 1, -1:
410 for scale = 1, 1.8:
411 beginsymbol(scale * 6u# + if scale > 1: (sqrt scale) * 3/4line_thickness# else: scale * 3u# fi + 2side_bearing#, vcentre(scale * 1.6asc_height#)); "oriented contour integral";
412 if scale > 1:
413 italcorr scale * 3u# - (sqrt scale) * 3/4line_thickness#; % kerning between upper limit and lower limit
414 fi
415
416 pair centre;
417 centre := (side_bearing + scale * (4u + if alpha > 90: u else: 0 fi), (h - d)/2);
418
419 draw_integral(a)(scale, centre, line_thickness * sqrt sqrt scale);
420
421 thick := line_thickness * sqrt sqrt scale;
422 r := scale * 4u;
423
424 reg_poly_points(a)(8, z0a, r, alpha + 25);
425 reg_poly_points(b)(8, z0a, r - thick, alpha + 25);
426 z.a8 = z0a + r * dir alpha;
427 z.b8 = z0a + (r - thick) * dir alpha;
428
429 if sign > 0:
430 fill z.a0 .. z.a1 .. z.a2 .. z.a3 .. z.a4 .. z.a5 .. z.a6 .. z.a7 .. z.a8 -- z.b8 .. z.b7 .. z.b6 .. z.b5 .. z.b4 .. z.b3 .. z.b2 .. z.b1 .. z.b0 -- cycle;
431 draw_arrowhead(1/2[z.a8, z.b8], alpha + 75, 2/3scale * arrow_spread, 5/6thick);
432 else:
433 fill z.a8 .. z.a0 .. z.a1 .. z.a2 .. z.a3 .. z.a4 .. z.a5 .. z.a6 .. z.a7 -- z.b7 .. z.b6 .. z.b5 .. z.b4 .. z.b3 .. z.b2 .. z.b1 .. z.b0 .. z.b8 -- cycle;
434 draw_arrowhead(1/2[z.a8, z.b8], alpha - 75, 2/3scale * arrow_spread, 5/6thick);
435 fi
436 endchar;
437 endfor;
438 charlist current_char - 1: current_char;
439 endfor;
440 endfor;
441
442 for serifs = true, false:
443 for scale = 1, 1.8:
444 beginsymbol(scale * 13/2u# + if scale > 1: 0 else: scale * u# fi + 2side_bearing#, vcentre(scale * 1.6asc_height#)); "sum integral";
445 if scale > 1:
446 italcorr scale * u#; % kerning between upper limit and lower limit
447 fi
448
449 pair centre;
450 centre := (side_bearing + scale * 4u, (h - d)/2);
451
452 draw_integral(a)(scale, centre, line_thickness * sqrt sqrt scale);
453 draw_sum(b, 1/4[z0a.l,z0a.r], scale * 7u, scale * 3/4asc_height, 5/6line_thickness * sqrt sqrt scale, serifs);
454 endchar;
455 endfor;
456 charlist current_char - 1: current_char;
457 endfor;