Debian Codegraph @

m4/printf-frexpl.m4

raw
1 # printf-frexpl.m4
2 # serial 10
3 dnl Copyright (C) 2007, 2009-2026 Free Software Foundation, Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7 dnl This file is offered as-is, without any warranty.
8
9 dnl Check how to define printf_frexpl() without linking with libm.
10
11 AC_DEFUN([gl_FUNC_PRINTF_FREXPL],
12 [
13 AC_REQUIRE([gl_MATH_H_DEFAULTS])
14 AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
15
16 dnl Subset of gl_FUNC_FREXPL_NO_LIBM.
17 gl_CHECK_FREXPL_NO_LIBM
18 if test $gl_cv_func_frexpl_no_libm = yes; then
19 gl_FUNC_FREXPL_WORKS
20 case "$gl_cv_func_frexpl_works" in
21 *yes) gl_func_frexpl_no_libm=yes ;;
22 *) gl_func_frexpl_no_libm=no; REPLACE_FREXPL=1 ;;
23 esac
24 else
25 gl_func_frexpl_no_libm=no
26 dnl Set REPLACE_FREXPL here because the system may have frexpl in libm.
27 REPLACE_FREXPL=1
28 fi
29 if test $gl_func_frexpl_no_libm = yes; then
30 AC_DEFINE([HAVE_FREXPL_IN_LIBC], [1],
31 [Define if the frexpl function is available in libc.])
32 dnl Also check whether it's declared.
33 dnl Mac OS X 10.3 has frexpl() in libc but doesn't declare it in <math.h>.
34 AC_CHECK_DECL([frexpl], , [HAVE_DECL_FREXPL=0], [[#include <math.h>]])
35 fi
36
37 gl_CHECK_LDEXPL_NO_LIBM
38 if test $gl_cv_func_ldexpl_no_libm = yes; then
39 gl_FUNC_LDEXPL_WORKS
40 case "$gl_cv_func_ldexpl_works" in
41 *yes)
42 AC_DEFINE([HAVE_LDEXPL_IN_LIBC], [1],
43 [Define if the ldexpl function is available in libc.])
44 dnl Also check whether it's declared.
45 dnl Mac OS X 10.3 has ldexpl() in libc but doesn't declare it in <math.h>.
46 AC_CHECK_DECL([ldexpl], , [HAVE_DECL_LDEXPL=0], [[#include <math.h>]])
47 ;;
48 esac
49 fi
50 ])