Debian Codegraph @

texmf-dist/fonts/source/public/mathabx/mathineq.mf

raw
1 % mathematical symbols by Anthony Phan.
2 % file: mathineq.mf (inequalities)
3 % last modification: May 16, 2005.
4 % Only known charcodes will be generated.
5
6 % Inequality signs and related things (relations).
7 % Some pictures overlap the bottom. It is necessary
8 % for correct centering of the whole box.
9 % Spreads for cross bars have been checked.
10 % Curly slants are strange: it is half way to two
11 % extreme solutions...
12
13 def horizontal_rules_list=math_axis,
14 -body_depth,-desc_depth,x_height,cap_height,asc_height,body_height
15 enddef;
16
17 use_rule1;
18 make_sim_picture;
19
20 if (main_name_string="less") or (main_name_string="greater"):
21
22 beginpicture(first,
23 12u#+2appr#,v_center(spread4#+rth#));
24 pickup tiny.nib;
25 y2r=0.5[y1,y3]=good.y math_axis; y1-y3=spread4;
26 rt x1=w-Appr; lft x2r=Appr; x1=x1r=x3=x3r;
27 adjust_slanted_bar(2r,1,2a,1a)(0.5(rth-tiny),-1);
28 adjust_slanted_bar(2r,3,2b,3b)(0.5(rth-tiny),1);
29 z1r=whatever[z2r,z1a]; z3r=whatever[z2r,z3b];
30 z1r-z1=z1-z1l; z3r-z3=z3-z3l;
31 z2l-z1l=whatever*(z2r-z1r);
32 z2l-z3l=whatever*(z2r-z3r);
33 filldraw stroke z3e--z2e--z1e;
34 a:=2vround 0.5(spread1/abs cosd angle(z2r-z3r));
35 endpicture;
36
37 beginpicture(second,
38 12u#+2appr#,v_center(spread4#+rth#));
39 pickup tiny.nib;
40 y2r=0.5[y1,y3]=good.y math_axis; y1-y3=spread4;
41 lft x1=Appr; rt x2r=w-Appr; x1=x1r=x3=x3r;
42 adjust_slanted_bar(2r,1,2a,1a)(0.5(rth-tiny),1);
43 adjust_slanted_bar(2r,3,2b,3b)(0.5(rth-tiny),-1);
44 z1r=whatever[z2r,z1a]; z3r=whatever[z2r,z3b];
45 z1r-z1=z1-z1l; z3r-z3=z3-z3l;
46 z2l-z1l=whatever*(z2r-z1r);
47 z2l-z3l=whatever*(z2r-z3r);
48 filldraw stroke z3e--z2e--z1e;
49 endpicture;
50
51 else:
52
53 beginpicture(first,
54 12u#+2appr#,v_center(spread4#+rth#));
55 pickup tiny.nib; pos2(rth,90); pos4(rth,90);
56 lft x2=Appr; rt x1r=rt x3l=w-Appr; x4=0.50[x2,x1r];
57 y2=y4=math_axis; y3l-y2r=y2l-y1r=0.5spread4; y1r=y1l; y3r=y3l;
58 x1r-x1l=diag_width(rth-tiny,z4r-z1r);
59 x3l-x3r=diag_width(rth-tiny,z4l-z3l);
60 filldraw stroke z2e{right}...z1e{z1r-z4r};
61 filldraw stroke z2e{right}...z3e{z3l-z4l};
62 a:=spread1;
63 endpicture;
64
65 beginpicture(second,
66 12u#+2appr#,v_center(spread4#+rth#));
67 pickup tiny.nib; pos2(rth,-90); pos4(rth,-90);
68 rt x2=w-Appr; lft x1l=lft x3r=Appr; x4=0.50[x2,x1l];
69 y2=y4=math_axis; y3r-y2l=y2r-y1l=0.5spread4; y1r=y1l; y3r=y3l;
70 x1l-x1r=-diag_width(rth-tiny,z4l-z1l);
71 x3r-x3l=-diag_width(rth-tiny,z4r-z3r);
72 filldraw stroke z2e{left}...z1e{z1l-z4l};
73 filldraw stroke z2e{left}...z3e{z3r-z4r};
74 endpicture;
75 fi
76
77 if (main_name_string="greater") or (main_name_string="successor"):
78 tmp_picture:=first_picture; first_picture:=second_picture;
79 second_picture:=tmp_picture;
80 fi
81
82 %
83 % Let's go
84 %
85
86 beginchar(main_name_with(),
87 12u#+2appr#,v_center(spread4#+rth#));
88 main_name_string&" sign";
89 currentpicture:=first_picture;
90 endchar;
91
92 beginchar(main_name_with(_not),
93 12u#+2appr#,asc_height#,asc_depth#);
94 "not " & main_name_string&" sign";
95 currentpicture:=first_picture;
96 pickup tiny.nib;
97 pos1(rth,0); pos2(rth,0); top y1l=h; bot y2l=-d;
98 lft x1l=lft x2l=hround 0.5(w-rth);
99 filldraw stroke z1e..z2e; penlabels(1,2);
100 endchar;
101
102 beginchar(main_name_with(_slant),
103 12u#+2appr#,v_center(spread4#+spread1#+rth#));
104 main_name_string&"-slant sign";
105 currentpicture:=first_picture shifted(0,0.5a);
106 save b;
107 pickup tiny.nib;
108 if (main_name_string="less") or (main_name_string="greater"):
109 y0=good.y math_axis; lft x1=Appr; rt x2=w-Appr;
110 b=(rth-tiny)/cosd angle(x2-x1,0.5spread4);
111 penpos1(b,90); penpos2(b,90);
112 if (main_name_string="less"): y1=y0-0.5a; y1-y2=0.5spread4;
113 else: y2=y0-0.5a; y1-y2=-0.5spread4; fi
114 filldraw stroke z1e..z2e; penlabels(1,2);
115 elseif main_name_string="predecessor":
116 pos2(rth,-90); pos3(rth,-90);
117 lft x2=Appr; y2=y3=math_axis-0.5spread1;
118 rt x1l=rt x1=w-Appr; y1=y2r-0.5spread4;
119 x3=0.50[x2,x1l];
120 y1l=y1r=y2r-vround(0.5spread4
121 *(0.5[1,1/abs cosd angle(z3l-z1)]));
122 x1l-x1r=diag_width(rth-tiny,z3l-z1l);
123 filldraw stroke z1e{z3l-z1l}...z2e{left};
124 penlabels(1,2,3);
125 else:
126 pos2(rth,-90); pos3(rth,-90);
127 rt x2=w-Appr; y2=y3=math_axis-0.5spread1;
128 lft x1l=lft x1=Appr; y1=y2r-0.5spread4;
129 x3=0.50[x2,x1l];
130 y1l=y1r=y2r-vround(0.5spread4
131 *(0.5[1,1/abs cosd angle(z3l-z1)]));
132 x1l-x1r=-diag_width(rth-tiny,z3l-z1l);
133 filldraw stroke z1e{z3l-z1l}...z2e{right};
134 penlabels(1,2,3);
135 fi
136 tmp_picture:=currentpicture;
137 endchar;
138
139 beginchar(main_name_with(_not_slant),
140 12u#+2appr#,asc_height#,asc_depth#);
141 "not "&main_name_string&"-slant sign";
142 currentpicture:=tmp_picture;
143 pickup tiny.nib;
144 pos1(rth,0); pos2(rth,0); top y1l=h; bot y2l=-d;
145 lft x1l=lft x2l=hround 0.5(w-rth);
146 filldraw stroke z1e..z2e; penlabels(1,2);
147 endchar;
148
149 beginchar(main_name_with(_eq),
150 12u#+2appr#,v_center(spread4#+spread0#+rth#));
151 main_name_string&"-bar sign";
152 currentpicture:=first_picture shifted(0,0.5spread0);
153 pickup tiny.nib;
154 pos1(rth,90); pos2(rth,90); rt x2=w-Appr; lft x1=Appr;
155 y1=y2=math_axis-0.5(spread4+spread0);
156 filldraw stroke z1e..z2e; penlabels(1,2);
157 tmp_picture:=currentpicture;
158 endchar;
159
160 beginchar(main_name_with(_not_eq),
161 12u#+2appr#,asc_height#,asc_depth#);
162 "not "&main_name_string&"-bar sign";
163 currentpicture:=tmp_picture;
164 pickup tiny.nib;
165 pos1(rth,0); pos2(rth,0); top y1l=h; bot y2l=-d;
166 lft x1l=lft x2l=hround 0.5(w-rth);
167 filldraw stroke z1e..z2e; penlabels(1,2);
168 endchar;
169
170 beginchar(main_name_with(_eq_not),
171 12u#+2appr#,v_center(spread4#+spread0#+rth#));
172 main_name_string&"-not bar sign";
173 currentpicture:=tmp_picture;
174 pickup tiny.nib;
175 y0=math_axis-0.5(spread4+spread0);
176 x0=0.5w;
177 v_adjust(1r,2l,y0,1.5spread1-0.5rth);
178 lft x2l-Appr=w-Appr-rt x1r=hround 3.5u;
179 adjust_slanted_bar(2l,1r,2r,1l)(rth-tiny,-1);
180 filldraw stroke z1e..z2e; penlabels(0,1,2);
181 endchar;
182
183 beginchar(main_name_with(_eq_varnot),
184 12u#+2appr#,v_center(spread4#+spread0#+rth#));
185 main_name_string&"-varnot bar sign";
186 currentpicture:=tmp_picture;
187 pickup tiny.nib;
188 y0=math_axis-0.5(spread4+spread0);
189 x0=0.5w;
190 v_adjust(1l,2l,y0,1.5spread1-0.5rth);
191 pos1(rth,0); pos2(rth,0);
192 lft x1l=lft x2l=hround 0.5(w-rth);
193 filldraw stroke z1e..z2e; penlabels(0,1,2);
194 endchar;
195
196 beginchar(main_name_with(_eqq),
197 12u#+2appr#,v_center(spread4#+spread1#+spread0#+rth#));
198 main_name_string&" equal sign";
199 currentpicture:=first_picture shifted(0,0.5(spread1+spread0));
200 pickup tiny.nib;
201 pos1(rth,90); pos2(rth,90); pos3(rth,90); pos4(rth,90);
202 rt x2=rt x4=w-Appr; lft x1=lft x3=Appr;
203 y1=y2=math_axis-0.5(spread4-spread1+spread0);
204 y3=y4=y1-spread1;
205 filldraw stroke z1e..z2e; filldraw stroke z3e..z4e;
206 penlabels(1,2,3,4);
207 tmp_picture:=currentpicture;
208 endchar;
209
210 beginchar(main_name_with(_not_eqq),
211 12u#+2appr#,v_center(max(asc_height#+asc_depth#,
212 spread4#+spread1#+spread0#+rth#)));
213 "not "&main_name_string&" equal sign";
214 currentpicture:=tmp_picture;
215 pickup tiny.nib;
216 pos1(rth,0); pos2(rth,0);
217 v_adjust(1l,2l,math_axis,max(h+d,spread4+spread0+2spread1));
218 lft x1l=lft x2l=hround 0.5(w-rth);
219 filldraw stroke z1e..z2e; penlabels(1,2);
220 endchar;
221
222 beginchar(main_name_with(_eqq_not),
223 12u#+2appr#,v_center(spread4#+spread1#+spread0#+rth#));
224 main_name_string&" but not equal sign";
225 currentpicture:=tmp_picture;
226 pickup tiny.nib;
227 y0=math_axis-0.5(spread4+spread0);
228 x0=0.5w;
229 v_adjust(1r,2l,y0,2.5spread1-0.5rth);
230 lft x2l-Appr=w-Appr-rt x1r=hround 2.75u;
231 adjust_slanted_bar(2l,1r,2r,1l)(rth-tiny,-1);
232 filldraw stroke z1e..z2e; penlabels(0,1,2);
233 endchar;
234
235 beginchar(main_name_with(_eqq_varnot),
236 12u#+2appr#,v_center(spread4#+spread1#+spread0#+rth#));
237 "variant "&main_name_string&" but not equal sign";
238 currentpicture:=tmp_picture;
239 pickup tiny.nib;
240 y0=math_axis-0.5(spread4+spread0);
241 x0=0.5w;
242 v_adjust(1l,2l,y0,2.5spread1-0.5rth);
243 pos1(rth,0); pos2(rth,0);
244 lft x1l=lft x2l=hround 0.5(w-rth);
245 filldraw stroke z1e..z2e; penlabels(1,2);
246 endchar;
247
248 beginchar(main_name_with(_upperslant),
249 12u#+2appr#,v_center(spread4#+spread1#+rth#));
250 main_name_string &"with upper slant sign";
251 currentpicture:=first_picture shifted(0,-0.5a);
252 save b;
253 pickup tiny.nib;
254 if (main_name_string="less") or (main_name_string="greater"):
255 y0=good.y math_axis; lft x1=Appr; rt x2=w-Appr;
256 b=(rth-tiny)/cosd angle(x2-x1,0.5spread4);
257 penpos1(b,90); penpos2(b,90);
258 if (main_name_string="less"): y1=y0+0.5a; y1-y2=-0.5spread4;
259 else: y2=y0+0.5a; y1-y2=0.5spread4; fi
260 filldraw stroke z1e..z2e; penlabels(1,2);
261 elseif main_name_string="predecessor":
262 pos2(rth,90); pos3(rth,90);
263 lft x2=Appr; y2=y3=math_axis+0.5spread1;
264 rt x1l=rt x1=w-Appr; y1=y2r+0.5spread4;
265 x3=0.50[x2,x1l];
266 y1l=y1r=y2r+vround(0.5spread4
267 *(0.5[1,1/abs cosd angle(z3l-z1)]));
268 x1l-x1r=diag_width(rth-tiny,z3l-z1l);
269 filldraw stroke z1e{z3l-z1l}...z2e{left};
270 penlabels(1,2,3);
271 else:
272 pos2(rth,90); pos3(rth,90);
273 rt x2=w-Appr; y2=y3=math_axis+0.5spread1;
274 lft x1l=lft x1=Appr; y1=y2r+0.5spread4;
275 x3=0.50[x2,x1l];
276 y1l=y1r=y2r+vround(0.5spread4
277 *(0.5[1,1/abs cosd angle(z3l-z1)]));
278 x1l-x1r=-diag_width(rth-tiny,z3l-z1l);
279 filldraw stroke z1e{z3l-z1l}...z2e{right};
280 penlabels(1,2,3);
281 fi
282 tmp_picture:=currentpicture;
283 endchar;
284
285 beginchar(main_name_with(_not_upperslant),
286 12u#+2appr#,asc_height#,asc_depth#);
287 "not " & main_name_string&" upper slant sign";
288 currentpicture:=tmp_picture;
289 pickup tiny.nib;
290 pos1(rth,0); pos2(rth,0); top y1l=h; bot y2l=-d;
291 lft x1l=lft x2l=hround 0.5(w-rth);
292 filldraw stroke z1e..z2e; penlabels(1,2);
293 endchar;
294
295 beginchar(main_name_with(_opposite),
296 12u#+2appr#,v_center(1.5spread4#+spread1#+rth#));
297 main_name_string&" and opposite sign";
298 currentpicture:=(first_picture
299 shifted(0,vround(0.5a+0.25spread4)))
300 +(second_picture
301 shifted(0,-vround(0.5a+0.25spread4)));
302 endchar;
303
304 beginchar(main_name_with(_eq_opposite),12u#+2appr#,
305 v_center(2spread4#+2spread0#+rth#));
306 main_name_string&" bar opposite sign";
307 currentpicture:=(first_picture
308 shifted(0,vround(spread0+0.5spread4)))
309 +(second_picture
310 shifted(0,-vround(spread0+0.5spread4)));
311 pickup tiny.nib; pos1(rth,90); pos2(rth,90);
312 lft x1=Appr; rt x2=w-Appr; y1=y2=math_axis;
313 filldraw stroke z1e..z2e; penlabels(1,2);
314 endchar;
315
316 beginchar(main_name_with(_eqq_opposite),12u#+2appr#,
317 v_center(2spread4#+2spread0#+spread1#+rth#));
318 main_name_string&" equal opposite sign";
319 pickup tiny.nib;
320 pos1(rth,90); pos2(rth,90); pos3(rth,90); pos4(rth,90);
321 lft x1=lft x3=Appr; rt x2=rt x4=w-Appr;
322 y1-y3=y2-y4=spread1; 0.5[y1,y3]=0.5[y2,y4]=math_axis;
323 currentpicture:=(first_picture
324 shifted(0,vround(spread0+0.5spread1+0.5spread4)))
325 +(second_picture
326 shifted(0,-vround(spread0+0.5spread1+0.5spread4)));
327 filldraw stroke z1e..z2e; filldraw stroke z3e..z4e;
328 penlabels(1,2,3,4);
329 endchar;
330
331 beginchar(main_name_with(_sim),12u#+2appr#,
332 v_center(spread4#+spread1#+spread0#+rth#));
333 main_name_string&" similarity sign";
334 numeric b,c; b=vround(0.5spread1+0.5spread0);
335 c=b-vround(0.5(spread4+spread1)+spread0);
336 currentpicture:=(first_picture shifted(0,b))
337 +(sim_picture shifted(0,c));
338 tmp_picture:=currentpicture;
339 endchar;
340
341 beginchar(main_name_with(_not_sim),
342 12u#+2appr#,v_center(max(asc_height#+asc_depth#,
343 spread4#+spread1#+spread0#+rth#)));
344 "not "&main_name_string&" similarity sign";
345 currentpicture:=tmp_picture;
346 pickup tiny.nib;
347 pos1(rth,0); pos2(rth,0);
348 v_adjust(1l,2l,math_axis,max(h+d,spread4+spread0+2spread1));
349 lft x1l=lft x2l=hround 0.5(w-rth);
350 filldraw stroke z1e..z2e; penlabels(1,2);
351 endchar;
352
353 beginchar(main_name_with(_sim_not),
354 12u#+2appr#,v_center(spread4#+spread1#+spread0#+rth#));
355 main_name_string&" but not similarity sign";
356 currentpicture:=tmp_picture;
357 pickup tiny.nib;
358 y0=math_axis-0.5(spread4+spread0);
359 x0=0.5w;
360 v_adjust(1r,2l,y0,2spread1);
361 lft x2l-Appr=w-Appr-rt x1r=hround 2.75u;
362 adjust_slanted_bar(2l,1r,2r,1l)(rth-tiny,-1);
363 filldraw stroke z1e..z2e; penlabels(0,1,2);
364 endchar;
365
366 beginchar(main_name_with(_approx),
367 12u#+2appr#,v_center(spread4#+2spread1#+spread0#+2rth#));
368 main_name_string&" approximative sign";
369 numeric b,c; b=vround(spread1+0.5spread0+0.5rth);
370 c=b-vround(0.5(spread4+spread1)+spread0);
371 currentpicture:=(first_picture shifted(0,b))
372 +(sim_picture shifted(0,c))
373 +(sim_picture shifted(0,c-spread1-rth));
374 tmp_picture:=currentpicture;
375 endchar;
376
377 beginchar(main_name_with(_not_approx),
378 12u#+2appr#,v_center(max(asc_height#+asc_depth#,
379 spread4#+2spread1#+spread0#+2rth#)));
380 main_name_string&" but not approximative sign";
381 currentpicture:=tmp_picture;
382 pickup tiny.nib;
383 pos1(rth,0); pos2(rth,0);
384 v_adjust(1l,2l,math_axis,max(h+d,spread4+spread0+3spread1));
385 lft x1l=lft x2l=hround 0.5(w-rth);
386 filldraw stroke z1e..z2e; penlabels(1,2);
387 endchar;
388
389 beginchar(main_name_with(_approx_not),
390 12u#+2appr#,v_center(spread4#+2spread1#+spread0#+2rth#));
391 main_name_string&" but not approximative sign";
392 currentpicture:=tmp_picture;
393 pickup tiny.nib;
394 y0=math_axis-0.5(spread4+spread0);
395 x0=0.5w;
396 v_adjust(1r,2l,y0,3spread1);
397 lft x2l-Appr=w-Appr-rt x1r=hround 2.5u;
398 adjust_slanted_bar(2l,1r,2r,1l)(rth-tiny,-1);
399 filldraw stroke z1e..z2e; penlabels(0,1,2);
400 endchar;
401
402 beginchar(main_name_with(_dot),
403 12u#+2appr#,v_center(spread4#+rth#));
404 main_name_string&" with dot sign";
405 currentpicture:=first_picture; pickup tiny.nib;
406 adjust_dot1((
407 if (main_name_string="less") or (main_name_string="predecessor"):
408 w-Appr-u-0.5dtsz else: Appr+u+0.5dtsz fi,
409 good.y math_axis),dtsz,false,true);
410 dot(1,1');
411 endchar;
412
413
414
415
416