Debian Codegraph @

texmf-dist/fonts/source/public/schulschriften/wesu14_def.mf

raw
1 % Suetterlinschrift wesu
2 % Parameter- und Makrodefinitionen
3 % Walter Entenmann
4 % 09.06.2011
5 %
6 % Parameterdefinitionen:
7 % fuer math. Sonderzeichen wie < > ...
8 hmath:=ht/2;
9 hdash:=ht/2;
10 % Superellipse fuer @-Zeichen
11 atb:=ht/2;
12 ata:=7ut;
13 sigma:=0.73345;
14 r := 3.5ut;
15 % Absenkung des Verbindungsniveaus
16 dy := 2ut;
17 % Endstrich, Breite und Hoehe bei fahne
18 endx:=9ut;
19 endy:=5ut;
20 % Stretch (Hoehe zu Breite beim o)
21 k := 4/3;
22 % ht/8 (haeufig benoetigtes Mass)
23 ds := ht/8;
24 % Fundamentaler Abstand z.B. zwischen a-Bogen und -Stamm
25 gap := 5ut;
26 % Schlingengroesse
27 s := 4ut; % Kleinbuchstaben
28 so := 10ut; % fuer "o"
29 S := 5ut; % Grossbuchstaben
30 % Ober-, Unterschleifenbreite und Faktor
31 sb := ht/2;
32 fs := 0.4;
33 % Breite und Hoehenkoordinate des v-Bauches
34 vb := 15ut;
35 vh := 12ut;
36
37 % Parameter fuer Grossbuchstaben:
38 % Oberschleifenbreite (Oschl)
39 Sb:=15ut;
40 % Breite und Hoehenkoordinate des V-Bauchs
41 Vb:=21ut;
42 Vh:=27.5ut;
43 % Breite und Hoehenkoordinate des gr. S
44 BS:=17.5ut;
45 Hs:=15ut;
46 Bs:=15ut; % reduzierte Breite fuer M, N, W, ...
47 % Weitere Parameter fuer die S-Schlaufe
48 Sm := 2; % Steigung S-Ansatz
49 Sf := 1/3; % Faktor wie fs
50 Stens := 1.2; % Spannung im S-Bogen rechts
51 Sab := 5ut; % Abhang beim S-Ansatz
52 % Breite der Schlingen bei der Doppelschleife Dschl fuer X
53 BX:=15ut;
54
55 % Makrodefinitionen:
56 % Fuer Sonderzeichen
57 def komma(expr deltax, deltay) =
58 draw ((0,0){1,-2}..tension1.2..{-1,-1}(-2ut,-10ut)) shifted (deltax,deltay);
59 enddef;
60
61 % Fuer Kleinbuchstaben (und teilweise auch fuer Grossbuchstaben)
62 def gerade (expr hy, br, mr, sx) =
63 draw ((0,hy)--(br,hy+mr*br)) shifted (sx,0);
64 xpos := sx+br;
65 if wmax<xpos: wmax:=xpos; fi
66 enddef;
67
68 def kurzstrich(expr sx) =
69 draw ((0,ht-dy)--(dy,ht)) shifted (sx,0);
70 xpos:=sx+dy;
71 if wmax<xpos: wmax:=xpos; fi
72 enddef;
73
74 def tangente (expr dx) =
75 if not wortende:
76 draw z0..tension2..{1,1}(x0+ht-dy-y0+dx,ht-dy);
77 xpos:=x0+ht-dy-y0+dx;
78 if wmax<xpos: wmax:=xpos; fi
79 else:
80 if wmax<x0: wmax:=x0; fi
81 fi
82 zeigen;
83 enddef;
84
85 def lschleife(expr sl, hy, fy, sx) =
86 draw ((0,0){up}..(-(1-fs)*sl,sl){left}..(-sl,(1-fs)*sl){down}..{right}(0,0)) yscaled fy shifted (sx,hy);
87 if wmax<sx: wmax:=sx; fi
88 enddef;
89
90
91 def stamm(expr ha, hb, sx) =
92 draw ((0,ha)--(0,hb)) shifted(sx,0);
93 if wmax<sx: wmax:=sx; fi
94 enddef;
95
96 def strich(expr sx) =
97 if not wortende :
98 % gerade(0,ht-dy,1,sx);
99 draw ((0,0)--(ht-dy,ht-dy)) shifted (sx,0);
100 xpos:=sx+ht-dy;
101 if wmax<xpos: wmax:=xpos; fi
102 else:
103 draw ((0,0)--(endx,endx)) shifted (sx,0);
104 xpos:=sx+endx;
105 if wmax<xpos: wmax:=xpos; fi
106 fi
107 zeigen;
108 enddef;
109
110 def spitz (expr sx) =
111 draw ((0,ht-dy){1,1}..tension 1.2..{up}(dy+gap,Ht)) shifted (sx,0);
112 xpos:=sx+dy+gap;
113 if wmax<xpos: wmax:=xpos; fi
114 enddef;
115
116 def oschl(expr sx) =
117 draw ((0,ht){1,1}..(sb,Ht-fs*sb){up}..((1-fs)*sb,Ht){left}..tension1.2..{down}(0,ht)) shifted (sx,0);
118 if wmax<(sx+sb): wmax:=sx+sb; fi
119 enddef;
120
121 def uschl(expr fscale, delta, sx) =
122 draw ((0,0){down}..tension1.2..(-sb*(1-fs),-dt){left}..(-sb,-dt+fs*sb){up}..{1,1}(0,0)) scaled fscale shifted (sx,delta);
123 if wmax<sx: wmax:=sx; fi
124 enddef;
125
126 % Hermite-Interpolation, 1 Intervall
127 def schweif(expr hl, hr, b, phil, phir, tens, mt, sx) =
128 p := (0,hl){dir phil}..tension tens..{dir phir}(b,hr);
129 draw p shifted (sx,0);
130 if ((b>0) and (phil<angle(1,mt)) and (phir>angle(1,mt))) or
131 ((b<0) and (angle(-dir(phir))<angle(1,mt)) and (angle(-dir(phil))>angle(1,mt))):
132 x0:=whatever; y0:=whatever;
133 z0=(directionpoint (1,mt) of if b<0: reverse fi p) shifted (sx,0); fi
134 xpos:=sx+b;
135 if wmax<xpos: wmax:=xpos; fi
136 enddef;
137
138 def fahne (expr hl, hr, b, phil, phir, tens, mt, sx) =
139 if not wortende:
140 schweif(hl, hr, b, phil, phir, tens, mt, sx);
141 else:
142 draw ((0,hl){dir phil}..
143 (endx,hl if phil<0: - else: + fi if phil=45: endx else: endy fi)) shifted (sx,0);
144 xpos:=sx+endx;
145 if wmax<xpos: wmax:=xpos; fi
146 fi
147 zeigen;
148 enddef;
149
150 def ipunkt(expr sx) =
151 draw ((-sqrt(2)*ds,0)--(sqrt(2)*ds,0)) rotated 45 shifted (sx,ht+(Ht-ht)/2);
152 if wmax<(sx+ds): wmax:=sx+ds; fi
153 enddef;
154
155 def umlaut(expr dx, sx) =
156 ipunkt(sx+dx);
157 ipunkt(sx+dx+7.5ut);
158 enddef;
159
160 def k_teil(expr sx) =
161 draw ((0,ht){up}..(3*ds,1.5*ht){right}..(3*ht/4,ht){down}..tension 1.5..(0,6ut){left}..(-4ut,8ut){up}..(-1ut,ht/2){right}..tension 1.5..{right}(12ut,ht/4)..{1,1}(15ut,7ut)) shifted (sx,0);
162 x0:=whatever; y0:=whatever;
163 z0 = (15ut,7ut) shifted (sx,0);
164 xpos:=sx+15ut;
165 if wmax<xpos: wmax:=xpos; fi
166 if wmax<(sx+3*ht/4): wmax:=sx+3*ht/4; fi
167 enddef;
168
169 def l_fuss (expr sx) =
170 draw ((0,ht/2){down}..tension1.2..(3.5ut,0){right}..tension1.2..{1,1}(7.5ut,3ut))
171 shifted (sx,0);
172 x0:=whatever; y0:=whatever;
173 z0 = (7.5ut,3ut) shifted (sx,0);
174 xpos:=sx+7.5ut;
175 if wmax<xpos: wmax:=xpos; fi
176 enddef;
177
178 def rschleife (expr sl, hy, deltay, fy, sx) =
179 draw ((0,0){right}..(sl,-(1-fs)*sl){down}..((1-fs)*sl,-sl){left}..if deltay<>0:tension1.5 ..fi(0,deltay){up}) yscaled fy shifted (sx,hy);
180 if wmax<(sx+sl): wmax:=sx+sl; fi
181 enddef;
182
183 def vbauch (expr hl, sx) =
184 bogen(hl,ht,vh,vb,0.5,90,-90,1,1,sx);
185 schweif(vh,fs*s/faktor,-(vb-s-1ut),-90,angle(-1,-0.25),1,1,xpos);
186 enddef;
187
188 def z_teil (expr sx) =
189 draw ((0,ht-dy){1,1}..(6ut,ht){right}..(12.5ut,ht-7ut){down}..tension 1.3..(5ut,5ut){left}..(2ut,6.5ut){up}..(5ut,8ut){right}..tension 1..(15ut,-7.5ut){down}..tension 1.2..(7ut,-dt){left}..(0,-dt+7ut){up}..tension 1.4..{1,1}(17.5ut,6.5ut)) shifted (sx,0);
190 x0:=whatever; y0:=whatever;
191 z0 = (17.5ut,6.5ut) shifted (sx,0);
192 xpos:=sx+17.5ut;
193 if wmax<xpos: wmax:=xpos; fi
194 if wmax<(sx+15ut): wmax:=sx+15ut; fi
195 enddef;
196
197 % Hermite-Interpolation, 2 Intervalle
198 % Scheitelpunkt bei (fx*b,hm)
199 def bogen (expr hl, hm, hr, b, fx, phil, phir, tensl, tensr, sx) =
200 p := (0,hl){dir phil}..tension tensl..(fx*b,hm){b/abs(b),0}..tension tensr..{dir phir}(b,hr);
201 draw p shifted (sx,0);
202 if (hm<hl) and (hm<hr) and
203 (((b>0) and (phir>45)) or ((b<0) and (phil>-135))):
204 x0:=whatever; y0:=whatever;
205 z0=(directionpoint (1,1) of if b<0: reverse fi p) shifted (sx,0); fi
206 xpos:=sx+b;
207 if wmax<xpos: wmax:=xpos; fi
208 enddef;
209
210 def ss_teil (expr sx) =
211 p := (0,ht){up}..tension 1.2..(8ut,35ut){right}..(15ut,27.5ut){down}..tension 1.2..(7.5ut,18.5ut){left}..(5.5ut,ht){up}..(7.5ut,21.5ut){right}..tension 1.1..(17.5ut,ht/2){down}..tension 1.2..(10ut,0){left}..(3ut,5ut);
212 draw p shifted (sx,0);
213 z0=(directionpoint (-1,-1) of (subpath (6,7) of p)) shifted (sx,0);
214 xpos:=sx+ht/2;
215 if wmax<xpos: wmax:=xpos; fi
216 if wmax<(s+17.5ut): wmax:=s+17.5ut; fi
217 enddef;
218
219 % Nur fuer Wartungszwecke
220 % Makro aktivieren, um die 'width' der Zeichen auszugeben
221 def zeigen=
222 % weite:=20*wmax/ht;
223 % showvariable weite;
224 enddef;
225
226 def a_teil =
227 kurzstrich(xpos);
228 stamm(ht,ht/2,xpos);
229 bogen(ht/2,0,ht/2,ht/k,0.5,-90,90,1,1,xpos);
230 stamm(ht/2,ht-s,xpos);
231 lschleife(s,ht-s,1,xpos);
232 schweif(ht-s,ht,gap,0,90,1,1,xpos);
233 stamm(ht,0,xpos);
234 enddef;
235
236 def o_char =
237 kurzstrich(xpos);
238 stamm(ht,ht/2,xpos);
239 bogen(ht/2,0,ht/2,ht/k,0.5,-90,90,1,1,xpos);
240 stamm(ht/2,ht-so,xpos);
241 fsalt:=fs; fs:=0.5;
242 lschleife(so,ht-so,1,xpos);
243 fs:=fsalt;
244 fahne(ht-so,ht-dy,3*ht/4-dy,0,45,1,1,xpos);
245 enddef;
246
247 %
248 % Makros fuer Grossbuchstaben
249 def Oval (expr Br, sx) =
250 p := (Br/2+0.5ut,Ht){left}..(0,Ht/2){down}..(Br/2,0){right}..(Br,Ht/2){up}..tension1.2..(Br/2+3.5ut,Ht){left}..(Br/2+1.5ut,Ht-1.5ut){down}..{right}(Br/2+8.5ut,Ht-5ut);
251 draw p shifted (sx,0);
252 x0:=whatever; y0:=whatever;
253 z0=(directionpoint (1,1) of (subpath (2,3) of p)) shifted (sx,0);
254 % Abstand vom Endpunkt bis zum rechten Rand des Ovals:
255 lastx:=Br/2-8.5ut;
256 xpos:=sx+Br/2+8.5ut;
257 if wmax<xpos: wmax:=xpos; fi
258 if wmax<(sx+Br): wmax:=sx+Br; fi
259 enddef;
260
261 def Stock (expr sx) =
262 breit:=12.5ut;
263 draw ((0,Ht-5ut){1,2}..(0.6*breit,Ht){right}..{down}(breit,Ht-10ut)) shifted (sx,0);
264 xpos:=sx+breit;
265 if wmax<xpos: wmax:=xpos; fi
266 enddef;
267
268 def Ihaken=
269 bogen(Ht-7.5ut,Ht,Ht-10ut,12.5ut,0.6,90,-90,1.5,1,xpos);
270 enddef;
271
272 def Ibogen=
273 bogen(10ut,0,10ut,-22.5ut,0.5,-90,90,1,1,xpos);
274 enddef;
275
276 def Oschl(expr sx) =
277 draw ((-10ut,ht+5ut){1,-2}..(0,ht){right}..(Sb,Ht-fs*ht){up}..((1-fs)*Sb,Ht){left}..{down}(0,ht)) shifted (sx+10ut,0);
278 xpos:=sx+10ut;
279 if wmax<xpos: wmax:=xpos; fi
280 if wmax<(sx+10ut+Sb): wmax:=sx+10ut+Sb;fi
281 enddef;
282
283 def L_fuss(expr B, sx) =
284 draw ((0,ht/4){down}..(-3.5ut,0){left}..(-7.5ut,3ut){up}..(-4ut,6ut){right}..tension 1.5..(B,0){right}) shifted (sx,0);
285 xpos:=sx+B;
286 if wmax<xpos: wmax:=xpos; fi
287 enddef;
288
289 def B_bauch(expr sx) =
290 lasty:=8.25ut;
291 draw ((0,0){right}..(5ut,5ut){up}..tension1..(0ut,12ut){left}..(-1.2ut,11ut){down}..tension1.2..(2.5ut,lasty){right}) shifted (sx,0);
292 xpos:=sx+2.5ut;
293 if wmax<xpos: wmax:=xpos; fi
294 if wmax<(sx+5ut): wmax:=sx+5ut; fi
295 enddef;
296
297 def D_kopf (expr sx) =
298 draw ((0,ht){up}..(-12ut,Ht){left}..(-20ut,32ut){down}..(0,ht){right}..(7.5ut,ht+2.5ut)) shifted (sx,0);
299 xpos:=sx+7.5ut;
300 if wmax<xpos: wmax:=xpos; fi
301 enddef;
302
303 def schwalbe(expr sx) =
304 draw ((0,Ht-7.5ut){up}..tension 1.5..(4ut,Ht){right}..tension 1.5..(11ut,Ht-7.5ut){right}..{up}(15ut,Ht)) shifted (sx,0);
305 xpos:=sx+15ut;
306 if wmax<xpos: wmax:=xpos; fi
307 enddef;
308
309 def Ipunkt (expr sx) =
310 draw ((-sqrt(2)*3ut,0)--(sqrt(2)*3ut,0)) rotated 45 shifted (sx,Ht+7ut);
311 if wmax<(sx+3ut): wmax:=sx+3ut; fi
312 enddef;
313
314 def Umlaut(expr dx, sx) =
315 Ipunkt(sx+dx);
316 Ipunkt(sx+dx+8.5ut);
317 enddef;
318
319 def A_teil =
320 Oval(25ut,xpos);
321 schweif(Ht-5ut,Ht,lastx+gap,0,90,1,1,xpos);
322 enddef;
323
324 def A_char =
325 xpos:=0;wmax:=xpos;
326 A_teil;
327 stamm(Ht,ht/2,xpos);
328 l_fuss(xpos);
329 tangente(0);
330 enddef;
331
332 def O_char =
333 xpos:=0;wmax:=xpos;
334 Oval(30ut,xpos);
335 a:=x0;b:=y0;
336 schweif(Ht-5ut,Ht,lastx,0,angle(1,2),1,1,xpos);
337 x0:=whatever;y0:=whatever;
338 z0=(a,b);
339 tangente(2.5ut);
340 enddef;
341
342 def U_char =
343 xpos:=0;wmax:=xpos;
344 Stock(xpos);
345 stamm(Ht-10ut,15ut,xpos);
346 bogen(15ut,0,15ut,20ut,0.5,-90,90,1,1,xpos);
347 stamm(Ht-S,15ut,xpos);
348 lschleife(S,Ht-S,1,xpos);
349 schweif(Ht-S,Ht,gap,0,90,1,1,xpos);
350 stamm(Ht,ht/2,xpos);
351 l_fuss(xpos);
352 tangente(0);
353 enddef;
354
355 def Vbauch (expr hl, sx) =
356 bogen(hl,Ht,Vh,Vb,0.5,90,-90,1,1,sx);
357 schweif(Vh,fs*S/faktor,-(Vb-S-1ut),-90,angle(-1,-0.25),1.2,0.5,xpos);
358 enddef;
359
360 def N_fuss (expr hl, br, tensl, tensr, sx) =
361 draw ((0,hl){down}..tension tensl..(br,0){right}..tension tensr..{1,1}(br+4ut,3ut))
362 shifted (sx,0);
363 x0:=whatever; y0:=whatever;
364 z0 = (br+4ut,3ut) shifted (sx,0);
365 xpos:=sx+br+4ut;
366 if wmax<xpos: wmax:=xpos; fi
367 enddef;
368
369 def Dschl (expr sx) =
370 draw ((-gap/2,0){down}..(-(BX+gap/2)*(1-fs),-ht){left}..(-(BX+gap/2),-ht*(1-fs)){up}..tension1.3..(0,0)..tension1.3..(BX+gap/2,ht*(1-fs)){up}..((BX+gap/2)*(1-fs),ht){left}..{down}(gap/2,0)) shifted (sx+gap/2,ht);
371 xpos:=sx+gap;
372 if wmax<xpos: wmax:=xpos; fi
373 if wmax<(sx+BX+gap/2): wmax:=sx+BX+gap/2; fi
374 enddef;
375
376 def P_teil(expr sx) =
377 draw ((0,25ut){up}..(10ut,Ht){right}..(20ut,30ut){down}..tension 1.5..(0,5ut){left}..(-4ut,8ut){up}..(-2ut,10ut){right}..tension 1.5..(10ut,5ut){right}..{1,1}(14ut,7ut)) shifted (sx,0);
378 x0:=whatever; y0:=whatever;
379 z0 = (14ut,7ut) shifted (sx,0);
380 xpos:=x0;
381 if wmax<xpos: wmax:=xpos; fi
382 if wmax<(sx+20ut): wmax:=sx+20ut; fi
383 enddef;
384
385 def K_teil (expr sx) =
386 breit:=13ut;
387 draw ((0,ht){down}..(-12.5ut,0){left}..(-20ut,7.5ut){up}..(0,ht){right}..(breit,ht-7.5ut){down}..tension 1.2..(1.5ut,5ut){left}..(-2ut,7.5ut){up}..(1.5ut,9ut){right}..tension 1.2..(13ut,0){right}) shifted (sx,0);
388 xpos:=sx+13ut;
389 if wmax<xpos: wmax:=xpos; fi
390 if wmax<(sx+breit): wmax:=sx+breit; fi
391 enddef;
392
393 def R_teil (expr sx) =
394 breit:=13ut;
395 draw ((0,Ht){right}..(breit,Ht-9ut){down}..(-2.5ut,ht-1ut){left}..(-5ut,ht+1.5ut){up}..(-2ut,ht+3ut){right}..tension1.5..(12ut,0){right}) shifted (sx,0);
396 xpos:=sx+12ut;
397 if wmax<xpos: wmax:=xpos; fi
398 if wmax<(sx+breit): wmax:=sx+breit; fi
399 enddef;
400
401 def Z_teil (expr sx) =
402 breit:=20ut;
403 p := (0,32.5ut){1,4}..(10ut,Ht){right}..(breit,29ut){down}..tension1.2..(6.25ut,13ut){left}..(4ut,15ut){up}..(6.25ut,17ut){right}..tension1..(breit,-2ut){down}..tension1.2..(12ut,-dt){left}..(4ut,-11ut){up}..tension 1.2..{1,1}(24ut,10ut);
404 draw p shifted (sx,0);
405 x0:=whatever; y0:=whatever;
406 z0=(24ut,10ut) shifted (sx,0);
407 xpos:=sx+24ut;
408 if wmax<xpos: wmax:=xpos; fi
409 if wmax<(sx+breit): wmax:=sx+breit; fi
410 enddef;
411
412 def Shalbe(expr B) =
413 bogen(Ht-Sab,Ht,Hs,B+gap,Sf,angle(1,Sm),-90,1,Stens,xpos);
414 bogen(Hs,0,Hs,-B,0.5,-90,90,1,1,xpos);
415 enddef;
416
417 def Szwbogen(expr B, ab, phir) =
418 bogen(Hs,Ht,Ht-ab,B,1-Sf,90,phir,Stens,1,xpos);
419 enddef;
420
421 def Nrechts =
422 schweif(Hs,Ht,Bs,90,angle(1,0.25),1,1,xpos);
423 schweif(Ht,Ht,Bs,-90,45,1,1,xpos);
424 schweif(Ht,Hs,-(Bs-gap),-135,-90,1,1,xpos);
425 enddef;
426 %%%%%%%%%%%%%%%%%%% File-Ende %%%%%%%%%%%%%%%%%%%