Debian Codegraph @

cmake/tribits/ci_support/TribitsDumpDepsXmlScript.cmake

raw
1 # @HEADER
2 # *****************************************************************************
3 # TriBITS: Tribal Build, Integrate, and Test System
4 #
5 # Copyright 2013-2016 NTESS and the TriBITS contributors.
6 # SPDX-License-Identifier: BSD-3-Clause
7 # *****************************************************************************
8 # @HEADER
9
10 #
11 # CMake script file to generate an xml dependencies file for PROJECT_NAME
12 #
13 # This script is designed to be run as:
14 #
15 # $ cmake \
16 # [-D PROJECT_SOURCE_DIR=<projectSourceDir>] \
17 # [-D <projectName>_PRE_REPOSITORIES=<prepo0>,<prepo1>,...] \
18 # [-D <projectName>_EXTRA_REPOSITORIES=<erepo0>,<erepo1>,...] \
19 # -D <projectName>_DEPS_XML_OUTPUT_FILE=<projectDepsFileOut> \
20 # -P <tribitsDir>/ci_support/TribitsDumpDepsXmlScript.cmake
21 #
22
23 cmake_minimum_required(VERSION 3.23.0 FATAL_ERROR)
24
25 # A) Echo input options (must be specified with -D arguments to CMake command)
26
27 # PROJECT_SOURCE_DIR
28 message("Input: PROJECT_SOURCE_DIR = '${PROJECT_SOURCE_DIR}'")
29 if ("${PROJECT_SOURCE_DIR}" STREQUAL "")
30 get_filename_component( DEFAULT_PROJECT_SOURCE_DIR
31 "${CMAKE_CURRENT_LIST_DIR}/../../.." ABSOLUTE )
32 message("-- DEFAULT_PROJECT_SOURCE_DIR='${DEFAULT_PROJECT_SOURCE_DIR}'")
33 if (EXISTS "${DEFAULT_PROJECT_SOURCE_DIR}/ProjectName.cmake")
34 message("-- Setting default PROJECT_SOURCE_DIR=${DEFAULT_PROJECT_SOURCE_DIR}")
35 set(PROJECT_SOURCE_DIR "${DEFAULT_PROJECT_SOURCE_DIR}")
36 else()
37 message(FATAL_ERROR
38 "ERROR: Cannot determine a default PROJECT_SOURCE_DIR location, please set PROJECT_SOURCE_DIR!")
39 endif()
40 else()
41 set(PROJECT_NAME_FILE "${PROJECT_SOURCE_DIR}/ProjectName.cmake")
42 if (NOT EXISTS "${PROJECT_NAME_FILE}")
43 message(FATAL_ERROR
44 "ERROR: PROJECT_SOURCE_DIR='${PROJECT_SOURCE_DIR}' is not a TriBITS project"
45 " base dir since it is missing the file ProjectName.cmake!")
46 endif()
47 # Else, this is a valid project source dir location
48 endif()
49
50 # Read in ProjectName.cmake to get PROJECT_NAME var
51 set(PROJECT_NAME_FILE "${PROJECT_SOURCE_DIR}/ProjectName.cmake")
52 include("${PROJECT_NAME_FILE}")
53
54 # Print the other vars
55 message("Input: ${PROJECT_NAME}_PRE_REPOSITORIES = '${${PROJECT_NAME}_PRE_REPOSITORIES}'")
56 message("Input: ${PROJECT_NAME}_EXTRA_REPOSITORIES = '${${PROJECT_NAME}_EXTRA_REPOSITORIES}'")
57 message("Input: ${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE = '${${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE}'")
58
59 if ("${${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE}" STREQUAL "")
60 message(FATAL_ERROR
61 "ERROR: ${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE cannot be empty."
62 " Please set ${PROJECT_NAME}_DEPS_XML_OUTPUT_FILE!")
63 endif()
64
65 #
66 # Execute the rest of the script now that everything has been asserted or found
67 #
68
69 # Get the TRIBITS_DIR (we can always find this easy since this script is in TriBITS)
70 get_filename_component( ${PROJECT_NAME}_TRIBITS_DIR "${CMAKE_CURRENT_LIST_DIR}/.." ABSOLUTE )
71 message("-- Setting ${PROJECT_NAME}_TRIBITS_DIR=${${PROJECT_NAME}_TRIBITS_DIR}")
72
73 include("${CMAKE_CURRENT_LIST_DIR}/../core/common/TribitsConstants.cmake")
74 tribits_asesrt_minimum_cmake_version()
75 include("${CMAKE_CURRENT_LIST_DIR}/../core/common/TribitsCMakePolicies.cmake" NO_POLICY_SCOPE)
76
77 set( CMAKE_MODULE_PATH
78 "${${PROJECT_NAME}_TRIBITS_DIR}/core/utils"
79 "${${PROJECT_NAME}_TRIBITS_DIR}/core/package_arch"
80 "${${PROJECT_NAME}_TRIBITS_DIR}/ci_support"
81 )
82
83 include(TribitsGlobalMacros)
84 include(TribitsPrintDependencyInfo)
85 include(TribitsWriteXmlDependenciesFiles)
86
87 # Generate the dependencies file
88
89 set(${PROJECT_NAME}_ASSERT_DEFINED_DEPENDENCIES OFF)
90 set(${PROJECT_NAME}_OUTPUT_DEPENDENCY_FILES FALSE)
91 if (NOT ${PROJECT_NAME}_PRE_REPOSITORIES) # Make sure is defined!
92 set(${PROJECT_NAME}_PRE_REPOSITORIES "")
93 endif()
94 if (NOT ${PROJECT_NAME}_EXTRA_REPOSITORIES) # Make sure is defined!
95 set(${PROJECT_NAME}_EXTRA_REPOSITORIES "")
96 endif()
97 tribits_read_in_native_repositories()
98 tribits_combine_native_and_extra_repos()
99 tribits_read_all_project_deps_files_create_deps_graph()
100 tribits_print_initial_dependency_info()
101 tribits_write_xml_dependency_files()