Debian Codegraph @

cmake/tribits/ci_support/TribitsWriteXmlDependenciesFiles.cmake

raw
1 # @HEADER
2 # *****************************************************************************
3 # TriBITS: Tribal Build, Integrate, and Test System
4 #
5 # Copyright 2013-2016 NTESS and the TriBITS contributors.
6 # SPDX-License-Identifier: BSD-3-Clause
7 # *****************************************************************************
8 # @HEADER
9
10
11 ################################################################################
12 # NOTE: This file gets included in the main TriBITS core framework. It is put
13 # here to reduce the size of the tribits/core/ directory as this is optional
14 # behavior.
15 ################################################################################
16
17
18 include(TribitsConfigureTiming)
19
20
21 # @MACRO: tribits_write_xml_dependency_files()
22 #
23 # Usage::
24 #
25 # tribits_write_xml_dependency_files()
26 #
27 # Macro that outputs XML dependency files if asked based in the global project
28 # package dependency graph previously constructed.
29 #
30 macro(tribits_write_xml_dependency_files)
31
32 tribits_config_code_start_timer(WRITE_DEPENDENCY_FILES_TIME_START_SECONDS)
33
34 if (${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE)
35 if (NOT IS_ABSOLUTE ${${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE})
36 set(${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE
37 ${CMAKE_CURRENT_BINARY_DIR}/${${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE})
38 endif()
39 message("" )
40 message("Dumping the XML dependencies file"
41 " ${${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE} ..." )
42 tribits_dump_deps_xml_file()
43 endif()
44
45 if (${PROJECT_NAME}_DEPS_HTML_OUTPUT_FILE AND ${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE)
46 if (NOT IS_ABSOLUTE ${${PROJECT_NAME}_DEPS_HTML_OUTPUT_FILE})
47 set(${PROJECT_NAME}_DEPS_HTML_OUTPUT_FILE
48 ${CMAKE_CURRENT_BINARY_DIR}/${${PROJECT_NAME}_DEPS_HTML_OUTPUT_FILE})
49 endif()
50 message("" )
51 message("Dumping the HTML dependencies webpage file"
52 " ${${PROJECT_NAME}_DEPS_HTML_OUTPUT_FILE} ..." )
53 set(tribitsCiSupportDir "${${PROJECT_NAME}_TRIBITS_DIR}/${TRIBITS_CI_SUPPORT_DIR}")
54 execute_process(
55 COMMAND ${Python3_EXECUTABLE}
56 ${tribitsCiSupportDir}/dump-package-dep-table.py
57 --input-xml-deps-file=${${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE}
58 --output-html-deps-file=${${PROJECT_NAME}_DEPS_HTML_OUTPUT_FILE} )
59 endif()
60
61 if (${PROJECT_NAME}_CDASH_DEPS_XML_OUTPUT_FILE AND ${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE)
62 if (NOT IS_ABSOLUTE ${${PROJECT_NAME}_CDASH_DEPS_XML_OUTPUT_FILE})
63 set(${PROJECT_NAME}_CDASH_DEPS_XML_OUTPUT_FILE
64 ${CMAKE_CURRENT_BINARY_DIR}/${${PROJECT_NAME}_CDASH_DEPS_XML_OUTPUT_FILE})
65 endif()
66 message("" )
67 message("Dumping the CDash XML dependencies file"
68 " ${${PROJECT_NAME}_CDASH_DEPS_XML_OUTPUT_FILE} ..." )
69 set(tribitsCtestDriverDir
70 "${${PROJECT_NAME}_TRIBITS_DIR}/${TRIBITS_CTEST_DRIVER_DIR}")
71 if (EXISTS "${tribitsCtestDriverDir}")
72 execute_process(
73 COMMAND ${Python3_EXECUTABLE}
74 ${tribitsCtestDriverDir}/dump-cdash-deps-xml-file.py
75 --input-xml-deps-file=${${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE}
76 --output-cdash-deps-xml-file=${${PROJECT_NAME}_CDASH_DEPS_XML_OUTPUT_FILE})
77 else()
78 message(FATAL_ERROR "\nERROR: Can't write"
79 " ${${PROJECT_NAME}_CDASH_DEPS_XML_OUTPUT_FILE}"
80 " because '${tribitsCtestDriverDir}' does not exist!")
81 endif()
82 endif()
83
84 if (${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE
85 OR ${PROJECT_NAME}_DEPS_HTML_OUTPUT_FILE
86 OR ${PROJECT_NAME}_CDASH_DEPS_XML_OUTPUT_FILE
87 )
88 tribits_config_code_stop_timer(WRITE_DEPENDENCY_FILES_TIME_START_SECONDS
89 "\nTotal time to write dependency files")
90 endif()
91
92 endmacro()
93
94
95 # Function that writes the dependency information for the TriBITS project
96 # ${PROJECT_NAME} into an XML file for other tools to use.
97 #
98 function(tribits_dump_deps_xml_file)
99
100 set(depsXml "")
101
102 get_filename_component(PROJECT_BASE_DIR_NAME "${${PROJECT_NAME}_SOURCE_DIR}" NAME)
103
104 list(APPEND depsXml
105 "<PackageDependencies project=\"${PROJECT_NAME}\" baseDirName=\"${PROJECT_BASE_DIR_NAME}\">\n"
106 )
107
108 foreach(tribitsPackage ${${PROJECT_NAME}_DEFINED_INTERNAL_PACKAGES})
109
110 list(APPEND depsXml
111 " <Package name=\"${tribitsPackage}\" dir=\"${${tribitsPackage}_REL_SOURCE_DIR}\" type=\"${${tribitsPackage}_TESTGROUP}\">\n")
112
113 tribits_write_deps_to_xml_string(${tribitsPackage} LIB REQUIRED PACKAGES depsXml)
114 tribits_write_deps_to_xml_string(${tribitsPackage} LIB OPTIONAL PACKAGES depsXml)
115 tribits_write_deps_to_xml_string(${tribitsPackage} TEST REQUIRED PACKAGES depsXml)
116 tribits_write_deps_to_xml_string(${tribitsPackage} TEST OPTIONAL PACKAGES depsXml)
117 tribits_write_deps_to_xml_string(${tribitsPackage} LIB REQUIRED TPLS depsXml)
118 tribits_write_deps_to_xml_string(${tribitsPackage} LIB OPTIONAL TPLS depsXml)
119 tribits_write_deps_to_xml_string(${tribitsPackage} TEST REQUIRED TPLS depsXml)
120 tribits_write_deps_to_xml_string(${tribitsPackage} TEST OPTIONAL TPLS depsXml)
121
122 list(APPEND depsXml
123 " <EmailAddresses>\n"
124 " <Regression address=\"${${tribitsPackage}_REGRESSION_EMAIL_LIST}\"/>\n"
125 " </EmailAddresses>\n"
126 )
127
128 list(APPEND depsXml
129 " <ParentPackage value=\"${${tribitsPackage}_PARENT_PACKAGE}\"/>\n"
130 )
131
132 list(APPEND depsXml
133 " </Package>\n" )
134
135 endforeach()
136
137 list(APPEND depsXml
138 "</PackageDependencies>\n" )
139
140 string(REPLACE "\n;" "\n" depsXml "${depsXml}")
141 file(WRITE ${${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE} "${depsXml}" )
142
143 endfunction()
144
145
146 function(tribits_write_deps_to_xml_string packageName libOrTest requiredOrOptional
147 packagesOrTpls xmlVarInOut
148 )
149
150 set(localXml "${${xmlVarInOut}}")
151
152 set(listType ${libOrTest}_${requiredOrOptional}_DEP_${packagesOrTpls})
153 message("")
154
155 tribits_get_legacy_package_deps_sublist(${packageName} ${libOrTest}
156 ${requiredOrOptional} ${packagesOrTpls} legacyPackageDepsList)
157
158 if (NOT legacyPackageDepsList)
159 list(APPEND localXml
160 " <${listType}/>\n" )
161 else()
162 set(depsListStr "")
163 foreach(depPkg IN LISTS legacyPackageDepsList)
164 tribits_append_dep_to_xml_string(${depPkg} depsListStr)
165 endforeach()
166 list(APPEND localXml
167 " <${listType} value=\"${depsListStr}\"/>\n" )
168 endif()
169
170 if (localXml)
171 set(${xmlVarInOut} "${localXml}" PARENT_SCOPE)
172 endif()
173
174 endfunction()
175
176
177 function(tribits_get_legacy_package_deps_sublist packageName libOrTest
178 requiredOrOptional packagesOrTpls legacyPackageDepsListOut
179 )
180
181 set(legacyPackageDepsList "")
182
183 foreach(depPkg IN LISTS ${packageName}_${libOrTest}_DEFINED_DEPENDENCIES)
184
185 set(matchesRequriedOrOptional FALSE)
186 if (((requiredOrOptional STREQUAL "REQUIRED")
187 AND ${packageName}_${libOrTest}_DEP_REQUIRED_${depPkg})
188 OR
189 ((requiredOrOptional STREQUAL "OPTIONAL")
190 AND (NOT ${packageName}_${libOrTest}_DEP_REQUIRED_${depPkg}))
191 )
192 set(matchesRequriedOrOptional TRUE)
193 endif()
194
195 set(matchesPackagesOrTpls FALSE)
196 if (((packagesOrTpls STREQUAL "PACKAGES")
197 AND (${depPkg}_PACKAGE_BUILD_STATUS STREQUAL "INTERNAL"))
198 OR
199 ((packagesOrTpls STREQUAL "TPLS")
200 AND (${depPkg}_PACKAGE_BUILD_STATUS STREQUAL "EXTERNAL"))
201 )
202 set(matchesPackagesOrTpls TRUE)
203 endif()
204
205 if (matchesRequriedOrOptional AND matchesPackagesOrTpls)
206 list(APPEND legacyPackageDepsList ${depPkg})
207 endif()
208
209 endforeach()
210
211 set(${legacyPackageDepsListOut} "${legacyPackageDepsList}" PARENT_SCOPE)
212
213 endfunction()
214
215
216
217 function(tribits_append_dep_to_xml_string depPkg depsListStrInOut)
218 set(depsListStr "${${depsListStrInOut}}")
219 if (depsListStr)
220 string(APPEND depsListStr ",")
221 endif()
222 string(APPEND depsListStr "${depPkg}")
223 set(${depsListStrInOut} "${depsListStr}" PARENT_SCOPE)
224 endfunction()