Debian Codegraph @

texmf-dist/fonts/source/public/fdsymbol/fddelims.mf

raw
1 %
2 % Copyright (c) 2011-2025, Michael Ummels <[email protected]>
3 %
4 % This Font Software is licensed under the SIL Open Font License,
5 % Version 1.1. This license is in the accompanying file OFL.txt, and
6 % is also available with a FAQ at: http://scripts.sil.org/OFL
7 %
8
9 % thickness factor for delimiters
10 def dthick(expr scale) =
11 1
12 enddef;
13
14 % parenthesis
15
16 lparen_char = current_char + 1;
17 rparen_char = current_char + 7;
18 for sign = 1, -1:
19 for scale = 1, 1.1, 1.4, 1.8, 2.4, 3:
20 beginsymbol((2scale + 4.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "parenthesis";
21 draw_paren(sign, dthick(scale) * line_thickness);
22 endchar;
23 endfor;
24 endfor;
25
26 for sign = 1, -1:
27 beginsymbol((6 + 4.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(3delim_height#)); "parenthesis -- top";
28 thick := dthick(3) * line_thickness;
29
30 penpos1(thick, -90 + sign * 60);
31 penpos2(thick, 90 - sign * 90);
32 penpos2'(thick, 90 - sign * 90);
33
34 x1 = x2 + sign * (w - 2side_bearing - thick);
35 x2 = x2';
36 y1 = h;
37 y2 = -d + 1/2line_thickness;
38 y2' = -d - 1/2line_thickness;
39 1/2[x1r,x2l] = w/2;
40
41 fill stroke z2'.e -- z2e{up} .. {3(x1e - x2e), y1e - y2e}z1e;
42
43 penlabels(1,2,2');
44 endchar;
45 endfor;
46
47 for sign = 1, -1:
48 beginsymbol((6 + 4.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(3delim_height#)); "parenthesis -- bot";
49 thick := dthick(3) * line_thickness;
50
51 penpos0(thick, 90 - sign * 60);
52 penpos2(thick, 90 - sign * 90);
53 penpos2'(thick, 90 - sign * 90);
54
55 x0 = x2 + sign * (w - 2side_bearing - thick);
56 x2 = x2';
57 y2 = h - 1/2line_thickness;
58 y2' = h + 1/2line_thickness;
59 y0 = -d;
60 1/2[x0r,x2l] = w/2;
61
62 fill stroke z0e{3(x2e - x0e), y2e - y0e} .. {up}z2e -- z2'.e;
63
64 penlabels(1,2,2');
65 endchar;
66 endfor;
67
68 for sign = 1, -1:
69 beginsymbol((6 + 4.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "parenthesis -- module";
70 thick := dthick(3) * line_thickness;
71
72 penpos1(thick, 90 - sign * 45);
73 penpos2(thick, 90 - sign * 90);
74 penpos3(thick, 90 - sign * 90);
75
76 x2 = x3 = x1 - sign * (w - 2side_bearing - thick);
77 y2 = h + 1/2line_thickness;
78 y3 = -d - 1/2line_thickness;
79 1/2[x1r,x2l] = w/2;
80
81 fill stroke z2e -- z3e;
82 endchar;
83 endfor;
84
85 extensible current_char - 1: current_char - 5, 0, current_char - 3, current_char - 1; %left parenthesis
86 extensible current_char: current_char - 4, 0, current_char - 2, current_char; %right parenthesis
87
88 charlist lparen_char: lparen_char + 1: lparen_char + 2: lparen_char + 3: lparen_char + 4: lparen_char + 5: current_char - 1;
89 charlist rparen_char: rparen_char + 1: rparen_char + 2: rparen_char + 3: rparen_char + 4: rparen_char + 5: current_char;
90
91 % brackets
92
93 lsquare_char = current_char + 1;
94 rsquare_char = current_char + 7;
95 for sign = 1, -1:
96 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
97 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "square bracket";
98 draw_bracket(sign, dthick(scale) * line_thickness, true, true, true, false);
99 endchar;
100 endfor;
101 endfor;
102
103 lfloor_char = current_char + 1;
104 rfloor_char = current_char + 7;
105 for sign = 1, -1:
106 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
107 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "floor";
108 draw_bracket(sign, dthick(scale) * line_thickness, false, true, true, false);
109 endchar;
110 endfor;
111 endfor;
112
113 lceil_char = current_char + 1;
114 rceil_char = current_char + 7;
115 for sign = 1, -1:
116 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
117 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "ceiling";
118 draw_bracket(sign, dthick(scale) * line_thickness, true, true, false, false);
119 endchar;
120 endfor;
121 endfor;
122
123 ulcorner_char = current_char + 1;
124 urcorner_char = current_char + 7;
125 for sign = 1, -1:
126 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
127 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "upper corner";
128 draw_bracket(sign, dthick(scale) * line_thickness, true, false, false, false);
129 endchar;
130 endfor;
131 endfor;
132
133 charlist ulcorner_char: ulcorner_char + 1: ulcorner_char + 2: ulcorner_char + 3: ulcorner_char + 4: ulcorner_char + 5;
134 charlist urcorner_char: urcorner_char + 1: urcorner_char + 2: urcorner_char + 3: urcorner_char + 4: urcorner_char + 5;
135
136 llcorner_char = current_char + 1;
137 lrcorner_char = current_char + 7;
138 for sign = 1, -1:
139 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
140 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "lower corner";
141 draw_bracket(sign, dthick(scale) * line_thickness, false, false, true, false);
142 endchar;
143 endfor;
144 endfor;
145
146 charlist llcorner_char: llcorner_char + 1: llcorner_char + 2: llcorner_char + 3: llcorner_char + 4: llcorner_char + 5;
147 charlist lrcorner_char: lrcorner_char + 1: lrcorner_char + 2: lrcorner_char + 3: lrcorner_char + 4: lrcorner_char + 5;
148
149 ullcorner_char = current_char + 1;
150 ulrcorner_char = current_char + 7;
151 for sign = 1, -1:
152 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
153 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "upper/lower corner";
154 draw_bracket(sign, dthick(scale) * line_thickness, true, false, true, false);
155 endchar;
156 endfor;
157 endfor;
158
159 charlist ullcorner_char: ullcorner_char + 1: ullcorner_char + 2: ullcorner_char + 3: ullcorner_char + 4: ullcorner_char + 5;
160 charlist ulrcorner_char: ulrcorner_char + 1: ulrcorner_char + 2: ulrcorner_char + 3: ulrcorner_char + 4: ulrcorner_char + 5;
161
162 for sign = 1, -1:
163 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "square bracket -- top";
164 draw_bracket(sign, dthick(3) * line_thickness, true, true, false, false);
165 endchar;
166 endfor;
167
168 for sign = 1, -1:
169 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "square bracket -- bot";
170 draw_bracket(sign, dthick(3) * line_thickness, false, true, true, false);
171 endchar;
172 endfor;
173
174 for sign = 1, -1:
175 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "square bracket -- module";
176 draw_bracket(sign, dthick(3) * line_thickness, false, true, false, false);
177 endchar;
178 endfor;
179
180 extensible current_char - 1: current_char - 5, 0, current_char - 3, current_char - 1; %left square bracket
181 extensible current_char: current_char - 4, 0, current_char - 2, current_char; %right square bracket
182 extensible current_char - 3: 0, 0, current_char - 3, current_char - 1; %left floor
183 extensible current_char - 2: 0, 0, current_char - 2, current_char; %right floor
184 extensible current_char - 5: current_char - 5, 0, 0, current_char - 1; %left ceiling
185 extensible current_char - 4: current_char - 4, 0, 0, current_char; %right ceiling
186
187 charlist lsquare_char: lsquare_char + 1: lsquare_char + 2: lsquare_char + 3: lsquare_char + 4: lsquare_char + 5: current_char - 1;
188 charlist rsquare_char: rsquare_char + 1: rsquare_char + 2: rsquare_char + 3: rsquare_char + 4: rsquare_char + 5: current_char;
189 charlist lfloor_char: lfloor_char + 1: lfloor_char + 2: lfloor_char + 3: lfloor_char + 4: lfloor_char + 5: current_char - 3;
190 charlist rfloor_char: rfloor_char + 1: rfloor_char + 2: rfloor_char + 3: rfloor_char + 4: rfloor_char + 5: current_char - 2;
191 charlist lceil_char: lceil_char + 1: lceil_char + 2: lceil_char + 3: lceil_char + 4: lceil_char + 5: current_char - 5;
192 charlist rceil_char: rceil_char + 1: rceil_char + 2: rceil_char + 3: rceil_char + 4: rceil_char + 5: current_char - 4;
193
194 % semantic brackets
195
196 lsem_char = current_char + 1;
197 rsem_char = current_char + 7;
198 for sign = 1, -1:
199 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
200 beginsymbol((2scale + 4)/2 * u# + 2line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "semantic bracket";
201 draw_bracket(sign, dthick(scale) * line_thickness, true, true, true, true);
202 endchar;
203 endfor;
204 endfor;
205
206 for sign = 1, -1:
207 beginsymbol(5u# + 2line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "semantic bracket -- top";
208 draw_bracket(sign, dthick(3) * line_thickness, true, true, false, true);
209 endchar;
210 endfor;
211
212 for sign = 1, -1:
213 beginsymbol(5u# + 2line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "semantic bracket -- bot";
214 draw_bracket(sign, dthick(3) * line_thickness, false, true, true, true);
215 endchar;
216 endfor;
217
218 for sign = 1, -1:
219 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "semantic bracket -- module";
220 draw_bracket(sign, dthick(3) * line_thickness, false, true, false, true);
221 endchar;
222 endfor;
223
224 extensible current_char - 1: current_char - 5, 0, current_char - 3, current_char - 1; %left semantic bracket
225 extensible current_char: current_char - 4, 0, current_char - 2, current_char; %right semantic bracket
226
227 charlist lsem_char: lsem_char + 1: lsem_char + 2: lsem_char + 3: lsem_char + 4: lsem_char + 5: current_char - 1;
228 charlist rsem_char: rsem_char + 1: rsem_char + 2: rsem_char + 3: rsem_char + 4: rsem_char + 5: current_char;
229
230 % curly braces
231
232 lcurly_char = current_char + 1;
233 rcurly_char = current_char + 7;
234 for sign = 1, -1:
235 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
236 beginsymbol((2scale + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "curly brace";
237 thick := dthick(scale) * line_thickness;
238
239 draw_brace((w/2, (h-d)/2), h + d, w - 2side_bearing, 90 + sign * 90, thick, 0, 0, 0)
240 endchar;
241 endfor;
242 endfor;
243
244 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "curly brace -- top";
245 thick := dthick(3) * line_thickness;
246
247 draw_brace((w/2, h - 3delim_height), 6delim_height, w - 2side_bearing, 180, thick, 0, 0, h + d);
248 endchar;
249
250 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "curly brace -- top";
251 thick := dthick(3) * line_thickness;
252
253 draw_brace((w/2, h - 3delim_height), 6delim_height, w - 2side_bearing, 0, thick, h + d, 0, 0);
254 endchar;
255
256 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "curly brace -- bot";
257 thick := dthick(3) * line_thickness;
258
259 draw_brace((w/2, 3delim_height - d), 6delim_height, w - 2side_bearing, 180, thick, h + d, 0, 0)
260 endchar;
261
262 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "curly brace -- bot";
263 thick := dthick(3) * line_thickness;
264
265 draw_brace((w/2, 3delim_height - d), 6delim_height, w - 2side_bearing, 0, thick, 0, 0, h + d)
266 endchar;
267
268 for sign = 1, -1:
269 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "curly brace -- middle";
270 thick := dthick(3) * line_thickness;
271
272 draw_brace((w/2, (h-d)/2), 6delim_height, w - 2side_bearing, 90 + sign * 90, thick, 0, h + d, 0);
273 endchar;
274 endfor;
275
276 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "curly brace -- module";
277 thick := dthick(3) * line_thickness;
278
279 x2 = x3 = w/2;
280 y2 = h + 1/2line_thickness;
281 y3 = -d - 1/2line_thickness;
282
283 draw_straight(z2, z3, thick, false);
284 endchar;
285
286 extensible current_char - 6: current_char - 6, 0, current_char - 4, current_char; %sharp left parenthesis
287 extensible current_char - 5: current_char - 5, 0, current_char - 3, current_char; %sharp right parenthesis
288 extensible current_char - 3: current_char - 6, 0, current_char - 3, current_char; %left moustache
289 extensible current_char - 4: current_char - 5, 0, current_char - 4, current_char; %right moustache
290 extensible current_char - 2: current_char - 6, current_char - 2, current_char - 4, current_char; %left curly brace
291 extensible current_char - 1: current_char - 5, current_char - 1, current_char - 3, current_char; %right curly brace
292 extensible current_char: 0, 0, 0, current_char; %vertical line
293
294 charlist lcurly_char: lcurly_char + 1: lcurly_char + 2: lcurly_char + 3: lcurly_char + 4: lcurly_char + 5: current_char - 2;
295 charlist rcurly_char: rcurly_char + 1: rcurly_char + 2: rcurly_char + 3: rcurly_char + 4: rcurly_char + 5: current_char - 1;
296
297 % angle brackets
298
299 for sign = 1, -1:
300 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
301 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "angle bracket";
302 draw_angle(a, 0, sign, dthick(scale) * line_thickness);
303 endchar;
304 endfor;
305 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
306 endfor;
307
308 for sign = 1, -1:
309 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
310 beginsymbol((2scale + 8)/2 * u# + 2line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "double angle bracket";
311 thick := dthick(scale) * line_thickness;
312
313 draw_angle(a, -5/4thick, sign, thick);
314 draw_angle(b, 5/4thick, sign, thick);
315 endchar;
316 endfor;
317 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
318 endfor;
319
320 for sign = 1, -1:
321 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
322 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "angle bracket with dot";
323 thick := dthick(scale) * line_thickness;
324
325 draw_angle(a, 0, sign, thick);
326
327 if sign > 0:
328 x3 = w - side_bearing - 3/4dot_size;
329 else:
330 x3 = side_bearing + 3/4dot_size;
331 fi
332 y3 = 1/2(h - d);
333
334 fill dot(z3, 3/4dot_size);
335 endchar;
336 endfor;
337 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
338 endfor;
339
340 % slash
341
342 for sign = 1, -1:
343 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
344 beginsymbol(6scale * u# + line_thickness# + side_bearing#, vcentre(2scale * delim_height#)); "slash";
345 x1 - x0 = sign * (w - 2side_bearing - line_thickness);
346 y1 = h;
347 y0 = -d;
348 1/2[x0,x1] = w/2;
349
350 draw_line(z0, z1, false);
351 endchar;
352 endfor;
353 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
354 endfor;
355
356 % vertical bars
357
358 for negated = false, true:
359 for scale = 0.5, 1, 1.2:
360 beginsymbol(2u# + if negated: 2u# + floor scale * u# else: 0u# fi + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "vertical bar";
361 x0 = x1 = w/2;
362 y0 = h;
363 y1 = -d;
364
365 draw_line(z0, z1, false);
366
367 if negated:
368 if scale < 1: theta := 30; else: theta := 45; fi
369 len := 1/2(4u + floor scale * u) / cosd theta;
370
371 draw_straight(1/2[z0,z1] + len * dir theta, 1/2[z0,z1] - len * dir theta, stroke_through_thickness, true);
372 fi
373 endchar;
374 endfor;
375 endfor;
376
377 beginsymbol(2u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "vertical bar -- module";
378 x0 = x1 = w/2;
379 y0 = h + 1/2line_thickness;
380 y1 = -d - 1/2line_thickness;
381
382 draw_line(z0, z1, false);
383 endchar;
384
385 extensible current_char: 0, 0, 0, current_char; % vertical bar
386 charlist current_char - 5: current_char - 4: current_char;
387
388 for negated = false, true:
389 for scale = 0.5, 1, 1.2:
390 beginsymbol(5u# + if negated: 2u# + floor scale * u# else: 0u# fi + 2line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "double vertical bar";
391 x0 = x1;
392 x2 = x3;
393 1/2[x0,x2] = w/2;
394 x2 - x0 = 3u + line_thickness;
395 y0 = y2 = h;
396 y1 = y3 = -d;
397
398 draw_line(z0, z1, false);
399 draw_line(z2, z3, false);
400
401 if negated:
402 if scale < 1: theta := 30; else: theta := 45; fi
403 len := 1/2(7u + floor scale * u + line_thickness) / cosd theta;
404 pair centre;
405 centre := 1/2[1/2[z0,z1],1/2[z2,z3]];
406
407 draw_straight(centre + len * dir theta, centre - len * dir theta, stroke_through_thickness, true);
408 fi
409 endchar;
410 endfor;
411 endfor;
412
413 beginsymbol(5u# + 2line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "double vertical bar -- module";
414 x0 = x1;
415 x2 = x3;
416 1/2[x0,x2] = w/2;
417 x2 - x0 = 3u + line_thickness;
418 y0 = y2 = h + 1/2line_thickness;
419 y1 = y3 = -d - 1/2line_thickness;
420
421 draw_line(z0, z1, false);
422 draw_line(z2, z3, false);
423 endchar;
424
425 extensible current_char: 0, 0, 0, current_char; % double vertical line
426 charlist current_char - 5: current_char -4: current_char;
427
428 for scale = 1, 1.2:
429 beginsymbol(8u# + 3line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "triple vertical bar";
430 x0 = x1;
431 x2 = x3;
432 x4 = x5;
433 1/2[x0,x4] = w/2;
434 x2 - x0 = x4 - x2 = 3u + line_thickness;
435 y0 = y2 = y4 = h;
436 y1 = y3 = y5 = -d;
437
438 draw_line(z0, z1, false);
439 draw_line(z2, z3, false);
440 draw_line(z4, z5, false);
441 endchar;
442 endfor;
443
444 beginsymbol(8u# + 3line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "triple vertical bar -- module";
445 x0 = x1;
446 x2 = x3;
447 x4 = x5;
448 1/2[x0,x4] = w/2;
449 x2 - x0 = x4 - x2 = 3u + line_thickness;
450 y0 = y2 = y4 = h + 1/2line_thickness;
451 y1 = y3 = y5 = -d - 1/2line_thickness;
452
453 draw_line(z0, z1, false);
454 draw_line(z2, z3, false);
455 draw_line(z4, z5, false);
456 endchar;
457
458 extensible current_char: 0, 0, 0, current_char; % triple vertical line
459 charlist current_char - 2: current_char -1: current_char;
460
461 % Arrows
462
463 for arrow_dir = 90, 270:
464 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "arrow up/down";
465 pair foot, head;
466
467 if arrow_dir = 90:
468 head = (w/2, h - 1/2line_thickness);
469 foot = (w/2, -d);
470 else:
471 head = (w/2, -d + 1/2line_thickness);
472 foot = (w/2, h + 1/2line_thickness);
473 fi;
474
475 draw_line(foot, head, false);
476 draw_arrowhead(head, arrow_dir, arrow_spread, line_thickness);
477 endchar;
478 endfor;
479
480 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "arrow module";
481 z0 = (w/2, h);
482 z1 = (w/2, -d);
483
484 draw_line(z0, z1, true);
485 endchar;
486
487 extensible current_char-2: current_char-2, 0, current_char, current_char;
488 extensible current_char-1: current_char, 0, current_char-1, current_char;
489 extensible current_char: current_char-2, 0, current_char-1, current_char;
490
491 for arrow_dir = 90, 270:
492 beginsymbol(7u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "double arrow up/down";
493 pair foot, head;
494
495 if arrow_dir = 90:
496 head = (w/2, h - 1/2line_thickness);
497 foot = (w/2, -d - 1/2line_thickness);
498 else:
499 head = (w/2, -d + 1/2line_thickness);
500 foot = (w/2, h + 1/2line_thickness);
501 fi;
502
503 z1 - z0 = z3 - z2 = equal_spread * dir (arrow_dir + 90);
504 1/2[z0,z1] = foot;
505 1/2[z2,z3] = head;
506
507 draw_line(z0, arrowhead_intersection(head, arrow_dir, 13/10arrow_spread, z0 -- z2), false);
508 draw_line(z1, arrowhead_intersection(head, arrow_dir, 13/10arrow_spread, z1 -- z3), false);
509 draw_arrowhead(head, arrow_dir, 13/10arrow_spread, line_thickness);
510 endchar;
511 endfor;
512
513 beginsymbol(7u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "double arrow module";
514 z1 - z0 = z3 - z2 = equal_spread * right;
515 1/2[z0,z1] = (w/2, h);
516 1/2[z2,z3] = (w/2, -d);
517
518 draw_line(z0, z2, true);
519 draw_line(z1, z3, true);
520 endchar;
521
522 extensible current_char-2: current_char-2, 0, current_char, current_char;
523 extensible current_char-1: current_char, 0, current_char-1, current_char;
524 extensible current_char: current_char-2, 0, current_char-1, current_char;
525
526 % horizontal curly braces
527
528 beginsymbol(1/2delim_height#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- left";
529 draw_brace((3delim_height, (h-d)/2), 6delim_height, h + d, 90, line_thickness, w, 0, 0);
530 endchar;
531
532 beginsymbol(1/2delim_height#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- left";
533 draw_brace((3delim_height, (h-d)/2), 6delim_height, h + d, -90, line_thickness, 0, 0, w);
534 endchar;
535
536 beginsymbol(1/2delim_height#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- right";
537 draw_brace((w - 3delim_height, (h-d)/2), 6delim_height, h + d, 90, line_thickness, 0, 0, w);
538 endchar;
539
540 beginsymbol(1/2delim_height#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- right";
541 draw_brace((w - 3delim_height, (h-d)/2), 6delim_height, h + d, -90, line_thickness, w, 0, 0);
542 endchar;
543
544 for sign = 1, -1:
545 beginsymbol(delim_height#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- middle";
546 draw_brace((w/2, (h-d)/2), 6delim_height, h + d, sign * 90, line_thickness, 0, w, 0);
547 endchar;
548 endfor;
549
550 beginsymbol(u#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- module";
551 y2 = y3 = (h - d)/2;
552 x2 = -1/2line_thickness;
553 x3 = w + 1/2line_thickness;
554
555 draw_line(z2, z3, false);
556 endchar;
557
558 % roots
559
560 root_char = current_char + 1;
561
562 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
563 beginsymbol((4scale + 2) * u# + 5/2line_thickness# + 2side_bearing#, rule_thickness#, 2scale * delim_height# - rule_thickness#); "root";
564 draw_root(line_thickness);
565 endchar;
566 endfor;
567
568 beginsymbol(14u# + 5/2line_thickness# + 2side_bearing#, rule_thickness#, 1.2delim_height# - rule_thickness#); "root -- top";
569 draw_root_top(line_thickness);
570 endchar;
571
572 beginsymbol(14u# + 5/2line_thickness# + 2side_bearing#, 0, 2.4delim_height#); "root -- bottom";
573 draw_root_bot(line_thickness);
574 endchar;
575
576 beginsymbol(14u# + 5/2line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "root -- module";
577 x0 = x1 = 4/9w + 1/2line_thickness;
578 y0 = h;
579 y1 = -d;
580
581 draw_line(z0, z1, true);
582 endchar;
583
584 extensible current_char - 2: current_char - 2, 0, current_char - 1, current_char;
585 charlist root_char: root_char + 1: root_char + 2: root_char + 3: root_char + 4: root_char + 5: current_char - 2;
586
587 % more roots
588
589 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
590 beginsymbol((4scale + 2) * u# + 5/2line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "root";
591 draw_root(line_thickness);
592 endchar;
593 endfor;
594
595 beginsymbol(14u# + 5/2line_thickness# + 2side_bearing#, 1.2delim_height#, 0); "root -- top";
596 draw_root_top(line_thickness);
597 endchar;
598
599 beginsymbol(14u# + 5/2line_thickness# + 2side_bearing#, 2.4delim_height#, 0); "root -- bottom";
600 draw_root_bot(line_thickness);
601 endchar;