Debian Codegraph @

texmf-dist/fonts/source/public/fdsymbol/fdaccents.mf

raw
1 %
2 % Copyright (c) 2011-2025, Michael Ummels <[email protected]>
3 %
4 % This Font Software is licensed under the SIL Open Font License,
5 % Version 1.1. This license is in the accompanying file OFL.txt, and
6 % is also available with a FAQ at: http://scripts.sil.org/OFL
7 %
8
9 for scale = 1, 1.8, 2.6, 3.4, 4.2, 5:
10 beginsymbol(scale * 7u#, x_height# + 2rule_thickness# + 1/2equal_spread# + line_thickness#, 0); "wide hat";
11 thick := line_thickness;
12
13 y2 = h - 1/2thick;
14 x2 = w/2;
15 x1 = w - x3 = 0;
16 y1 = y3 = y2 - 1/2equal_spread;
17
18 theta := angle(z2 - z1);
19
20 penpos2(6/5thick, 90);
21 penpos1(thick, theta + 90);
22 penpos3(thick, 90 - theta);
23
24 fill stroke z1e -- z2e -- z3e;
25 endchar;
26 endfor;
27
28 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
29
30 for scale = 1, 1.8, 2.6, 3.4, 4.2, 5:
31 beginsymbol(scale * 7u#, x_height# + 2rule_thickness# + 1/2equal_spread# + line_thickness#, 0); "wide tilde";
32 draw_sim(a, (0, 1/2[x_height + 2rule_thickness, h]), (w, 1/2[x_height + 2rule_thickness, h]), 1/4equal_spread, line_thickness);
33 endchar;
34 endfor;
35
36 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
37
38 for scale = 1, 1.8, 2.6, 3.4, 4.2, 5:
39 beginsymbol(scale * 7u#, x_height# + 2rule_thickness# + 1/2equal_spread# + line_thickness#, 0); "wide paren";
40 draw_smile(a, -1, (0, 1/2[x_height + 2rule_thickness, h]), (w, 1/2[x_height + 2rule_thickness, h]), 1/2equal_spread, line_thickness, true);
41 endchar;
42 endfor;
43
44 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
45
46 beginsymbol(6u# + side_bearing#, x_height# + 2rule_thickness# + 5/2line_thickness#, 0); "vec";
47 thick := 3/4line_thickness;
48
49 x0 = side_bearing;
50 x1 = w - 1/2thick;
51 y0 = y1 = h - 5/4line_thickness;
52
53 draw_straight(z0, z1, thick, false);
54 draw_arrowhead(z1, 0, 5/2line_thickness, thick);
55 endchar;
56
57 beginsymbol(5u#, (-1)[x_height#, asc_height#], 0); "middle bar";
58 penpos0(5/6line_thickness, 85);
59 penpos1(5/6line_thickness, 85);
60
61 x0 = w - x1 = 0;
62 y0 = y1 = h;
63
64 fill stroke z0e -- z1e;
65 endchar;
66
67 beginsymbol(5u#, (-1)[x_height#, asc_height#], 0); "middle slash";
68 penpos0(line_thickness, 85);
69 penpos1(line_thickness, 85);
70
71 x0 = w - x1 = 0;
72 1/2[y0,y1] = h;
73 y1 - y0 = 2line_thickness;
74
75 fill stroke z0e -- z1e;
76 endchar;
77
78 beginsymbol(5u# + 2side_bearing#, 3/2asc_height#, 0); "stroke through";
79 theta := 70;
80
81 penpos1(line_thickness, theta - 90);
82 penpos2(line_thickness, theta - 90);
83
84 z0 = (w/2,1/6asc_height);
85 z1 = z0 + 3/4asc_height / cosd (90 - theta) * dir theta;
86 z2 = z0 - 3/4asc_height / cosd (90 - theta) * dir theta;
87
88 fill stroke z1e -- z2e;
89 endchar;