Debian Codegraph @

m4/mkdir.m4

raw
1 # mkdir.m4
2 # serial 20
3 dnl Copyright (C) 2001, 2003-2004, 2006, 2008-2026 Free Software Foundation,
4 dnl Inc.
5 dnl This file is free software; the Free Software Foundation
6 dnl gives unlimited permission to copy and/or distribute it,
7 dnl with or without modifications, as long as this notice is preserved.
8 dnl This file is offered as-is, without any warranty.
9
10 # On some systems, mkdir ("foo/", 0700) fails because of the trailing slash.
11 # On others, mkdir ("foo/./", 0700) mistakenly succeeds.
12 # On such systems, arrange to use a wrapper function.
13 AC_DEFUN([gl_FUNC_MKDIR],
14 [dnl
15 AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
16 AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
17 AC_CHECK_HEADERS_ONCE([unistd.h])
18 AC_CACHE_CHECK([whether mkdir handles trailing slash],
19 [gl_cv_func_mkdir_trailing_slash_works],
20 [rm -rf conftest.dir
21 AC_RUN_IFELSE(
22 [AC_LANG_PROGRAM([[
23 #include <sys/types.h>
24 #include <sys/stat.h>
25 ]GL_MDA_DEFINES],
26 [[return mkdir ("conftest.dir/", 0700);]])],
27 [gl_cv_func_mkdir_trailing_slash_works=yes],
28 [gl_cv_func_mkdir_trailing_slash_works=no],
29 [case "$host_os" in
30 # Guess yes on Linux systems.
31 linux-* | linux) gl_cv_func_mkdir_trailing_slash_works="guessing yes" ;;
32 # Guess yes on systems that emulate the Linux system calls.
33 midipix*) gl_cv_func_mkdir_trailing_slash_works="guessing yes" ;;
34 # Guess yes on glibc systems.
35 *-gnu* | gnu*) gl_cv_func_mkdir_trailing_slash_works="guessing yes" ;;
36 # Guess yes on MSVC, no on mingw.
37 windows*-msvc*) gl_cv_func_mkdir_trailing_slash_works="guessing yes" ;;
38 mingw* | windows*) AC_EGREP_CPP([Known], [
39 #ifdef _MSC_VER
40 Known
41 #endif
42 ],
43 [gl_cv_func_mkdir_trailing_slash_works="guessing yes"],
44 [gl_cv_func_mkdir_trailing_slash_works="guessing no"])
45 ;;
46 # If we don't know, obey --enable-cross-guesses.
47 *) gl_cv_func_mkdir_trailing_slash_works="$gl_cross_guess_normal" ;;
48 esac
49 ])
50 rm -rf conftest.dir
51 ])
52 case "$gl_cv_func_mkdir_trailing_slash_works" in
53 *yes) ;;
54 *)
55 REPLACE_MKDIR=1
56 ;;
57 esac
58
59 AC_CACHE_CHECK([whether mkdir handles trailing dot],
60 [gl_cv_func_mkdir_trailing_dot_works],
61 [rm -rf conftest.dir
62 AC_RUN_IFELSE(
63 [AC_LANG_PROGRAM([[
64 #include <sys/types.h>
65 #include <sys/stat.h>
66 ]GL_MDA_DEFINES],
67 [[return !mkdir ("conftest.dir/./", 0700);]])],
68 [gl_cv_func_mkdir_trailing_dot_works=yes],
69 [gl_cv_func_mkdir_trailing_dot_works=no],
70 [case "$host_os" in
71 # Guess yes on glibc systems.
72 *-gnu* | gnu*) gl_cv_func_mkdir_trailing_dot_works="guessing yes" ;;
73 # Guess yes on musl systems.
74 *-musl*) gl_cv_func_mkdir_trailing_dot_works="guessing yes" ;;
75 # Guess yes on systems that emulate the Linux system calls.
76 midipix*) gl_cv_func_mkdir_trailing_dot_works="guessing yes" ;;
77 # Guess no on native Windows.
78 mingw* | windows*) gl_cv_func_mkdir_trailing_dot_works="guessing no" ;;
79 # If we don't know, obey --enable-cross-guesses.
80 *) gl_cv_func_mkdir_trailing_dot_works="$gl_cross_guess_normal" ;;
81 esac
82 ])
83 rm -rf conftest.dir
84 ]
85 )
86 case "$gl_cv_func_mkdir_trailing_dot_works" in
87 *yes) ;;
88 *)
89 REPLACE_MKDIR=1
90 AC_DEFINE([FUNC_MKDIR_DOT_BUG], [1], [Define to 1 if mkdir mistakenly
91 creates a directory given with a trailing dot component.])
92 ;;
93 esac
94 ])