Debian Codegraph @

texmf-dist/fonts/source/public/schulschriften/wela14_def.mf

raw
1 % Lateinische Ausgangsschrift (LA) wela
2 % Parameter und Makrodefinitionen
3 % 16.10.2011
4 % 11.09.2014: Schleifchen-e modifiziert
5 % e am Wortanfang
6 % latin_e, latin_eg,
7 % latin_er, latin_eb, e mit langem Schweif, latin_e_form,
8 % Oberlaengen bei b,f,h,k,l Schnittpunkt tiefer gelegt (ht-Delta)
9 % n,m,r,v,w Spazierstock Biegung verschaerft
10 % a,ä,d,h,i,m,n,p,u,ü Stock staerker verrundet (0,2rho)..(1.5rho,0)
11 % s beginn jetzt oben abwaerts in Richtung Anstrich {-1,-m}
12 % und Bauch etwas tiefer gelegt
13 % 15.09.2014: Als neue Version von wela verwendet
14 % 14.11.2014: s', r' geaendert
15 %
16 % Parameter:
17
18 % kl. Abstand in der Groesse der Strichstaerke
19 eta:=1ut;
20 % Steigung des Verbindungsstrichs
21 m:=1.5;
22 % Superellipse
23 b=ht/2;
24 k:=1.425;
25 a*k=b;
26 sigma:=0.73345;
27
28 % Delta, delta
29 z1=(0,b); z2=(-a,0);
30 z5=(-sigma*a,sigma*b);
31 p := z1{left}..z5{z2-z1}..{down}z2;
32 x0:=whatever;y0:=whatever;
33 z0=(directionpoint(1,m) of (reverse (subpath (0,2) of p)));
34 delta:=a+x0;Delta:=b-y0;
35
36 % typische kleine Masse
37 dd:=2.5ut;
38 D:=5ut;
39 s:=7.5ut;
40 % Radius z.B. bei "a"
41 rho:=2ut;
42
43 % Unterschleife, Schnittpunkt bei (0,0)
44 % Steigung m
45 sb:=9ut;
46 sbf:=0.35; % sb*sbf
47 sbfh:=0.23; % dt*sbfh
48 % vor lat. e, Steigung m'
49 m':=0.87;
50 sb':=9ut;
51 sbf':=sbf;
52 sbfh':=0.28;
53 % Oberschleife, Schnittpunkt bei (0,ht)
54 % Steigung m
55 sb'':=9ut;
56 sbf'':=0.35; % sb''*sbf''
57 sbfh'':=0.23; % dt*sbfh''
58 % Breite von "h" etc (breite=ht/kh)
59 kh:=1.66;
60 % Breite der Fahne bei r
61 rfahne:=12ut;
62 % Einrollmass
63 einroll:=ht/9;
64 % Breite der Fahne bei o, v, w
65 ofahne:=rfahne+einroll;
66 % Breite der Fahne bei b
67 bfahne:=ofahne;
68 % Steigung der Fahne bei b, v, w
69 mfahne:=2;
70 % Breite von "s"
71 sbreite:=7.5ut;
72 % gekroepftes e
73 me:=0.33;
74 ebreite:=8ut;
75 ef:=0.3;
76 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%
77 % Parameter fuer Grossbuchstaben:
78
79 % Flaggen
80 flaggenbreite:=17.5ut;
81 zbreite:=flaggenbreite;
82 Zbreite:=22.5ut;
83 % Stamm
84 % Radius bei "Stamm"
85 R:=10ut;
86 % Abstand der Umlautstriche bei Grossbuchstaben:
87 dumlaut:=7.5ut;
88 % Oberschleifenbreite:
89 Sb:=17.5ut; % bei C, G %%
90 SbL:=15ut;% L
91 % Schleifenbreitenfaktor
92 Sbf:=0.267;
93 sporn:=12.5ut; %% am Oschl
94 Sporn:=10ut; % am Fuss von A,M,N...
95 over:=7.5ut; %% bei A, 5ut bei M,N
96 Abreite:=ht; % 20ut %%
97 Mbreite:=0.9Abreite;
98 Nbreite:=12.5ut;
99 mN:=5.33;
100 % Superellipse: O, Q
101 A:=12.5ut; %%
102 B:=Ht/2;
103 % Steigung des Ohrs bei "O"
104 mO:=4;
105 X:=ht/2; % fuer X
106 % H-Kurve:
107 Hf:=0.18;
108 Hfx:=0.35;
109 Hbreite:=12.5ut; %%
110 mt:=m;
111 % Parameter fuer Ziffern:
112 s':=5ut; % seitlicher Abstand
113 w':= Wz-2s'; % effektive Breite der Ziffern
114 r:=(w'-dd)/2; % Radius bei "2"
115 % Zeichen:
116 hmath:=ht/2;
117 hdash:=ht/2;
118 % Kerning:
119 Bkern#:=-10.5ut#;
120 Dkern#:=-12.5ut#;
121 Fkern#:=-20ut#;
122 Ikern#:=-9ut#;
123 Nkern#:=-20ut#;
124 Okern#:=-18.79ut#;
125 Pkern#:=-25ut#;
126 Skern#:=-22.5ut#;
127 Tkern#:=-20ut#;
128 Vkern#:=-18.778ut#; % auch W
129 skern#:=-7.5ut#;
130 sskern#:=-7.018ut#;
131
132 %%%%%%%%%%%%%% Makros %%%%%
133 Kern:=0;
134 % Nur fuer Wartungszwecke
135 % Makro aktivieren, um die 'width' der Zeichen auszugeben
136 def zeigen=
137 % weite:=20*xpos/ht;
138 % if Kern>0:
139 % kernwert:=20*Kern/ht;
140 %showvariable kernwert;
141 % fi
142 % showvariable weite;
143 % Kern:=0;
144 enddef;
145
146 % Fuer Kleinbuchstaben:
147 def oval(expr sx)=
148 x1:=whatever;y1:=whatever;
149 x2:=whatever;y2:=whatever;
150 x3:=whatever;y3:=whatever;
151 x4:=whatever;y4:=whatever;
152 x5:=whatever;y5:=whatever;
153 x6:=whatever;y6:=whatever;
154 x7:=whatever;y7:=whatever;
155 x8:=whatever;y8:=whatever;
156 z1=(0,b); z2=(-a,0); z3=(0,-b); z4=(a,0);
157 z5=(-sigma*a,sigma*b);
158 z6=(-sigma*a,-sigma*b);
159 z7=(sigma*a,-sigma*b);
160 z8=(sigma*a,sigma*b);
161 p:= (z1{left}..z5{z2-z1}..z2{down}..z6{z3-z2}..
162 {right}z3..z7{z4-z3}..z4{up}..z8{z1-z4}..{left}z1);
163 draw p shifted (sx+a-delta,b);
164 x1:=whatever;y1:=whatever;
165 z1=(directionpoint (-1,mfahne) of (subpath (6,8) of p)) shifted (sx+a-delta,b);
166 xpos:=sx+2a-delta;
167 enddef;
168
169 def ohr=
170 draw (z1--(x1-(ht-y1)/mfahne,ht));
171 xpos:=x1-(ht-y1)/mfahne;
172 enddef;
173
174 \def stock(expr sx)=
175 if not wortende:
176 draw ((0,2*rho){down}..(1.5rho,0){right}..tension2.5 and 4..{1,m}(2.5*rho+(ht-Delta)/m,ht-Delta)) shifted (sx,0);
177 xpos:=sx+2.5*rho+(ht-Delta)/m;
178 else:
179 draw ((0,2*rho){down}..{right}(1.5rho,0)) shifted (sx,0);
180 xpos:=sx+rho;
181 fi
182 enddef;
183
184 def oschl(expr sx)=
185 draw ((0,ht-Delta){1,m}..tension1.5..(sb'',Ht-dt*sbfh''){up}..((1-sbf'')*sb'',Ht){left}..tension 1.5..{down}(0,ht-Delta)) shifted (sx,0);
186 xpos:=sx;
187 enddef;
188
189 def uschl(expr sx)=
190 draw ((0,0){down}..tension 1.5..(-(1-sbf)*sb,-dt){left}..(-sb,-dt*(1-sbfh)){up}..tension1.5..{1,m}(0,0)) shifted (sx,0);
191 xpos:=sx;
192 enddef;
193
194 def latin_eg (expr sx) =
195 % draw ((0,0)--(0.5ht/m',ht/2)) shifted (sx,0);
196 % draw ((0.5ht/m',ht/2){1,me}..(ebreite+0.5ht/m',ht-ef*ebreite){up}..(ebreite*(1-ef)+0.5ht/m',ht){left}..(0.5ht/m',ht/2){down}..{right}(ebreite*(1-ef)+0.5ht/m',0)) shifted (sx,0);
197 draw ((0,0){1,m'}..(ebreite+8ut,ht-ef*ebreite){up}..(ebreite*(1-ef)+8ut,ht){left}..(8ut,ht/2){down}..{right}(ebreite*(1-ef)+8ut,0)) shifted (sx,0);
198 xpos:=sx+ebreite*(1-ef)+8ut;
199 enddef;
200
201 def uschl_e (expr sx) =
202 draw ((0,0){down}..tension 1.5..(-(1-sbf')*sb',-dt){left}..(-sb',-dt*(1-sbfh')){up}..tension1.5..{1,m'}(0,0)) shifted (sx,0);
203 xpos:=sx;
204 enddef;
205
206 def stamm(expr ha, hb, sx)=
207 draw ((0,ha)--(0,hb)) shifted (sx,0);
208 xpos:=sx;
209 enddef;
210
211 def strich (expr sx)=
212 if not wortende:
213 draw ((0,0)--((ht-Delta)/m,ht-Delta)) shifted (sx,0);
214 xpos:=sx+(ht-Delta)/m;
215 else:
216 xpos:=sx;
217 fi
218 enddef;
219
220 def kurzstrich(expr sx)=
221 draw ((0,ht-Delta)--(Delta/m,ht)) shifted (sx,0);
222 xpos:=sx+Delta/m;
223 enddef;
224
225 def ipunkt (expr sx)=
226 drawdot ((0,0)) shifted (sx,ht+dt/2);
227 xpos:=sx;
228 enddef;
229
230 def schweif (expr hl, hr, bt, phil, phir, tens, sx) =
231 p := (0,hl){dir phil}..tension tens..{dir phir}(bt,hr);
232 draw p shifted (sx,0);
233 if ((bt>0) and (phil<angle(1,mt)) and (angle(1,mt)<phir)) or ((bt<0) and (phir<angle(-1,-mt)) and (angle(-1,-mt)<phil)):
234 x0:=whatever; y0:=whatever;
235 z0=(directionpoint (1,mt) of if bt>0:(subpath (0,1) of p)else: reverse(subpath (0,1) of p)fi ) shifted (sx,0);
236 fi
237 xpos:=sx+bt;
238 enddef;
239
240 def fahne (expr hl, hr, bt, phil, phir, tens, sx) =
241 if not wortende:
242 schweif(hl, hr, bt, phil, phir, tens, sx);
243 else:
244 xpos:=sx;
245 fi
246 enddef;
247
248 def spitz(expr sx)=
249 % draw ((0,ht-Delta){1,m}..{up}(eta,ht)) shifted (sx,0); %%%%% leer
250 % xpos:=sx+eta;
251 xpos:=sx; %%%% Breite=0
252 enddef;
253
254 def bogen(expr hl,hm,hr,bt,fx,phil,phir,tensl,tensr,sx)=
255 p:=((0,hl){dir phil}..tension tensl..(bt*fx,hm){bt,0}..tension tensr..{dir phir}(bt,hr));
256 draw p shifted (sx,0);
257 if (hl>hm) and (hr>hm):
258 x0:=whatever; y0:=whatever;
259 z0=(directionpoint (1,mt) of if bt>0:(subpath (1,2) of p)else: reverse(subpath (0,1) of p)fi) shifted (sx,0);
260 fi
261 xpos:=sx+bt;
262 enddef;
263
264 def fuss(expr sx)=
265 draw ((0,2*rho)..{right}(2*rho,0)) shifted (sx,0);
266 xpos:=sx+2*rho;
267 enddef;
268
269 def quer(expr ha, sx)=
270 draw ((-s+dd/2,0)--(s-dd/2,0)) shifted (sx,ha);
271 enddef;
272
273 def gerade (expr ha, hb, bt, sx)=
274 draw ((0,ha)--(bt,hb)) shifted (sx,0);
275 xpos:=sx+bt;
276 enddef;
277
278 def c_form (expr sx)=
279 x1:=whatever;y1:=whatever;
280 x2:=whatever;y2:=whatever;
281 x3:=whatever;y3:=whatever;
282 x4:=whatever;y4:=whatever;
283 x5:=whatever;y5:=whatever;
284 x6:=whatever;y6:=whatever;
285 x7:=whatever;y7:=whatever;
286 x8:=whatever;y8:=whatever;
287 z1=(0,b); z2=(-a,0); z3=(0,-b); z4=(a,0);
288 z5=(-sigma*a,sigma*b);
289 z6=(-sigma*a,-sigma*b);
290 z7=(sigma*a,-sigma*b);
291 z8=(sigma*a,sigma*b);
292 draw (z8{z1-z4}..z1{left}..z5{z2-z1}..z2{down}..z6{z3-z2}..
293 {right}z3) shifted (sx+a-delta,b);
294 xpos:=sx+a-delta;
295 enddef;
296
297 def tangente (expr ddx)=
298 if not wortende:
299 draw ((x0,y0){1,mt}..{1,m}(x0+ddx+(ht-Delta-y0)/m,ht-Delta));
300 mt:=m;
301 xpos:=x0+ddx+(ht-Delta-y0)/m;
302 fi
303 enddef;
304
305 def spazierstock (expr sx)=
306 % draw ((0,ht-Delta){1,m}..(Delta+rho,ht){right}..{down}(Delta+2*rho,ht-rho)) shifted (sx,0);
307 draw ((0,ht-Delta){1,m}..(Delta,ht){right}..{down}(Delta+rho,ht-rho)) shifted (sx,0);
308 xpos:=sx+Delta+rho;
309 enddef;
310
311 def s_form(expr sx)=
312 p:= ((0,ht){-1,-m}..(sbreite,sbreite-2ut){down}..(0,0){left}..(-sbreite+2ut,dd));
313 draw p shifted (sx,0);
314 x0:=whatever;y0:=whatever;
315 z0=(directionpoint(1,mt) of (reverse (subpath (1,2) of p))) shifted (sx,0);
316 xpos:=sx+sbreite;
317 Kern:=sbreite;
318 enddef;
319
320 def ss_form (expr sx)=
321 draw ((0,ht){up}..(0.6*ht/kh,Ht){right}..(ht/kh,ht+0.6*dt){down}..{left}(ht/6,ht)) shifted (sx,0);
322 p:=(ht/6,ht)--(ht/6+ht/12,ht){right}..(2*a,0.5*ht){down}..(a,0){left}..(ht/6,ht/12);
323 draw p shifted (sx,0);
324 x0:=whatever;y0:=whatever;
325 z0=(directionpoint (-1,-mt) of (subpath (2,3) of p)) shifted (sx,0);
326 xpos:=sx+2*a;
327 Kern:=a;
328 enddef;
329
330 def ss_ansatz(expr sx)=
331 draw ((0,ht-Delta){1,m}..(Delta,ht){right}..{down}(Delta+rho,ht-rho)) shifted (sx,0);
332 xpos:=sx+Delta+rho;
333 enddef;
334
335 def a_char=
336 oval(xpos);
337 stamm(ht,2rho,xpos);
338 stock(xpos);
339 enddef;
340
341 def o_char=
342 oval(xpos);
343 ohr;
344 fahne(ht,ht-Delta,ofahne,angle(1,-mfahne),angle(1,m),1,xpos);
345 enddef;
346
347 def u_char=
348 spitz(xpos);
349 stamm(ht,ht/6,xpos);
350 bogen(ht/6,0,3ht/4,ht/kh,0.2,-90,90,1,1.2,xpos);
351 stamm(ht,2rho,xpos);
352 stock(xpos);
353 enddef;
354
355 def umlaut(expr dx,sx)=
356 draw ((0,s/2)--(0,-s/2)) shifted (sx+dx,ht+dt/2);
357 draw ((D,s/2)--(D,-s/2)) shifted (sx+dx,ht+dt/2);
358 xpos:=sx;
359 enddef;
360
361 def k_form(expr sx)=
362 draw ((0,ht/3){up}..(1.5*a,ht){right}..(2*a,0.8*ht){down}..tension1.2..{left}(ht/6,ht/2)) shifted (sx,0);
363 draw ((ht/6,ht/2){1,-0.5}..tension1.5..{right}(2*a-rho,0)) shifted (sx,0);
364 xpos:=sx+2*a-rho;
365 enddef;
366
367 % lat. e, Normalform
368 def latin_e (expr sx)=
369 % draw ((0,0){right}..tension1..{1,m}(3.5ut+0.5ht/m,ht/2)) shifted (sx,0);
370 % draw ((3.5ut+0.5ht/m,ht/2){1,me}..(ebreite+3.5ut+0.5ht/m,ht-ebreite*ef){up}..(ebreite*(1-ef)+3.5ut+0.5ht/m,ht){left}..(3.5ut+0.5ht/m,ht/2){down}..{right}(ebreite*(1-ef)+3.5ut+0.5ht/m,0)) shifted (sx,0);
371 draw ((0,0){right}..(ebreite+0.5ut+0.5ht/m,ht-ebreite*ef){up}..(ebreite*(1-ef)+0.5ut+0.5ht/m,ht){left}..(0.5ut+0.5ht/m,ht/2){down}..{right}(ebreite*(1-ef)+0.5ut+0.5ht/m,0)) shifted (sx,0);
372 xpos:=sx+ebreite*(1-ef)+0.5ut+0.5ht/m;
373 enddef;
374
375 def latin_e_form (expr sx)=
376 draw ((ebreite,ht-ebreite*ef){up}..(ebreite*(1-ef),ht){left}..(0,ht/2){down}..{right}(ebreite*(1-ef),0)) shifted (sx,0);
377 xpos:=sx+ebreite*(1-ef);
378 enddef;
379
380
381
382 % lat. e nach b, o, v, w
383 def latin_eb (expr sx)=
384 draw ((0,ht){1,-mfahne}..(10ut,ht/2){right}..(17.5ut,ht-2.5ut){up}..(15ut,ht){left}..(10ut,ht/2){down}..{right}(15ut,0)) shifted (sx,0);
385 xpos:=sx+15ut;
386 enddef;
387
388 % lat. e nach r
389 def latin_er (expr sx)=
390 draw ((0,ht){down}..(7.5ut,ht/2){right}..(15ut,ht-2.5ut){up}..(12.5ut,ht){left}..(7.5ut,ht/2){down}..{right}(12.5ut,0)) shifted (sx,0);
391 xpos:=sx+12.5ut;
392 enddef;
393
394 def x_form (expr bt, ha, sx)=
395 draw ((0,ha-Delta){1,m}..(0.2bt,ha){right}..(bt/2,2ha/3){down}--(bt/2,ha/3){down}..(0.2bt,0){left}..(0,0.15ha){up}..tension1.5..(bt,0.85ha){up}..(0.8bt,ha){left}..{down}(bt/2,2ha/3)--(bt/2,ha/3){down}..{right}(0.8bt,0)) shifted (sx,0);
396 xpos:=sx+0.8bt;
397 enddef;
398
399
400 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
401 % Makros fuer Grossbuchstaben
402 def Umlaut (expr dx,sx)=
403 draw ((0,s/2)--(0,-s/2)) shifted (sx+dx,Ht+dumlaut);
404 draw ((D,s/2)--(D,-s/2)) shifted (sx+dx,Ht+dumlaut);
405 xpos:=sx;
406 enddef;
407
408 def Stamm (expr bt, ha, sx)=
409 p:=((0,dd)..(0.4bt,0){right}..{up}(bt,0.6bt)--(bt,ha));
410 draw p shifted (sx,0);
411 x0:=whatever; y0:=whatever;
412 z0=(directionpoint (1,mt) of (subpath (1,2) of p)) shifted (sx,0);
413 xpos:=sx+bt;
414 enddef;
415
416 def Spazierstock (expr sx)=
417 draw ((0,Ht-D){1,2}..(D,Ht){right}..{down}(D+rho,Ht-rho)) shifted (sx,0);
418 xpos:=sx+D+rho;
419 enddef;
420
421 def Dach (expr sx)=
422 draw((0,Ht-dt/2){up}..(10ut,Ht){right}--(27.5ut,Ht))
423 shifted (sx,0);
424 xpos:=sx;
425 enddef;
426
427 def HaubeD(expr sx)=
428 p:= ((0,Ht-D){1,1}..(10ut,Ht){right}..(30ut,ht){down}..{left}(17.5ut,0));
429 draw p shifted (sx,0);
430 x0:=whatever; y0:=whatever;
431 z0=(directionpoint (-1,-mt) of (subpath (2,3) of p)) shifted (sx,0);
432 enddef;
433
434 def schlinge_links (expr ha,dicke,bt,sx) =
435 draw ((0,ha+dicke/2){left}..(-bt,ha){down}..{right}(0,ha-dicke/2)) shifted (sx,0);
436 xpos:=sx;
437 enddef;
438
439 def Flagge (expr sx) =
440 bogen(Ht-D,Ht,Ht,flaggenbreite,0.3,75,90,1,1,sx);
441 enddef;
442
443 def Oschl (expr sp, bt, sx)=
444 bogen(ht+D,top(ht),Ht-bt*Sbf,sp+bt,sp/(sp+bt),-45,90,1,1,sx);
445 bogen(Ht-bt*Sbf,Ht,top(ht),-bt,Sbf,90,-90,1,1,xpos);
446 enddef;
447
448 def Oval(expr sx)=
449 x1:=whatever;y1:=whatever;
450 x2:=whatever;y2:=whatever;
451 x3:=whatever;y3:=whatever;
452 x4:=whatever;y4:=whatever;
453 x5:=whatever;y5:=whatever;
454 x6:=whatever;y6:=whatever;
455 x7:=whatever;y7:=whatever;
456 x8:=whatever;y8:=whatever;
457 z1=(0,B); z2=(-A,0); z3=(0,-B); z4=(A,0);
458 z5=(-sigma*A,sigma*B);
459 z6=(-sigma*A,-sigma*B);
460 z7=(sigma*A,-sigma*B);
461 z8=(sigma*A,sigma*B);
462 p:= (z1{left}..z5{z2-z1}..z2{down}..z6{z3-z2}..
463 {right}z3..{z4-z3}z7..z4{up}..z8{z1-z4}..{left}z1);
464 draw p shifted (sx+A,B);
465 x1:=whatever;y1:=whatever;
466 z1=(directionpoint (-1,mO) of (subpath (6,8) of p)) shifted (sx+A,B);
467 x0:=whatever; y0:=whatever;
468 z0=(directionpoint (1,mt) of (subpath (4,6) of p)) shifted (sx+A,B);
469 xpos:=sx+2*A; % max Breite
470 enddef;
471
472 def Ohr =
473 draw (z1--(x1-(Ht-y1)/mO,Ht){1,-mO}..{1,4}(x1-(Ht-y1)/mO+10ut,Ht));
474 xpos:=x1-(Ht-y1)/mO+10ut;
475 enddef;
476
477 def E_form(expr sx)=
478 draw ((s,Ht-dd)..(0,Ht){left}..(-10ut,Ht-dt/2){down}..{right}(dd,top(ht))) shifted (sx+12.5ut,0);
479 draw ((dd,top(ht)){left}..(-12.5ut,ht/2){down}..{right}(0,0)) shifted (sx+12.5ut,0);
480 xpos:=sx+12.5ut;
481 enddef;
482
483 def Flanke(expr sp,bt,o,sx)=
484 mA:=(Ht+o)/bt;
485 draw ((0,dd)..(sp/2,0){right}..tension1.2..{1,mA}(sp+R/mA,R)--(sp+(Ht-R)/mA,Ht-R){1,mA}..(sp+bt,Ht)) shifted (sx,0);
486 xpos:=sx+sp+bt;
487 enddef;
488
489 def A_schlaufe(expr sx )=
490 draw ((0,0){up}..tension1..(-Abreite,ht/2+dd){-1,-Ht/Abreite}..{right}(0,0)) shifted (sx,0);
491 xpos:=sx;
492 enddef;
493
494 def X_form(expr sx)=
495 x1:=whatever;y1:=whatever;
496 x2:=whatever;y2:=whatever;
497 x3:=whatever;y3:=whatever;
498 x4:=whatever;y4:=whatever;
499 x5:=whatever;y5:=whatever;
500 x6:=whatever;y6:=whatever;
501 x7:=whatever;y7:=whatever;
502 x8:=whatever;y8:=whatever;
503 z1=(0,B); z2=(-X,0); z3=(0,-B); z4=(X,0);
504 z5=(-sigma*X,sigma*B);
505 z6=(-sigma*X,-sigma*B);
506 z7=(sigma*X,-sigma*B);
507 z8=(sigma*X,sigma*B);
508 p:= ((X*sigma,B-dd)..z1{left}..z5{z2-z1}..z2{down}..z6{z3-z2}..
509 {right}z3);
510 q:=((-X*sigma,-B+dd)..{right}z3..{z4-z3}z7..z4{up}..z8{z1-z4}..{left}z1..z5{z2-z1});
511 draw q shifted (sx+X*sigma,B);
512 draw p shifted (sx+X*(2+sigma),B);
513 xpos:=sx+X*(2+sigma);
514 enddef;
515
516 def S_kurve (expr sx)=
517 p:=((-s/2,-Ht/2+1.5R){down}..(-s/2-Hbreite*(1-Hfx),-Ht/2){left}..(-s/2-Hbreite,-Ht/2*(1-Hf)){up}..tension1.2..{1,0.65}(0,0));
518 draw p shifted (sx,Ht/2);
519 draw (p rotated 180) shifted (sx,Ht/2);
520 xpos:=sx+s/2;
521 enddef;
522
523 def A_char=
524 Flanke(Sporn,Abreite,over,xpos);
525 stamm(Ht,0,xpos);
526 A_schlaufe(xpos);
527 fahne(0,ht-Delta,2rho+(ht-Delta)/m,0,angle(1,m),1.5,xpos);
528 enddef;
529
530 def O_char=
531 mt:=0.3;
532 Oval(xpos);
533 Ohr;
534 Kern:=xpos-A;
535 tangente(10ut);
536 enddef;
537
538 def U_char=
539 Spazierstock(xpos);
540 stamm(Ht-rho,ht/2,xpos);
541 bogen(ht/2,0,ht,ht,0.35,-90,90,1,1,xpos);
542 stamm(Ht,rho,xpos);
543 stock(xpos);
544 enddef;
545
546 % Sonderzeichen
547 def komma (expr ha,sx)=
548 draw ((0,0){down}--(0,-s)) shifted (sx,ha);
549 enddef;
550 %%%%%%%%%%%%%%%%%%%%%% Ende Makros %%%%%%%%%%%%%%%%%%%%%%%%%%%