Debian Codegraph @

packages/seacas/applications/mapvar-kd/srchq-kd.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE SRCHQ (
8 * NPSRF, NFSRF, LINKSRF, XYZSRF,
9 * NPTS, XYZPTS, TOLSRCH,
10 * NISR, NRSR, NISS, NRSS, ISRCHR, RSRCHR,
11 * LIST, IERR )
12
13 C-----------------------------------------------------------------------
14
15 C DESCRIPTION:
16
17 C THIS SUBROUTINE CALCULATES THE CLOSEST POINT PROBLEM
18 C BETWEEN NPTS POINTS AND NFSRF SURFACES AND RETURNS RESULTS OF
19 C SEARCH IN ISRCHR,RSRCHR
20
21 C USED HERE FOR FINDING LOCATION OF EITHER NODE OR ELEMENT CENTROID
22 C FROM MESH-B IN QUAD-4 ELEMENT OF MESH-A
23
24 C-----------------------------------------------------------------------
25
26 C FORMAL PARAMETERS
27
28 C MEMORY : P=PERMANENT, S=SCRATCH
29 C NAME : IMPLICIT A-H,O-Z REAL, I-N INTEGER
30 C TYPE : INPUT_STATUS/OUTPUT_STATUS (I=INPUT,O=OUTPUT,P=PASSED,
31 C U=UNMODIFIED,-=UNDEFINED)
32 C DESCRIPTION : DESCRIPTION OF VARIABLE
33
34 C-----------------------------------------------------------------------
35
36 C CALLING ARGUMENTS:
37
38 C MEMORY NAME TYPE DESCRIPTION
39 C --- ---- --- -----------
40 C P NPSRF I/U NUMBER OF POINTS THAT DEFINE THE SURFACE
41 C P NFSRF I/U NUMBER OF SURFACES
42 C P LINKSRF I/U CONNECTIVITY OF SURFACES OF SIZE (4*NFSRF),
43 C NUMBERS REFER TO LOCATIONS IN XYZSRF ARRAY
44 C P XYZSRF I/U XYZ COORDS OF POINTS DEFINING SURFACE
45 C P NPTS I/U NUMBER OF POINTS TO BE SEARCHED
46 C P XYZPTS I/U XYZ COORDS OF POINTS TO BE SEARCHED
47 C P TOLSRCH I/U PROXIMITY TOLERANCE FOR POINT-TO-SURFACE SEARCH
48 C P NISR I/U NUMBER OF INTEGER SEARCH RESULTS (>=1)
49 C P NRSR I/U NUMBER OF REAL SEARCH RESULTS (>=4)
50 C P NISS I/U NUMBER OF INTEGER SEARCH SCRATCH (=5)
51 C P NRSS I/U NUMBER OF REAL SEARCH SCRATCH (=10)
52 C P ISRCHR -/O INTEGER SEARCH RESULTS
53 C P RSRCHR -/O REAL SEARCH RESULTS
54 C S LIST -/- LIST OF POTENTIAL CONTACTS FOR A SURFACE
55 C P IERR -/O ERROR FLAG
56
57 C-----------------------------------------------------------------------
58
59 include 'amesh.blk'
60 include 'tapes.blk'
61 include 'debg.blk'
62
63 C INPUT/OUTPUT ARRAYS
64
65 C ... Needed to interact with C routines on 64-bit systems which have
66 C 8-byte integers in Fortran and 4-byte integers in C.
67 INTEGER*4 NPTS4, NDIM4, NLIST, LIST(*)
68
69 DIMENSION
70 * LINKSRF(NELNDA,NFSRF), XYZSRF(NPSRF,3),
71 * XYZPTS(NPTS,3),
72 * ISRCHR(NISR,NPTS), RSRCHR(NRSR,NPTS)
73 DIMENSION
74 * XMIN(2), XMAX(2), GXMIN(2), GXMAX(2)
75
76 C ISRCHR and RSRCHR must be initialized to zero
77
78 DO 1 I = 1, NPTS
79 DO 2 J = 1, NISR
80 ISRCHR(J,I) = 0
81 2 CONTINUE
82 DO 3 K = 1, NRSR
83 RSRCHR(K,I) = 0.
84 3 CONTINUE
85 1 CONTINUE
86
87 IF( NISR .LT. 1 .OR. NRSR .LT. 2 .OR. NISS .LT. 5 .OR.
88 * NRSS .LT. 10 )THEN
89 IERR = 1
90 RETURN
91 ENDIF
92
93 C DIMENSION OF COORDINATES
94 NDIM = 2
95 NDIM4 = NDIM
96 NPTS4 = NPTS
97
98 c ... Calculate min/max extents of all points...
99 GXMIN(1) = XYZPTS(1,1)
100 GXMAX(1) = XYZPTS(1,1)
101 GXMIN(2) = XYZPTS(1,2)
102 GXMAX(2) = XYZPTS(1,2)
103 DO 10 I=2,NPTS
104 GXMIN(1) = MIN(GXMIN(1), XYZPTS(I,1))
105 GXMIN(2) = MIN(GXMIN(2), XYZPTS(I,2))
106
107 GXMAX(1) = MAX(GXMAX(1), XYZPTS(I,1))
108 GXMAX(2) = MAX(GXMAX(2), XYZPTS(I,2))
109 10 CONTINUE
110
111 C Build KD Tree
112 if (idebug .ge. 2) then
113 call excpus(t1)
114 write(nout, *) ' In kdBuildTree ', npts4
115 write(ntpout, *) ' In kdBuildTree ', npts4
116 end if
117
118 call kdbuildtree(xyzpts, npts4, ndim4)
119
120 if (idebug .ge. 2) then
121 call excpus(t2)
122 write(nout, *) ' Out of kdBuildTree', t2-t1
123 write(ntpout, *) ' Out of kdBuildTree', t2-t1
124 end if
125
126 C LOOP OVER SURFACES AND SEARCH FOR POINTS WITHIN CAPTURE BOX
127 qt = 0.0
128 j = 0
129 nlistt = 0
130 nlistp = 0
131 nskip = 0
132 call excpus(t3p)
133
134 C LOOP OVER SURFACES AND SEARCH FOR POINTS WITHIN CAPTURE BOX
135 DO 100 IFSRF = 1, NFSRF
136 NI = LINKSRF(1,IFSRF)
137 NJ = LINKSRF(2,IFSRF)
138 NK = LINKSRF(3,IFSRF)
139 NL = LINKSRF(4,IFSRF)
140
141 XMINMS = MIN(XYZSRF(NI,1),XYZSRF(NJ,1),
142 * XYZSRF(NK,1),XYZSRF(NL,1))
143 XMAXMS = MAX(XYZSRF(NI,1),XYZSRF(NJ,1),
144 * XYZSRF(NK,1),XYZSRF(NL,1))
145 YMINMS = MIN(XYZSRF(NI,2),XYZSRF(NJ,2),
146 * XYZSRF(NK,2),XYZSRF(NL,2))
147 YMAXMS = MAX(XYZSRF(NI,2),XYZSRF(NJ,2),
148 * XYZSRF(NK,2),XYZSRF(NL,2))
149 TOLER = TOLSRCH * (XMAXMS - XMINMS)
150 XMIN(1) = XMINMS - TOLER
151 XMAX(1) = XMAXMS + TOLER
152 TOLER = TOLSRCH * (YMAXMS - YMINMS)
153 XMIN(2) = YMINMS - TOLER
154 XMAX(2) = YMAXMS + TOLER
155
156 C ... Build a list of points in the query region...
157 j = j + 1
158 C ... Skip past points that are outside search domain.
159 C This is much faster than the failed search in kdrectquery, but
160 C does add overhead if all points are in the domain....
161
162 if (xmax(1) .lt. gxmin(1) .or. xmin(1) .gt. gxmax(1) .or.
163 * xmax(2) .lt. gxmin(2) .or. xmin(2) .gt. gxmax(2)) then
164 nskip = nskip + 1
165 nlist = 0
166 else
167 call excpus(t4)
168 call kdrectquery(xyzpts,npts4,ndim4, xmin,xmax, list,nlist)
169 call excpus(t5)
170 qt = qt + (t5-t4)
171 end if
172
173 C ... Debugging statistics. Also give user an idea that calculation is progressing...
174 if (idebug .ge. 2) then
175 nlistp = nlistp + nlist
176 nlistt = nlistt + nlist
177 if (j .eq. 100000 .or. ifsrf .eq. nfsrf) then
178 call excpus(t3)
179 write (nout, 190) ifsrf, nfsrf, t3-t3p, t3-t2,
180 * j/(t3-t3p), ifsrf/(t3-t2), nlistp, nlistt
181 write (ntpout, 190) ifsrf, nfsrf, t3-t3p, t3-t2,
182 * j/(t3-t3p), ifsrf/(t3-t2), nlistp, nlistt
183 j = 0
184 t3p = t3
185 nlistp = 0
186 end if
187 end if
188
189 DO 140 K = 1, NLIST
190 lval = list(k)
191 CALL QADSRC(
192 * NDIM, NPTS, NPSRF, NFSRF, NISR,
193 * NRSR, NRSS, XYZSRF, XYZPTS, LINKSRF,
194 * ISRCHR, RSRCHR, LVAL, IFSRF, IERR )
195 140 CONTINUE
196 100 CONTINUE
197
198 C ... More debugging stats
199 if (idebug .ge. 2) then
200 call excpus(t3)
201 write(nout, *) ' Finish Queries', t3-t2, NFSRF/(t3-t2), qt
202 write(ntpout, *) ' Finish Queries', t3-t2, NFSRF/(t3-t2), qt
203 write(nout, *) ' Matches = ',nlistt,' Rate = ',nlistt/(t3-t2)
204 write(ntpout, *) ' Matches = ',nlistt,' Rate = ',nlistt/(t3-t2)
205 end if
206
207 call kdkilltree()
208
209 190 format(1x,i9,'/',i9,' T= ',1pe10.3,'/',1pe10.3,
210 * ', R= ',1pe10.3,'/',1pe10.3,' M = ',i10,'/',i10)
211
212 RETURN
213 END