| 1 |
# setenv.m4 |
| 2 |
# serial 36 |
| 3 |
dnl Copyright (C) 2001-2004, 2006-2026 Free Software Foundation, Inc. |
| 4 |
dnl This file is free software; the Free Software Foundation |
| 5 |
dnl gives unlimited permission to copy and/or distribute it, |
| 6 |
dnl with or without modifications, as long as this notice is preserved. |
| 7 |
dnl This file is offered as-is, without any warranty. |
| 8 |
|
| 9 |
AC_DEFUN([gl_FUNC_SETENV], |
| 10 |
[ |
| 11 |
AC_REQUIRE([gl_FUNC_SETENV_SEPARATE]) |
| 12 |
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles |
| 13 |
if test $ac_cv_func_setenv = no; then |
| 14 |
HAVE_SETENV=0 |
| 15 |
else |
| 16 |
AC_CACHE_CHECK([whether setenv validates arguments], |
| 17 |
[gl_cv_func_setenv_works], |
| 18 |
[AC_RUN_IFELSE([AC_LANG_PROGRAM([[ |
| 19 |
#include <stdlib.h> |
| 20 |
#include <errno.h> |
| 21 |
#include <string.h> |
| 22 |
]], [[ |
| 23 |
int result = 0; |
| 24 |
{ |
| 25 |
if (setenv ("", "", 0) != -1) |
| 26 |
result |= 1; |
| 27 |
else if (errno != EINVAL) |
| 28 |
result |= 2; |
| 29 |
} |
| 30 |
{ |
| 31 |
if (setenv ("a", "=", 1) != 0) |
| 32 |
result |= 4; |
| 33 |
else if (strcmp (getenv ("a"), "=") != 0) |
| 34 |
result |= 8; |
| 35 |
} |
| 36 |
return result; |
| 37 |
]])], |
| 38 |
[gl_cv_func_setenv_works=yes], [gl_cv_func_setenv_works=no], |
| 39 |
[case "$host_os" in |
| 40 |
# Guess yes on glibc systems. |
| 41 |
*-gnu* | gnu*) gl_cv_func_setenv_works="guessing yes" ;; |
| 42 |
# Guess yes on musl systems. |
| 43 |
*-musl* | midipix*) gl_cv_func_setenv_works="guessing yes" ;; |
| 44 |
# If we don't know, obey --enable-cross-guesses. |
| 45 |
*) gl_cv_func_setenv_works="$gl_cross_guess_normal" ;; |
| 46 |
esac |
| 47 |
])]) |
| 48 |
case "$gl_cv_func_setenv_works" in |
| 49 |
*yes) ;; |
| 50 |
*) |
| 51 |
REPLACE_SETENV=1 |
| 52 |
;; |
| 53 |
esac |
| 54 |
fi |
| 55 |
]) |
| 56 |
|
| 57 |
# Like gl_FUNC_SETENV, except prepare for separate compilation |
| 58 |
# (no REPLACE_SETENV, no AC_LIBOBJ). |
| 59 |
AC_DEFUN([gl_FUNC_SETENV_SEPARATE], |
| 60 |
[ |
| 61 |
AC_REQUIRE([gl_STDLIB_H_DEFAULTS]) |
| 62 |
AC_CHECK_DECLS_ONCE([setenv]) |
| 63 |
if test $ac_cv_have_decl_setenv = no; then |
| 64 |
HAVE_DECL_SETENV=0 |
| 65 |
fi |
| 66 |
AC_CHECK_FUNCS_ONCE([setenv]) |
| 67 |
gl_PREREQ_SETENV |
| 68 |
]) |
| 69 |
|
| 70 |
AC_DEFUN([gl_FUNC_UNSETENV], |
| 71 |
[ |
| 72 |
AC_REQUIRE([gl_STDLIB_H_DEFAULTS]) |
| 73 |
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles |
| 74 |
AC_CHECK_DECLS_ONCE([unsetenv]) |
| 75 |
if test $ac_cv_have_decl_unsetenv = no; then |
| 76 |
HAVE_DECL_UNSETENV=0 |
| 77 |
fi |
| 78 |
AC_CHECK_FUNCS([unsetenv]) |
| 79 |
if test $ac_cv_func_unsetenv = no; then |
| 80 |
HAVE_UNSETENV=0 |
| 81 |
else |
| 82 |
HAVE_UNSETENV=1 |
| 83 |
dnl Some BSDs return void, failing to do error checking. |
| 84 |
AC_CACHE_CHECK([for unsetenv() return type], [gt_cv_func_unsetenv_ret], |
| 85 |
[AC_COMPILE_IFELSE( |
| 86 |
[AC_LANG_PROGRAM( |
| 87 |
[[ |
| 88 |
#include <stdlib.h> |
| 89 |
extern |
| 90 |
#ifdef __cplusplus |
| 91 |
"C" |
| 92 |
#endif |
| 93 |
int unsetenv (const char *name); |
| 94 |
]], |
| 95 |
[[]])], |
| 96 |
[gt_cv_func_unsetenv_ret='int'], |
| 97 |
[gt_cv_func_unsetenv_ret='void'])]) |
| 98 |
if test $gt_cv_func_unsetenv_ret = 'void'; then |
| 99 |
AC_DEFINE([VOID_UNSETENV], [1], [Define to 1 if unsetenv returns void |
| 100 |
instead of int.]) |
| 101 |
REPLACE_UNSETENV=1 |
| 102 |
fi |
| 103 |
|
| 104 |
dnl Solaris 10 unsetenv does not remove all copies of a name. |
| 105 |
dnl Haiku alpha 2 unsetenv gets confused by assignment to environ. |
| 106 |
dnl OpenBSD 4.7 unsetenv("") does not fail. |
| 107 |
AC_CACHE_CHECK([whether unsetenv obeys POSIX], |
| 108 |
[gl_cv_func_unsetenv_works], |
| 109 |
[AC_RUN_IFELSE( |
| 110 |
[AC_LANG_PROGRAM([[ |
| 111 |
#include <stdlib.h> |
| 112 |
#include <errno.h> |
| 113 |
extern char **environ; |
| 114 |
]GL_MDA_DEFINES], |
| 115 |
[[ |
| 116 |
char entry1[] = "a=1"; |
| 117 |
char entry2[] = "b=2"; |
| 118 |
char *env[] = { entry1, entry2, NULL }; |
| 119 |
if (putenv ((char *) "a=1")) return 1; |
| 120 |
if (putenv (entry2)) return 2; |
| 121 |
entry2[0] = 'a'; |
| 122 |
unsetenv ("a"); |
| 123 |
if (getenv ("a")) return 3; |
| 124 |
if (!unsetenv ("") || errno != EINVAL) return 4; |
| 125 |
entry2[0] = 'b'; |
| 126 |
environ = env; |
| 127 |
if (!getenv ("a")) return 5; |
| 128 |
entry2[0] = 'a'; |
| 129 |
unsetenv ("a"); |
| 130 |
if (getenv ("a")) return 6; |
| 131 |
]])], |
| 132 |
[gl_cv_func_unsetenv_works=yes], |
| 133 |
[gl_cv_func_unsetenv_works=no], |
| 134 |
[case "$host_os" in |
| 135 |
# Guess yes on glibc systems. |
| 136 |
*-gnu*) gl_cv_func_unsetenv_works="guessing yes" ;; |
| 137 |
# If we don't know, obey --enable-cross-guesses. |
| 138 |
*) gl_cv_func_unsetenv_works="$gl_cross_guess_normal" ;; |
| 139 |
esac |
| 140 |
]) |
| 141 |
]) |
| 142 |
case "$gl_cv_func_unsetenv_works" in |
| 143 |
*yes) ;; |
| 144 |
*) |
| 145 |
REPLACE_UNSETENV=1 |
| 146 |
;; |
| 147 |
esac |
| 148 |
fi |
| 149 |
]) |
| 150 |
|
| 151 |
# Prerequisites of lib/setenv.c. |
| 152 |
AC_DEFUN([gl_PREREQ_SETENV], |
| 153 |
[ |
| 154 |
AC_REQUIRE([gl_ENVIRON]) |
| 155 |
AC_CHECK_HEADERS_ONCE([unistd.h]) |
| 156 |
AC_CHECK_HEADERS([search.h]) |
| 157 |
AC_CHECK_DECLS_ONCE([_putenv]) |
| 158 |
gl_CHECK_FUNCS_ANDROID([tsearch], [[#include <search.h>]]) |
| 159 |
]) |
| 160 |
|
| 161 |
# Prerequisites of lib/unsetenv.c. |
| 162 |
AC_DEFUN([gl_PREREQ_UNSETENV], |
| 163 |
[ |
| 164 |
AC_REQUIRE([gl_ENVIRON]) |
| 165 |
AC_CHECK_HEADERS_ONCE([unistd.h]) |
| 166 |
AC_CHECK_DECLS_ONCE([_putenv]) |
| 167 |
]) |