Debian Codegraph @

packages/seacas/applications/algebra/ag_loceqv.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE LOCEQV (NAMECO, NAMES,
9 & NUMENT, NAMENT, TYPENT, INXENT, VALENT, ITMENT, IEVENT, VSZENT,
10 & ISEVOK, IDEFEV, NUMEV, MAXSTK, NERR)
11 C=======================================================================
12
13 C --*** LOCEQV *** (ALGEBRA) Locate equation variables and add to list
14 C -- Written by Amy Gilkey - revised 05/25/88
15 C --
16 C --LOCEQV determines the type, location, and node/element specific (if any)
17 C --of an equation's variables. The variable names, types, and
18 C --database indices (for input variables) are added to the /VAR../
19 C --arrays.
20 C --
21 C --The variable name in the NAMVAR array is stripped of any specifier
22 C --to eliminate multiple references to a single variable.
23 C --The node/element specifier is stored in VALENT and associated with
24 C --the equation reference. Similarly, all global input variables are
25 C --assigned one dummy name, and the variable number is stored in VALENT.
26 C --
27 C --If there have been no errors up to this point, the equation is in
28 C --postfix form. Each entry in the equation is assigned a number
29 C --representing the number of items expected after the entry is put
30 C --on the stack. With a nodal or element variable (or an action
31 C --involving such a variable), this is simply the number of nodes or
32 C --elements. With a constant, TIME or global variable, this may be
33 C --one or the number of nodes or element if the value must be converted
34 C --to an array.
35 C --
36 C --Parameters:
37 C -- NAMECO - IN - the coordinate names
38 C -- NAMES - IN - the global, nodal, and element variable names
39 C -- NUMENT - IN - the number of entries (as in /ENT../)
40 C -- NAMENT - IN/OUT - the equation entries (as in /ENT../)
41 C -- TYPENT - IN - the type of each equation entry (as in /ENT../)
42 C -- INXENT - IN/OUT - based on TYPENT (as in /ENT../)
43 C -- VALENT - IN/OUT - based on TYPENT (as in /ENT../)
44 C -- ITMENT - IN/OUT - based on TYPENT (as in /ENT../)
45 C -- IEVENT - IN/OUT - the ISEVOK index for this entry (as in /ENT../)
46 C -- VSZENT - OUT - the type of variable on the stack after processing
47 C -- this entry (as in /ENT../)
48 C -- ISEVOK - IN/OUT - the element variable truth table;
49 C -- includes input, temporary, and output variables
50 C -- IDEFEV - IN - the default ISEVOK variable index
51 C -- NUMEV - IN/OUT - the maximum ISEVOK variable index
52 C -- MAXSTK - OUT - the maximum stack size for this equation
53 C -- NERR - IN/OUT - the number of errors in the equation, may be set
54 C --
55 C --Common Variables:
56 C -- Sets NUMINP, IXLHS, NAMVAR, TYPVAR, IDVAR, ISTVAR, IEVVAR of /VAR../
57 C -- Uses NDIM, NUMNP, NUMEL, NVARNP, NVAREL, NVARGL of /DBNUMS/
58 C -- Uses FNCTYP of /FNCTB./
59
60 include 'exodusII.inc'
61 include 'ag_namlen.blk'
62 include 'ag_numeqn.blk'
63 include 'ag_var.blk'
64 include 'ag_dbnums.blk'
65 include 'ag_fnctbc.blk'
66 PARAMETER (ICURTM = 1, ILSTTM = 2, IONETM = 3)
67
68 CHARACTER*(*) NAMECO(*)
69 CHARACTER*(*) NAMES(*)
70 CHARACTER*(*) NAMENT(*)
71 CHARACTER TYPENT(*)
72 INTEGER INXENT(*)
73 REAL VALENT(*)
74 INTEGER ITMENT(*)
75 INTEGER IEVENT(*)
76 CHARACTER VSZENT(*)
77 LOGICAL ISEVOK(NELBLK,*)
78
79 CHARACTER*(maxnam) NAME
80 CHARACTER TYPEQV
81 CHARACTER VTYP
82 LOGICAL ALLSAM
83 CHARACTER*5 STRA, STRB
84
85 CHARACTER TYPSTK(MAXENT)
86 INTEGER INXSTK(MAXENT)
87 C --TYPSTK - type of variables for stack item
88 C --INXSTK - equation entry which pushed this stack item
89
90 C --Save the /VAR../ indices so they can be restored in case of error
91 NINP = NUMINP
92 ILHS = IXLHS
93
94 C --Set up to check postfix stack if no errors so far
95 ITOS = 0
96 INERR = NERR
97 IF (INERR .NE. 0) TYPSTK(1) = 'G'
98
99 MAXSTK = 0
100
101 VTYP = ' '
102 DO 100 NENT = 1, NUMENT
103 IEVENT(NENT) = -999
104 100 CONTINUE
105
106 DO 180 NENT = 3, NUMENT
107
108 IF (TYPENT(NENT) .EQ. 'V') THEN
109
110 C --Get the name and the node/element specifier, if any
111
112 NAME = NAMENT(NENT)
113 NENUM = INT(VALENT(NENT))
114
115 C --Locate where the variable name is in the list of variables
116
117 CALL LOCNAM (NAME, NAMECO, NAMES,
118 & NENUM, TYPEQV, IDEQV, NERR)
119
120 C --Reference variable from entry
121
122 VALENT(NENT) = NENUM
123 IF (IDEQV .LT. 0) THEN
124 INXENT(NENT) = -1
125 ELSE
126 INXENT(NENT) = +1
127 END IF
128 C --Set INXENT -1 for reference to LHS variable, +1 for
129 C --input variable; used to link variables
130 IF (TYPEQV .EQ. 'E') THEN
131 NEWEV = NUMEV + 1
132 IEVOLD = IDEFEV
133 IF (IDEQV .GE. 0) THEN
134 IEVNEW = IDEQV
135 ELSE
136 IEVNEW = IEVVAR(IABS(IDEQV))
137 END IF
138 CALL MAKEVO (NELBLK, ISEVOK,
139 & IEVOLD, IEVNEW, NEWEV, IEVOLD)
140 NEWEV = IEVOLD
141 IF (NEWEV .GT. NUMEV) NUMEV = NEWEV
142 IEVENT(NENT) = NEWEV
143 ELSE
144 IEVENT(NENT) = -999
145 END IF
146
147 C --Correct variable name to eliminate duplicate references in
148 C --the variable array
149
150 IF (((TYPEQV .EQ. 'H') .OR. (TYPEQV .EQ. 'G'))
151 & .AND. (IDEQV .GE. 0)) THEN
152 C --Input history and global variables are all in the same entry
153 IF (TYPEQV .EQ. 'H') THEN
154 NAME = '.GLOBAL'
155 ELSE
156 NAME = '.GLOBAL'
157 END IF
158 NAMENT(NENT) = NAME
159 END IF
160
161 C --Insert name in list of input variables, if not LHS and not
162 C --already there; update time reference
163
164 IF (TYPEQV .EQ. 'C') ITMENT(NENT) = ICURTM
165 IF (IDEQV .GE. 0) THEN
166 IVAR = LOCSTR (NAME, NUMINP, NAMVAR)
167 IF (IVAR .LE. 0) THEN
168 NUMINP = NUMINP + 1
169 IVAR = NUMINP
170 IF (NUMINP .LT. IXLHS) THEN
171 NAMVAR(IVAR) = NAME
172 TYPVAR(IVAR) = TYPEQV
173 IDVAR(IVAR) = IDEQV
174 ISTVAR(ICURTM,IVAR) = 0
175 ISTVAR(ILSTTM,IVAR) = 0
176 ISTVAR(IONETM,IVAR) = 0
177 IF (TYPEQV .EQ. 'E') THEN
178 IEVVAR(IVAR) = IDEQV
179 ELSE
180 IEVVAR(IVAR) = -999
181 END IF
182 END IF
183 END IF
184 ITM = ITMENT(NENT)
185 ISTVAR(ITM,IVAR) = 1
186 ELSE
187 ITM = ITMENT(NENT)
188 IF (ITM .NE. ICURTM) THEN
189 NUMLHS = MAXVAR - IXLHS + 1
190 IVAR = LOCSTR (NAME, NUMLHS, NAMVAR(IXLHS))
191 IF (IVAR .GT. 0) THEN
192 IVAR = IXLHS + IVAR - 1
193 ISTVAR(ITM,IVAR) = 1
194 END IF
195 END IF
196 END IF
197
198 C --Get the variable type to check arrays
199
200 IF ((TYPEQV .EQ. ' ') .OR. (TYPEQV .EQ. 'T') .OR.
201 * (TYPEQV .EQ. 'G')) THEN
202 VTYP = 'G'
203 ELSE IF (TYPEQV .EQ. 'H') THEN
204 VTYP = 'H'
205 ELSE
206 IF (NENUM .NE. 0) THEN
207 VTYP = 'G'
208 ELSE IF (TYPEQV .EQ. 'C') THEN
209 VTYP = 'N'
210 ELSE
211 VTYP = TYPEQV
212 END IF
213 END IF
214 END IF
215
216 C --Get the equation variable type, and check for mixed array errors
217
218 IF (INERR .EQ. 0) THEN
219
220 C --Check by manipulating the postfix string
221
222 IF (TYPENT(NENT) .EQ. 'C') THEN
223
224 C --Constant - push global type
225
226 ITOS = ITOS + 1
227 IF (ITOS .GT. MAXENT) GOTO 190
228 MAXSTK = MAX (MAXSTK, ITOS)
229
230 TYPSTK(ITOS) = 'G'
231 INXSTK(ITOS) = NENT
232 VSZENT(NENT) = 'G'
233
234 ELSE IF (TYPENT(NENT) .EQ. 'V') THEN
235
236 C --Variable - push variable array type
237
238 ITOS = ITOS + 1
239 IF (ITOS .GT. MAXENT) GOTO 190
240 MAXSTK = MAX (MAXSTK, ITOS)
241
242 TYPSTK(ITOS) = VTYP
243 INXSTK(ITOS) = NENT
244 VSZENT(NENT) = VTYP
245
246 ELSE IF (TYPENT(NENT) .EQ. 'O') THEN
247
248 C --Operator - pop operands, push type of any operand array
249
250 IF (INXENT(NENT) .LE. 1) THEN
251 NOP = 1
252 ELSE
253 NOP = 2
254 END IF
255 IOP1 = ITOS - NOP + 1
256 ILAST = ITOS
257 ITOS = IOP1
258 IF (ITOS .LE. 0) GOTO 190
259
260 ALLSAM = .TRUE.
261 VTYP = TYPSTK(IOP1)
262 DO 110 I = IOP1+1, ILAST
263 IF (VTYP .NE. TYPSTK(I)) ALLSAM = .FALSE.
264 IF (TYPSTK(I) .NE. VTYP) THEN
265 IF (TYPSTK(I) .EQ. 'H') THEN
266 CONTINUE
267 ELSE IF (TYPSTK(I) .EQ. 'G') THEN
268 IF ((VTYP .EQ. 'T') .OR. (VTYP .EQ. 'H'))
269 & VTYP = TYPSTK(I)
270 ELSE IF ((TYPSTK(I) .EQ. 'N')
271 & .OR. (TYPSTK(I) .EQ. 'E')) THEN
272 IF ((VTYP .EQ. 'N') .OR. (VTYP .EQ. 'E')) THEN
273 IF (TYPSTK(I) .NE. VTYP) VTYP = '?'
274 ELSE
275 IF (VTYP .NE. '?') VTYP = TYPSTK(I)
276 END IF
277 ELSE IF (TYPSTK(I) .EQ. '?') THEN
278 VTYP = TYPSTK(I)
279 END IF
280 END IF
281 110 CONTINUE
282
283 IF (VTYP .EQ. 'E') THEN
284 NEWEV = NUMEV + 1
285 IEVOLD = IDEFEV
286 DO 120 I = IOP1, ILAST
287 IF (TYPSTK(I) .EQ. 'E') THEN
288 IEVNEW = IEVENT(INXSTK(I))
289 CALL MAKEVO (NELBLK, ISEVOK,
290 & IEVOLD, IEVNEW, NEWEV, IEVOLD)
291 END IF
292 120 CONTINUE
293 NEWEV = IEVOLD
294 IF (NEWEV .GT. NUMEV) NUMEV = NEWEV
295 IEVENT(NENT) = NEWEV
296 END IF
297
298 IF (.NOT. ALLSAM) THEN
299 DO 130 I = IOP1, ILAST
300 IF (VTYP .NE. TYPSTK(I)) THEN
301 VSZENT(INXSTK(I)) = VTYP
302 END IF
303 130 CONTINUE
304 END IF
305
306 TYPSTK(ITOS) = VTYP
307 INXSTK(ITOS) = NENT
308 VSZENT(NENT) = VTYP
309
310 ELSE IF (TYPENT(NENT) .EQ. 'F') THEN
311
312 C --Function - pop parameters and push type of function
313
314 NPARM = INT(VALENT(NENT))
315 IPARM = ITOS - NPARM + 1
316 ILAST = ITOS
317 ITOS = IPARM
318 IF (ITOS .LE. 0) GOTO 190
319
320 IF (FNCTYP(INXENT(NENT)) .EQ. ' ') THEN
321
322 C --Get function type from parameter types
323
324 ALLSAM = .TRUE.
325 VTYP = TYPSTK(IPARM)
326 DO 140 I = IPARM+1, ILAST
327 IF (VTYP .NE. TYPSTK(I)) ALLSAM = .FALSE.
328 IF (TYPSTK(I) .NE. VTYP) THEN
329 IF (TYPSTK(I) .EQ. 'H') THEN
330 CONTINUE
331 ELSE IF (TYPSTK(I) .EQ. 'G') THEN
332 IF (VTYP .EQ. 'H') VTYP = TYPSTK(I)
333 ELSE IF ((TYPSTK(I) .EQ. 'N')
334 & .OR. (TYPSTK(I) .EQ. 'E')) THEN
335 IF ((VTYP .EQ. 'N')
336 & .OR. (VTYP .EQ. 'E')) THEN
337 IF (TYPSTK(I) .NE. VTYP) VTYP = '?'
338 ELSE
339 IF (VTYP .NE. '?') VTYP = TYPSTK(I)
340 END IF
341 ELSE IF (TYPSTK(I) .EQ. '?') THEN
342 VTYP = TYPSTK(I)
343 END IF
344 END IF
345 140 CONTINUE
346
347 IF (.NOT. ALLSAM) THEN
348 DO 150 I = IPARM, ILAST
349 IF (VTYP .NE. TYPSTK(I)) THEN
350 VSZENT(INXSTK(I)) = VTYP
351 END IF
352 150 CONTINUE
353 END IF
354
355 ELSE
356
357 C --Function has a defined type, parameters may be mixed types
358
359 VTYP = FNCTYP(INXENT(NENT))
360 DO 160 I = IPARM, ILAST
361 IF (TYPSTK(I) .EQ. '?') VTYP = TYPSTK(I)
362 IF ((TYPSTK(I) .EQ. 'H')
363 & .OR. (TYPSTK(I) .EQ. 'G')) THEN
364 VSZENT(INXSTK(I)) = '*'
365 END IF
366 160 CONTINUE
367 END IF
368
369 NEV = 0
370 NEWEV = NUMEV + 1
371 IEVOLD = IDEFEV
372 DO 170 I = IPARM, ILAST
373 IF (TYPSTK(I) .EQ. 'E') THEN
374 NEV = NEV + 1
375 IEVNEW = IEVENT(INXSTK(I))
376 CALL MAKEVO (NELBLK, ISEVOK,
377 & IEVOLD, IEVNEW, NEWEV, IEVOLD)
378 END IF
379 170 CONTINUE
380 IF (NEV .GT. 0) THEN
381 NEWEV = IEVOLD
382 IF (NEWEV .GT. NUMEV) NUMEV = NEWEV
383 IEVENT(NENT) = NEWEV
384 END IF
385
386 TYPSTK(ITOS) = VTYP
387 INXSTK(ITOS) = NENT
388 VSZENT(NENT) = VTYP
389 END IF
390
391 ELSE
392
393 C --Do simple check that variable types match since postfix string
394 C --is incorrect
395
396 IF (TYPENT(NENT) .EQ. 'V') THEN
397
398 C --Check that there are no mixed array types
399
400 IF (TYPSTK(1) .NE. ' ') THEN
401 IF (TYPSTK(1) .NE. VTYP) THEN
402 IF (TYPSTK(1) .EQ. 'H') THEN
403 CONTINUE
404 ELSE IF (TYPSTK(1) .EQ. 'G') THEN
405 IF (VTYP .EQ. 'H') VTYP = TYPSTK(1)
406 ELSE IF ((TYPSTK(1) .EQ. 'N')
407 & .OR. (TYPSTK(1) .EQ. 'E')) THEN
408 IF ((VTYP .EQ. 'N') .OR. (VTYP .EQ. 'E')) THEN
409 IF (TYPSTK(1) .NE. VTYP) VTYP = '?'
410 ELSE
411 IF (VTYP .NE. '?') VTYP = '?'
412 END IF
413 ELSE IF (TYPSTK(1) .EQ. '?') THEN
414 VTYP = TYPSTK(1)
415 END IF
416 END IF
417 END IF
418
419 ELSE IF (TYPENT(NENT) .EQ. 'F') THEN
420
421 C --If defined-type function is present, do not check array types
422
423 IF (FNCTYP(INXENT(NENT)) .NE. ' ') THEN
424 IF (TYPSTK(1) .NE. '?') TYPSTK(1) = ' '
425 END IF
426 END IF
427
428 END IF
429 180 CONTINUE
430
431 IF (TYPENT(1) .EQ. 'V') THEN
432
433 NAME = NAMENT(1)
434
435 C --Specifier is not valid on the assigned variable
436
437 IF (VALENT(1) .GT. 0) THEN
438 NERR = NERR + 1
439 CALL PRTERR ('CMDSPEC', 'Node/element specifier not allowed'
440 & // ' on assigned variable')
441 END IF
442
443 IF (ITMENT(1) .NE. ICURTM) THEN
444 NERR = NERR + 1
445 CALL PRTERR ('CMDSPEC', 'Time specifier not allowed'
446 & // ' on assigned variable')
447 END IF
448
449 INXENT(1) = -1
450 C --Set INXENT -1 for reference to LHS variable
451 VALENT(1) = 0
452 IF (TYPEQV .EQ. 'E') THEN
453 IEVENT(1) = NEWEV
454 ELSE
455 IEVENT(1) = -999
456 END IF
457
458 ELSE
459 NAME = ' '
460 END IF
461
462 C --Assign and check the type for the assigned variable
463
464 IF (TYPSTK(1) .EQ. '?') THEN
465 TYPEQV = 'G'
466 NERR = NERR + 1
467 CALL PRTERR ('CMDSPEC',
468 & 'Nodal and element variables are mixed')
469 ELSE
470 TYPEQV = TYPSTK(1)
471 END IF
472 VSZENT(1) = TYPEQV
473
474 IF (NAME .EQ. 'TIME') THEN
475 IF (TYPEQV .NE. 'G') THEN
476 NERR = NERR + 1
477 CALL PRTERR ('CMDSPEC', 'TIME must be a global variable')
478 END IF
479 TYPEQV = 'T'
480 END IF
481
482 C --If the assigned variable does not exist, add it to the list,
483 C --else check that its type has not changed
484
485 NUMLHS = MAXVAR - IXLHS + 1
486 IVAR = LOCSTR (NAME, NUMLHS, NAMVAR(IXLHS))
487
488 IF (IVAR .LE. 0) THEN
489 IXLHS = IXLHS - 1
490 IF (NUMINP .LT. IXLHS) THEN
491 NAMVAR(IXLHS) = NAME
492 TYPVAR(IXLHS) = TYPEQV
493 IDVAR(IXLHS) = -999
494 ISTVAR(ICURTM,IXLHS) = 1
495 ISTVAR(ILSTTM,IXLHS) = 0
496 ISTVAR(IONETM,IXLHS) = 0
497 IF (TYPEQV .EQ. 'E') THEN
498 IEVVAR(IXLHS) = NEWEV
499 ELSE
500 IEVVAR(IXLHS) = -999
501 END IF
502 END IF
503 ELSE
504 IVAR = IXLHS + IVAR - 1
505 IF (TYPEQV .NE. TYPVAR(IVAR)) THEN
506 IF (TYPEQV .NE. ' ') THEN
507 NERR = NERR + 1
508 CALL PRTERR ('CMDSPEC', NAME(:LENSTR(NAME))
509 & // ' was previously assigned as a different type')
510 END IF
511 END IF
512
513 C --Change DELETEd or SAVEd variable to assigned variable
514 IF ((NERR .EQ. 0) .AND. (ISTVAR(ICURTM,IVAR) .NE. 1))
515 & ISTVAR(ICURTM,IVAR) = 1
516 END IF
517
518 GOTO 200
519
520 190 CONTINUE
521 NERR = NERR + 1
522 CALL PRTERR ('PROGRAM', 'Program stack problem in LOCEQV')
523
524 200 CONTINUE
525
526 IF (NUMINP .GE. IXLHS) THEN
527 NERR = NERR + 1
528 N = NUMINP + (MAXVAR - IXLHS + 1)
529 CALL INTSTR (1, 0, N, STRA, LSTRA)
530 CALL INTSTR (1, 0, MAXVAR, STRB, LSTRB)
531 CALL PRTERR ('CMDSPEC',
532 & 'Too many variable names to store, '
533 & // STRA(:LSTRA) // ' > ' // STRB(:LSTRB))
534 END IF
535
536 IF (NERR .GT. 0) THEN
537 NUMINP = NINP
538 IXLHS = ILHS
539 END IF
540
541 RETURN
542 END