Debian Codegraph @

texmf-dist/fonts/source/public/schulschriften/wela14_sz.mf

raw
1 % Lateinische Ausgangsschrift (LA) wela
2 % Walter Entenmann
3 % 16.10.2011
4 % 14.11.2014: Aenderungen
5 % 1. 3/4 hohe Ziffern 0-9
6 % 2. 3/4 hohe Zeichen ? und !
7 % 3. Einheitliche Sonderzeichen
8 % # % & § $ @ / * euro
9 % franz < > << >>
10 % Bindestrich/Trennstrich -
11 % -- --- + < > =
12
13 % #
14 beginchar("#",35ut#,Ht#,0);
15 pickup wela_pen;
16 p:=(0,0)--(0,Ht);
17 draw p slanted 0.176 shifted (10ut,0);
18 draw p slanted 0.176 shifted (20ut,0);
19 q:=((0,0)--(26ut,0)) shifted (2ut,0);
20 draw q shifted(0,Ht/3) slanted 0.176;
21 draw q shifted(0,2Ht/3) slanted 0.176;
22 endchar;
23
24 % §
25 beginchar(oct"237",43.333ut#,Ht#,dt#);
26 pickup wela_pen;
27 sep:=10ut; breit:=20ut;
28 p := ((8ut,20ut){curl 10}..(0ut,30ut){left}..(-breit/2,22ut){down}..
29 (breit/2,-2.5ut){down}..{-1,2/3}(2ut,-11ut)) scaled ((Ht+dt)/60ut);
30 draw p shifted (sep+breit*0.583,ht/2);
31 draw p rotated 180 shifted (sep+breit*0.583,ht/2);
32 endchar;
33
34 % *
35 beginchar("*",30ut#,Ht#,0);
36 pickup wela_pen;
37 p:= (-ht/2,0)--(ht/2,0);
38 draw p rotated 90 shifted (15ut,1.5ht);
39 draw p rotated 30 shifted (15ut,1.5ht);
40 draw p rotated -30 shifted (15ut,1.5ht);
41 endchar;
42
43 % Prozentzeichen (%)
44 beginchar("%",40ut#,Ht#,0);
45 pickup wela_pen;
46 q := (-23.6ut,0)--(23.6ut,0);
47 breit:=12.5ut;hoch:=17.5ut;
48 p := (breit/2,0){up}..(0,hoch/2){left}..(-breit/2,0){down}..(0,-hoch/2){right}..{up}(breit/2,0);
49 x0:=whatever;y0:=whatever;
50 z0=(directionpoint (-1,2) of (subpath (0,1) of p)) shifted (7.5ut+breit/2,Ht-hoch/2);
51 draw p shifted (7.5ut+breit/2,Ht-hoch/2);
52 draw p shifted (7.5ut+25ut-breit/2,hoch/2);
53 draw q rotated 58 shifted (w/2,h/2);
54 draw z0{1,-2}..{dir 58}(7.5ut+25ut,Ht);
55 endchar;
56
57 % &
58 beginchar("&",40ut#,Ht#,0);
59 pickup wela_pen;
60 p := (22.5ut,12.5ut)..tension 1.2..(7.5ut,0){left}..(0,8ut){up}..
61 %(8.167ut,21ut){3,2}..
62 tension 1.2..(17ut,34.5ut){up}..(11.5ut,Ht){left}..(4ut,30ut){down}..{2,-3}(8.167ut,21ut)--(22.5ut,0);
63 draw p shifted (10ut,0);
64 endchar;
65
66 % $
67 beginchar("$",30ut#,Ht#,0);
68 pickup wela_pen;
69 draw halfcircle xscaled 20ut yscaled 20ut shifted (15ut,30ut);
70 draw (halfcircle rotated 180 xscaled 20ut yscaled 20ut) shifted (15ut,10ut);
71 draw ((-10ut,10ut){down}..{down}(10ut,-10ut)) shifted (15ut,ht);
72 draw ((0,ht+2.5ut)--(0,-ht-2.5ut)) shifted (15ut,ht);
73 endchar;
74
75 % "+"
76 beginchar("+",30ut#,22.5ut#,0);
77 path p;
78 pickup wela_pen;
79 z0=(15ut,hmath);
80 z1=(0ut,10ut);
81 z2=(0ut,-10ut);
82 p := z1--z2;
83 draw p shifted z0 ;
84 draw p rotated 90 shifted z0 ;
85 labels(range 0 thru 2);
86 endchar;
87
88 % ASCII Bindestrich oct"055" (OT1: auch Trennstrich)
89 beginchar("-",27.5ut#,ht#,0);
90 pickup wela_pen;
91 draw ((0,0)--(12.5ut,0)) shifted (7.5ut,hdash);
92 endchar;
93
94 % T1: Trennstrich
95 beginchar(oct"177",27.5ut#,ht#,0);
96 pickup wela_pen;
97 draw ((0,0)--(12.5ut,0)) shifted (7.5ut,hdash);
98 endchar;
99
100 % "/"
101 beginchar("/",25ut#,Ht#,0);
102 pickup wela_pen;
103 draw ((5ut,0)--(20ut,Ht));
104 endchar;
105
106 % ">"
107 beginchar(">",30ut#,Ht#,0);
108 path p;
109 pickup wela_pen;
110 p:=(0,0)--(20ut,0);
111 draw p rotated 30 shifted (6.33ut,hmath);
112 draw p rotated -30 shifted (6.33ut,hmath);
113 endchar;
114
115 % "="
116 beginchar("=",30ut#,ht#,0);
117 pickup wela_pen;
118 draw((0,0)--(20ut,0)) shifted (5ut,hmath-2.5ut);
119 draw((0,0)--(20ut,0)) shifted (5ut,hmath+2.5ut);
120 endchar;
121
122 % "<"
123 beginchar("<",30ut#,Ht#,0);
124 path p;
125 pickup wela_pen;
126 p:=(0,0)--(-20ut,0);
127 draw p rotated 30 shifted (23.66ut,hmath);
128 draw p rotated -30 shifted (23.66ut,hmath);
129 endchar;
130
131 % oct"025" Bis-Strich --, Gedankenstrich
132 beginchar(oct"025",30ut#,ht#,0);
133 pickup wela_pen;
134 draw ((0,0)--(20ut,0)) shifted (5ut,hdash);
135 endchar;
136
137 % engl. Gedankenstrich ---
138 beginchar(oct"026",45ut#,ht#,0);
139 pickup wela_pen;
140 draw ((0,0)--(30ut,0)) shifted (7.5ut,hdash);
141 endchar;
142
143 % oct"023" franz. Anfz. <<
144 beginchar(oct"023",32.5ut#,ht#,0);
145 path p, q;
146 pickup wela_pen;
147 z1=(0ut,0ut);
148 z2=(1.1*ht/2,0);
149 z3=(6,-1);
150 z4=(6,1);
151 z5=(7.5ut,ht/2);
152 z6=(15ut,ht/2);
153 p := (z1{z3}..z2) rotated 45;
154 q := (z1{z4}..z2) rotated -45;
155 draw p shifted z5 ;
156 draw p shifted z6 ;
157 draw q shifted z5 ;
158 draw q shifted z6 ;
159 labels(range 1 thru 6);
160 endchar;
161
162 % oct"024" franz. Anfz. >>
163 beginchar(oct"024",32.5ut#,ht#,0);
164 path p, q;
165 pickup wela_pen;
166 z1=(0ut,0ut);
167 z2=(1.1*ht/2,0);
168 z3=(6,-1);
169 z4=(6,1);
170 z5=(17.5ut,ht/2);
171 z6=(25ut,ht/2);
172
173 p := (z1{z4}..z2) rotated 135;
174 q := (z1{z3}..z2) rotated -135;
175 draw p shifted z5 ;
176 draw p shifted z6 ;
177 draw q shifted z5 ;
178 draw q shifted z6 ;
179 labels(range 1 thru 6);
180 endchar;
181
182 % oct"016" franz. Anfz. <
183 beginchar(oct"016",25ut#,ht#,0);
184 path p, q;
185 pickup wela_pen;
186 z1=(0ut,0ut);
187 z2=(1.1*ht/2,0);
188 z3=(6,-1);
189 z4=(6,1);
190 z5=(7.5ut,ht/2);
191 p := (z1{z3}..z2) rotated 45;
192 q := (z1{z4}..z2) rotated -45;
193 draw p shifted z5 ;
194 draw q shifted z5 ;
195 labels(range 1 thru 5);
196 endchar;
197
198 % oct"017" franz. Anfz. >
199 beginchar(oct"017",25ut#,ht#,0);
200 path p, q;
201 pickup wela_pen;
202 z1=(0ut,0ut);
203 z2=(1.1*ht/2,0);
204 z3=(6,-1);
205 z4=(6,1);
206 z5=(17.5ut,ht/2);
207 p := (z1{z4}..z2) rotated 135;
208 q := (z1{z3}..z2) rotated -135;
209 draw p shifted z5 ;
210 draw q shifted z5 ;
211 labels(range 1 thru 5);
212 endchar;
213
214 % "@":
215 beginchar("@",50ut#,Ht#,0);
216 pickup wela_pen;
217 sep:=10ut;gap:=8ut;
218 draw (superellipse((a,0),(0,b),(-a,0),(0,-b),sigma)) shifted (gap+a+sep,ht);
219 draw ((0,ht)--(0,5ut){down}..(2ut,0){right}..tension 1.5..(gap,ht/2){up}..
220 (-a,3ht/2){left}..(-2*a-gap,ht/2){down}..
221 (-a,-ht/2){right}..(7.5ut,-5ut)) shifted (2*a+gap+sep,ht/2);
222 endchar;
223
224 % Euro (\symbol{160})
225 beginchar(oct"240",47.5ut#,Ht#,0);
226 pickup wela_pen;
227 sep:=7.5ut; gap:=7.5ut;
228 draw (halfcircle rotated 90) xscaled 30ut yscaled Ht shifted (15ut+gap+sep,Ht/2);
229 draw ((0,0){right}..(7.5ut,-3ut)) shifted (15ut+gap+sep,Ht);
230 draw ((0,0){right}..(7.5ut,3ut)) shifted (15ut+gap+sep,0);
231 draw (((-25ut,2.5ut)--(0,2.5ut)) shifted (15ut+gap+sep,ht)) slanted 0.25;
232 draw (((-25ut,-2.5ut)--(0,-2.5ut)) shifted (15ut+gap+sep,ht)) slanted 0.25;
233 endchar;
234
235 % Aufstrich am Wortanfang
236 beginchar(oct"200",11.446ut#,ht#,0);
237 pickup wela_pen;
238 draw ((0,0)--((ht-Delta)/m,ht-Delta));
239 xpos:=(ht-Delta)/m;
240 zeigen;
241 endchar;
242
243 % Verbindungsstrich normal
244 beginchar(oct"005",13.446ut#,ht#,0);
245 pickup wela_pen;
246 draw ((0,0){right}..tension2 and 3.5..{1,m}(rho+(ht-Delta)/m,ht-Delta));
247 xpos:=rho+(ht-Delta)/m;
248 zeigen;
249 endchar;
250
251 % "e" mit Aufstrich am Wortanfang
252 beginchar(oct"030",12.267ut#,ht#,0);
253 pickup wela_pen;
254 % xpos:=0;
255 % draw ((0,0)--(0.5ht/m,ht/2)) shifted (xpos,0);
256 % xpos:=xpos+0.5ht/m;
257 % latin_e_form(xpos);
258 xpos:=0;
259 draw ((0,0)..(ebreite+0.5ht/m,ht-ebreite*ef){up}) shifted (xpos,0);
260 xpos:=xpos+0.5ht/m;
261 latin_e_form(xpos);
262 % xpos:=ebreite*(1-ef)+0.5ht/m;
263 zeigen;
264 endchar;
265
266 % Endstueck gerade
267 beginchar(oct"007",3.5ut#,ht#,0);
268 pickup wela_pen;
269 draw ((0,0)--(3.5ut,m'*3.5ut));
270 endchar;
271
272 % Endstueck rund
273 beginchar(oct"006",3.5ut#,ht#,0);
274 pickup wela_pen;
275 draw ((0,0){right}..{1,m}(3.5ut,2.5ut));
276 endchar;
277
278 % Verlaengerungsstriche mit e,
279 % 8ut
280 beginchar(oct"000",22.267ut#,ht#,0);
281 pickup wela_pen;
282 xpos:=0;
283 draw ((0,0){right}..{up}(8ut+rho+0.5ht/m+ebreite,ht-ebreite*ef)) shifted (xpos,0);
284 xpos:=xpos+8ut+rho+0.5ht/m;
285 latin_e_form(xpos);
286 zeigen;
287 endchar;
288
289 % 10ut
290 beginchar(oct"001",24.267ut#,ht#,0);
291 pickup wela_pen;
292 xpos:=0;
293 draw ((0,0){right}..{up}(10ut+rho+0.5ht/m+ebreite,ht-ebreite*ef)) shifted (xpos,0);
294 xpos:=xpos+10ut+rho+0.5ht/m;
295 latin_e_form(xpos);
296 zeigen;
297 endchar;
298
299 % 12ut
300 beginchar(oct"002",26.267ut#,ht#,0);
301 pickup wela_pen;
302 xpos:=0;
303 draw ((0,0){right}..{up}(12ut+rho+0.5ht/m+ebreite,ht-ebreite*ef)) shifted (xpos,0);
304 xpos:=xpos+12ut+rho+0.5ht/m;
305 latin_e_form(xpos);
306 zeigen;
307 endchar;
308
309 % 14ut
310 beginchar(oct"003",28.267ut#,ht#,0);
311 pickup wela_pen;
312 xpos:=0;
313 draw ((0,0){right}..{up}(14ut+rho+0.5ht/m+ebreite,ht-ebreite*ef)) shifted (xpos,0);
314 xpos:=xpos+14ut+rho+0.5ht/m;
315 latin_e_form(xpos);
316 zeigen;
317 endchar;
318
319 % 16ut
320 beginchar(oct"004",30.267ut#,ht#,0);
321 pickup wela_pen;
322 xpos:=0;
323 draw ((0,0){right}..{up}(16ut+rho+0.5ht/m+ebreite,ht-ebreite*ef)) shifted (xpos,0);
324 xpos:=xpos+16ut+rho+0.5ht/m;
325 latin_e_form(xpos);
326 zeigen;
327 endchar;
328
329 % Aufstriche zu spitzen Buchstaben:
330 % normal
331 beginchar(oct"035",12.5ut#,ht#,0);
332 pickup wela_pen;
333 draw ((0,0){right}..tension 1.2..{up}(12.5ut,ht));
334 endchar;
335
336 % nach Unterlaengen
337 beginchar(oct"036",12.5ut#,ht#,0);
338 pickup wela_pen;
339 draw ((0,0){1,m'}..tension 1..{up}(12.5ut,ht));
340 endchar;
341
342 % Lange Aufstriche vor spitzen BSt.
343 % 18ut
344 beginchar(oct"021",18ut#,ht#,0);
345 pickup wela_pen;
346 axe:=18ut; sigm:=0.71;
347 draw ((0,0){right}..{axe,ht}(sigm*axe,(1-sigm)*ht)..{up}(axe,ht));
348 endchar;
349
350 % 21ut
351 beginchar(oct"031",21ut#,ht#,0);
352 pickup wela_pen;
353 axe:=21ut; sigm:=0.72;
354 draw ((0,0){right}..{axe,ht}(sigm*axe,(1-sigm)*ht)..{up}(axe,ht));
355 endchar;
356
357 % 25ut
358 beginchar(oct"032",25ut#,ht#,0);
359 pickup wela_pen;
360 axe:=25ut; sigm:=0.73;
361 draw ((0,0){right}..{axe,ht}(sigm*axe,(1-sigm)*ht)..{up}(axe,ht));
362 endchar;
363
364 % 29ut
365 beginchar(oct"033",29ut#,ht#,0);
366 pickup wela_pen;
367 axe:=29ut; sigm:=0.74;
368 draw ((0,0){right}..{axe,ht}(sigm*axe,(1-sigm)*ht)..{up}(axe,ht));
369 endchar;
370
371 % 33ut
372 beginchar(oct"034",33ut#,ht#,0);
373 pickup wela_pen;
374 axe:=33ut; sigm:=0.75;
375 draw ((0,0){right}..{axe,ht}(sigm*axe,(1-sigm)*ht)..{up}(axe,ht));
376 endchar;
377
378 % fuer oben verbundene Buchstaben
379 % von b,o,v,w
380 beginchar(oct"027",14.222ut#,ht#,0);
381 pickup wela_pen;
382 draw ((0,ht){1,-mfahne}..tension 1.2..{up}(bfahne,ht));
383 xpos:=bfahne;
384 zeigen;
385 endchar;
386
387 % von r
388 beginchar(oct"037",12ut#,ht#,0);
389 pickup wela_pen;
390 draw ((0,ht){down}..tension 1.2..{up}(rfahne,ht));
391 xpos:=rfahne;
392 zeigen;
393 endchar;
394
395
396
397 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
398
399 % Ziffern und Satzzeichen
400 %
401 % Ziffern
402 beginchar("0",Wz#,Hz#,0);
403 pickup wela_pen;
404 draw (fullcircle xscaled w' yscaled h) shifted (w/2,h/2);
405 draw ((w/2,h){down}..(s'+w',h));
406 endchar;
407
408 beginchar("1",Wz#,Hz#,0);
409 pickup wela_pen;
410 draw ((-w'/2,0.6*h)--(0,h)--(0,0)) shifted (w/2+s'/2,0);
411 endchar;
412
413 beginchar("2",Wz#,Hz#,0);
414 pickup wela_pen;
415 draw ((0,h-r)..(r,h){right}..(2r,h-r){down}..tension2 and 3..{-1,-1}(0,0)) shifted (s',0);
416 draw ((0,0){1,1.5}..(0.75w',0){right}..(w',D)) shifted (s',0);
417 endchar;
418
419 beginchar("3",Wz#,Hz#,0);
420 pickup wela_pen;
421 draw ((w'/8,7h/8)..(w'/2,h){right}..(7w'/8,0.75h){down}..top(w'/2,0.5h){left})
422 shifted (s',0);
423 draw (top(w'/2,0.5h){right}..tension1..(w',w'/2){down}..(w'/2,0){left}..(0,w'/4)) shifted (s',0);
424 endchar;
425
426 beginchar("4",Wz#,Hz#,0);
427 pickup wela_pen;
428 draw ((w'/2,h)--(0,h/4)--(w',h/4)) shifted (s',0);
429 draw ((0.75w',h/2)--(0.75w',0)) shifted (s',0);
430 endchar;
431
432 beginchar("5",Wz#,Hz#,0);
433 pickup wela_pen;
434 draw ((0.8w',h){dir190}..{dir170}(0,h)--(0,5h/8-dd){1,1}..(w'/2,5h/8){right}..(w',2.5h/8){down}..(w'/2,0){left}..(0,h/8)) shifted (s',0);
435 endchar;
436
437 beginchar("6",Wz#,Hz#,0);
438 pickup wela_pen;
439 draw ((0.8w',h){left}..tension0.8..(0,3h/8){down}..(w'/2,0){right}..(w',3h/8){up}..(w'/2,5h/8){left}..(0,3h/8){down}) shifted (s',0);
440 endchar;
441
442 beginchar("7",Wz#,Hz#,0);
443 pickup wela_pen;
444 xpos:=0;
445 bogen(h-D,h,h,w',0.3,75,angle(1,2.67),1,1,xpos+s');
446 draw ((w',h)--(0.4w',0)) shifted (s',0);
447 quer(bot(h/2),xpos-7.5ut)
448 endchar;
449
450 beginchar("8",Wz#,Hz#,0);
451 pickup wela_pen;
452 draw ((0,0.5625h){1,0.15}..(3w'/8,h-3w'/8){up}..(0,h){left}..(-3w'/8,h-3w'/8){down}..(0,0.5625h){1,-0.15}..
453 (w'/2,h/4){down}..(0,0){left}..(-w'/2,h/4){up}..{1,0.15}(0,0.5625h)) shifted (s'+w'/2,0);
454 draw ((w/2,h){down}..(s'+w'-dd/2,h));
455 endchar;
456
457 beginchar("9",Wz#,Hz#,0);
458 pickup wela_pen;
459 draw (fullcircle xscaled w' yscaled (5h/8)) shifted (w/2,0.6875h);
460 draw ((w',h)--(w',h/2){down}..(w'/2,0){left}..(w'/8,h/16)) shifted (s',0);
461 endchar;
462
463
464 % Satzzeichen
465 % ASCII-Zeichen
466 % !
467 beginchar("!",20ut#,Hz#,0);
468 pickup wela_pen;
469 stamm(Hz,10ut,10ut);
470 pickup wela_pen_thick;
471 drawdot (0,0) shifted (10ut,0);
472 endchar;
473
474 % ", oct"042", ASCII-Doppelapostroph, hier identisch mit oct"020", dt. Anfz. o.
475 beginchar(oct"042",20ut#,Ht#,0);
476 pickup wela_pen;
477 komma(Ht,7.5ut);
478 komma(Ht,12.5ut);
479 endchar;
480
481 % ' (Apostroph)
482 beginchar("'",15ut#,Ht#,0);
483 pickup wela_pen;
484 komma(Ht,7.5ut);
485 endchar;
486
487 % "("
488 beginchar("(",20ut#,Ht#,0);
489 pickup wela_pen;
490 draw ((5ut,Ht)..(0,ht){down}..(5ut,0)) shifted (10ut,0);
491 endchar;
492
493 % ")"
494 beginchar(")",20ut#,Ht#,0);
495 pickup wela_pen;
496 draw ((5ut,Ht)..(10ut,ht){down}..(5ut,0));
497 endchar;
498
499 % "," Komma
500 beginchar(",",20ut#,ht#,dt#);
501 pickup wela_pen;
502 komma(2.5ut,10ut);
503 endchar;
504
505 % "." Punkt
506 beginchar(".",20ut#,ht#,0);
507 pickup wela_pen_thick;
508 drawdot top(0,0) shifted (10ut,0);
509 endchar;
510
511 % ":" Doppelpunkt
512 beginchar(":",20ut#,ht#,0);
513 pickup wela_pen_thick;
514 drawdot top(0,0) shifted (10ut,0);
515 drawdot (0,0) shifted (10ut,15ut);
516 endchar;
517
518 % ";" Strichpunkt
519 beginchar(";",20ut#,ht#,dt#);
520 pickup wela_pen;
521 komma(2.5ut,10ut);
522 pickup wela_pen_thick;
523 drawdot (0,0) shifted (10ut,15ut);
524 endchar;
525
526 % ?
527 beginchar("?",30ut#,Hz#,0);
528 radi:=5ut;
529 pickup wela_pen;
530 z1=(-1.5radi,h-0.5radi);
531 z2=(0,h);
532 z3=(1.5radi,h-radi);
533 z5=(-1.5radi,2.5radi);
534 z6=(0,1.5radi);
535 z7=(1.5radi,2radi);
536 p := z1..z2{right}..z3{down}..{down}z5..z6{right}..z7;
537 draw p shifted (15ut,0);
538 pickup wela_pen_thick;
539 drawdot top(0,0) shifted (15ut,0);
540 endchar;
541
542 % spezielle Sonderzeichen (ec-Kodierung(
543 % oct"020", wie ASCII " (oct"042"), dt. Anfuehrungszeichen oben
544 beginchar(oct"020",20ut#,Ht#,0);
545 pickup wela_pen;
546 komma(Ht,7.5ut);
547 komma(Ht,12.5ut);
548 endchar;
549
550 % oct"022", dt. Anfuehrungszeichen unten
551 beginchar(oct"022",25ut#,ht#,dt#);
552 pickup wela_pen;
553 komma(2.5ut,10ut);
554 komma(2.5ut,15ut);
555 endchar;
556
557 % oct"133" [
558 beginchar("[",25ut#,Ht#,0);
559 pickup wela_pen;
560 draw ((5ut,Ht)--(0,Ht)--(0,0)--(5ut,0)) shifted (10ut,0);
561 endchar;
562
563 % oct"135" ]
564 beginchar("]",25ut#,Ht#,0);
565 pickup wela_pen;
566 draw ((5ut,Ht)--(10ut,Ht)--(10ut,0)--(5ut,0)) shifted (5ut,0);
567 endchar;
568
569
570
571 %%%%%%%%%%%%%%%%%%%% End of File %%%%%%%%%%%%%%%%%