Debian Codegraph @

m4/utmp_h.m4

raw
1 # utmp_h.m4
2 # serial 2
3 dnl Copyright (C) 2023-2026 Free Software Foundation, Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7 dnl This file is offered as-is, without any warranty.
8
9 # Configure a GNU-like replacement for <utmp.h>.
10
11 AC_DEFUN_ONCE([gl_UTMP_H],
12 [
13 dnl Ensure to expand the default settings once only, before all statements
14 dnl that occur in other macros.
15 AC_REQUIRE([gl_UTMP_H_DEFAULTS])
16
17 gl_CHECK_NEXT_HEADERS([utmp.h])
18 if test $ac_cv_header_utmp_h = yes; then
19 HAVE_UTMP_H=1
20 else
21 HAVE_UTMP_H=0
22 fi
23 AC_SUBST([HAVE_UTMP_H])
24
25 gl_PTY_CHECK_UTIL_H
26
27 AC_CHECK_HEADERS_ONCE([termios.h])
28 if test $ac_cv_header_termios_h != yes; then
29 HAVE_TERMIOS_H=0
30 fi
31
32 dnl Check for declarations of anything we want to poison if the
33 dnl corresponding gnulib module is not in use, and which is not
34 dnl guaranteed by C89.
35 gl_WARN_ON_USE_PREPARE([[
36 #include <sys/types.h>
37 #include <utmp.h>
38 ]],
39 [login_tty])
40 ])
41
42 # gl_UTMP_MODULE_INDICATOR([modulename])
43 # sets the shell variable that indicates the presence of the given module
44 # to a C preprocessor expression that will evaluate to 1.
45 # This macro invocation must not occur in macros that are AC_REQUIREd.
46 AC_DEFUN([gl_UTMP_MODULE_INDICATOR],
47 [
48 dnl Ensure to expand the default settings once only.
49 gl_UTMP_H_REQUIRE_DEFAULTS
50 gl_MODULE_INDICATOR_SET_VARIABLE([$1])
51 dnl Define it also as a C macro, for the benefit of the unit tests.
52 gl_MODULE_INDICATOR_FOR_TESTS([$1])
53 ])
54
55 # Initializes the default values for AC_SUBSTed shell variables.
56 # This macro must not be AC_REQUIREd. It must only be invoked, and only
57 # outside of macros or in macros that are not AC_REQUIREd.
58 AC_DEFUN([gl_UTMP_H_REQUIRE_DEFAULTS],
59 [
60 m4_defun(GL_MODULE_INDICATOR_PREFIX[_UTMP_H_MODULE_INDICATOR_DEFAULTS], [
61 gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_LOGIN_TTY])
62 ])
63 m4_require(GL_MODULE_INDICATOR_PREFIX[_UTMP_H_MODULE_INDICATOR_DEFAULTS])
64 AC_REQUIRE([gl_UTMP_H_DEFAULTS])
65 ])
66
67 AC_DEFUN([gl_UTMP_H_DEFAULTS],
68 [
69 dnl For HAVE_UTIL_H, HAVE_LIBUTIL_H.
70 AC_REQUIRE([gl_PTY_H_DEFAULTS])
71 dnl For HAVE_TERMIOS_H.
72 AC_REQUIRE([gl_TERMIOS_H_DEFAULTS])
73 dnl Assume proper GNU behavior unless another module says otherwise.
74 HAVE_LOGIN_TTY=1; AC_SUBST([HAVE_LOGIN_TTY])
75 REPLACE_LOGIN_TTY=0; AC_SUBST([REPLACE_LOGIN_TTY])
76 ])