Debian Codegraph @

texmf-dist/fonts/source/public/fdsymbol/fdgeometric.mf

raw
1 %
2 % Copyright (c) 2011-2025, Michael Ummels <[email protected]>
3 %
4 % This Font Software is licensed under the SIL Open Font License,
5 % Version 1.1. This license is in the accompanying file OFL.txt, and
6 % is also available with a FAQ at: http://scripts.sil.org/OFL
7 %
8
9 beginsymbol(2dot_size# + 2side_bearing#, vcentre(2dot_size#)); "centre dot";
10 fill dot((w/2, (h-d)/2), dot_size);
11 endchar;
12
13 for alpha = 0, 90, 45, 135:
14 beginsymbol((4dot_size# + equal_spread#) * abs (cosd alpha) + 2dot_size# * abs (sind alpha) + 2side_bearing#, vcentre(2dot_size# * abs (cosd alpha) + (4dot_size# + equal_spread#) * abs (sind alpha))); "colon (" & decimal alpha & ")";
15 pair centre;
16 centre := (w/2, (h-d)/2);
17
18 z1 - z0 = (2dot_size + equal_spread) * dir alpha;
19 1/2[z0,z1] = centre;
20
21 fill dot(z0, dot_size);
22 fill dot(z1, dot_size);
23 endchar;
24 endfor;
25
26 for alpha = 0, 90, 45, 135:
27 beginsymbol((6dot_size# + 2equal_spread#) * abs (cosd alpha) + 2dot_size# * abs (sind alpha) + 2side_bearing#, vcentre(2dot_size# * abs (cosd alpha) + (6dot_size# + 2equal_spread#) * abs (sind alpha))); "triple colon (" & decimal alpha & ")";
28 pair centre;
29 centre := (w/2, (h-d)/2);
30
31 z1 - z0 = (2dot_size + equal_spread) * dir alpha;
32 z2 - z1 = (2dot_size + equal_spread) * dir alpha;
33 z1 = centre;
34
35 fill dot(z0, dot_size);
36 fill dot(z1, dot_size);
37 fill dot(z2, dot_size);
38 endchar;
39 endfor;
40
41 for alpha = 0, 90, 180, 270:
42 beginoperator(plus_size#, 1); "therefore (" & decimal alpha & ")";
43 r := 1/2plus_size - dot_size;
44 r := r * 1/3[1, sqrt 2];
45
46 z1 = z0 + r * dir alpha;
47 z2 = z0 + r * dir (alpha + 120);
48 z3 = z0 + r * dir (alpha + 240);
49
50 1/2[z1,1/2[z2,z3]] = centre;
51
52 fill dot(z1, dot_size);
53 fill dot(z2, dot_size);
54 fill dot(z3, dot_size);
55 endchar;
56 endfor;
57
58 beginoperator(plus_size#, 1); "double colon";
59 r := (1/2plus_size - dot_size) * sqrt(2);
60
61 fill dot(centre + r * dir 45, dot_size);
62 fill dot(centre + r * dir 135, dot_size);
63 fill dot(centre + r * dir 225, dot_size);
64 fill dot(centre + r * dir 315, dot_size);
65 endchar;
66
67 beginoperator(plus_size#, 1); "minus";
68 draw_line(centre + radius * right, centre + radius * left, true);
69 endchar;
70
71 beginoperator(plus_size#, 1); "medium slash";
72 draw_line(centre + 4/3radius * dir 45, centre + 4/3radius * dir 225, true);
73 endchar;
74
75 beginoperator(plus_size#, 1); "medium backslash";
76 draw_line(centre + 4/3radius * dir 135, centre + 4/3radius * dir 315, true);
77 endchar;
78
79 beginoperator(plus_size#, 1); "plus";
80 draw_line(centre + radius * right, centre + radius * left, true);
81 draw_line(centre + radius * up, centre + radius * down, true);
82 endchar;
83
84 beginoperator(plus_size#, 1); "times";
85 r := 4/3radius;
86
87 draw_line(centre + r * dir 45, centre + r * dir 225, true);
88 draw_line(centre + r * dir 135, centre + r * dir 315, true);
89 endchar;
90
91 for angle = 0, 180:
92 beginoperator(plus_size#, 1); "dot minus (" & decimal angle & ")";
93 draw_line(centre - radius * dir angle, centre + radius * dir angle, true);
94 fill dot(centre + equal_spread * dir (angle + 90), 3/4dot_size);
95 endchar;
96 endfor;
97
98 beginoperator(plus_size#, 1); "divide";
99 draw_line(centre + radius * right, centre + radius * left, true);
100 fill dot(centre + equal_spread * up, 3/4dot_size);
101 fill dot(centre + equal_spread * down, 3/4dot_size);
102 endchar;
103
104 for sign = 1, -1:
105 beginoperator(plus_size#, 1); "minus with two dots";
106 draw_line(centre + radius * right, centre + radius * left, true);
107 fill dot(centre + sign * (radius - 3/4dot_size) * left + equal_spread * up, 3/4dot_size);
108 fill dot(centre + sign * (radius - 3/4dot_size) * right + equal_spread * down, 3/4dot_size);
109 endchar;
110 endfor;
111
112 beginoperator(plus_size#, 1); "minus with four dots";
113 draw_line(centre + radius * right, centre + radius * left, true);
114 fill dot(centre + (radius - 3/4dot_size) * left + equal_spread * up, 3/4dot_size);
115 fill dot(centre + (radius - 3/4dot_size) * right + equal_spread * up, 3/4dot_size);
116 fill dot(centre + (radius - 3/4dot_size) * left + equal_spread * down, 3/4dot_size);
117 fill dot(centre + (radius - 3/4dot_size) * right + equal_spread * down, 3/4dot_size);
118 endchar;
119
120 for angle = 0, 180:
121 beginoperator(plus_size#, 1.25); "plus minus (" & decimal angle & ")";
122 centre := centre + 0.125plus_size * dir (angle + 90);
123 pair bt;
124 bt := centre + (radius + 0.25plus_size) * dir (angle - 90);
125
126 draw_line(centre + radius * right, centre + radius * left, true);
127 draw_line(centre + radius * up, centre + radius * down, true);
128 draw_line(bt + radius * right, bt + radius * left, true);
129 endchar;
130 endfor;
131
132 for angle = 0, 180:
133 beginoperator(plus_size#, 1.25); "dot plus (" & decimal angle & ")";
134 centre := centre + 0.125plus_size * dir (angle - 90);
135 pair tp;
136 tp := centre + (radius + 0.25plus_size) * dir (angle + 90);
137
138 draw_line(centre + radius * right, centre + radius * left, true);
139 draw_line(centre + radius * up, centre + radius * down, true);
140 fill dot(tp, 3/4dot_size);
141 endchar;
142 endfor;
143
144 beginoperator(plus_size#, 1.25); "dot times";
145 centre := centre + 0.125plus_size * down;
146 pair tp;
147 tp := centre + (radius + 0.2plus_size) * up;
148 r := 4/3radius;
149
150 draw_line(centre + r * dir 45, centre + r * dir 225, true);
151 draw_line(centre + r * dir 135, centre + r * dir 315, true);
152 fill dot(tp, 3/4dot_size);
153 endchar;
154
155 beginoperator(plus_size#, 1.25); "times bar";
156 centre := centre + 0.125plus_size * up;
157 pair bt;
158 bt := centre + (radius + 0.25plus_size) * down;
159 r := 4/3radius;
160
161 draw_line(centre + r * dir 45, centre + r * dir 225, true);
162 draw_line(centre + r * dir 135, centre + r * dir 315, true);
163 draw_line(bt + radius * right, bt + radius * left, true);
164 endchar;
165
166 beginoperator(plus_size#, 1); "divide on times";
167 r := 4/3radius;
168
169 draw_line(centre + radius * right, centre + radius * left, true);
170 draw_line(centre + r * dir 45, centre + r * dir 225, true);
171 draw_line(centre + r * dir 135, centre + r * dir 315, true);
172 fill dot(centre + equal_spread * up, 3/4dot_size);
173 fill dot(centre + equal_spread * down, 3/4dot_size);
174 endchar;
175
176 for sign = 1, -1:
177 beginoperator(plus_size#, 1); "logical not";
178 draw_line(centre + radius * left, centre + radius * right, true);
179 draw_line(centre + sign * radius * right, centre + sign * radius * right + equal_spread * down, true);
180 endchar;
181 endfor;
182
183 for sign = 1, -1:
184 beginoperator(plus_size#, 1); "upside down logical not";
185 draw_line(centre + radius * left, centre + radius * right, true);
186 draw_line(centre + sign * radius * right, centre + sign * radius * right + equal_spread * up, true);
187 endchar;
188 endfor;
189
190 for sign = -1, 1:
191 beginoperator(plus_size#, 1); "three times";
192 r := 4/3radius;
193
194 z0 = centre + r * dir (sign * 45);
195 z1 = centre + r * dir (sign * 225);
196 z2 = centre + r * dir (270 + sign * 45);
197 z3 = centre + 1/4line_thickness * dir (270 + sign * 45);
198
199 draw_line(z0, z1, true);
200 draw_line(z3, z2, true);
201 endchar;
202 endfor;
203
204 for alpha = 0, 90, 180, 270:
205 beginoperator(plus_size#, 1); "closed times (" & decimal alpha & ")";
206 thick := line_thickness;
207 r := 4/3radius;
208
209 z0 = centre + (r + 1/2line_thickness) * dir (alpha + 45);
210 z1 = centre + r * dir (alpha + 315);
211 z2 = centre + r * dir (alpha + 225);
212 z3 = centre + (r + 1/2line_thickness) * dir (alpha + 135);
213
214 penpos0(thick,alpha + 315);
215 penpos1(thick,alpha + 45);
216 penpos2(thick,alpha + 315);
217 penpos3(thick,alpha + 45);
218
219 z5 = z1r + whatever * dir (270 + alpha - 15);
220 z6 = z2l + whatever * dir (270 + alpha + 15);
221 z5 = whatever[z1r + thick * dir (270 + alpha), z2l + thick * dir (270 + alpha)];
222 z6 = whatever[z1r + thick * dir (270 + alpha), z2l + thick * dir (270 + alpha)];
223
224 fill stroke z0e -- z2e;
225 fill stroke z1e -- z3e;
226 fill z1r -- z5 -- z6 -- z2l -- cycle;
227
228 penlabels(0,1,2,3,5,6);
229 endchar;
230 endfor;
231
232 for alpha = 0, 90:
233 beginoperator(plus_size#, 1); "bowtie (" & decimal alpha & ")";
234 thick := line_thickness;
235 r := 4/3radius;
236
237 z0 = centre + r * dir (alpha + 135);
238 z1 = centre + r * dir (alpha + 45);
239 z2 = centre + r * dir (alpha + 315);
240 z3 = centre + r * dir (alpha + 225);
241
242 penpos0(thick,alpha + 45);
243 penpos1(thick,alpha + 135);
244 penpos2(thick,alpha + 45);
245 penpos3(thick,alpha + 135);
246
247 z4 = z0r + whatever * dir (180 + alpha + 15);
248 z5 = z1r + whatever * dir (alpha - 15);
249 z6 = z2l + whatever * dir (alpha + 15);
250 z7 = z3l + whatever * dir (180 + alpha - 15);
251 z4 = whatever[z0r + thick * dir (180 + alpha), z3l + thick * dir (180 + alpha)];
252 z5 = whatever[z1r + thick * dir alpha, z2l + thick * dir alpha];
253 z6 = whatever[z1r + thick * dir alpha, z2l + thick * dir alpha];
254 z7 = whatever[z0r + thick * dir (180 + alpha), z3l + thick * dir (180 + alpha)];
255
256 fill stroke z0e -- z2e;
257 fill stroke z1e -- z3e;
258 fill z1r -- z5 -- z6 -- z2l -- cycle;
259 fill z0r -- z4 -- z7 -- z3l -- cycle;
260
261 penlabels(0,1,2,3,4,5,6,7);
262 endchar;
263 endfor;
264
265 for alpha = 0, 90, 180, 270:
266 beginoperator(plus_size#, 1); "Y (" & decimal alpha & ")";
267 s := 1/15plus_size;
268
269 draw_line(centre - s * dir alpha, centre + radius * dir alpha, true);
270 draw_line(centre - s * dir alpha, centre - s * dir alpha + (radius + s) * dir (alpha + 135), true);
271 draw_line(centre - s * dir alpha, centre - s * dir alpha + (radius + s) * dir (alpha + 225), true);
272 endchar;
273 endfor;
274
275 % operators
276
277 for sign = 1, -1:
278 beginoperator(plus_size#, 1); "wedge";
279 draw_less(a, centre + sign * plus_size/2 * up, centre - sign * plus_size/2 * up, 2radius, line_thickness, false);
280 endchar;
281 endfor;
282
283 for sign = 1, -1:
284 beginoperator(plus_size#, 1); "wedge dot";
285 draw_less(a, centre + sign * plus_size/2 * up, centre - sign * plus_size/2 * up, 2radius, line_thickness, false);
286 fill dot(centre - sign * 1/3plus_size * up, 3/4dot_size);
287 endchar;
288 endfor;
289
290 for sign = 1, -1:
291 beginsymbol(13/9plus_size# + 2side_bearing#, vcentre(plus_size#)); "double wedge";
292 1/2[z0,z1] = (w/2, (h-d)/2);
293 z1 - z0 = 4/9plus_size * right;
294
295 draw_less(a, z0 + sign * plus_size/2 * up, z0 - sign * plus_size/2 * up, 2radius, line_thickness, false);
296 draw_less(b, z1 + sign * plus_size/2 * up, z1 - sign * plus_size/2 * up, 2radius, line_thickness, false);
297 endchar;
298 endfor;
299
300 for sign = 1, -1:
301 beginoperator(plus_size#, 1); "curly wedge";
302 draw_prec(a, centre + sign * plus_size/2 * up, centre - sign * plus_size/2 * up, 2radius, line_thickness, false);
303 endchar;
304 endfor;
305
306 for sign = 1, -1:
307 beginoperator(plus_size#, 1.25); "bar wedge";
308 centre := centre - sign * 0.125plus_size * up;
309 pair tp;
310 tp := centre + sign * (radius + 0.25plus_size) * up;
311
312 draw_less(a, centre + sign * plus_size/2 * up, centre - sign * plus_size/2 * up, 2radius, line_thickness, false);
313 draw_line(tp + radius * left, tp + radius * right, true);
314 endchar;
315 endfor;
316
317 for sign = 1, -1:
318 beginoperator(plus_size#, 1.5); "double bar wedge";
319 centre := centre - sign * 0.25plus_size * up;
320 pair tpa, tpb;
321 tpa := centre + sign * (radius + 0.25plus_size) * up;
322 tpb := centre + sign * (radius + 0.5plus_size) * up;
323
324 draw_less(a, centre + sign * plus_size/2 * up, centre - sign * plus_size/2 * up, 2radius, line_thickness, false);
325 draw_line(tpa + radius * left, tpa + radius * right, true);
326 draw_line(tpb + radius * left, tpb + radius * right, true);
327 endchar;
328 endfor;
329
330 for sign = 1, -1:
331 beginoperator(plus_size#, 1); "union";
332 draw_subset(a,centre - sign * plus_size/2 * up, centre + sign * plus_size/2 * up, 2radius, line_thickness);
333 endchar;
334 endfor;
335
336 for sign = 1, -1:
337 beginoperator(4/3plus_size#, 1); "double union";
338 draw_subset(a, centre - sign * 5/18plus_size * up, centre + sign * 2/3plus_size * up, 5/6radius, line_thickness);
339 draw_subset(b, centre - sign * 2/3plus_size * up, centre + sign * 2/3plus_size * up, 2radius, line_thickness);
340 endchar;
341 endfor;
342
343 for sign = 1, -1:
344 beginoperator(plus_size#, 1); "union dot";
345 draw_subset(a, centre - sign * plus_size/2 * up, centre + sign * plus_size/2 * up, 2radius, line_thickness);
346 fill dot(centre + sign * 1/6plus_size * up, 3/4dot_size);
347 endchar;
348 endfor;
349
350 for sign = 1, -1:
351 beginoperator(plus_size#, 1); "union plus";
352 draw_subset(a, centre - sign * plus_size/2 * up, centre + sign * plus_size/2 * up, 2radius, line_thickness);
353
354 r := 1/6plus_size;
355
356 draw_line(centre + sign * 1/6plus_size * up + r * right, centre + sign * 1/6plus_size * up + r * left, true);
357 draw_line(centre + (r + sign * 1/6plus_size) * up, centre + (r - sign * 1/6plus_size) * down, true);
358 endchar;
359 endfor;
360
361 for sign = 1, -1:
362 beginoperator(plus_size#, 1); "square union";
363 z3 - z0 = z2 - z1 = 2radius * right;
364 z0 - z1 = sign * 2radius * up;
365 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
366
367 draw_line(z0, z1, true);
368 draw_line(z1, z2, false);
369 draw_line(z2, z3, true);
370 endchar;
371 endfor;
372
373 for sign = 1, -1:
374 beginoperator(4/3plus_size#, 1); "double square union";
375 z3a - z0a = z2a - z1a = 2radius * right;
376 z0a - z1a = sign * 2radius * up;
377 1/2[1/2[z0a,z1a], 1/2[z2a,z3a]] = centre;
378 z3b - z0b = z2b - z1b = 5/9plus_size * right;
379 z0b - z1b = sign * 17/12radius * up;
380 y0b = y0a;
381 1/2[x0b, x3b] = xpart centre;
382
383 draw_line(z0a, z1a, true);
384 draw_line(z1a, z2a, false);
385 draw_line(z2a, z3a, true);
386 draw_line(z0b, z1b, true);
387 draw_line(z1b, z2b, false);
388 draw_line(z2b, z3b, true);
389 endchar;
390 endfor;
391
392 for sign = 1, -1:
393 beginoperator(plus_size#, 1); "square union dot";
394 z3 - z0 = z2 - z1 = 2radius * right;
395 z0 - z1 = sign * 2radius * up;
396 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
397
398 draw_line(z0, z1, true);
399 draw_line(z1, z2, false);
400 draw_line(z2, z3, true);
401 fill dot(centre + sign * 1/6plus_size * up, 3/4dot_size);
402 endchar;
403 endfor;
404
405 for sign = 1, -1:
406 beginoperator(plus_size#, 1); "square union plus";
407 z3 - z0 = z2 - z1 = 2radius * right;
408 z0 - z1 = sign * 2radius * up;
409 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
410
411 draw_line(z0, z1, true);
412 draw_line(z1, z2, false);
413 draw_line(z2, z3, true);
414
415 r := 1/6plus_size;
416
417 draw_line(centre + sign * 1/6plus_size * up + r * right, centre + sign * 1/6plus_size * up + r * left, true);
418 draw_line(centre + (r + sign * 1/6plus_size) * up, centre + (r - sign * 1/6plus_size) * down, true);
419 endchar;
420 endfor;
421
422 for alpha = 0, 180:
423 beginoperator(plus_size#, 1); "corner with dot";
424 z3 - z0 = z2 - z1 = 2radius * dir alpha;
425 z0 - z1 = 2radius * dir (alpha + 90);
426 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
427
428 draw_line(z1, z2, true);
429 draw_line(z2, z3, true);
430 fill dot(centre, 3/4dot_size);
431 endchar;
432 endfor;
433
434 % triangles
435
436 for alpha = 0, 90, 180, 270:
437 beginsymbol((3/4small_op_size# + 3/2line_thickness#) * abs(cosd alpha) + sqrt(3) * (small_op_size#/2 + line_thickness#) * abs(sind alpha) + 2side_bearing#, vcentre(sqrt(3) * (small_op_size#/2 + line_thickness#) * abs(cosd alpha) + (3/4small_op_size# + 3/2line_thickness#) * abs(sind alpha))); "small triangle (" & decimal alpha & ")";
438 thick := line_thickness;
439 radius := small_op_size/2;
440 centre := (w/2, (h - d)/2) - 1/4(radius + thick) * dir alpha;
441
442 draw_triangle(a, centre, radius, alpha, thick);
443 endchar;
444 endfor;
445
446 for alpha = 0, 90, 180, 270:
447 beginsymbol((3/4small_op_size# + 3/2line_thickness#) * abs(cosd alpha) + sqrt(3) * (small_op_size#/2 + line_thickness#) * abs(sind alpha) + 2side_bearing#, vcentre(sqrt(3) * (small_op_size#/2 + line_thickness#) * abs(cosd alpha) + (3/4small_op_size# + 3/2line_thickness#) * abs(sind alpha))); "small filled triangle (" & decimal alpha & ")";
448 thick := line_thickness;
449 radius := small_op_size/2;
450 centre := (w/2, (h - d)/2) - 1/4(radius + thick) * dir alpha;
451
452 filldraw_triangle(a, centre, radius, alpha, thick);
453 endchar;
454 endfor;
455
456 for alpha = 0, 90, 180, 270:
457 beginsymbol((3/4med_op_size# + 3/2line_thickness#) * abs(cosd alpha) + sqrt(3) * (med_op_size#/2 + line_thickness#) * abs(sind alpha) + 2side_bearing#, vcentre(sqrt(3) * (med_op_size#/2 + line_thickness#) * abs(cosd alpha) + (3/4med_op_size# + 3/2line_thickness#) * abs(sind alpha))); "medium triangle (" & decimal alpha & ")";
458 thick := line_thickness;
459 radius := med_op_size/2;
460 centre := (w/2, (h - d)/2) - 1/4(radius + thick) * dir alpha;
461
462 draw_triangle(a, centre, radius, alpha, thick);
463 endchar;
464 endfor;
465
466 for alpha = 0, 90, 180, 270:
467 beginsymbol((3/4med_op_size# + 3/2line_thickness#) * abs(cosd alpha) + sqrt(3) * (med_op_size#/2 + line_thickness#) * abs(sind alpha) + 2side_bearing#, vcentre(sqrt(3) * (med_op_size#/2 + line_thickness#) * abs(cosd alpha) + (3/4med_op_size# + 3/2line_thickness#) * abs(sind alpha))); "medium filled triangle (" & decimal alpha & ")";
468 thick := line_thickness;
469 radius := med_op_size/2;
470 centre := (w/2, (h - d)/2) - 1/4(radius + thick) * dir alpha;
471
472 filldraw_triangle(a, centre, radius, alpha, thick);
473 endchar;
474 endfor;
475
476 for alpha = 90, 270:
477 beginsymbol(sqrt(3) * (large_op_size#/2 + line_thickness#) + 2side_bearing#, vcentre(3/4large_op_size# + 3/2line_thickness#)); "large triangle (" & decimal alpha & ")";
478 thick := line_thickness;
479 radius := large_op_size/2;
480 centre := (w/2, (h - d)/2) - 1/4(radius + thick) * dir alpha;
481
482 draw_triangle(a, centre, radius, alpha, thick);
483 endchar;
484 endfor;
485
486 % circles
487
488 beginoperator(4/5small_op_size#, 1); "small circle";
489 draw_circle(centre, radius, line_thickness);
490 endchar;
491
492 beginoperator(4/5small_op_size#, 1); "small filled circle";
493 filldraw_circle(centre, radius, line_thickness);
494 endchar;
495
496 beginoperator(4/5med_op_size#, 1); "medium circle";
497 draw_circle(centre, radius, line_thickness);
498 endchar;
499
500 beginoperator(4/5med_op_size#, 1); "medium filled circle";
501 filldraw_circle(centre, radius, line_thickness);
502 endchar;
503
504 beginoperator(4/5med_op_size#, 1); "medium circle minus";
505 draw_circle(centre, radius, line_thickness);
506 draw_line(centre + radius * left, centre + radius * right, false);
507 endchar;
508
509 beginoperator(4/5med_op_size#, 1); "medium circle bar";
510 draw_circle(centre, radius, line_thickness);
511 draw_line(centre + radius * up, centre + radius * down, false);
512 endchar;
513
514 beginoperator(4/5med_op_size#, 1); "medium circle slash";
515 draw_circle(centre, radius, line_thickness);
516 draw_line(centre + radius * dir 45, centre + radius * dir 225, false);
517 endchar;
518
519 beginoperator(4/5med_op_size#, 1); "medium circle backslash";
520 draw_circle(centre, radius, line_thickness);
521 draw_line(centre + radius * dir 135, centre + radius * dir 315, false);
522 endchar;
523
524 beginoperator(4/5med_op_size#, 1); "medium circle plus";
525 draw_circle(centre, radius, line_thickness);
526 draw_line(centre + radius * left, centre + radius * right, false);
527 draw_line(centre + radius * up, centre + radius * down, false);
528 endchar;
529
530 beginoperator(4/5med_op_size#, 1); "medium circle times";
531 draw_circle(centre, radius, line_thickness);
532 draw_line(centre + radius * dir 45, centre + radius * dir 225, false);
533 draw_line(centre + radius * dir 135, centre + radius * dir 315, false);
534 endchar;
535
536 beginoperator(4/5med_op_size#, 1); "medium circle dot";
537 draw_circle(centre, radius, line_thickness);
538 fill dot(centre, dot_size);
539 endchar;
540
541 beginoperator(4/5med_op_size#, 1); "medium circle circle";
542 draw_circle(centre, radius, line_thickness);
543 draw_circle(centre, 2/5radius, line_thickness);
544 endchar;
545
546 beginoperator(4/5med_op_size#, 1); "medium circle asterisk";
547 thick := line_thickness;
548
549 draw_circle(centre, radius, thick);
550
551 penpos a0(4/3thick, 0);
552 penpos a1(4/3thick, 60);
553 penpos a2(4/3thick, 120);
554 penpos a3(4/3thick, 180);
555 penpos a4(4/3thick, 240);
556 penpos a5(4/3thick, 300);
557
558 penpos b0(2/3thick, 0);
559 penpos b1(2/3thick, 60);
560 penpos b2(2/3thick, 120);
561 penpos b3(2/3thick, 180);
562 penpos b4(2/3thick, 240);
563 penpos b5(2/3thick, 300);
564
565 reg_poly_points(a)(6, centre, radius, 90);
566
567 z.b0 = z.b1 = z.b2 = z.b3 = z.b4 = z.b5 = centre;
568
569 fill stroke z.a0e -- z.b0e;
570 fill stroke z.a1e -- z.b1e;
571 fill stroke z.a2e -- z.b2e;
572 fill stroke z.a3e -- z.b3e;
573 fill stroke z.a4e -- z.b4e;
574 fill stroke z.a5e -- z.b5e;
575 endchar;
576
577 beginoperator(4/5med_op_size#, 1); "medium circle dash";
578 draw_circle(centre, radius, line_thickness);
579 draw_line(centre + 2/3radius * left, centre + 2/3radius * right, false);
580 endchar;
581
582 beginoperator(4/5med_op_size#, 1); "medium circle equal";
583 draw_circle(centre, radius, line_thickness);
584 draw_line(centre + 2/5equal_spread * up + 2/3radius * left, centre + 2/5equal_spread * up + 2/3radius * right, false);
585 draw_line(centre + 2/5equal_spread * down + 2/3radius * left, centre + 2/5equal_spread * down + 2/3radius * right, false);
586 endchar;
587
588 for sign = 1,-1:
589 beginoperator(4/5med_op_size#, 1); "negated medium circle";
590 r := 4/3radius;
591
592 draw_circle(centre, radius, line_thickness);
593 draw_line(centre + r * dir (sign * 45), centre + r * dir (sign * 225), true);
594 endchar;
595 endfor;
596
597 beginoperator(4/5large_op_size#, 1); "large circle";
598 draw_circle(centre, radius, line_thickness);
599 endchar;
600
601 beginoperator(4/5large_op_size#, 1); "large filled circle";
602 filldraw_circle(centre, radius, line_thickness);
603 endchar;
604
605 % squares
606
607 beginoperator(small_op_size#/sqrt(2), 1); "small square";
608 draw_square(centre, radius, 0, line_thickness);
609 endchar;
610
611 beginoperator(small_op_size#/sqrt(2), 1); "small filled square";
612 filldraw_square(centre, radius, 0, line_thickness);
613 endchar;
614
615 beginoperator(med_op_size#/sqrt(2), 1); "medium square";
616 draw_square(centre, radius, 0, line_thickness);
617 endchar;
618
619 beginoperator(med_op_size#/sqrt(2), 1); "medium filled square";
620 filldraw_square(centre, radius, 0, line_thickness);
621 endchar;
622
623 beginoperator(med_op_size#/sqrt(2), 1); "medium square minus";
624 draw_square(centre, radius, 0, line_thickness);
625 draw_line(centre + radius * right, centre + radius * left, false);
626 endchar;
627
628 beginoperator(med_op_size#/sqrt(2), 1); "medium square vert";
629 draw_square(centre, radius, 0, line_thickness);
630 draw_line(centre + radius * up, centre + radius * down, false);
631 endchar;
632
633 beginoperator(med_op_size#/sqrt(2), 1); "medium square slash";
634 r := radius * sqrt(2);
635
636 draw_square(centre, radius, 0, line_thickness);
637 draw_line(centre + r * dir 45, centre + r * dir 225, false);
638 endchar;
639
640 beginoperator(med_op_size#/sqrt(2), 1); "medium square backslash";
641 r := radius * sqrt(2);
642
643 draw_square(centre, radius, 0, line_thickness);
644 draw_line(centre + r * dir 135, centre + r * dir 315, false);
645 endchar;
646
647 beginoperator(med_op_size#/sqrt(2), 1); "medium square plus";
648 draw_square(centre, radius, 0, line_thickness);
649 draw_line(centre + radius * right, centre + radius * left, false);
650 draw_line(centre + radius * up, centre + radius * down, false);
651 endchar;
652
653 beginoperator(med_op_size#/sqrt(2), 1); "medium square times";
654 r := radius * sqrt(2);
655
656 draw_square(centre, radius, 0, line_thickness);
657 draw_line(centre + r * dir 45, centre + r * dir 225, false);
658 draw_line(centre + r * dir 135, centre + r * dir 315, false);
659 endchar;
660
661 beginoperator(med_op_size#/sqrt(2), 1); "medium square dot";
662 draw_square(centre, radius, 0, line_thickness);
663 fill dot(centre, dot_size);
664 endchar;
665
666 beginoperator(med_op_size#/sqrt(2), 1); "medium square square";
667 draw_square(centre, radius, 0, line_thickness);
668 draw_square(centre, 2/5radius, 0, 4/5line_thickness);
669 endchar;
670
671 beginoperator(large_op_size#/sqrt(2), 1); "large square";
672 draw_square(centre, radius, 0, line_thickness);
673 endchar;
674
675 beginoperator(large_op_size#/sqrt(2), 1); "large filled square";
676 filldraw_square(centre, radius, 0, line_thickness);
677 endchar;
678
679 beginoperator(small_op_size#, 1); "small diamond";
680 draw_square(centre, radius / sqrt(2), 45, line_thickness);
681 endchar;
682
683 beginoperator(small_op_size#, 1); "small filled diamond";
684 filldraw_square(centre, radius / sqrt(2), 45, line_thickness);
685 endchar;
686
687 beginoperator(med_op_size#, 1); "medium diamond";
688 draw_square(centre, radius / sqrt(2), 45, line_thickness);
689 endchar;
690
691 beginoperator(med_op_size#, 1); "medium filled diamond";
692 filldraw_square(centre, radius / sqrt(2), 45, line_thickness);
693 endchar;
694
695 beginoperator(med_op_size#, 1); "medium diamond minus";
696 draw_square(centre, radius / sqrt(2), 45, line_thickness);
697 draw_line(centre + radius * right, centre + radius * left, false);
698 endchar;
699
700 beginoperator(med_op_size#, 1); "medium diamond vert";
701 draw_square(centre, radius / sqrt(2), 45, line_thickness);
702 draw_line(centre + radius * up, centre + radius * down, false);
703 endchar;
704
705 beginoperator(med_op_size#, 1); "medium diamond slash";
706 r := radius / sqrt(2);
707
708 draw_square(centre, r, 45, line_thickness);
709 draw_line(centre + r * dir 45, centre + r * dir 225, false);
710 endchar;
711
712 beginoperator(med_op_size#, 1); "medium diamond backslash";
713 r := radius / sqrt(2);
714
715 draw_square(centre, r, 45, line_thickness);
716 draw_line(centre + r * dir 135, centre + r * dir 315, false);
717 endchar;
718
719 beginoperator(med_op_size#, 1); "medium diamond plus";
720 draw_square(centre, radius / sqrt(2), 45, line_thickness);
721 draw_line(centre + radius * right, centre + radius * left, false);
722 draw_line(centre + radius * up, centre + radius * down, false);
723 endchar;
724
725 beginoperator(med_op_size#, 1); "medium diamond times";
726 r := radius / sqrt(2);
727
728 draw_square(centre, r, 45, line_thickness);
729 draw_line(centre + r * dir 45, centre + r * dir 225, false);
730 draw_line(centre + r * dir 135, centre + r * dir 315, false);
731 endchar;
732
733 beginoperator(med_op_size#, 1); "medium diamond dot";
734 draw_square(centre, radius / sqrt(2), 45, line_thickness);
735 fill dot(centre, dot_size);
736 endchar;
737
738 beginoperator(med_op_size#, 1); "medium diamond diamond";
739 draw_square(centre, radius / sqrt(2), 45, line_thickness);
740 draw_square(centre, 2/5radius / sqrt(2), 45, 4/5line_thickness);
741 endchar;
742
743 beginoperator(5/6small_op_size#, 8/5); "small lozenge";
744 x0 = w - x2 = side_bearing;
745 y0 = y2 = ypart centre;
746 x1 = x3 = xpart centre;
747 y1 = h;
748 y3 = -d;
749
750 theta := angle(z1 - z0);
751
752 x0' = x0 + line_thickness / sind theta;
753 x2' = x2 - line_thickness / sind theta;
754 y0' = y2' = y0;
755 y1' = y1 - line_thickness / cosd theta;
756 y3' = y3 + line_thickness / cosd theta;
757 x1' = x3' = x1;
758
759 fill z0 -- z1 -- z2 -- z3 -- cycle;
760 unfill z0' -- z1' -- z2' -- z3' -- cycle;
761 endchar;
762
763 beginoperator(5/6small_op_size#, 8/5); "small filled lozenge";
764 x0 = w - x2 = side_bearing;
765 y0 = y2 = ypart centre;
766 x1 = x3 = xpart centre;
767 y1 = h;
768 y3 = -d;
769
770 fill z0 -- z1 -- z2 -- z3 -- cycle;
771 endchar;
772
773 beginoperator(1/sqrt(2)*med_op_size#, 8/5); "medium lozenge";
774 x0 = w - x2 = side_bearing;
775 y0 = y2 = ypart centre;
776 x1 = x3 = xpart centre;
777 y1 = h;
778 y3 = -d;
779
780 theta := angle(z1 - z0);
781
782 x0' = x0 + line_thickness / sind theta;
783 x2' = x2 - line_thickness / sind theta;
784 y0' = y2' = y0;
785 y1' = y1 - line_thickness / cosd theta;
786 y3' = y3 + line_thickness / cosd theta;
787 x1' = x3' = x1;
788
789 fill z0 -- z1 -- z2 -- z3 -- cycle;
790 unfill z0' -- z1' -- z2' -- z3' -- cycle;
791 endchar;
792
793 beginoperator(1/sqrt(2)*med_op_size#, 8/5); "medium filled lozenge";
794 x0 = w - x2 = side_bearing;
795 y0 = y2 = ypart centre;
796 x1 = x3 = xpart centre;
797 y1 = h;
798 y3 = -d;
799
800 fill z0 -- z1 -- z2 -- z3 -- cycle;
801 endchar;
802
803 beginoperator(1/sqrt(2)*med_op_size#, 8/5); "medium lozenge minus";
804 thick := line_thickness;
805
806 x0 = w - x2 = side_bearing;
807 y0 = y2 = ypart centre;
808 x1 = x3 = xpart centre;
809 y1 = h;
810 y3 = -d;
811
812 theta := angle(z1 - z0);
813
814 x0' = x0 + thick / sind theta;
815 x2' = x2 - thick / sind theta;
816 y0' = y2' = y0;
817 y1' = y1 - thick / cosd theta;
818 y3' = y3 + thick / cosd theta;
819 x1' = x3' = x1;
820
821 fill z0 -- z1 -- z2 -- z3 -- cycle;
822 unfill z0' -- z1' -- z2' -- z3' -- cycle;
823 draw_line(z0', z2', true);
824 endchar;
825
826 beginoperator(5/4small_op_size#, 1); "small star";
827 r := radius + line_thickness;
828 t := 1/11r;
829
830 reg_poly_points(a)(5, centre - t * up, r, 90);
831 reg_poly_points(b)(5, centre - t * up, .4r, 126);
832
833 s := r - 4/5line_thickness / sind (270 - angle (z.b0 - z.a0));
834
835 reg_poly_points(c)(5, centre - t * up, s, 90);
836 reg_poly_points(d)(5, centre - t * up, .4s, 126);
837
838 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
839 unfill z.c0 -- z.d0 -- z.c1 -- z.d1 -- z.c2 -- z.d2 -- z.c3 -- z.d3 -- z.c4 -- z.d4 -- cycle;
840 endchar;
841
842 beginoperator(small_op_size#, 1); "small filled star";
843 r := radius + line_thickness;
844 t := 1/11r;
845
846 reg_poly_points(a)(5, centre - t * up, r, 90);
847 reg_poly_points(b)(5, centre - t * up, .4r, 126);
848
849 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
850 endchar;
851
852 beginoperator(med_op_size#, 1); "medium star";
853 r := radius + line_thickness;
854 t := 1/11r;
855
856 reg_poly_points(a)(5, centre - t * up, r, 90);
857 reg_poly_points(b)(5, centre - t * up, .4r, 126);
858
859 s := r - line_thickness / sind (270 - angle (z.b0 - z.a0));
860
861 reg_poly_points(c)(5, centre - t * up, s, 90);
862 reg_poly_points(d)(5, centre - t * up, .4s, 126);
863
864 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
865 unfill z.c0 -- z.d0 -- z.c1 -- z.d1 -- z.c2 -- z.d2 -- z.c3 -- z.d3 -- z.c4 -- z.d4 -- cycle;
866 endchar;
867
868 beginoperator(med_op_size#, 1); "medium filled star";
869 r := radius + line_thickness;
870 t := 1/11r;
871
872 reg_poly_points(a)(5, centre - t * up, r, 90);
873 reg_poly_points(b)(5, centre - t * up, .4r, 126);
874
875 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
876 endchar;
877
878 beginoperator(large_op_size#, 1); "large star";
879 r := radius + line_thickness;
880 t := 1/11r;
881
882 reg_poly_points(a)(5, centre - t * up, r, 90);
883 reg_poly_points(b)(5, centre - t * up, .4r, 126);
884
885 s := r - line_thickness / sind (270 - angle (z.b0 - z.a0));
886
887 reg_poly_points(c)(5, centre - t * up, s, 90);
888 reg_poly_points(d)(5, centre - t * up, .4s, 126);
889
890 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
891 unfill z.c0 -- z.d0 -- z.c1 -- z.d1 -- z.c2 -- z.d2 -- z.c3 -- z.d3 -- z.c4 -- z.d4 -- cycle;
892 endchar;
893
894 beginoperator(large_op_size#, 1); "large filled star";
895 r := radius + line_thickness;
896 t := 1/11r;
897
898 reg_poly_points(a)(5, centre - t * up, r, 90);
899 reg_poly_points(b)(5, centre - t * up, .4r, 126);
900
901 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
902 endchar;
903
904 beginoperator(small_op_size#, 1); "asterisk";
905 r := w/2 - side_bearing;
906
907 penpos a0(4/3line_thickness, 0);
908 penpos a1(4/3line_thickness, 60);
909 penpos a2(4/3line_thickness, 120);
910 penpos a3(4/3line_thickness, 180);
911 penpos a4(4/3line_thickness, 240);
912 penpos a5(4/3line_thickness, 300);
913
914 penpos b0(2/3line_thickness, 0);
915 penpos b1(2/3line_thickness, 60);
916 penpos b2(2/3line_thickness, 120);
917 penpos b3(2/3line_thickness, 180);
918 penpos b4(2/3line_thickness, 240);
919 penpos b5(2/3line_thickness, 300);
920
921 reg_poly_points(a)(6, centre, r, 90);
922
923 z.b0 = z.b1 = z.b2 = z.b3 = z.b4 = z.b5 = centre;
924
925 fill stroke z.a0e -- z.b0e;
926 fill stroke z.a1e -- z.b1e;
927 fill stroke z.a2e -- z.b2e;
928 fill stroke z.a3e -- z.b3e;
929 fill stroke z.a4e -- z.b4e;
930 fill stroke z.a5e -- z.b5e;
931 endchar;
932
933 beginsymbol(18/10order_width# + 2side_bearing#, vcentre(2equal_spread# + line_thickness#)); "infinity";
934 pair centre;
935 centre := (w/2, (h-d)/2);
936 thick := line_thickness;
937 alpha := 0;
938
939 z0 = centre - (9/10order_width - 1/2thick) * dir alpha;
940 z1 = centre + (9/10order_width - 1/2thick) * dir alpha;
941 z6 = 1/5[z0,z1];
942 z7 = 4/5[z0,z1];
943 z2 = z6 + equal_spread * dir (alpha + 90);
944 z3 = z6 - equal_spread * dir (alpha + 90);
945 z4 = z7 + equal_spread * dir (alpha + 90);
946 z5 = z7 - equal_spread * dir (alpha + 90);
947 z8 = z9 = centre;
948
949 penpos0(thick, alpha);
950 penpos1(thick, alpha);
951 penpos2(thick, alpha - 90);
952 penpos3(thick, alpha + 90);
953 penpos4(thick, alpha + 90);
954 penpos5(thick, alpha - 90);
955 penpos8(thick, alpha - 135);
956 penpos9(thick, alpha + 135);
957
958 fill stroke z4.e{dir (alpha + 180)}
959 .. {dir (alpha + 225)}z9.e
960 .. {dir (alpha + 180)}z3.e
961 .. {dir (alpha + 90)}z0.e
962 .. {dir alpha}z2.e
963 .. {dir (alpha - 45)}z8.e
964 .. {dir alpha}z5.e
965 .. {dir (alpha + 90)}z1.e
966 .. cycle;
967
968 penlabels (0,1,2,3,4,5,6,7,8,9);
969 endchar;
970
971 for alpha = 0, 180:
972 beginsymbol(16/10order_width# + 2side_bearing#, vcentre(2equal_spread# + line_thickness#)); "proportional";
973 pair centre;
974 centre := (w/2, (h-d)/2);
975 thick := line_thickness;
976
977 z0 = centre - (8/10order_width - 1/2thick) * dir alpha;
978 z1 = centre + (7/10order_width - 1/2thick) * dir alpha;
979 z4 = z1 + equal_spread * dir (alpha + 90);
980 z5 = z1 - equal_spread * dir (alpha + 90);
981 z6 - z4 = z7 - z5 = (1/10order_width + 1/2thick) * dir alpha;
982 z10 = 1/4[z0,z1];
983 z2 = z10 + equal_spread * dir (alpha + 90);
984 z3 = z10 - equal_spread * dir (alpha + 90);
985 z8 = z9 = centre + 1/10order_width * dir alpha;
986
987 penpos0(thick, alpha);
988 penpos2(thick, alpha - 90);
989 penpos3(thick, alpha + 90);
990 penpos4(thick, alpha + 90);
991 penpos5(thick, alpha - 90);
992 penpos6(thick, alpha + 90);
993 penpos7(thick, alpha - 90);
994 penpos8(thick, alpha + 225);
995 penpos9(thick, alpha + 135);
996
997 fill stroke z6.e
998 -- z4.e{dir (alpha + 180)}
999 .. {dir (alpha + 225)}z9.e
1000 .. {dir (alpha + 180)}z3.e
1001 .. {dir (alpha + 90)}z0.e
1002 .. {dir alpha}z2.e
1003 .. {dir (alpha - 45)}z8.e
1004 .. {dir alpha}z5.e
1005 -- z7.e;
1006
1007 penlabels (0,1,2,3,4,5,6,7,8,9);
1008 endchar;
1009 endfor;
1010
1011 beginsymbol(14/10order_width# + 2side_bearing#, vcentre(2equal_spread# + line_thickness#)); "crossing";
1012 pair centre;
1013 centre := (w/2, (h-d)/2);
1014 thick := line_thickness;
1015 alpha := 0;
1016
1017 z0 = centre - (6/10order_width - 1/2thick) * dir alpha;
1018 z1 = centre + (6/10order_width - 1/2thick) * dir alpha;
1019 z2 = z0 + equal_spread * dir (alpha + 90);
1020 z3 = z0 - equal_spread * dir (alpha + 90);
1021 z4 = z1 + equal_spread * dir (alpha + 90);
1022 z5 = z1 - equal_spread * dir (alpha + 90);
1023 z6 - z4 = z7 - z5 = (1/10order_width + 1/2thick) * dir alpha;
1024 z2 - z8 = z3 - z9 = (1/10order_width + 1/2thick) * dir alpha;
1025 z10 = z11 = 1/2[z0,z1];
1026
1027 penpos2(thick, alpha + 90);
1028 penpos3(thick, alpha + 90);
1029 penpos4(thick, alpha + 90);
1030 penpos5(thick, alpha + 90);
1031 penpos6(thick, alpha + 90);
1032 penpos7(thick, alpha + 90);
1033 penpos8(thick, alpha + 90);
1034 penpos9(thick, alpha + 90);
1035 penpos10(thick, alpha + 45);
1036 penpos11(thick, alpha + 135);
1037
1038 fill stroke z6.e
1039 -- z4.e{dir (alpha + 180)}
1040 .. {dir (alpha + 225)}z11.e
1041 .. {dir (alpha + 180)}z3.e
1042 -- z9.e;
1043 fill stroke z8.e
1044 -- z2.e{dir alpha}
1045 .. {dir (alpha - 45)}z10.e
1046 .. {dir alpha}z5.e
1047 -- z7.e;
1048
1049 penlabels (0,1,2,3,4,5,6,7,8,9,10,11);
1050 endchar;
1051
1052 beginsymbol(equal_spread# + line_thickness# + 2side_bearing#, vcentre(med_op_size#)); "between";
1053 pair centre;
1054 centre := (w/2, (h-d)/2);
1055 r := med_op_size/2;
1056
1057 z0 = centre;
1058 z1 = centre;
1059
1060 draw_smile(a, 1, z0 - r * up, z0 + r * up, equal_spread, line_thickness, true);
1061 draw_smile(b, -1, z1 - r * up, z1 + r * up, equal_spread, line_thickness, true);
1062 endchar;
1063
1064 beginsymbol(2equal_spread# + 2side_bearing#, x_height#, desc_depth#); "intercalate";
1065 z1 - z0 = z3 - z2 = (2equal_spread - line_thickness) * right;
1066 z2 - z0 = (h + d - line_thickness) * up;
1067
1068 1/2[1/2[z0,z1], 1/2[z2,z3]] = (w/2, (h-d)/2);
1069
1070 draw_line(z2, z3, true);
1071 draw_line(1/2[z0,z1], 1/2[z2,z3], true);
1072 endchar;
1073
1074 beginsymbol(2/3equal_spread# + line_thickness# + 2side_bearing#, vcentre(plus_size#)); "wreath";
1075 pair centre;
1076 centre := (w/2, (h-d)/2);
1077
1078 draw_sim(a, centre + 1/2plus_size * up, centre - 1/2plus_size * up, 1/3equal_spread, thick);
1079 endchar;
1080
1081 for sign = 1, -1:
1082 beginoperator(plus_size#, 1); "angle";
1083 z0 = centre + (plus_size - line_thickness)/2 * down;
1084 z1 = z0 + sign * 1/2plus_size * right;
1085 z2 = z0 + sign * 1/2plus_size * left;
1086 x3 = xpart centre + sign * 1/2plus_size;
1087 y3 = ypart centre + 2/3plus_size;
1088 z4 = 4/5[z2,z3];
1089 z5 = z4l + whatever * (z2 - z4);
1090 z5 = z1r + whatever * right;
1091 z6 = z4r + whatever * (z2 - z4);
1092 z6 = z1r + whatever * right;
1093 z7 = z1l + whatever * right;
1094 z7 = z6 + whatever * dir (90 + sign * 17);
1095
1096 penpos1(line_thickness, 90);
1097 penpos4(line_thickness, angle(z3 - z2) + sign * 90);
1098
1099 fill z1r -- z5 -- z4l -- z4r -- z6 -- z7 -- z1l -- cycle;
1100
1101 penlabels(1,2,3,4,5,6,7);
1102 endchar;
1103 endfor;
1104
1105 for sign = 1, -1:
1106 beginoperator(plus_size#, 1); "measured angle";
1107 z0 = centre + (plus_size - line_thickness)/2 * down;
1108 z1 = z0 + sign * 1/2plus_size * right;
1109 z2 = z0 + sign * 1/2plus_size * left;
1110 x3 = xpart centre + sign * 1/2plus_size;
1111 y3 = ypart centre + 2/3plus_size;
1112 z4 = 4/5[z2,z3];
1113 z5 = z4l + whatever * (z2 - z4);
1114 z5 = z1r + whatever * right;
1115 z6 = z4r + whatever * (z2 - z4);
1116 z6 = z1r + whatever * right;
1117 z7 = z1l + whatever * right;
1118 z7 = z6 + whatever * dir (90 + sign * 17);
1119 z8 = 2/3[z2,z1];
1120 z9 = z2 + sign * ((z8 - z2) rotated angle (z3 - z2));
1121
1122 penpos1(line_thickness, 90);
1123 penpos4(line_thickness, angle(z3 - z2) + sign * 90);
1124 penpos8(line_thickness, 90 - sign * 90);
1125 penpos9(line_thickness, angle(z3 - z2));
1126
1127 fill z1r -- z5 -- z4l -- z4r -- z6 -- z7 -- z1l -- cycle;
1128 fill stroke z8.e{up} .. {dir (angle (z3 - z2) + sign * 90)}z9.e;
1129
1130 penlabels(1,2,3,4,5,6,7,8,9);
1131 endchar;
1132 endfor;
1133
1134 for alpha = 0, 90, 180, 270:
1135 beginoperator(plus_size#, 1); "spherical angle (" & decimal alpha & ")";
1136 draw_less(a, centre - 1/2plus_size * dir alpha, centre + 1/2plus_size * dir alpha, 2radius, line_thickness, false);
1137 z3 = 2/3[z2a, z0a];
1138 z4 = 2/3[z2a, z1a];
1139
1140 penpos3(line_thickness, alpha + 35);
1141 penpos4(line_thickness, alpha - 35);
1142
1143 fill stroke z4.e{dir (alpha + 55)} .. {dir (alpha + 125)}z3.e;
1144
1145 penlabels(3,4);
1146 endchar;
1147 endfor;
1148
1149 beginoperator(plus_size#, 1); "right angle";
1150 z3 - z0 = z2 - z1 = 2radius * right;
1151 z0 - z1 = 2radius * up;
1152 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
1153
1154 draw_line(z0, z1, true);
1155 draw_line(z1, z2, true);
1156 endchar;
1157
1158 beginoperator(plus_size#, 1); "measured right angle";
1159 thick := line_thickness;
1160
1161 z3 - z0 = z2 - z1 = 2radius * right;
1162 z0 - z1 = 2radius * up;
1163 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
1164 z4 = 3/5[z1,z0] + (1/2thick - eps) * right;
1165 z5 = 3/5[z1,z2] + (1/2thick - eps) * up;
1166
1167 penpos4(thick, 90);
1168 penpos5(thick, 0);
1169
1170 draw_line(z0, z1, true);
1171 draw_line(z1, z2, true);
1172 fill stroke z4.e{right} .. {down}z5.e;
1173
1174 penlabels(0,1,2,3,4,5);
1175 endchar;
1176
1177 beginoperator(plus_size#, 1); "squared right angle";
1178 z3 - z0 = z2 - z1 = 2radius * right;
1179 z0 - z1 = 2radius * up;
1180 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
1181 z4 = 1/2[z1,z0];
1182 z5 = 1/2[z1,z2];
1183
1184 penpos4(line_thickness, 90);
1185 penpos5(line_thickness, 0);
1186
1187 draw_line(z0, z1, true);
1188 draw_line(z1, z2, true);
1189 draw_line(z4, centre, true);
1190 draw_line(z5, centre, true);
1191
1192 penlabels(0,1,2,3,4,5);
1193 endchar;
1194
1195 beginoperator(plus_size#, 1); "right angle with dot";
1196 thick := line_thickness;
1197
1198 z3 - z0 = z2 - z1 = 2radius * right;
1199 z0 - z1 = 2radius * up;
1200 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
1201 z4 = 3/5[z1,z0] + (1/2thick - eps) * right;
1202 z5 = 3/5[z1,z2] + (1/2thick - eps) * up;
1203 z6 = 1/4[z1,z3];
1204
1205 penpos4(line_thickness, 90);
1206 penpos5(line_thickness, 0);
1207
1208 draw_line(z0, z1, true);
1209 draw_line(z1, z2, true);
1210 fill stroke z4.e{right} .. {down}z5.e;
1211 fill dot(z6, 1/2dot_size);
1212
1213 penlabels(0,1,2,3,4,5);
1214 endchar;
1215
1216 beginsymbol(3u# + line_thickness#, 4/5asc_height#, 0); "prime";
1217 z0 = (w, h);
1218 z1 = z0 + (u + line_thickness) * left;
1219 z2 = (1u, 1/9h);
1220 z3 = z2 + 4/3line_thickness * right;
1221
1222 fill z0 -- z1 -- z2 -- z3 -- cycle;
1223 endchar;
1224
1225 beginsymbol(3u# + line_thickness#, 4/5asc_height#, 0); "backprime";
1226 z0 = (0, h);
1227 z1 = z0 + (u + line_thickness) * right;
1228 z2 = (w - 1u, 1/9h);
1229 z3 = z2 + 4/3line_thickness * left;
1230
1231 fill z0 -- z1 -- z2 -- z3 -- cycle;
1232 endchar;
1233
1234 for sign = 1, -1:
1235 for serifs = true, false:
1236 beginoperator(plus_size#, 1); "product";
1237 draw_product(centre, plus_size, plus_size, sign, line_thickness, serifs);
1238 endchar;
1239 endfor;
1240 endfor;
1241
1242 beginsymbol(2/5asc_height# + 2side_bearing#, asc_height#, 0); "small integral";
1243 pair centre;
1244 centre := (w/2, (h - d)/2);
1245
1246 draw_integral(a, 1/2, centre, line_thickness);
1247 endchar;
1248
1249 beginsymbol(11u# + line_thickness# + 2side_bearing#, asc_height#, 0); "check mark";
1250 thick := line_thickness;
1251
1252 x1l = side_bearing;
1253 y1 = math_axis;
1254 x2 = side_bearing + 3u;
1255 y2 = -d;
1256 x3 = w -x2;
1257 y3 = h;
1258 x4r = w - side_bearing;
1259 y4l = h;
1260 z5r = 1/10[z4r,z1r];
1261
1262 theta := angle(z3 - z2);
1263
1264 penpos1(4/3thick, 30);
1265 penpos2(thick, 0);
1266 penpos3(thick, -90 + theta);
1267 penpos4(1/3thick, -80);
1268 penpos5(thick, -50);
1269
1270 z6 = z1r + whatever * (z2l - z1l);
1271 z6 = z3l + whatever * (z3r - z2r);
1272
1273 fill z1l -- z2l -- z2r{z3r - z2r} .. {dir 40}z5r .. z4r -- z4l{dir 180} ... z5l{dir 220} .. {z2l - z3l}z6 -- z1r -- cycle;
1274
1275 penlabels(1,2,3,4,5,6);
1276 endchar;
1277
1278 beginsymbol(6u# + line_thickness# + 2side_bearing#, 5/4asc_height#, 1/8asc_height#); "lightning";
1279 thick := line_thickness;
1280
1281 x3r = w - side_bearing;
1282 x2l = side_bearing + u;
1283 x4 = 1/3w;
1284 y1l = h;
1285 y3r = 14/24h;
1286 y4 = -d + 1/2thick;
1287 z6 - z5 = whatever * dir 15;
1288
1289 penpos1(3/2thick, -20);
1290 penpos2(3/2thick, 15);
1291 penpos3(2thick, 15);
1292 penpos4(thick, -20);
1293 penpos5(thick, -75);
1294 penpos6(thick, -75);
1295
1296 z1 - z2 = whatever * (z4 - z3);
1297 z5r = z2;
1298 z6l = z3;
1299 z7 = whatever[z1r,z2r];
1300 z7 = whatever[z5l,z6l];
1301 z8 = whatever[z4l,z3l];
1302 z8 = whatever[z6r,z5r];
1303
1304 fill z1l -- z2l -- z8 -- z4l -- z4r -- z3r -- z7 -- z1r -- cycle;
1305 draw_arrowhead(z4, angle (z4l - z3l), 4/5arrow_spread, thick);
1306
1307 penlabels(1,2,3,4,7,8);
1308 endchar;
1309
1310 for filled = false, true:
1311 beginsymbol(13u#, cap_height#, 0); "diamond suit";
1312 thick := line_thickness;
1313 bend := 5;
1314
1315 x0 = x2 = x4 = x6 = w/2;
1316 1/2[y0,y2] = 1/2[y4,y6] = h/2;
1317 y2 - y0 = h;
1318 1/2[x1,x3] = 1/2[x5,x7] = w/2;
1319 x3 - x1 = w - 2side_bearing;
1320 y1 = y3 = y5 = y7 = h/2;
1321
1322 theta := angle(z2 - z1);
1323
1324 y6 - y4 = h - 2thick / cosd theta;
1325 x7 - x5 = w - 2side_bearing - 2thick / sind theta;
1326
1327 fill z0{dir (180-theta-bend)} .. {dir (180-theta+bend)}z1{dir (theta-bend)} .. {dir (theta+bend)}z2{dir (-theta-bend)} .. {dir (-theta+bend)}z3{dir (180+theta-bend)} .. {dir (180+theta+bend)}z0 & cycle;
1328 if not filled:
1329 unfill z4{dir (180-theta-bend)} .. {dir (180-theta+bend)}z5{dir (theta-bend)} .. {dir (theta+bend)}z6{dir (-theta-bend)} .. {dir (-theta+bend)}z7{dir (180+theta-bend)} .. {dir (180+theta+bend)}z4 & cycle;
1330 fi;
1331 labels(0,1,2,3,4,5,6,7);
1332 endchar;
1333 endfor;
1334
1335 for filled = false, true:
1336 beginsymbol(14u#, cap_height#, 0); "heart suit";
1337 thick := line_thickness;
1338
1339 x0 = x1l = x1'l = w/2;
1340 y0 = 0;
1341 1/2[x2l,x3l] = w/2;
1342 x3l - x2l = w - 2side_bearing;
1343 y1r = y1'r;
1344 y2l = y3l = 3/4h;
1345 x4 = 1/2[x1,x2];
1346 x5 = 1/2[x1',x3];
1347 y4l = y5l = h;
1348 h - y2 = 2(h - y1l);
1349
1350 penpos1(thick, 180+45);
1351 penpos1'(thick, -45);
1352 penpos2(thick, 0);
1353 penpos3(thick, 180);
1354 penpos4(thick, -90);
1355 penpos5(thick, -90);
1356
1357 path p[];
1358 numeric t[];
1359
1360 z6 = z1r + whatever * dir (270+45);
1361 z6 = z1'r + whatever * dir (270-45);
1362 z7 = z0 + thick * dir 20;
1363 z8 = z0 + thick * dir (180-20);
1364 p1 = z7{dir (90+35)} .. {dir 90}z2r;
1365 p2 = z3r{dir 270} .. {dir (270-35)}z8;
1366 (t1,t2) = p1 intersectiontimes p2;
1367
1368 fill z0{dir (90+35)} .. {dir 90}z2l .. {dir 0}z4l .. {dir (270+45)}z1l{dir (90-45)} .. {dir 0}z5l .. {dir 270}z3l .. {dir (270-35)}z0 & cycle;
1369 if not filled:
1370 unfill subpath (t1,1) of p1 & z2r{dir 90} .. {dir 0}z4r .. {dir (270+45)}z1r -- z6 -- z1'r{dir (90-45)} .. {dir 0}z5r .. {dir 270}z3r & subpath (0,t2) of p2 -- cycle;
1371 fi;
1372
1373 penlabels(0,1,1',2,3,4,5,6,7,8);
1374 endchar;
1375 endfor;
1376
1377 beginsymbol(13u#, cap_height#, 0); "spade suit";
1378 x0 = x1 = w/2;
1379 y0 = h;
1380 1/2[x2,x3] = w/2;
1381 x3 - x2 = w - 2side_bearing;
1382 y2 = y3;
1383 x4 = 1/2[x1,x2];
1384 x5 = 1/2[x1,x3];
1385 y4 = y5 = 1/6h;
1386 y2 - y4 = x4 - x2;
1387 y1 = 3/5[y2,y4];
1388 x6 = x0;
1389 y6 = 0;
1390
1391 penpos1(2u, 0);
1392 penpos6(3u, 0);
1393
1394 fill z0{dir (270-30)} .. z2 .. z4 .. {dir (90-30)}z1l -- z6l --
1395 z6r -- z1r{dir (270+30)} .. z5 .. z3 .. {dir (90+30)}z0 -- cycle;
1396
1397 penlabels(0,1,2,3,4,5,6);
1398 endchar;
1399
1400 beginsymbol(14u#, cap_height#, 0); "club suit";
1401 r := 1/4(w - 2side_bearing);
1402
1403 x0 = w/2;
1404 y0 = h - 2.5r;
1405 x1 = w - x3 = side_bearing + r;
1406 y1 = y3 = y0;
1407 x2 = x4 = x0;
1408 y2 = h - r;
1409 y4 = 0;
1410
1411 penpos0(3/2u, 0);
1412 penpos2(3/2u, 0);
1413 penpos4(3u, 0);
1414
1415 fill circle(z1, r);
1416 fill circle(z2, r);
1417 fill circle(z3, r);
1418 fill stroke z2e -- z0e -- z4e;
1419
1420 penlabels(0,1,2,3,4);
1421 endchar;
1422
1423 beginoperator(med_op_size#, 1); "maltese";
1424 r := 1/2med_op_size;
1425 thick := line_thickness;
1426
1427 1/2[z0,z1] = centre + r * left;
1428 1/2[z2,z3] = centre + r * down;
1429 1/2[z4,z5] = centre + r * right;
1430 1/2[z6,z7] = centre + r * up;
1431 z0 - z1 = z5 - z4 = r * up;
1432 z3 - z2 = z6 - z7 = r * right;
1433 1/2[z8,z9] = centre + 1/2thick * up;
1434 1/2[z10,z11] = centre - 1/2thick * up;
1435 z9 - z8 = z11 - z10 = 2thick * right;
1436 1/2[z12,z13] = centre + thick * up;
1437 1/2[z14,z15] = centre - thick * up;
1438 z13 - z12 = z15 - z14 = thick * right;
1439
1440 fill z0 -- z1 -- z10 -- z11 -- z4 -- z5 -- z9 -- z8 -- cycle;
1441 fill z6 -- z7 -- z12 -- z14 -- z2 -- z3 -- z15 -- z13 -- cycle;
1442
1443 labels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15);
1444 endchar;
1445
1446 beginoperator(med_op_size#, 2/sqrt(3)); "star of david";
1447 r := med_op_size/sqrt(3);
1448
1449 reg_poly_points(a)(6, centre, r, 90);
1450
1451 s := r - 4/5line_thickness / sind (270 - angle (z.a2 - z.a0));
1452
1453 reg_poly_points(b)(6, centre, s, 90);
1454
1455 z0.r = z.a0; z0.l = z.b0;
1456 z1.r = z.a2; z1.l = z.b2;
1457 z2.r = z.a4; z2.l = z.b4;
1458 z3.r = z.a1; z3.l = z.b1;
1459 z4.r = z.a3; z4.l = z.b3;
1460 z5.r = z.a5; z5.l = z.b5;
1461
1462 fill stroke z0.e -- z1.e -- z2.e -- cycle;
1463 fill stroke z4.e -- z5.e -- z3.e -- cycle;
1464
1465 penlabels(0,1,2,3,4,5);
1466 endchar;
1467
1468 beginoperator(plus_size#, 1); "sector";
1469 thick := line_thickness;
1470 alpha := 90;
1471
1472 z0 = centre - 1/2plus_size * dir alpha;
1473 z1 = z0 + 9/10plus_size * dir alpha;
1474
1475 draw_less(a, z0, z1, 9/10plus_size, thick, false);
1476
1477 theta := angle(z0a - z2a) - alpha;
1478
1479 z0a = z4r;
1480 z0a.r = z4'.r;
1481 z1a = z5r;
1482 z1a.r = z5'.r;
1483
1484 penpos4(thick, alpha + theta);
1485 penpos4'(thick, alpha + theta);
1486 penpos5(thick, alpha - theta);
1487 penpos5'(thick, alpha - theta);
1488
1489 fill stroke z4e -- z4'.e{dir (alpha + theta - 90)} .. {dir(alpha - theta - 90)}z5'.e -- z5e;
1490
1491 penlabels(4,5);
1492 endchar;
1493
1494 beginsymbol(5/4order_width# + 2side_bearing#, cap_height#, 0); "forall";
1495 thick := 5/4line_thickness;
1496
1497 x0 = side_bearing + 1/2thick;
1498 x1 = w - side_bearing - 1/2thick;
1499 x2 = w/2 - 1/4thick;
1500 x3 = w/2 + 1/4thick;
1501 y0 = y1 = h;
1502 y2 = y3 = 0;
1503
1504 penpos0(thick * cosd(angle(z2 - z0) + 90), 0);
1505 penpos1(thick * cosd(angle(z2 - z0) + 90), 0);
1506
1507 z4 = z0l + whatever * (z2 - z0) = z2 + whatever * right;
1508 z5 = z1r + whatever * (z3 - z1) = z2 + whatever * right;
1509 z6 = z0r + whatever * (z2 - z0) = z1l + whatever * (z3 - z1);
1510 z7 = whatever [z0,z2];
1511 z8 = whatever [z1,z2];
1512 y7 = y8 = 0.6 * y0;
1513
1514 fill z0l -- z4 -- z5 -- z1r -- z1l -- z6 -- z0r -- cycle;
1515 draw_line(z7, z8, false);
1516
1517 penlabels(0,1,2,3,4,5,6,7,8);
1518 endchar;
1519
1520 for negated = 0, 1:
1521 beginsymbol(order_width# + 2side_bearing#, if negated = 0: cap_height# else: cap_height# + 2/3equal_spread# fi, if negated = 0: 0 else: 2/3equal_spread# fi); "exists";
1522 thick := 5/4line_thickness;
1523
1524 x1 = x3 = w - side_bearing - thick/2;
1525 y1 = cap_height;
1526 y3 = 0;
1527 x1' = x3' = w - side_bearing;
1528 x0 = x2 = side_bearing;
1529 y0 = y1' = cap_height - line_thickness/2;
1530 y2 = y3' = line_thickness/2;
1531 z4 = 1/8[1/2[z0,z2], 1/2[z1,z3]];
1532
1533 draw_straight(z1, z3, thick, false);
1534 draw_line(z0, z1', false);
1535 draw_line(z4, 1/2[z1,z3], false);
1536 draw_line(z2, z3', false);
1537
1538 if negated = 1:
1539 stroke_through(1/2[1/2[z0,z2], 1/2[z1,z3]], h + d - stroke_through_thickness)
1540 fi;
1541 endchar;
1542 endfor;
1543
1544 beginsymbol(order_width# + 2side_bearing#, cap_height#, 0); "exists finitely many";
1545 thick := 5/4line_thickness;
1546
1547 x1 = x3 = w - side_bearing - thick/2;
1548 y1 = cap_height;
1549 y3 = 0;
1550 x3' = w - side_bearing;
1551 x0 = x2 = side_bearing;
1552 y0 = cap_height - line_thickness/2;
1553 y2 = y3' = line_thickness/2;
1554 z4 = 1/8[1/2[z0,z2], 1/2[z1,z3]];
1555
1556 draw_straight(z1, z3, thick, false);
1557 draw_line(z4, 1/2[z1,z3], false);
1558 draw_line(z2, z3', false);
1559 endchar;
1560
1561 beginsymbol(5/4order_width# + 2side_bearing#, cap_height#, 0); "game quantifier";
1562 thick := 5/4line_thickness;
1563
1564 x0 = x1 = 1/2order_width + side_bearing;
1565 y0 = cap_height - 1/2thick;
1566 y1 = 1/2line_thickness;
1567 x2 = w - side_bearing - 1/2thick;
1568 y2 = (h - d)/2;
1569 x3r = x4r = side_bearing;
1570 y3 = 5/6cap_height;
1571 y4 = 1/6cap_height;
1572
1573 penpos0(thick, 90);
1574 penpos1(thick, -90);
1575 penpos2(thick, 0);
1576 penpos3(thick, 125);
1577 penpos4(thick, -125);
1578
1579 fill stroke z3.e .. z0.e .. z2.e{down} .. z1.e{left} .. z4.e;
1580 draw_straight(z4r + 1/2thick * right, 2/5[z4r,z3r] + 1/2thick * right, thick, false);
1581 draw_line(2/5[z4r,z3r], 2/5[z4r,z3r] + 1/2order_width * right, false);
1582
1583 penlabels(0,1,2,3,4);
1584 endchar;
1585
1586 beginsymbol(7/8order_width# + 2side_bearing#, cap_height#, 0); "complement";
1587 thick := 5/4line_thickness;
1588
1589 z0 - z1 = (cap_height - thick) * up;
1590 z3 - z2 = (w - 2side_bearing - thick) * right;
1591 1/2[z0,z1] = 1/2[z2,z3] = (w/2,(h-d)/2);
1592 x4 = x6 = x2;
1593 x5 = x7 = x3;
1594 y4 = y5 = 1/4[y0,y1];
1595 y6 = y7 = 3/4[y0,y1];
1596
1597 penpos0(thick, 90);
1598 penpos1(thick, -90);
1599 penpos4(thick, -180);
1600 penpos5(thick, 0);
1601 penpos6(thick, -180);
1602 penpos7(thick, 0);
1603
1604 fill stroke z5.e{up} .. z0.e .. {down}z4.e -- z6.e{down} .. z1.e .. {up}z7.e;
1605
1606 penlabels(0,1,2,3,4,5,6,7);
1607 endchar;
1608
1609 beginsymbol(5u# + line_thickness# + 2side_bearing#, asc_height#, 1/2line_thickness#); "flat";
1610 thick := line_thickness;
1611
1612 x0l = x1l = side_bearing;
1613 x4l = x5 = side_bearing + thick;
1614 y0 = -d;
1615 y1 = h;
1616 x2r = w - side_bearing;
1617 x3 = w/2;
1618 y3r = x_height;
1619 y2 = 1/2[y0,y1];
1620 y4r = 5/6x_height;
1621 y5 = thick * (1 + sind 35) / cosd 35 - d;
1622
1623 penpos0(thick, 0);
1624 penpos1(thick, 0);
1625 penpos2(4/3thick, 0);
1626 penpos3(thick, 90);
1627 penpos4(thick, 130);
1628
1629 fill z1.l -- z0.l{dir 35} ... {up}z2.r .. {left}z3.r ..{dir 230}z4.r -- z4.l{dir 50} .. {right}z3.l .. {down}z2.l .. {dir 215}z5 -- z1.r -- cycle;
1630
1631 penlabels (0,1,2,3,4,5);
1632 endchar;
1633
1634 beginsymbol(5u# + line_thickness# + 2side_bearing#, asc_height#, desc_depth#); "natural";
1635 thick := line_thickness;
1636
1637 x0l = x1l = w - x2r = w - x3r = side_bearing;
1638 x4 = x5 = w - x6 = w - x7 = side_bearing;
1639 y1 = y3 = h;
1640 y7r = x_height;
1641 y4l = 0;
1642 y0 = y2 = -d;
1643 z6 = z4 + whatever * dir 15;
1644 z5 = z7 + whatever * dir 15;
1645
1646 penpos0(thick, 0);
1647 penpos1(thick, 0);
1648 penpos2(thick, 0);
1649 penpos3(thick, 0);
1650 penpos4(3/2thick, 90);
1651 penpos5(3/2thick, 90);
1652 penpos6(3/2thick, 90);
1653 penpos7(3/2thick, 90);
1654
1655 z8 = whatever[z0,z1] = whatever[z4,z6];
1656 z9 = whatever[z2,z3] = whatever[z5,z7];
1657
1658 penpos8(thick, 0);
1659 penpos9(thick, 0);
1660
1661 fill stroke z1e -- z8e;
1662 fill stroke z9e -- z2e;
1663 fill stroke z4e -- z6e;
1664 fill stroke z5e -- z7e;
1665
1666 penlabels(1,2,4,5,6,7);
1667 endchar;
1668
1669 beginsymbol(5u# + line_thickness# + 2side_bearing#, asc_height#, desc_depth#); "sharp";
1670 thick := line_thickness;
1671
1672 x0l - x4 = x1l - x5 = x6 - x2r = x7 - x3r;
1673 x2l - x0r = x3l - x1r = 2(x0l - x4);
1674 x4 = x5 = w - x6 = w - x7 = side_bearing;
1675 y3 = h;
1676 y7r = x_height;
1677 y4l = 0;
1678 y0 = -d;
1679 z2 = z0 + whatever * dir 20;
1680 z1 = z3 + whatever * dir 20;
1681 z6 = z4 + whatever * dir 15;
1682 z5 = z7 + whatever * dir 15;
1683
1684 penpos0(thick, 0);
1685 penpos1(thick, 0);
1686 penpos2(thick, 0);
1687 penpos3(thick, 0);
1688 penpos4(3/2thick, 90);
1689 penpos5(3/2thick, 90);
1690 penpos6(3/2thick, 90);
1691 penpos7(3/2thick, 90);
1692
1693 fill stroke z0e -- z1e;
1694 fill stroke z2e -- z3e;
1695 fill stroke z4e -- z6e;
1696 fill stroke z5e -- z7e;
1697
1698 penlabels (0,1,2,3,4,5,6,7);
1699 endchar;
1700
1701 beginsymbol(9u# + line_thickness# + 2side_bearing#, cap_height#, 0); "aleph";
1702 thick := line_thickness;
1703
1704 x0l = x2l = side_bearing;
1705 x1r = x3r = w - side_bearing;
1706 y0 = h;
1707 y1 = h;
1708 y2 = 0;
1709 y3 = 0;
1710
1711 penpos0(3/2thick, 20);
1712 penpos1(4/3thick, 2);
1713 penpos2(3/2thick, 0);
1714 penpos3(4/3thick, 20);
1715
1716 path p;
1717 p = z0{dir -70} .. {dir -70}z3;
1718
1719 z4 = point 3/10 of p;
1720 z5 = point 5/8 of p;
1721
1722 penpos4(5/4thick, -40);
1723 penpos5(5/4thick, -45);
1724
1725 fill stroke z0.e{dir -70} .. {dir -70}z3.e;
1726 fill stroke z2.e{up} .. {dir 50}z4.e;
1727 fill stroke z5.e{dir 45} .. {up}z1.e;
1728
1729 penlabels(0,1,2,3,4,5);
1730 endchar;
1731
1732 beginsymbol(9u# + line_thickness# + 2side_bearing#, cap_height#, 0); "beth";
1733 thick := line_thickness;
1734
1735 x0 = u + side_bearing;
1736 x1 = 5/8[x2,x4];
1737 x2 = side_bearing;
1738 x3 = w - side_bearing;
1739 y0r = h;
1740 y1r = h;
1741 y2l = 0;
1742 y3l = 0;
1743 z4r = 7/8[z2,z3];
1744 x5 = x4;
1745 y5 = 2/3h;
1746
1747 penpos0(3/2thick, 75);
1748 penpos1(3/2thick * sind 75, 90);
1749 penpos2(3/2thick, 75);
1750 penpos3(3/2thick, 75);
1751 penpos4(5/4thick, 0);
1752 penpos5(5/4thick, 0);
1753
1754 fill stroke z2.e -- z3.e;
1755 fill stroke z0.e -- z1.e{right} ..tension3/4.. {down}z5.e -- z4.e;
1756
1757 penlabels(0,1,2,3,4,5);
1758 endchar;
1759
1760 beginsymbol(6u# + line_thickness# + 2side_bearing#, cap_height#, 0); "gimel";
1761 thick := line_thickness;
1762
1763 x0 = x2 = side_bearing;
1764 x2'r = 1/8[x0,x1];
1765 x1 = x3r = w - side_bearing;
1766 x4 = 1/4[x0,x1];
1767 x5 = 1/2[x0,x1];
1768 x6 = 2/3[x0,x1];
1769 y0 = y1 = h;
1770 y2l = y3 = 0;
1771 y2' = y2;
1772 y4r = h + 1/4thick;
1773 z5 = z4 + whatever * dir -30;
1774 y6 = 2/3h;
1775
1776 penpos2(4/3thick, 80);
1777 penpos2'(4/3thick * sind 80, 90);
1778 penpos3(4/3thick, 0);
1779 penpos4(3/2thick, 60);
1780 penpos5(3/2thick, 60);
1781 penpos6(5/4thick, 0);
1782
1783 path p;
1784 p = z6{dir -82} .. {dir -67}z3;
1785 z7 = point 1/4 of p;
1786 x8 = 2/5[x0,x1];
1787 z7 = z8 + whatever * dir 60;
1788
1789 penpos7(thick, 150);
1790 penpos8(thick, 150);
1791
1792 fill stroke z4.e -- z5.e{dir -30} .. {dir -82}z6.e .. {dir -67}z3.e;
1793 fill stroke z2.e -- z2'.e{right} ..tension 3/4 and 1.. {dir 60}z8.e -- z7.e;
1794
1795 penlabels(2,2',3,4,5,6,7,8);
1796 endchar;
1797
1798 beginsymbol(8u# + line_thickness# + 2side_bearing#, cap_height#, 0); "daleth";
1799 thick := line_thickness;
1800
1801 x0 = side_bearing;
1802 x1 = w - side_bearing;
1803 y0r = y1r = h;
1804 x3r = x2r = 4/5[x0,x1];
1805 y2 = y0;
1806 y3 = 0;
1807
1808 penpos0(3/2thick, 75);
1809 penpos1(3/2thick, 75);
1810 penpos2(5/4thick, 0);
1811 penpos3(5/4thick, 0);
1812
1813 fill stroke z0.e -- z1.e;
1814 fill stroke z2.e -- z3.e;
1815
1816 penlabels(0,1,2,3);
1817 endchar;
1818
1819 begingroup;
1820 save slant;
1821 save currenttransform;
1822 slant := 0.212557;
1823 transform currenttransform;
1824 currenttransform := identity slanted slant yscaled aspect_ratio scaled granularity shifted (-u,0);
1825
1826 beginsymbol(9u# + 2line_thickness#, x_height#, desc_depth#); "Weierstrass p";
1827 numeric theta;
1828 theta = 90 - angle(8u,h);
1829 slope := -h/8u; % angle at middle
1830 superness := 1/sqrt 2;
1831 superpull := 1/6;
1832
1833 penpos2(line_thickness, -60);
1834 penpos1(4/3line_thickness, theta);
1835 penpos7(line_thickness, -90);
1836
1837 x2 + 1/2u = x1 = x7 - 1/2u = 3u;
1838 y2l = h;
1839 y7r = -d;
1840 y1 = 2/5[-d, h];
1841 x3l = 1/2u;
1842 x6r = max(x7 + line_thickness, 1/2w - 1/4u);
1843 x3r - x3l = x6r - x6l = 5/4line_thickness;
1844
1845 ellipse_set(2l,3l,4l,1l);
1846 ellipse_set(2r,3r,4r,1r);
1847 ellipse_set(7l,6l,5l,1l);
1848 ellipse_set(7r,6r,5r,1r);
1849
1850 y3 = y3r;
1851 y6 = y6r;
1852
1853 fill stroke super_arc.e(2,3) & z3e{down} .. z4e .. z5e .. z6e{down} & super_arc.e(6,7); % flourish
1854
1855 penpos8(line_thickness, 180);
1856 penpos9(line_thickness, 90);
1857 penpos10(3/2line_thickness, 0);
1858 penpos11(line_thickness, -90);
1859 penpos12(line_thickness, -100);
1860
1861 x10r = w - 3/2u + 1/2line_thickness;
1862 x8r = u;
1863 x9 = x11 = 1/2w + 3/2u;
1864 x12l = max(x6r, .5w + .5u);
1865 y8 = y11r = 0;
1866 y9r = 19/20h;
1867 y10 = 1/2[y9,y11];
1868 y12r = 1/4[y11r,y1l];
1869
1870 fill stroke z7e{left} ... z8e{up} ... pulled_arc.e(9,10) & pulled_arc.e(10,11) .. z12.e; % stem and bowl
1871
1872 penlabels(1,2,3,4,5,6,7,8,9,10,11,12);
1873 endchar;
1874 endgroup;