Debian Codegraph @

common/WriteEnv.nsh

raw
1 !include WinMessages.nsh
2
3 #
4 # WriteEnvStr - Writes an environment variable
5 # Note: Win9x systems requires reboot
6 #
7 # Example:
8 # Push "HOMEDIR" # name
9 # Push "C:\New Home Dir\" # value
10 # Push "true" # true or false if admin user
11 # Call WriteEnvStr
12 #
13 Function WriteEnvStr
14 Pop $8 ; $8 IsAdminUser: true or false
15 Exch $1 ; $1 has environment variable value
16 Exch
17 Exch $0 ; $0 has environment variable name
18 Push $2
19
20 Call IsNT
21 Pop $2
22 StrCmp $2 1 WriteEnvStr_NT
23 ; Not on NT
24 StrCpy $2 $WINDIR 2 ; Copy drive of windows (c:)
25 FileOpen $2 "$2\autoexec.bat" a
26 FileSeek $2 0 END
27 FileWrite $2 "$\r$\nSET $0=$1$\r$\n"
28 FileClose $2
29 SetRebootFlag true
30 Goto WriteEnvStr_done
31
32 WriteEnvStr_NT:
33 StrCmp $8 "false" WriteEnvStr_NormalUser
34 WriteRegStr HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" $0 $1
35 DetailPrint "Setting environment variable $0 to $1 for All Users"
36 Goto WriteEnvStr_cont
37 WriteEnvStr_NormalUser:
38 WriteRegStr HKCU "Environment" $0 $1
39 DetailPrint "Setting environment variable $0 to $1 for Current User"
40 WriteEnvStr_cont:
41 SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} \
42 0 "STR:Environment" /TIMEOUT=5000
43
44 WriteEnvStr_done:
45 Pop $2
46 Pop $1
47 Pop $0
48 FunctionEnd
49
50 #
51 # un.DeleteEnvStr - Removes an environment variable
52 # Note: Win9x systems requires reboot
53 #
54 # Example:
55 # Push "HOMEDIR" # name
56 # Push "true" # true or false if admin user
57 # Call un.DeleteEnvStr
58 #
59 Function un.DeleteEnvStr
60 Pop $8 ; $8 IsAdminUser: true or false
61 Exch $0 ; $0 now has the name of the variable
62 Push $1
63 Push $2
64 Push $3
65 Push $4
66 Push $5
67
68 Call un.IsNT
69 Pop $1
70 StrCmp $1 1 DeleteEnvStr_NT
71 ; Not on NT
72 StrCpy $1 $WINDIR 2
73 FileOpen $1 "$1\autoexec.bat" r
74 GetTempFileName $4
75 FileOpen $2 $4 w
76 StrCpy $0 "SET $0="
77 SetRebootFlag true
78
79 DeleteEnvStr_dosLoop:
80 FileRead $1 $3
81 StrLen $5 $0
82 StrCpy $5 $3 $5
83 StrCmp $5 $0 DeleteEnvStr_dosLoop
84 StrCmp $5 "" DeleteEnvStr_dosLoopEnd
85 FileWrite $2 $3
86 Goto DeleteEnvStr_dosLoop
87
88 DeleteEnvStr_dosLoopEnd:
89 FileClose $2
90 FileClose $1
91 StrCpy $1 $WINDIR 2
92 Delete "$1\autoexec.bat"
93 CopyFiles /SILENT $4 "$1\autoexec.bat"
94 Delete $4
95 Goto DeleteEnvStr_done
96
97 DeleteEnvStr_NT:
98 StrCmp $8 "false" DeleteEnvStr_NormalUser
99 DeleteRegValue HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" $0
100 DetailPrint "Deleting environment variable $0 from All Users"
101 Goto DeleteEnvStr_cont
102 DeleteEnvStr_NormalUser:
103 DeleteRegValue HKCU "Environment" $0
104 DetailPrint "Deleting environment variable $0 from Current User"
105 DeleteEnvStr_cont:
106 SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} \
107 0 "STR:Environment" /TIMEOUT=5000
108
109 DeleteEnvStr_done:
110 Pop $5
111 Pop $4
112 Pop $3
113 Pop $2
114 Pop $1
115 Pop $0
116 FunctionEnd
117