Debian Codegraph @

packages/seacas/applications/mapvar-kd/srchs-kd.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE SRCHS (
8 * NPSRF, NFSRF, LINKSRF, XYZSRF,
9 * NPTS, XYZPTS, TOLSRCH,
10 * NISR, NRSR, NISS, NRSS, ISRCHR, RSRCHR,
11 * LIST, IERR )
12
13 C-----------------------------------------------------------------------
14
15 C DESCRIPTION:
16
17 C THIS SUBROUTINE CALCULATES THE CLOSEST POINT PROBLEM
18 C BETWEEN NPTS POINTS AND NFSRF SURFACES AND RETURNS RESULTS OF
19 C SEARCH IN ISRCHR,RSRCHR
20
21 C USED HERE FOR FINDING LOCATION OF EITHER NODE OR ELEMENT CENTROID
22 C FROM MESH-B IN SHELL ELEMENT OF MESH-A
23
24 C-----------------------------------------------------------------------
25
26 C FORMAL PARAMETERS
27
28 C MEMORY : P=PERMANENT, S=SCRATCH
29 C NAME : IMPLICIT A-H,O-Z REAL, I-N INTEGER
30 C TYPE : INPUT_STATUS/OUTPUT_STATUS (I=INPUT,O=OUTPUT,P=PASSED,
31 C U=UNMODIFIED,-=UNDEFINED)
32 C DESCRIPTION : DESCRIPTION OF VARIABLE
33
34 C-----------------------------------------------------------------------
35
36 C CALLING ARGUMENTS:
37
38 C MEMORY NAME TYPE DESCRIPTION
39 C --- ---- --- -----------
40 C P NPSRF I/U NUMBER OF POINTS THAT DEFINE THE SURFACE
41 C P NFSRF I/U NUMBER OF SURFACES
42 C P LINKSRF I/U CONNECTIVITY OF SURFACES OF SIZE (4*NFSRF),
43 C NUMBERS REFER TO LOCATIONS IN XYZSRF ARRAY
44 C P XYZSRF I/U XYZ COORDS OF POINTS DEFINING SURFACE
45 C P NPTS I/U NUMBER OF POINTS TO BE SEARCHED
46 C P XYZPTS I/U XYZ COORDS OF POINTS TO BE SEARCHED
47 C P TOLSRCH I/U PROXIMITY TOLERANCE FOR POINT-TO-SURFACE SEARCH
48 C P NISR I/U NUMBER OF INTEGER SEARCH RESULTS (>=1)
49 C P NRSR I/U NUMBER OF REAL SEARCH RESULTS (>=4)
50 C P NISS I/U NUMBER OF INTEGER SEARCH SCRATCH (=5)
51 C P NRSS I/U NUMBER OF REAL SEARCH SCRATCH (=10)
52 C P ISRCHR -/O INTEGER SEARCH RESULTS
53 C P RSRCHR -/O REAL SEARCH RESULTS
54 C S LIST -/- LIST OF POTENTIAL CONTACTS FOR A SURFACE
55 C S IND -/- INDEX ARRAY INDICATING COORD. ORDER OF EACH POINT
56 C S IRNK -/- RANK ARRAY
57 C S IRNK2 -/- RANK ARRAY (INDIRECT)
58 C S INDX -/P INTERMEDIATE LIST OF POTENTIAL PAIRS (CONSTRUCTED
59 C AFTER THE INTERSECTION OF TWO OF THREE LISTS)
60 C S ILO -/- SEARCH BOX MINIMUM INDEX
61 C S IUP -/- SEARCH BOX MAXIMUM INDEX
62 C P IERR -/O ERROR FLAG
63
64 C-----------------------------------------------------------------------
65
66 include 'tapes.blk'
67 include 'debg.blk'
68
69 C INPUT/OUTPUT ARRAYS
70
71 C ... Needed to interact with C routines on 64-bit systems which have
72 C 8-byte integers in Fortran and 4-byte integers in C.
73 INTEGER*4 NPTS4, NDIM4, NLIST, LIST(*)
74
75 DIMENSION
76 * LINKSRF(4,NFSRF), XYZSRF(NPSRF,3),
77 * XYZPTS(NPTS,3),
78 * ISRCHR(NISR,NPTS), RSRCHR(NRSR,NPTS)
79 DIMENSION
80 * XMIN(3), XMAX(3), GXMIN(3), GXMAX(3)
81
82 C ISRCHR and RSRCHR must be initialized to zero
83
84 DO 1 I = 1, NPTS
85 DO 2 J = 1, NISR
86 ISRCHR(J,I) = 0
87 2 CONTINUE
88 DO 3 K = 1, NRSR
89 RSRCHR(K,I) = 0.
90 3 CONTINUE
91 1 CONTINUE
92
93 IF( NISR .LT. 1 .OR. NRSR .LT. 4 .OR. NISS .LT. 5 .OR.
94 * NRSS .LT. 10 )THEN
95 IERR = 1
96 RETURN
97 ENDIF
98 C DIMENSION OF COORDINATES
99 NDIM = 3
100 NDIM4 = 3
101 NPTS4 = NPTS
102
103 c ... Calculate min/max extents of all points...
104 GXMIN(1) = XYZPTS(1,1)
105 GXMAX(1) = XYZPTS(1,1)
106 GXMIN(2) = XYZPTS(1,2)
107 GXMAX(2) = XYZPTS(1,2)
108 GXMIN(3) = XYZPTS(1,3)
109 GXMAX(3) = XYZPTS(1,3)
110 DO 10 I=2,NPTS
111 GXMIN(1) = MIN(GXMIN(1), XYZPTS(I,1))
112 GXMIN(2) = MIN(GXMIN(2), XYZPTS(I,2))
113 GXMIN(3) = MIN(GXMIN(3), XYZPTS(I,3))
114
115 GXMAX(1) = MAX(GXMAX(1), XYZPTS(I,1))
116 GXMAX(2) = MAX(GXMAX(2), XYZPTS(I,2))
117 GXMAX(3) = MAX(GXMAX(3), XYZPTS(I,3))
118 10 CONTINUE
119
120 C Build KD Tree
121 if (idebug .ge. 2) then
122 call excpus(t1)
123 write(nout, *) ' In kdBuildTree ', npts4
124 write(ntpout, *) ' In kdBuildTree', npts4
125 end if
126
127 call kdbuildtree(xyzpts, npts4, ndim4)
128
129 if (idebug .ge. 2) then
130 call excpus(t2)
131 write(nout, *) ' Out of kdBuildTree', t2-t1
132 write(ntpout, *) ' Out of kdBuildTree', t2-t1
133 end if
134
135 C LOOP OVER SURFACES AND SEARCH FOR POINTS WITHIN CAPTURE BOX
136 qt = 0.0
137 j = 0
138 nlistt = 0
139 nlistp = 0
140 nskip = 0
141 call excpus(t3p)
142
143 C LOOP OVER SURFACES AND SEARCH FOR POINTS WITHIN CAPTURE BOX
144 DO 100 IFSRF = 1, NFSRF
145 NI = LINKSRF(1,IFSRF)
146 NJ = LINKSRF(2,IFSRF)
147 NK = LINKSRF(3,IFSRF)
148 NL = LINKSRF(4,IFSRF)
149
150 XMINMS = MIN(XYZSRF(NI,1),XYZSRF(NJ,1),
151 * XYZSRF(NK,1),XYZSRF(NL,1))
152 XMAXMS = MAX(XYZSRF(NI,1),XYZSRF(NJ,1),
153 * XYZSRF(NK,1),XYZSRF(NL,1))
154 YMINMS = MIN(XYZSRF(NI,2),XYZSRF(NJ,2),
155 * XYZSRF(NK,2),XYZSRF(NL,2))
156 YMAXMS = MAX(XYZSRF(NI,2),XYZSRF(NJ,2),
157 * XYZSRF(NK,2),XYZSRF(NL,2))
158 ZMINMS = MIN(XYZSRF(NI,3),XYZSRF(NJ,3),
159 * XYZSRF(NK,3),XYZSRF(NL,3))
160 ZMAXMS = MAX(XYZSRF(NI,3),XYZSRF(NJ,3),
161 * XYZSRF(NK,3),XYZSRF(NL,3))
162 XDEL = XMAXMS - XMINMS
163 YDEL = YMAXMS - YMINMS
164 ZDEL = ZMAXMS - ZMINMS
165 TOLER = TOLSRCH * MAX(XDEL,YDEL,ZDEL)
166 XMIN(1) = XMINMS - TOLER
167 XMAX(1) = XMAXMS + TOLER
168 XMIN(2) = YMINMS - TOLER
169 XMAX(2) = YMAXMS + TOLER
170 XMIN(3) = ZMINMS - TOLER
171 XMAX(3) = ZMAXMS + TOLER
172
173 C ... Build a list of points in the query region...
174 j = j + 1
175 C ... Skip past points that are outside search domain.
176 C This is much faster than the failed search in kdrectquery, but
177 C does add overhead if all points are in the domain....
178
179 if (xmax(1) .lt. gxmin(1) .or. xmin(1) .gt. gxmax(1) .or.
180 * xmax(2) .lt. gxmin(2) .or. xmin(2) .gt. gxmax(2) .or.
181 * xmax(3) .lt. gxmin(3) .or. xmin(3) .gt. gxmax(3)) then
182 nskip = nskip + 1
183 nlist = 0
184 else
185 call excpus(t4)
186 call kdrectquery(xyzpts,npts4,ndim4, xmin,xmax, list,nlist)
187 call excpus(t5)
188 qt = qt + (t5-t4)
189 end if
190
191 C ... Debugging statistics. Also give user an idea that calculation is progressing...
192 if (idebug .ge. 2) then
193 nlistp = nlistp + nlist
194 nlistt = nlistt + nlist
195 if (j .eq. 100000 .or. ifsrf .eq. nfsrf) then
196 call excpus(t3)
197 write (nout, 190) ifsrf, nfsrf, t3-t3p, t3-t2,
198 * j/(t3-t3p), ifsrf/(t3-t2), nlistp, nlistt
199 write (ntpout, 190) ifsrf, nfsrf, t3-t3p, t3-t2,
200 * j/(t3-t3p), ifsrf/(t3-t2), nlistp, nlistt
201 j = 0
202 t3p = t3
203 nlistp = 0
204 end if
205 end if
206
207 DO 140 K = 1, NLIST
208 lval = list(k)
209 CALL SHLSRC(
210 * NDIM, NPTS, NPSRF, NFSRF, NISR,
211 * NRSR, NRSS, XYZSRF, XYZPTS, LINKSRF,
212 * ISRCHR, RSRCHR, LVAL, IFSRF, TOLSRCH, IERR )
213
214 140 CONTINUE
215 100 CONTINUE
216
217 C ... More debugging stats
218 if (idebug .ge. 2) then
219 call excpus(t3)
220 write(nout, *) ' Finish Queries', t3-t2, NFSRF/(t3-t2), qt
221 write(ntpout, *) ' Finish Queries', t3-t2, NFSRF/(t3-t2), qt
222 write(nout, *) ' Matches = ',nlistt,' Rate = ',nlistt/(t3-t2)
223 write(ntpout, *) ' Matches = ',nlistt,' Rate = ',nlistt/(t3-t2)
224 end if
225
226 call kdkilltree()
227
228 190 format(1x,i9,'/',i9,' T= ',1pe10.3,'/',1pe10.3,
229 * ', R= ',1pe10.3,'/',1pe10.3,' M = ',i10,'/',i10)
230
231 RETURN
232 END