Debian Codegraph @

packages/seacas/applications/algebra/ag_cmdtim.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6 C=======================================================================
7 SUBROUTINE CMDTIM (INLINE, VERB, IFLD, INTYP, CFIELD, IFIELD,
8 & RFIELD,NSTEPS, TIMES, TMIN, TMAX,
9 & DELT, NINTV, NPTIMS, IPTIMS)
10 C=======================================================================
11
12 C --*** CMDTIM *** (TIMSEL) Process time step parameter command
13 C -- Written by Amy Gilkey - revised 05/18/88
14 C --
15 C --CMDTIM processes a time step parameter command. The commands are:
16 C -- TMIN - sets the minimum selected time TMIN
17 C -- TMAX - sets the maximum selected time TMAX
18 C -- DELTIME - sets the selected time interval DELT
19 C -- ZINTV - sets the number of selected times NINTV
20 C -- with interval starting at TMIN
21 C -- NINTV - sets the number of selected times NINTV
22 C -- with interval starting at TMIN + offset
23 C -- ALLTIMES - sets DELT = 0 for all times
24 C -- TIMES - selects time steps by time
25 C -- STEPS - selects time steps by number
26 C --
27 C --Parameters:
28 C -- INLINE - IN/OUT - the parsed input lines for the log file
29 C -- VERB - IN/OUT - the time step parameter command verb; set for SHOW
30 C -- IFLD - IN/OUT - the field number
31 C -- INTYP - IN - the input types from the free field reader
32 C -- CFIELD - IN - the character fields
33 C -- IFIELD - IN - the integer fields
34 C -- RFIELD - IN - the real fields
35 C -- NSTEPS - IN - the number of time steps
36 C -- TIMES - IN - the database times
37 C -- TMIN - IN/OUT - the minimum selected time
38 C -- TMAX - IN/OUT - the maximum selected time
39 C -- DELT - IN/OUT - the interval between selected times
40 C -- (<0 = selected times)
41 C -- NINTV - IN/OUT - the number of times between tmin and tmax to select
42 C -- (negative for zero interval)
43 C -- NPTIMS - IN/OUT - the number of selected times
44 C -- IPTIMS - IN/OUT - the selected time step numbers
45
46 C --Routines Called:
47 C -- LOCREA - (ETCLIB) Find closest value
48 C -- MINMAX - (ETCLIB) Find minimum and maximum value
49 C -- MINMXL - (ETCLIB) Find minimum and maximum value of selected values
50 C -- NUMEQL - (ETCLIB) Count the number of equal values
51
52 CHARACTER*(*) INLINE(*)
53 CHARACTER*(*) VERB
54 INTEGER INTYP(*)
55 CHARACTER*(*) CFIELD(*)
56 INTEGER IFIELD(*)
57 REAL RFIELD(*)
58 REAL TIMES(*)
59 INTEGER IPTIMS(*)
60
61 LOGICAL FFEXST, FFMATC
62 LOGICAL ISTIME
63 CHARACTER*5 STR5
64
65 NSTEPX = NSTEPS
66
67 IF ((VERB .EQ. 'TMIN') .OR. (VERB .EQ. 'TMAX')) THEN
68 CALL FFADDC (VERB, INLINE(1))
69 CALL MINMAX (NSTEPS, TIMES, TIMMIN, TIMMAX)
70 IF (VERB .EQ. 'TMIN') THEN
71 CALL FFREAL (IFLD, INTYP, RFIELD,
72 & 'minimum time', TIMMIN, X, *120)
73 TMIN = X
74 CALL FFADDR (TMIN, INLINE(1))
75 ELSE
76 CALL FFREAL (IFLD, INTYP, RFIELD,
77 & 'maximum time', TIMMAX, X, *120)
78 TMAX = X
79 CALL FFADDR (TMAX, INLINE(1))
80 END IF
81 IF (TMIN .GT. TMAX) CALL PRTERR ('CMDWARN',
82 & 'Minimum time is greater than maximum time')
83 IF (DELT .LT. 0) THEN
84 NINTV = 0
85 DELT = 0.0
86 END IF
87
88 ELSE IF ((VERB .EQ. 'NINTV') .OR. (VERB .EQ. 'ZINTV')) THEN
89 CALL FFADDC (VERB, INLINE(1))
90 IF (VERB .EQ. 'NINTV') THEN
91 NT = MIN (10, NSTEPX-1)
92 ELSE
93 NT = MIN (10, NSTEPX)
94 END IF
95 CALL FFINTG (IFLD, INTYP, IFIELD,
96 & 'number of times', NT, N, *120)
97 NINTV = N
98 CALL FFADDI (NINTV, INLINE(1))
99 IF (VERB .EQ. 'NINTV') THEN
100 NINTV = N
101 ELSE
102 NINTV = -N
103 END IF
104 DELT = 999.0
105
106 ELSE IF (VERB .EQ. 'DELTIME') THEN
107 CALL FFADDC (VERB, INLINE(1))
108 NT = - MIN (10, NSTEPX)
109 IF (NT .LT. -1) THEN
110 DDELT = (TMAX - TMIN) / (-NT-1)
111 IF (DDELT .LE. 0.) DDELT = 1.0
112 ELSE
113 DDELT = 0.0
114 END IF
115 CALL FFREAL (IFLD, INTYP, RFIELD,
116 & 'delta time', DDELT, X, *120)
117 DELT = X
118 CALL FFADDR (DELT, INLINE(1))
119 NINTV = 0
120
121 ELSE IF (VERB .EQ. 'ALLTIMES') THEN
122 CALL FFADDC (VERB, INLINE(1))
123 DELT = 0.0
124 NINTV = 0
125
126 ELSE IF ((VERB .EQ. 'TIMES') .OR. (VERB .EQ. 'STEPS')) THEN
127 CALL FFADDC (VERB, INLINE(1))
128 ISTIME = (VERB .EQ. 'TIMES')
129 VERB = 'DELTIME'
130 IF (DELT .GE. 0.0) THEN
131 NINTV = NPTIMS
132 DELT = -1.0
133 END IF
134
135 C --Reset is assumed, unless ADD is first parameter
136 IF (.NOT. FFMATC (IFLD, INTYP, CFIELD, 'ADD', 1)) NINTV = 0
137
138 100 CONTINUE
139 IF (FFEXST (IFLD, INTYP)) THEN
140 IF (ISTIME) THEN
141 CALL FFREAL (IFLD, INTYP, RFIELD,
142 & 'time, ignored', 0.0, T, *110)
143 CALL FFADDR (T, INLINE(1))
144 ISTEP = LOCREA (T, NSTEPS, TIMES)
145 ELSE
146 CALL FFINTG (IFLD, INTYP, IFIELD,
147 & 'step, ignored', 0, ISTEP, *110)
148 IF ((ISTEP .LE. 0) .OR. (ISTEP .GT. NSTEPS)) THEN
149 CALL INTSTR (1, 0, ISTEP, STR5, LSTR)
150 CALL PRTERR ('CMDERR', 'Step ' // STR5(:LSTR)
151 & // ' does not exist, ignored')
152 GOTO 110
153 END IF
154 CALL FFADDI (ISTEP, INLINE(1))
155 END IF
156
157 IF (LOCINT (ISTEP, NINTV, IPTIMS) .LE. 0) THEN
158 NINTV = NINTV + 1
159 IPTIMS(NINTV) = ISTEP
160 END IF
161 110 CONTINUE
162 GOTO 100
163 END IF
164 END IF
165
166 NPTIMS = -999
167 CALL CALTIM (TMIN, TMAX, DELT, NINTV,
168 & NSTEPS, TIMES, NPTIMS, IPTIMS)
169
170 120 CONTINUE
171 RETURN
172 END