Debian Codegraph @

cmake/tribits/ci_support/TribitsGetExtraReposForCheckinTest.cmake

raw
1 # @HEADER
2 # *****************************************************************************
3 # TriBITS: Tribal Build, Integrate, and Test System
4 #
5 # Copyright 2013-2016 NTESS and the TriBITS contributors.
6 # SPDX-License-Identifier: BSD-3-Clause
7 # *****************************************************************************
8 # @HEADER
9
10 #
11 # CMake -P script that prints out a python datastructure for the
12 # info for extra repos read from a file
13 #
14
15 #
16 # A) Get the input
17 #
18
19 # Echo input commandline
20 message("*** Generate a Python datastructure containing TriBITS/git repos ...")
21 if (NOT SUPPRESS_PRINT_VAR_OUTPUT)
22 message("PROJECT_SOURCE_DIR = ${PROJECT_SOURCE_DIR}")
23 message("TRIBITS_BASE_DIR = ${TRIBITS_BASE_DIR}")
24 message("EXTRA_REPOS_FILE = ${EXTRA_REPOS_FILE}")
25 message("EXTRA_REPOS = ${EXTRA_REPOS}")
26 message("EXTRA_REPOS_PYTHON_OUT_FILE = ${EXTRA_REPOS_PYTHON_OUT_FILE}")
27 message("ENABLE_KNOWN_EXTERNAL_REPOS_TYPE = ${ENABLE_KNOWN_EXTERNAL_REPOS_TYPE}")
28 message("IGNORE_MISSING_EXTRA_REPOSITORIES = ${IGNORE_MISSING_EXTRA_REPOSITORIES}")
29 message("CHECK_EXTRAREPOS_EXIST = ${CHECK_EXTRAREPOS_EXIST}")
30 endif()
31
32 if ("${CHECK_EXTRAREPOS_EXIST}" STREQUAL "")
33 set(CHECK_EXTRAREPOS_EXIST TRUE)
34 endif()
35
36 # Set up necessary variables
37 include(${PROJECT_SOURCE_DIR}/ProjectName.cmake)
38 if (NOT SUPPRESS_PRINT_VAR_OUTPUT)
39 message("PROJECT_NAME = ${PROJECT_NAME}")
40 endif()
41 set(${PROJECT_NAME}_TRIBITS_DIR ${TRIBITS_BASE_DIR})
42 set(${PROJECT_NAME}_ENABLE_KNOWN_EXTERNAL_REPOS_TYPE ${ENABLE_KNOWN_EXTERNAL_REPOS_TYPE})
43 set(${PROJECT_NAME}_EXTRAREPOS_FILE ${EXTRA_REPOS_FILE})
44 set(${PROJECT_NAME}_EXTRA_REPOSITORIES ${EXTRA_REPOS})
45 set(${PROJECT_NAME}_IGNORE_MISSING_EXTRA_REPOSITORIES ${IGNORE_MISSING_EXTRA_REPOSITORIES})
46 set(${PROJECT_NAME}_CHECK_EXTRAREPOS_EXIST ${CHECK_EXTRAREPOS_EXIST})
47 #message("${PROJECT_NAME}_TRIBITS_DIR = ${${PROJECT_NAME}_TRIBITS_DIR}")
48
49 #set(${PROJECT_NAME}_VERBOSE_CONFIGURE TRUE)
50
51 #
52 # B) Include files from TriBITS
53 #
54
55 include("${CMAKE_CURRENT_LIST_DIR}/../core/common/TribitsCMakePolicies.cmake" NO_POLICY_SCOPE)
56
57 set( CMAKE_MODULE_PATH
58 "${${PROJECT_NAME}_TRIBITS_DIR}/core/utils"
59 "${${PROJECT_NAME}_TRIBITS_DIR}/core/package_arch"
60 )
61 include(Split)
62 include(AppendStringVar)
63 include(SetDefaultAndFromEnv) # Used in ExtraRepositoriesList.cmake file?
64 include(TribitsProcessExtraRepositoriesList)
65
66 # Need to split this argument
67 split("${${PROJECT_NAME}_EXTRA_REPOSITORIES}" ","
68 ${PROJECT_NAME}_EXTRA_REPOSITORIES)
69
70 if (NOT ${PROJECT_NAME}_ENABLE_KNOWN_EXTERNAL_REPOS_TYPE)
71 set(${PROJECT_NAME}_ENABLE_KNOWN_EXTERNAL_REPOS_TYPE "Continuous")
72 endif()
73
74 #
75 # C) Read in and process the extra repos list variable and process the list
76 #
77
78 tribits_get_and_process_extra_repositories_lists()
79
80 #
81 # D) Write the python dictionary/string that will be evaluated by checkin-test.py
82 #
83
84 set(EXTRA_REPOS_PYTHON_STRING)
85
86 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
87 "[\n")
88
89 if ("${${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES}" STREQUAL ""
90 AND ${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_DIRS
91 )
92 set(${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES
93 ${${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_DEFAULT})
94 endif()
95
96 set(EXTRAREPO_IDX 0)
97 foreach(EXTRAREPO_NAME ${${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES})
98
99 # Extract the data for current extra repo
100 list(GET ${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_DIRS ${EXTRAREPO_IDX}
101 EXTRAREPO_DIR )
102 list(GET ${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_VCTYPES ${EXTRAREPO_IDX}
103 EXTRAREPO_REPOTYPE )
104 list(GET ${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_REPOURLS ${EXTRAREPO_IDX}
105 EXTRAREPO_REPOURL )
106 list(GET ${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_HASPKGS ${EXTRAREPO_IDX}
107 EXTRAREPO_HASPKGS )
108 list(GET ${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_PREPOSTS ${EXTRAREPO_IDX}
109 EXTRAREPO_PREPOST )
110 list(GET ${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_CATEGORIES ${EXTRAREPO_IDX}
111 EXTRAREPO_CATEGORY )
112
113 # Write the dictorary entries for this extra rep
114 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
115 "{" )
116 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
117 "'NAME' : '${EXTRAREPO_NAME}', " )
118 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
119 "'DIR' : '${EXTRAREPO_DIR}', " )
120 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
121 "'REPOTYPE' : '${EXTRAREPO_REPOTYPE}', " )
122 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
123 "'REPOURL' : '${EXTRAREPO_REPOURL}', " )
124 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
125 "'HASPKGS' : '${EXTRAREPO_HASPKGS}', " )
126 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
127 "'PREPOST' : '${EXTRAREPO_PREPOST}', " )
128 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
129 "'CATEGORY' : '${EXTRAREPO_CATEGORY}', " )
130 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
131 "},\n" )
132
133 math(EXPR EXTRAREPO_IDX "${EXTRAREPO_IDX}+1")
134
135 endforeach()
136
137 append_string_var_ext(EXTRA_REPOS_PYTHON_STRING
138 "]\n")
139
140 #
141 # E) Write the generated python list/dictionary string to the output file
142 #
143 # NOTE: This must be the only output from this script since it gets evaluated.
144 #
145 # NOTE: You could use message(STATUS ...) to print to stdout but then it would
146 # also print an annoying '-- ' at the beginning which might not be porable to just
147 # remove it. CMake is not a great general scripting language :-(
148 #
149
150 message("")
151 if (EXTRA_REPOS_PYTHON_OUT_FILE)
152 message("Writing Python datastructure to ${EXTRA_REPOS_PYTHON_OUT_FILE} ...")
153 file(WRITE ${EXTRA_REPOS_PYTHON_OUT_FILE} "${EXTRA_REPOS_PYTHON_STRING}")
154 else()
155 message("*** Extra Repositories Python Dictionary")
156 message("${EXTRA_REPOS_PYTHON_STRING}")
157 endif()