Debian Codegraph @

packages/seacas/applications/mapvar-kd/srchh-kd.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE SRCHH (
8 * NPSRF, NFSRF, LINKSRF, XYZSRF,
9 * NPTS, XYZPTS, TOLSRCH,
10 * NISR, NRSR, NISS, NRSS, ISRCHR, RSRCHR,
11 * LIST, IERR)
12
13 C-----------------------------------------------------------------------
14
15 C DESCRIPTION:
16
17 C THIS SUBROUTINE CALCULATES THE CLOSEST POINT PROBLEM
18 C BETWEEN NPTS POINTS AND NFSRF SURFACES AND RETURNS RESULTS OF
19 C SEARCH IN ISRCHR,RSRCHR
20
21 C USED HERE FOR FINDING LOCATION OF EITHER NODE OR ELEMENT CENTROID
22 C FROM MESH-B IN HEX-8 ELEMENT OF MESH-A
23
24 C-----------------------------------------------------------------------
25
26 C FORMAL PARAMETERS
27
28 C MEMORY : P=PERMANENT, S=SCRATCH
29 C NAME : IMPLICIT A-H,O-Z REAL, I-N INTEGER
30 C TYPE : INPUT_STATUS/OUTPUT_STATUS (I=INPUT,O=OUTPUT,P=PASSED,
31 C U=UNMODIFIED,-=UNDEFINED)
32 C DESCRIPTION : DESCRIPTION OF VARIABLE
33
34 C-----------------------------------------------------------------------
35
36 C CALLING ARGUMENTS:
37
38 C MEMORY NAME TYPE DESCRIPTION
39 C --- ---- --- -----------
40 C P NPSRF I/U NUMBER OF POINTS THAT DEFINE THE SURFACE
41 C P NFSRF I/U NUMBER OF SURFACES
42 C P LINKSRF I/U CONNECTIVITY OF SURFACES OF SIZE (8*NFSRF),
43 C NUMBERS REFER TO LOCATIONS IN XYZSRF ARRAY
44 C P XYZSRF I/U XYZ COORDS OF POINTS DEFINING SURFACE
45 C P NPTS I/U NUMBER OF POINTS TO BE SEARCHED
46 C P XYZPTS I/U XYZ COORDS OF POINTS TO BE SEARCHED
47 C P TOLSRCH I/U PROXIMITY TOLERANCE FOR POINT-TO-SURFACE SEARCH
48 C P NISR I/U NUMBER OF INTEGER SEARCH RESULTS (>=1)
49 C P NRSR I/U NUMBER OF REAL SEARCH RESULTS (>=4)
50 C P NISS I/U NUMBER OF INTEGER SEARCH SCRATCH (=5)
51 C P NRSS I/U NUMBER OF REAL SEARCH SCRATCH (=10)
52 C P ISRCHR -/O INTEGER SEARCH RESULTS
53 C P RSRCHR -/O REAL SEARCH RESULTS
54 C S LIST -/- LIST OF POTENTIAL CONTACTS FOR A SURFACE
55 C P IERR -/O ERROR FLAG
56
57 C-----------------------------------------------------------------------
58
59 include 'tapes.blk'
60 include 'debg.blk'
61
62 C INPUT/OUTPUT ARRAYS
63
64 C ... Needed to interact with C routines on 64-bit systems which have
65 C 8-byte integers in Fortran and 4-byte integers in C.
66 INTEGER*4 NPTS4, NDIM4, NLIST, LIST(*)
67
68 DIMENSION
69 * LINKSRF(8,NFSRF), XYZSRF(NPSRF,3),
70 * XYZPTS(NPTS,3),
71 * ISRCHR(NISR,NPTS), RSRCHR(NRSR,NPTS)
72 DIMENSION
73 * XMIN(3), XMAX(3), GXMIN(3), GXMAX(3)
74
75 C ISRCHR and RSRCHR must be initialized to zero
76
77 DO 1 I = 1, NPTS
78 DO 2 J = 1, NISR
79 ISRCHR(J,I) = 0
80 2 CONTINUE
81 DO 3 K = 1, NRSR
82 RSRCHR(K,I) = 0.
83 3 CONTINUE
84 1 CONTINUE
85
86 IF( NISR .LT. 1 .OR. NRSR .LT. 3 .OR. NISS .LT. 5 .OR.
87 * NRSS .LT. 10 )THEN
88 IERR = 1
89 RETURN
90 ENDIF
91
92 C DIMENSION OF COORDINATES
93 NDIM = 3
94 NDIM4 = 3
95 NPTS4 = NPTS
96
97 c ... Calculate min/max extents of all points...
98 GXMIN(1) = XYZPTS(1,1)
99 GXMAX(1) = XYZPTS(1,1)
100 GXMIN(2) = XYZPTS(1,2)
101 GXMAX(2) = XYZPTS(1,2)
102 GXMIN(3) = XYZPTS(1,3)
103 GXMAX(3) = XYZPTS(1,3)
104 DO 10 I=2,NPTS
105 GXMIN(1) = MIN(GXMIN(1), XYZPTS(I,1))
106 GXMIN(2) = MIN(GXMIN(2), XYZPTS(I,2))
107 GXMIN(3) = MIN(GXMIN(3), XYZPTS(I,3))
108
109 GXMAX(1) = MAX(GXMAX(1), XYZPTS(I,1))
110 GXMAX(2) = MAX(GXMAX(2), XYZPTS(I,2))
111 GXMAX(3) = MAX(GXMAX(3), XYZPTS(I,3))
112 10 CONTINUE
113
114 C Build KD Tree
115 if (idebug .ge. 2) then
116 call excpus(t1)
117 write(nout, *) ' In kdBuildTree ', npts4
118 write(ntpout, *) ' In kdBuildTree', npts4
119 end if
120
121 call kdbuildtree(xyzpts, npts4, ndim4)
122
123 if (idebug .ge. 2) then
124 call excpus(t2)
125 write(nout, *) ' Out of kdBuildTree', t2-t1
126 write(ntpout, *) ' Out of kdBuildTree', t2-t1
127 end if
128
129 C LOOP OVER SURFACES AND SEARCH FOR POINTS WITHIN CAPTURE BOX
130 qt = 0.0
131 j = 0
132 nlistt = 0
133 nlistp = 0
134 nskip = 0
135 call excpus(t3p)
136
137 DO 100 IFSRF = 1, NFSRF
138
139 C CONSTRUCT THE BOUNDING BOX FOR A SURFACE
140 NI = LINKSRF(1,IFSRF)
141 NJ = LINKSRF(2,IFSRF)
142 NK = LINKSRF(3,IFSRF)
143 NL = LINKSRF(4,IFSRF)
144 NM = LINKSRF(5,IFSRF)
145 NN = LINKSRF(6,IFSRF)
146 NO = LINKSRF(7,IFSRF)
147 NP = LINKSRF(8,IFSRF)
148
149 XMINMS = MIN(XYZSRF(NI,1),XYZSRF(NJ,1),
150 * XYZSRF(NK,1),XYZSRF(NL,1),
151 * XYZSRF(NM,1),XYZSRF(NN,1),
152 * XYZSRF(NO,1),XYZSRF(NP,1))
153 XMAXMS = MAX(XYZSRF(NI,1),XYZSRF(NJ,1),
154 * XYZSRF(NK,1),XYZSRF(NL,1),
155 * XYZSRF(NM,1),XYZSRF(NN,1),
156 * XYZSRF(NO,1),XYZSRF(NP,1))
157 YMINMS = MIN(XYZSRF(NI,2),XYZSRF(NJ,2),
158 * XYZSRF(NK,2),XYZSRF(NL,2),
159 * XYZSRF(NM,2),XYZSRF(NN,2),
160 * XYZSRF(NO,2),XYZSRF(NP,2))
161 YMAXMS = MAX(XYZSRF(NI,2),XYZSRF(NJ,2),
162 * XYZSRF(NK,2),XYZSRF(NL,2),
163 * XYZSRF(NM,2),XYZSRF(NN,2),
164 * XYZSRF(NO,2),XYZSRF(NP,2))
165 ZMINMS = MIN(XYZSRF(NI,3),XYZSRF(NJ,3),
166 * XYZSRF(NK,3),XYZSRF(NL,3),
167 * XYZSRF(NM,3),XYZSRF(NN,3),
168 * XYZSRF(NO,3),XYZSRF(NP,3))
169 ZMAXMS = MAX(XYZSRF(NI,3),XYZSRF(NJ,3),
170 * XYZSRF(NK,3),XYZSRF(NL,3),
171 * XYZSRF(NM,3),XYZSRF(NN,3),
172 * XYZSRF(NO,3),XYZSRF(NP,3))
173 TOLER = TOLSRCH * (XMAXMS - XMINMS)
174 XMIN(1) = XMINMS - TOLER
175 XMAX(1) = XMAXMS + TOLER
176 TOLER = TOLSRCH * (YMAXMS - YMINMS)
177 XMIN(2) = YMINMS - TOLER
178 XMAX(2) = YMAXMS + TOLER
179 TOLER = TOLSRCH * (ZMAXMS - ZMINMS)
180 XMIN(3) = ZMINMS - TOLER
181 XMAX(3) = ZMAXMS + TOLER
182
183 C ... Build a list of points in the query region...
184 j = j + 1
185 C ... Skip past points that are outside search domain.
186 C This is much faster than the failed search in kdrectquery, but
187 C does add overhead if all points are in the domain....
188
189 if (xmax(1) .lt. gxmin(1) .or. xmin(1) .gt. gxmax(1) .or.
190 * xmax(2) .lt. gxmin(2) .or. xmin(2) .gt. gxmax(2) .or.
191 * xmax(3) .lt. gxmin(3) .or. xmin(3) .gt. gxmax(3)) then
192 nskip = nskip + 1
193 nlist = 0
194 else
195 call excpus(t4)
196 call kdrectquery(xyzpts,npts4,ndim4, xmin,xmax, list,nlist)
197 call excpus(t5)
198 qt = qt + (t5-t4)
199 end if
200
201 C ... Debugging statistics. Also give user an idea that calculation is progressing...
202 if (idebug .ge. 2) then
203 nlistp = nlistp + nlist
204 nlistt = nlistt + nlist
205 if (j .eq. 100000 .or. ifsrf .eq. nfsrf) then
206 call excpus(t3)
207 write (nout, 190) ifsrf, nfsrf, t3-t3p, t3-t2,
208 * j/(t3-t3p), ifsrf/(t3-t2), nlistp, nlistt
209 write (ntpout, 190) ifsrf, nfsrf, t3-t3p, t3-t2,
210 * j/(t3-t3p), ifsrf/(t3-t2), nlistp, nlistt
211 j = 0
212 t3p = t3
213 nlistp = 0
214 end if
215 end if
216
217 DO 140 K = 1, NLIST
218 lval = list(k)
219 CALL HEXSRC(
220 * NDIM, NPTS, NPSRF, NFSRF, NISR,
221 * NRSR, NRSS, XYZSRF, XYZPTS, LINKSRF,
222 * ISRCHR, RSRCHR, LVAL, IFSRF,
223 * IERR )
224 140 CONTINUE
225 100 CONTINUE
226
227 C ... More debugging stats
228 if (idebug .ge. 2) then
229 call excpus(t3)
230 write(nout, *) ' Finish Queries', t3-t2, NFSRF/(t3-t2), qt
231 write(ntpout, *) ' Finish Queries', t3-t2, NFSRF/(t3-t2), qt
232 write(nout, *) ' Matches = ',nlistt,' Rate = ',nlistt/(t3-t2)
233 write(ntpout, *) ' Matches = ',nlistt,' Rate = ',nlistt/(t3-t2)
234 end if
235
236 call kdkilltree()
237
238 190 format(1x,i9,'/',i9,' T= ',1pe10.3,'/',1pe10.3,
239 * ', R= ',1pe10.3,'/',1pe10.3,' M = ',i10,'/',i10)
240 RETURN
241 END