Debian Codegraph @

packages/seacas/applications/algebra/ag_zmnps.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE ZMNPS (NUMNP, NUMNPO, IXNODE, NUMNPS, LNPSNL,
9 & IDNPS, NNNPS, IXNNPS, NDNPS, IXDNPS, LTNNPS, FACNPS,
10 & NEWIX, IXNPS)
11 C=======================================================================
12
13 C --*** ZMNPS *** (ALGEBRA) Compress database node sets
14 C -- Written by Amy Gilkey - revised 07/13/89
15 C --
16 C --ZMNPS compresses the node set information by renumbering the
17 C --nodes and removing deleted nodes.
18 C --
19 C --Parameters:
20 C -- NUMNP - IN - the number of nodes
21 C -- NUMNPO - IN - the number of nodes
22 C -- IXNODE - IN - the indices of the output nodes(iff NUMNPO <> NUMNP)
23 C -- NUMNPS - IN/OUT - the number of node sets
24 C -- LNPSNL - IN/OUT - the length of the node sets node list
25 C -- IDNPS - IN/OUT - the node set ID for each set
26 C -- NNNPS - IN/OUT - the number of nodes for each set
27 C -- IXNNPS - IN/OUT - the index of the first node for each set
28 C -- NDNPS - IN/OUT - number of distribution factors for each node set
29 C -- IXDNPS - IN/OUT - indices into FACNPS; location of 1st dist fact/n set
30 C -- LTNNPS - IN/OUT - the nodes for all sets
31 C -- FACNPS - IN/OUT - the distribution factors for all sets
32 C -- NEWIX - SCRATCH - size = NUMNP
33 C -- IXNPS - SCRATCH - size = LNPSNL
34
35 INTEGER NUMNP
36 INTEGER NUMNPO
37 INTEGER IXNODE(*)
38 INTEGER NUMNPS
39 INTEGER LNPSNL
40 INTEGER IDNPS(*)
41 INTEGER NNNPS(*)
42 INTEGER IXNNPS(*)
43 INTEGER NDNPS(*)
44 INTEGER IXDNPS(*)
45 INTEGER LTNNPS(*)
46 REAL FACNPS(*)
47 INTEGER NEWIX(*)
48 INTEGER IXNPS(*)
49
50 IF (NUMNP .EQ. NUMNPO) RETURN
51
52 DO 100 INP = 1, NUMNP
53 NEWIX(INP) = 0
54 100 CONTINUE
55 DO 110 IX = 1, NUMNPO
56 NEWIX(IXNODE(IX)) = IX
57 110 CONTINUE
58
59 NLO = 0
60 DO 120 NL = 1, LNPSNL
61 IF (NEWIX(LTNNPS(NL)) .GT. 0) THEN
62 NLO = NLO + 1
63 LTNNPS(NLO) = NEWIX(LTNNPS(NL))
64 FACNPS(NLO) = FACNPS(NL)
65 IXNPS(NL) = NLO
66 ELSE
67 IXNPS(NL) = 0
68 END IF
69 120 CONTINUE
70 LNPSNL = NLO
71
72 NNPSO = 0
73 DO 140 INPS = 1, NUMNPS
74 NN = 0
75 IX0 = 0
76 DO 130 IX = IXNNPS(INPS), IXNNPS(INPS)+NNNPS(INPS)-1
77 IF (IXNPS(IX) .GT. 0) THEN
78 NN = NN + 1
79 IF (IX0 .EQ. 0) IX0 = IXNPS(IX)
80 END IF
81 130 CONTINUE
82 IF (NN .GT. 0) THEN
83 NNPSO = NNPSO + 1
84 IDNPS(NNPSO) = IDNPS(INPS)
85 NNNPS(NNPSO) = NN
86 IXNNPS(NNPSO) = IX0
87 NDNPS(NNPSO) = NN
88 IXDNPS(NNPSO) = IX0
89 END IF
90 140 CONTINUE
91 NUMNPS = NNPSO
92
93 RETURN
94 END