Debian Codegraph @

texmf-dist/fonts/source/public/mathabx/mathastr.mf

raw
1 % mathematical symbols by Anthony Phan.
2 % file: mathastr.mf (mathematical astronomical symbols)
3 % last modification: May 16, 2005.
4 % Only known charcodes will be generated.
5
6 % stem_corr had been added (darkness).
7 % also vair_corr and slab.
8
9 %astro := 1;
10
11 % from cmbase.mf
12
13 % super_arc.r(suffix $, $$) and super_arc.l(suffix $, $$)
14 % have the same effect as a right_to_down
15
16 vardef pulled_super_arc.r(suffix $, $$)(expr superpull) =
17 pair center, corner;
18 if y$ = y$r: center = (x$$r, y$r); corner = (x$r, y$$r);
19 else: center = (x$r, y$$r); corner = (x$$r, y$r); fi
20 z$r{corner-z$r}...superness[center, corner]{z$$r-z$r}
21 ...{z$$r-corner}z$$r
22 enddef;
23
24 vardef pulled_super_arc.l(suffix $, $$)(expr superpull) =
25 pair center, corner, outer_point;
26 if y$ = y$r: center = (x$$l, y$l); corner = (x$l, y$$l);
27 outer_point = superness[(x$$r, y$r), (x$r, y$$r)];
28 else: center = (x$l, y$$l); corner = (x$$l, y$l);
29 outer_point = superness[(x$r, y$$r), (x$$r, y$r)]; fi
30 z$l{corner-z$l}
31 ...superpull[superness[center, corner], outer_point]{z$$l-z$l}
32 ...{z$$l-corner}z$$l
33 enddef;
34
35 vardef pulled_arc@#(suffix $, $$) =
36 pulled_super_arc@#($, $$)(superpull)
37 enddef;
38
39 % let's go
40
41 use_rule4;
42
43 boolean serifs;
44 if astro > 0.75: serifs := true; else: serifs := false; fi
45
46 astro.hair := hround astro[rth, hair];
47 astro.vair := vround astro[rth, vair];
48 astro.stem := hround astro[rth, stem];
49 astro.light_stem := astro[rth, 0.9[vair, 0.85stem]];
50 astro.curve := hround astro[rth, curve];
51 astro.vair' := vround astro[rth, vair'];
52 astro.cap_hair := vround astro[rth, cap_hair];
53 astro.cap_stem := hround astro[rth, cap_stem];
54 astro.cap_curve := hround astro[rth, cap_curve];
55 astro.rth := astro[rth, rth];
56 astro.beak := astro[0, 0.38cap_height-astro.cap_hair];
57 astro.slab := vround astro[rth, slab];
58
59 superpull := astro*1/6;
60 arrow_breadth := astro[0, vair];
61 arrow_stress := astro[1, 0.7];
62 arrow_tense1 := astro[1, 0.75];
63 arrow_tense2 := astro[1, 0.875];
64
65 % absolutely okay
66 beginchar(astro_sun, 13u#+2appr#, cap_height#, 0);
67 "Sun";
68 italcorr 0; % italcorr 0.6cap_height#*slant-.5u#;
69 autorounded;
70 pickup null.nib;
71 % circle
72 penpos1(astro.vair', 90);
73 penpos2(hround astro[rth, cap_curve-stem_corr], 180);
74 penpos3(vround astro[rth, vair+1.5vair_corr], -90);
75 penpos4(hround astro[rth, cap_curve-stem_corr], 0);
76 y1r = h+o; y3r = -o; y2 = y4 = 0.5h;
77 x2r = appr; x4r = w-appr; x1 = x3 = 0.5[x2, x4];
78 y2l := y4l := astro[y2, 0.52h];
79 penstroke pulled_arc.e(1, 2) & pulled_arc.e(2, 3)
80 & pulled_arc.e(3, 4) & pulled_arc.e(4, 1) & cycle;
81 % dot
82 adjust_dot5((x1, y2), astro[2.7rth, 1.3dtsz], true, true);
83 dot(5, 5');
84 penlabels(1, 2, 3, 4);
85 endchar;
86
87 % okay
88 beginchar(astro_left_moon, 10u#+2appr#, cap_height#, 0);
89 "Left moon (Moon)";
90 italcorr 0; % italcorr cap_height#*slant-.5u#;
91 save tmp_path, a, t; path tmp_path[];
92 %
93 % Two solutions may be considered for
94 % this construction. The first (and the
95 % one which is done here) is to put the
96 % two centers of circles at a predeterminated
97 % distance $a$ from each others (namely $a = 4u$)
98 % and do the construction hoping that edges
99 % will fit the right bound.
100 % The second one consists in calculating that
101 % distance $a$ to make sure that edges will lie
102 % on the right bound (the calculations are shown
103 % commentated). The problem with this method
104 % is that there is no control of the clear part's
105 % width of the drawing. Moreover, when the inner
106 % radius become too small there is no more solution
107 % to that problem (see below).
108 %
109 %% The actual width of the drawing must be 10u.
110 %% The problem is to calculate the distance
111 %% between the two centers to make it work.
112 %% Alas when the two radius are too far from
113 %% each over, this problem has no solution.
114 %%
115 %% 6.5u = radius of great circle.
116 %% 3.5u = 10u-6.5u = (inner width)-radius.
117 %% 6.5u-rth = radius of small circle.
118 %%
119 % b = (3.5u)**2+(rth**2)-2*6.5u*rth;
120 % if b> = 0: a = hround(3.5u+sqrt b);
121 % else: a = hround(3.5u); fi
122 a = hround(4u-rth+astro.rth);
123 penpos2(vround astro.rth, 90);
124 penpos3(hround astro.rth, 180);
125 penpos4(vround astro.rth, -90);
126 penpos1(hround astro.rth, 0);
127 x3r = appr; x1r-x3r = 13u; y2r = h+o; y4r = -o;
128 y1 = y3 = 0.5[y2, y4]; x2 = x4 = 0.5[x1, x3];
129 tmp_path1 = z1r up_to_left z2r left_to_down z3r
130 down_to_right z4r right_to_up z1r..cycle;
131 tmp_path2 = z1l up_to_left z2l left_to_down z3l
132 down_to_right z4l right_to_up z1l..cycle;
133 tmp_path3 = tmp_path1 shifted (a, 0);
134 tmp_path4 = tmp_path2 shifted (a, 0);
135 %
136 % The presence of epsilons makes almost certain
137 % that paths won't have double points causing
138 % trouble with filling commands.
139 %
140 (t1-eps, t4-eps) = (subpath (0, 4) of tmp_path1)
141 intersectiontimes (subpath (0, 4) of tmp_path4);
142 (t2-4+eps, t3-4+eps) = (subpath (4, 8) of tmp_path1)
143 intersectiontimes (subpath (4, 8) of tmp_path4);
144 (t5-eps, t8-eps) = (subpath (0, 4) of tmp_path2)
145 intersectiontimes (subpath (0, 4) of tmp_path3);
146 (t6-4+eps, t7-4+eps) = (subpath (4, 8) of tmp_path2)
147 intersectiontimes (subpath (4, 8) of tmp_path3);
148 fill subpath (t1, t2) of tmp_path1
149 ..reverse subpath(t4, t3) of tmp_path4..cycle;
150 unfill subpath (t5, t6) of tmp_path2
151 ..reverse subpath(t8, t7) of tmp_path3..cycle;
152 penlabels(1, 2, 3, 4);
153 endchar;
154
155 beginchar(astro_right_moon, 10u#+2appr#, cap_height#, 0);
156 "Right moon";
157 italcorr 0; % italcorr cap_height#*slant-.5u#;
158 save tmp_path, a, t; path tmp_path[];
159 a = -hround(4u-rth+astro.rth);
160 penpos2(vround astro.rth, 90);
161 penpos3(hround astro.rth, 0);
162 penpos4(vround astro.rth, -90);
163 penpos1(hround astro.rth, 180);
164 x3 = w-appr-0.5rth; x1r-x3r = -13u; y2r = h+o; y4r = -o;
165 y1 = y3 = 0.5[y2, y4]; x2 = x4 = 0.5[x1, x3];
166 tmp_path1 = z1r up_to_left z2r left_to_down z3r
167 down_to_right z4r right_to_up z1r..cycle;
168 tmp_path2 = z1l up_to_left z2l left_to_down z3l
169 down_to_right z4l right_to_up z1l..cycle;
170 tmp_path3 = tmp_path1 shifted (a, 0);
171 tmp_path4 = tmp_path2 shifted (a, 0);
172 (t1-eps, t4-eps) = (subpath (0, 4) of tmp_path1)
173 intersectiontimes (subpath (0, 4) of tmp_path4);
174 (t2-4+eps, t3-4+eps) = (subpath (4, 8) of tmp_path1)
175 intersectiontimes (subpath (4, 8) of tmp_path4);
176 (t5-eps, t8-eps) = (subpath (0, 4) of tmp_path2)
177 intersectiontimes (subpath (0, 4) of tmp_path3);
178 (t6-4+eps, t7-4+eps) = (subpath (4, 8) of tmp_path2)
179 intersectiontimes (subpath (4, 8) of tmp_path3);
180 fill subpath (t1, t2) of tmp_path1
181 ..reverse subpath(t4, t3) of tmp_path4..cycle;
182 unfill subpath (t5, t6) of tmp_path2
183 ..reverse subpath(t8, t7) of tmp_path3..cycle;
184 penlabels(1, 2, 3, 4);
185 endchar;
186
187 beginchar(astro_full_moon, 13u#+2appr#, cap_height#, 0);
188 "Full moon";
189 italcorr 0; % italcorr 0.6cap_height#*slant-.5u#;
190 autorounded;
191 % circle
192 penpos1(vround astro.rth, 90);
193 penpos2(hround astro.rth, 180);
194 penpos3(vround astro.rth, -90);
195 penpos4(hround astro.rth, 0);
196 y1r = h+o; y3r = -o; y2 = y4 = 0.5h;
197 x2r = appr; x4r = w-appr; x1 = x3 = 0.5[x2, x4];
198 y2l := y4l := astro[y2, y2];
199 penstroke z1e left_to_down z2e down_to_right
200 z3e right_to_up z4e up_to_left z1e;
201 penlabels(1, 2, 3, 4);
202 endchar;
203
204 beginchar(astro_new_moon, 13u#+2appr#, cap_height#, 0);
205 "New moon";
206 italcorr 0; % italcorr cap_height#*slant-.5u#;
207 autorounded;
208 x4 = w-appr; x2 = appr; y1 = h+o; y3 = -o;
209 y2 = y4 = 0.5h; x1 = x3 = 0.5[x2, x4];
210 fill z1 left_to_down z2 down_to_right z3
211 right_to_up z4 up_to_left z1..cycle;
212 labels(1, 2, 3, 4);
213 endchar;
214
215 % okay
216 beginchar(astro_mercury, 9u#+2appr#, cap_height#, 0);
217 "Mercury";
218 italcorr 0; % italcorr cap_height#*slant-.5u#;
219 save a; a = astro.light_stem;
220 ensure_centering_of(a);
221 % circle
222 penpos1(astro.vair, 90);
223 penpos2(astro.curve, 180);
224 penpos3(astro.vair, -90);
225 penpos4(astro.curve, 0);
226 y1r = cap_height+oo;
227 y3r = vround astro[0.30cap_height, cap_height-x_height]-oo;
228 y2 = y4 = 0.5[y1, y3];
229 x2r = appr; x4r = w-appr; x1 = x3 = 0.5[x2, x4];
230 y2l := y4l := astro[y2, 0.52[y3, y1]];
231 penstroke pulled_arc.e(1, 2) & pulled_arc.e(2, 3)
232 & pulled_arc.e(3, 4) & pulled_arc.e(4, 1) & cycle;
233 % queue
234 tmp_path := pulled_arc.r(1, 2) & pulled_arc.r(2, 3)
235 & pulled_arc.r(3, 4) & pulled_arc.r(4, 1) & cycle;
236 pickup crisp.nib;
237 bot y5 = -o; bot y6l = bot y7l = vround(0.5[-d, y3r]-0.5a);% a little higher
238 pos5(hround a, 0); pos6(vround a, 90); pos7(vround a, 90);
239 x5 = x3; x5l-x6 = x7-x5r = hround 0.5(x1-x2l);
240 save t;
241 forsuffixes $ = , r, l:
242 t$ = xpart(tmp_path intersectiontimes (z5$..(x5$, y2)));
243 endfor
244 filldraw subpath (t.r, t.l) of tmp_path--z5l--z5r--cycle;
245 filldraw stroke z6e..z7e;
246 % horns
247 tmp_path := reverse tmp_path;
248 save p; path p.r, p.l;
249 a := astro[rth, stem];
250 pos8(a, 90); pos9(hround 0.5[a, astro.vair], 180);
251 pos10(astro.vair, -90); pos11(hround 0.5[a, astro.vair], 0);
252 lft x9r = appr; x8 = x10 = x1; rt x11r = w-appr;
253 y9 = y11 = 0.5[y8, y10] = y1;
254 top y8 = vround max(1.22cap_height, y1r+a);
255 p.r = z8r left_to_down z9r down_to_right
256 z10r right_to_up z11r up_to_left z8r;
257 p.l = z8l right_to_down z11l down_to_left
258 z10l left_to_up z9l up_to_right z8l;
259 t1 = xpart(p.r intersectiontimes (z8..(x9r, y8)));
260 (t2, t3-4) = p.r intersectiontimes subpath (4, 8) of tmp_path;
261 (t5, t4-4) = p.l intersectiontimes subpath (4, 8) of tmp_path;
262 t6-6 = xpart(subpath (6, 8) of p.l intersectiontimes
263 ((point t1 of p.r)..(x1, y2)));
264 t7 = xpart(p.r intersectiontimes (z8..(x11r, y8)));
265 (t8, t9) = p.r intersectiontimes subpath (0, 4) of tmp_path;
266 (t11, t10) = p.l intersectiontimes subpath (0, 4) of tmp_path;
267 t12 = xpart(subpath (0, 2) of p.l intersectiontimes
268 ((point t7 of p.r)..(x1, y2)));
269 interim turningcheck := 0;% I hate turning numbers
270 filldraw subpath (t1, t2) of p.r
271 --subpath (t3, t4) of tmp_path
272 --subpath (t5, t6) of p.l -- cycle;
273 filldraw subpath (t12, t11) of p.l
274 --subpath (t10, t9) of tmp_path
275 --subpath (t8, t7) of p.r -- cycle;
276 penlabels(1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11);
277 endchar;
278
279 % okay
280 beginchar(astro_venus, 9u#+2appr#, cap_height#, 0);
281 "Venus";
282 italcorr 0; % italcorr cap_height#*slant-.5u#;
283 save a, t; a = astro.light_stem;
284 ensure_centering_of(a);
285 % circle
286 penpos1(astro.vair, 90);
287 penpos2(astro.curve, 180);
288 penpos3(astro.vair', -90);
289 penpos4(astro.curve, 0);
290 y1r = cap_height+oo;
291 y3r = vround astro[0.30cap_height, cap_height-x_height]-oo;
292 y2 = y4 = 0.5[y1, y3];
293 x2r = appr; x4r = w-appr; x1 = x3 = 0.5[x2, x4];
294 y2l := y4l := astro[y2, 0.52[y3, y1]];
295 penstroke pulled_arc.e(1, 2) & pulled_arc.e(2, 3)
296 & pulled_arc.e(3, 4) & pulled_arc.e(4, 1)& cycle;
297 % queue
298 tmp_path := pulled_arc.r(1, 2) & pulled_arc.r(2, 3)
299 & pulled_arc.r(3, 4) & pulled_arc.r(4, 1) & cycle;
300 pickup crisp.nib;
301 bot y5 = -o; bot y6l = bot y7l = vround(0.5[-d, y3r]-0.5a);% a little higher
302 pos5(hround a, 0); pos6(vround a, 90); pos7(vround a, 90);
303 x5 = x3; x5l-x6 = x7-x5r = hround 0.5(x1-x2l);
304 forsuffixes $ = , r, l:
305 t$ = xpart(tmp_path intersectiontimes (z5$..(x5$, y2)));
306 endfor
307 filldraw subpath (t.r, t.l) of tmp_path--z5l--z5r--cycle;
308 filldraw stroke z6e..z7e;
309 penlabels(1, 2, 3, 4, 5, 6, 7);
310 endchar;
311
312 % absolutely okay
313 beginchar(astro_earth, 13u#+2appr#, cap_height#, 0);
314 "Earth";
315 italcorr 0; % italcorr 0.6cap_height#*slant-.5u#;
316 save a; a = astro.light_stem;
317 ensure_centering_of(a);
318 pickup null.nib;
319 autorounded;
320 % circle
321 penpos1(astro.vair', 90);
322 penpos2(hround astro[rth, cap_curve-2stem_corr], 180);
323 penpos3(vround astro[rth, vair+1.5vair_corr], -90);
324 penpos4(hround astro[rth, cap_curve-2stem_corr], 0);
325 y1r = h+o; y3r = -o; y2 = y4 = 0.5h;
326 x2r = appr; x4r = w-appr; x1 = x3 = 0.5[x2, x4];
327 y2l := y4l := astro[y2, 0.52h];
328 penstroke pulled_arc.e(1, 2) & pulled_arc.e(2, 3)
329 & pulled_arc.e(3, 4) & pulled_arc.e(4, 1) & cycle;
330 % cross
331 tmp_path := z1 left_to_down z2 down_to_right
332 z3 right_to_up z4 up_to_right z1;
333 penpos5(hround a, 0); penpos6(vround a, 90);
334 x5 = x6 = 0.5w;
335 y5 = y6 = vround(y2-0.5vround a)+0.5vround a;
336 forsuffixes $ = , r, l:
337 z7$ = tmp_path intersectionpoint (z5$..(x5$, y1r));
338 z8$ = tmp_path intersectionpoint (z5$..(x5$, y3r));
339 z9$ = tmp_path intersectionpoint (z6$..(x2r, y6$));
340 z10$ = tmp_path intersectionpoint (z6$..(x4r, y6$));
341 endfor
342 fill z7r..z7..z7l--z8l..z8..z8r--cycle;
343 fill z9r..z9..z9l--z10l..z10..z10r--cycle;
344 penlabels(1, 2, 3, 4, 5, 6, 7, 8, 9, 10);
345 endchar;
346
347 % almost okay (see arrows dimensions)
348 beginchar(astro_mars, 9u#+2appr#, body_height#, 0);
349 "Mars";
350 italcorr 0; % italcorr body_height#*slant-.5u#;
351 save a; a = astro.light_stem;
352 % ensure_centering_of(a);% just for homogeneity
353 % circle
354 penpos1(astro.vair, 90);
355 penpos2(astro.curve, 180);
356 penpos3(astro.vair', -90);
357 penpos4(astro.curve, 0);
358 y1r = vround astro[0.70cap_height, x_height]+oo;
359 y3r = -oo;
360 y2 = y4 = 0.5[y1, y3];
361 x2r = appr; x4r = w-appr; x1 = x3 = 0.5[x2, x4];
362 y2l := y4l := astro[y2, 0.52[y3, y1]];
363 penstroke pulled_arc.e(1, 2) & pulled_arc.e(2, 3)
364 & pulled_arc.e(3, 4) & pulled_arc.e(4, 1) & cycle;
365 % arrow
366 tmp_path := pulled_arc.r(1, 2) & pulled_arc.r(2, 3)
367 & pulled_arc.r(3, 4) & pulled_arc.r(4, 1) & cycle;
368 z6 = (x1, y2); top y7 = body_height+o; rt x7 = w-appr;
369 arrow_height := vround astro[0.2cap_height, 0.3cap_height];
370 arrow_width := max(4.9rth, rth+3u);
371 save rth; rth = a;
372 arrow_head5(z6..z7, both);
373 z6r-z6 = z5r-z5; z6-z6l = z5-z5l;
374 save t;
375 forsuffixes $ = r, l:
376 t$ = xpart(tmp_path intersectiontimes (z6$..z5$));
377 endfor
378 filldraw if t.l>t.r: subpath (t.r, t.l) of tmp_path
379 else: subpath (t.r, 8) of tmp_path & subpath (0, t.l) of tmp_path fi
380 --z5l--z5r--cycle;
381 penlabels(1, 2, 3, 4, 6, 7);
382 endchar;
383
384 % humm
385 beginchar(astro_jupiter, 10u#+2appr#, asc_height#, desc_depth#);
386 "Jupiter";
387 italcorr 0; % italcorr body_height#*slant-.5u#;
388 pickup crisp.nib;
389 %
390 top y1r = h; bot y2l = -d;
391 rt x1r = w-appr-.5u;
392 lft x2l = appr+3u;
393 adjust_slanted_bar(1r, 2l, 1l, 2r)(astro[rth, cap_stem]-crisp, -1);
394 z1r-z1 = z1-z1l; z2r-z2 = z2-z2l;
395 filldraw stroke z1e..z2e;
396 %
397 top y3r-bot y3l = top y4r-bot y4l = astro.cap_hair;
398 z3r-z3l = whatever*(z1-z2);
399 bot y3l = bot y4l = bot y5l = vround 0.0h;
400 lft x5l = appr-0.5u;
401 adjust_slanted_bar(1l, 5l, 0, 5)(0.5(astro.cap_hair-crisp), -1);
402 z5r-z5 = z5-z5l;
403 top y8 = h-0.5rth; lft x8 = appr;
404 z0' = 0.72[z5, z1l]; z6 = 0.25[z5, z1l];
405 pos6(astro.cap_hair, angle(z1l-z5)-90);
406 pos8(astro.cap_curve, angle(z8-z0')-90);
407 x4l = x5; z4r-z4l = whatever*(z6-z5); z3 = 0.5[z3l, z3r];
408 filldraw stroke z5e---z6e{z0'-z6}...{z8-z0'}z8e;
409 %
410 if serifs:
411 save beak_jut, bracket, cap_jut;
412 cap_jut = hround astro[0, 1.8u];
413 bracket = 0.5cap_jut;
414 serif(1, 2, bracket, cap_jut, astro.slab, true, dish,
415 cap_jut, astro.slab, true, dish);
416 serif(2, 1, bracket, cap_jut, astro.slab, true, dish,
417 cap_jut, astro.slab, true, dish);
418 z3l = whatever[z1r, z2r];
419 beak_jut = (astro.beak+astro.slab)*(x1-x2)/(y1-y2);
420 arm3(astro.beak, beak_jut, astro.slab, beak_darkness, up, w-appr+0.75u);
421 else: x3l = 0.8[x2, x1];
422 fi
423 filldraw stroke z3e..z4e;
424 labels(0, 0'); penlabels(1, 2, 3, 4, 5, 6, 7, 8);
425 endchar;
426
427 % humm
428 beginchar(astro_saturn, 9.5u#+2appr#, body_height#, 0);
429 "Saturn";
430 italcorr 0; % italcorr body_height#*slant-.5u#;
431 % curve
432 pickup crisp.nib;
433 pos1(astro.cap_hair, 180); pos2(astro.cap_hair, 90);
434 pos3(hround 0.43[astro.cap_hair, astro.cap_stem], 0);
435 pos5(hround 0.44[astro.cap_hair, astro.cap_stem], 0);
436 pos6(astro.cap_hair, 90);
437 pos7(hround 0.44[astro.cap_hair, astro.cap_stem], 180);
438 pos10(astro.cap_stem, 0);
439 lft x10l = appr+hround 1.5u;
440 x10r = x1l;
441 rt x3r = rt x7l = w-appr;
442 x2 = (astro[0.5,0.57])[x1l, x3l];
443 rt x5r+eps = hround astro[x2, x10r+0.5[astro.cap_hair, astro.cap_stem]];
444 x6 = 0.5[x5, x7];
445 %
446 % Construction with tangent circles
447 %
448 save d, k, R; k = (x7-x5)/(x3-x1);
449 k' = (1+k-2sqrt k)/((1-k)**2);
450 bot y6l = -o;
451 top y2r = vround 0.8h+o;
452 R = k'*(y2-y6);
453 y3 = y2-R; bot y1 = bot y10 = vround y3;
454 y5 = y7 = y6+k*R;
455 z4 = (1/(1+k))[(x2, y1), (x6, y5)]; d = R/(x2-x1);
456 pos4(astro.cap_stem, angle((y1-y5)/d, (x6-x2)*d)-90);
457 % stem
458 save rth; rth = astro.cap_stem;
459 arrow_height := vround astro[h-cap_height, 0.2cap_height]+o;
460 arrow_width := rth+hround 2(2.25u)+0.5;
461 arrow_head9(z10..(x10, h+o-pen_top), left);
462 filldraw stroke z9e..z10e;
463 %
464 x7 := x7r+1;
465 tmp_path := z6l right_to_up z7l;
466 t := xpart(tmp_path intersectiontimes (z7..(x7, y6l)));
467 autorounded;
468 filldraw subpath (0, t) of tmp_path
469 --z7--z7r down_to_left z6r--cycle;
470 filldraw stroke z1e up_to_right z2e right_to_down
471 z3e...z4e{((y5-y1)/d, (x2-x6)*d)}
472 ...z5e down_to_right z6e;
473 penlabels(0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10);
474 endchar;
475
476 % almost okay (see arrows dimensions)
477 beginchar(astro_uranus, 9u#+2appr#, body_height#, 0);
478 "Uranus";
479 italcorr 0; % italcorr body_height#*slant-.5u#;
480 save a;
481 a = astro.light_stem;
482 ensure_centering_of(a);% just for homogeneity
483 % circle
484 penpos1(astro.vair, 90);
485 penpos2(hround astro[rth, curve-stem_corr], 180);
486 penpos3(astro.vair', -90);
487 penpos4(hround astro[rth, curve-stem_corr], 0);
488 y1r = vround astro[0.70cap_height, x_height]+oo;
489 y3r = -oo;
490 y2 = y4 = 0.5[y1, y3];
491 x2r = appr; x4r = w-appr; x1 = x3 = 0.5[x2, x4];
492 y2l := y4l := astro[y2, 0.52[y3, y1]];
493 penstroke pulled_arc.e(1, 2) & pulled_arc.e(2, 3)
494 & pulled_arc.e(3, 4) & pulled_arc.e(4, 1) & cycle;
495 % dot
496 adjust_dot5((x1, y2), astro[1.6rth, dtsz], true, true);
497 dot(5, 5');
498 % arrow
499 tmp_path := pulled_arc.r(1, 2) & pulled_arc.r(2, 3)
500 & pulled_arc.r(3, 4) & pulled_arc.r(4, 1) & cycle;
501 arrow_height := vround astro[0.2cap_height, 0.3cap_height]+eps;
502 arrow_width := max(4.9rth, rth+3u);
503 save rth; rth = hround a;
504 arrow_head6(z1..(x1, body_height+o-pen_top), both);
505 save t;
506 forsuffixes $ = , r, l:
507 t$ = xpart(tmp_path intersectiontimes (z6$..(x6$, y2)));
508 endfor
509 pickup crisp.nib;
510 filldraw subpath (t.r, 8) of tmp_path
511 & subpath (0, t.l) of tmp_path --z6l--z6r--cycle;
512 penlabels(1, 2, 3, 4, 6, 7);
513 endchar;
514
515 % almost okay (see arrows dimensions)
516 beginchar(astro_neptune, 10.5u#+2Appr#, cap_height#, 0);
517 "Neptune";
518 italcorr 0; % italcorr cap_height#*slant-.5u#;
519 save a;
520 a = hround astro[rth, cap_stem-2stem_corr];
521 ensure_centering_of(a);
522 % stems
523 x1-0.5a = hround astro[Appr, appr];
524 x3 = x7 = 0.5w;
525 x1 = x2; x4-x3 = x3-x1;
526 pickup crisp.nib;
527 % arrows
528 save rth; rth = a;
529 arrow_height := vround astro[0.125cap_height, 0.25cap_height]+eps;
530 arrow_width := min(3a, x3-x1-0.5u, 2.5u+a);
531 arrow_head0((x1, 0)..(x1, h+o-pen_top), both);
532 arrow_head5((x4, 0)..(x4, h+o-pen_top), both);
533 arrow_head6((x3, 0)..(x3, h+o-pen_top), both);
534 % cup and queue
535 pos1(a, 180); pos2(a, 180); pos3(astro.vair, -90); pos4(a, 0); pos7(a, 0);
536 pos8(vround astro.light_stem, 90); pos9(vround astro.light_stem, 90);
537 bot y3r = vround 0.2cap_height;
538 y1 = y0; y2 = y4 = 0.5[y1, y3]; bot y7 = -o;
539 top y8r = top y9r = vround 0.2cap_height-1;
540 x7l-x8 = x9-x7r = hround 0.5(x3-x1-a);
541 filldraw stroke z1e..z2e down_to_right z3e right_to_up z4e..z5e;
542 filldraw stroke z6e..z7e; filldraw stroke z8e..z9e;
543 penlabels(1, 2, 3, 4, 7, 8, 9);
544 endchar;
545
546 % The serifs are not cm compatible
547 beginchar(astro_pluto, 7.75u#+Appr#+appr#, cap_height#, 0);
548 "Pluto";
549 italcorr 0; % italcorr 0.75cap_height#*slant-.5u#;
550 pickup crisp.nib;
551 %
552 % stem
553 %
554 pos1(astro.cap_stem, 0);
555 pos2(astro.cap_stem, 0);
556 top y1 = h; bot y2 = 0; lft x1l = lft x2l = Appr;
557 filldraw stroke z1e..z2e;
558 %
559 % curve
560 %
561 penpos3(astro.cap_hair, 90);
562 penpos4(astro.cap_hair, 90);
563 penpos5(astro.cap_curve, 0);
564 penpos6(astro.vair, -90);
565 penpos7(astro.vair, -90);
566 y3r = y4r = h; y5 = 0.5[y4, y6];
567 y6r = y7r = vround astro[0.275h, 0.5h-astro.vair];
568 x3 = x7 = x1; x5r = w-appr; x4 = x6 = 0.4[x3, x5];
569 penstroke z3e..pulled_arc.e(4, 5) & pulled_arc.e(5, 6)..z7e;
570 %
571 % arm or beak, and serifs
572 %
573 pos9(astro.slab, 90); pos10(astro.slab, 90); y9l = y10l = y2; x9 = x2r;
574 if serifs: x10 = 0.5w;
575 save beak_jut, bracket, cap_jut;
576 beak_jut = hround astro[0, 0.75u];
577 cap_jut = hround astro[0, 1.8u];
578 bracket = 0.5cap_jut;
579 arm10(astro.beak, beak_jut, astro.slab, beak_darkness, up, w-appr);
580 serif(1, 2, bracket, cap_jut, astro.slab, true,
581 0, 0.5cap_jut, astro.slab, true, 0);
582 serif(2, 1, bracket, cap_jut, astro.slab, true,
583 0, 0.5cap_jut, astro.slab, true, 0);
584 else: rt x10 = w-appr; fi
585 filldraw stroke z9e..z10e;
586 penlabels(1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11);
587 endchar;
588
589 % okay
590 beginchar(astro_varearth, 9u#+2appr#, cap_height#, 0);
591 "Variant Earth";
592 italcorr 0; % italcorr x_height#*slant-.5u#;
593 save a;
594 a = astro.light_stem;
595 ensure_centering_of(a);
596 % circle
597 penpos1(astro.vair, 90);
598 penpos2(astro.curve, 180);
599 penpos3(astro.vair', -90);
600 penpos4(astro.curve, 0);
601 y1r = vround astro[0.70cap_height, x_height]+oo;
602 y3r = -oo;
603 y2 = y4 = 0.5[y1, y3];
604 x2r = appr; x4r = w-appr; x1 = x3 = 0.5[x2, x4];
605 y2l := y4l := astro[y2, 0.52[y3, y1]];
606 penstroke pulled_arc.e(1, 2) & pulled_arc.e(2, 3)
607 & pulled_arc.e(3, 4) & pulled_arc.e(4, 1) & cycle;
608 % head
609 tmp_path := pulled_arc.r(1, 2) & pulled_arc.r(2, 3)
610 & pulled_arc.r(3, 4) & pulled_arc.r(4, 1) & cycle;
611 pickup crisp.nib;
612 top y5 = h+o; top y6r = top y7r = vround(0.5[h, y1r]+0.5o+0.5a);
613 pos5(hround a, 0); pos6(vround a, 90); pos7(vround a, 90);
614 x5 = x1; x5l-x6 = x7-x5r = hround 0.5(x1-x2l);
615 save t;
616 forsuffixes $ = , r, l:
617 t$ = xpart(tmp_path intersectiontimes (z5$..(x5$, y2)));
618 endfor
619 filldraw subpath (t.r, 8) of tmp_path
620 & subpath (0, t.l) of tmp_path --z5l--z5r--cycle;
621 filldraw stroke z6e..z7e;
622 penlabels(1, 2, 3, 4, 5, 6, 7);
623 endchar;
624
625 beginchar(astro_aries, 13u#+2appr#, cap_height#, 0);
626 "Aries";
627 italcorr 0; % italcorr 0.7x_height#*slant-.5u#;
628 save a, b;
629 a = 10; b = hround astro[1.2rth,astro.cap_stem];
630 ensure_centering_of(b);
631 x1 = x2 = x3 = 0.5w; y3 = 0.5h;
632 if serifs:
633 save bracket, cap_jut;
634 pickup crisp.nib;
635 cap_jut = hround astro[0, 1.8u];
636 bracket = 0.5cap_jut;
637 bot y2=0;
638 pos2(b, 0); pos3(b, 0);
639 serif(2, 3, bracket, cap_jut, astro.slab, true, dish,
640 cap_jut, astro.slab, true, dish);
641 filldraw stroke z2e..z3e;
642 else:
643 pickup tiny.nib;
644 bot y1 = -d-o; y2-y1 = o;
645 pos1(max(0.75b, tiny+eps), 0);
646 pos2(b, 0); pos3(b, 0);
647 filldraw stroke z1e--z2e--z3e;
648 penlabels(1);
649 fi
650 pickup tiny.nib;
651 pos3a(astro.light_stem, 0); pos4a(vround astro.light_stem, 90);
652 pos5a(astro.curve, 180); pos6a(astro.cap_hair, 270-a);
653 pos3b(astro.light_stem, 180); pos4b(vround astro.light_stem, 90);
654 pos5b(astro.curve, 0); pos6b(astro.cap_hair, -90+a);
655 y3 = y3a = y3b;
656 top y4a.r = top y4b.r = h+o;
657 y5a = y5b = 0.6[y6a, y4a];
658 bot y6a.r = bot y6b.r = vround 0.5h;
659 lft x3a.l = 0.5(w-b); rt x3b.l = 0.5(w+b);
660 x4a = 0.6[x3a, x5a]; x4b = 0.6[x3b, x5b];
661 lft x5a.r = appr; rt x5b.r = w-appr;
662 x6a.r = good.x 0.5[x5a.r, x3a.l];
663 x3a.l-x6a.r = x6b.r-x3b.l;
664 filldraw stroke z3a.e up_to_left z4a.e
665 & pulled_arc.e(4a, 5a)...z6a.e{dir -a};
666 filldraw stroke z3b.e up_to_right z4b.e
667 & pulled_arc.e(4b, 5b)...z6b.e{dir(180+a)};
668 penlabels(1, 2, 3, 3a, 4a, 5a, 6a, 3b, 4b, 5b, 6b);
669 endchar;
670
671 % okay
672 beginchar(astro_taurus, 9u#+2appr#, cap_height#, 0);
673 "Taurus";
674 italcorr 0; % italcorr x_height#*slant-.5u#;
675 % circle
676 penpos1(astro.vair, 90);
677 penpos2(astro.curve, 180);
678 penpos3(astro.vair', -90);
679 penpos4(astro.curve, 0);
680 y1r = vround astro[0.70cap_height, x_height]+oo;
681 y3r = -oo;
682 y2 = y4 = 0.5[y1, y3];
683 x2r = appr; x4r = w-appr; x1 = x3 = 0.5[x2, x4];
684 y2l := y4l := astro[y2, 0.52[y3, y1]];
685 penstroke pulled_arc.e(1, 2) & pulled_arc.e(2, 3)
686 & pulled_arc.e(3, 4) & pulled_arc.e(4, 1) & cycle;
687 % head
688 pickup crisp.nib;
689 pos5(astro.hair, 180);
690 pos6(vround astro.light_stem, -90);
691 pos7(astro.hair, 0);
692 top y5 = top y7 = h+o; bot y6r = y1l;
693 lft x5r = appr; rt x7r = w-appr; x6 = x1;
694 filldraw stroke z5e down_to_right z6e right_to_up z7e;
695 penlabels(1, 2, 3, 4, 5, 6, 7);
696 endchar;
697
698 beginchar(astro_gemini, 11u#+2appr#, cap_height#, 0);
699 "Gemini";
700 italcorr 0; % italcorr asc_height#*slant-.5u#;
701 pickup crisp.nib;
702 save c, bracket;
703 bracket = 0.5hround astro[0, 1.8u];
704 c = hround 0.25(w-2appr-2astro.stem);
705 % stems
706 pos1(astro.stem, 0); pos2(astro.stem, 0);
707 pos3(astro.stem, 0); pos4(astro.stem, 0);
708 top y1 = top y3 = h; bot y2 = bot y4 = 0;
709 lft x1l = lft x2l = appr+c; rt x3r = rt x4r = w-appr-c;
710 filldraw stroke z1e..z2e;
711 filldraw stroke z3e..z4e;
712 % serifs
713 if serifs:
714 serif(1, 2, bracket, c, astro.slab, true, dish, 0.0c, astro.slab, true, 0);
715 serif(2, 1, bracket, c, astro.slab, true, dish, 0.0c, astro.slab, true, 0);
716 serif(3, 4, bracket, 0.0c, astro.slab, true, 0, c, astro.slab, true, dish);
717 serif(4, 3, bracket, 0.0c, astro.slab, true, 0, c, astro.slab, true, dish);
718 filldraw z1e--z1f--z3c--z3d--cycle;
719 filldraw z2e--z2f--z4c--z4d--cycle;
720 else:
721 pos5(astro.slab, 90); pos6(astro.slab, 90);
722 pos7(astro.slab, 90); pos8(astro.slab, 90);
723 lft x5r = lft x7l = appr; rt x6r = rt x8l = w-appr;
724 y5r = y6r = y1; y7l = y8l = y2;
725 filldraw stroke z5e..z6e;
726 filldraw stroke z7e..z8e;
727 penlabels(5, 6, 7, 8);
728 fi
729 penlabels(1, 2, 3, 4);
730 endchar;
731
732 beginchar(astro_cancer, 13u#+2appr#, cap_height#, 0);
733 "Cancer";
734 italcorr 0; % italcorr 0.7x_height#*slant-.5u#;
735 labels(1, 2, 3, 4);
736 endchar;
737
738 beginchar(astro_leo, 13u#+2appr#, cap_height#, 0);
739 "Leo";
740 italcorr 0; % italcorr 0.7x_height#*slant-.5u#;
741 pickup crisp.nib;
742 pos1(astro.cap_hair,0);
743 pos2(astro.vair,90);
744 pos3(astro.cap_hair,180);
745 pos4(astro.vair,-90);
746 pos5(astro.cap_hair,180);
747 pos6(astro.cap_curve,180);
748 pos7(astro.vair,90);
749 pos8(astro.cap_curve,0);
750 pos9(astro.cap_hair,0);
751 pos10(astro.vair,90);
752 pos11(astro.cap_hair,180);
753 bot y4r=bot y10.l=-o; top y7r=h+o;top y2r=vround 0.3h+o;
754 y1=y3=y5=y9=0.5[y2, y4]; y6=y8=0.6[y1,y7]; y11=good.y y9;
755 lft x3r=appr; rt x11l=w-appr;
756 lft x6r=w-rt x8r=appr+hround(2.5u-0.5astro.cap_curve);
757 rt x1r-lft x3r=rt x11l-lft x9l=hround 5u;
758 x5=x1; x2=x4=0.5[x1,x3]; x10=0.5[x9,x11];
759 x7=0.5[x6, x8];
760 filldraw stroke z1e up_to_left z2e left_to_down z3e down_to_right z4e
761 right_to_up z1e;
762 filldraw stroke z5e{up}...pulled_arc.e(6,7)&pulled_arc.e(7,8)...z9e
763 down_to_right z10e right_to_up z11e;
764 penlabels(1,2,3,4,5,6,7,8,9,10,11);
765 endchar;
766
767 beginchar(astro_virgo, 13u#+2appr#, cap_height#, 0);
768 "Virgo";
769 italcorr 0; % italcorr 0.7x_height#*slant-.5u#;
770 labels(1, 2, 3, 4);
771 endchar;
772
773 beginchar(astro_libra, 13u#+2appr#, cap_height#, 0);
774 "Libra";
775 italcorr 0; % italcorr 0.7x_height#*slant-.5u#;
776 pickup crisp.nib;
777 save a, b;
778 % horizontal stems
779 top y1r-bot y1l = astro.slab;
780 y1=0.5[y1r, y1l]; x1 = x1l= x1r;
781 forsuffixes $ = 2, 3, 4, 5, 6:
782 y$r-y$l = y1r-y1l; y$ = 0.5[y$r, y$l]; x$ = x$l = x$r;
783 endfor
784 bot y1l = 0; y1 = y2;
785 y3-y1= vround astro[0.375x_height, 0.2x_height]; y3 = y4 = y5 = y6;
786 rt x4= hround(0.5w-astro[1.5u, 1u]); x5 = w-x4; lft x1= appr; rt x2=w-appr;
787 % ellipses $(x-x_0)^2/a^2+(y-y_0)^2/b^2=1$
788 pos8(astro.curve, 180); pos9(astro.vair, 90); pos10(astro.curve, 0);
789 top y9r=h+o; lft x8r=w-rt x10r=appr+hround(2u-0.5astro.curve);
790 x0 = x9 = 0.5w; y7l = y7r = y11l = y11r = y4r; x7l = x4r; x11l = x5r;
791 % inner ellipse
792 a = x10l-x0;
793 b*(1+-+((x11l-x0)/a)) = (-b+y9l-y7l);
794 y0 = y8 = y10 = y9l-b;
795 z7'l=unitvector((y7l-y0)/b/b, -(x7l-x0)/a/a);
796 z11'l=unitvector((y11l-y0)/b/b, -(x11l-x0)/a/a);
797 % outer ellipse
798 a := x10r-x0;
799 b := y9r-y0;
800 x0-x7r = x11r-x0 = a*(1+-+((y11r-y0)/b));
801 z7'r=unitvector((y7r-y0)/b/b, -(x7r-x0)/a/a);
802 z11'r=unitvector((y11r-y0)/b/b, -(x11r-x0)/a/a);
803 % draw things
804 if serifs: x3=x7r; x6=x11r;
805 arm3(astro.beak, -astro[0, 0.75u], -astro.slab,
806 beak_darkness, up, appr-0.75u);
807 arm6(astro.beak, astro[0, 0.75u], astro.slab,
808 beak_darkness, up, w-appr+0.75u);
809 else: x3=x1; x6=x2;
810 fi
811 filldraw stroke z1e..z2e;
812 filldraw stroke z3e..z4e;
813 filldraw stroke z5e..z6e;
814 filldraw stroke z7e{z7'e}...pulled_arc.e(8, 9)
815 & pulled_arc.e(9, 10)...z11e{z11'e};
816 penlabels(0, 1, 2, 3, 4,5,6,7,8,9,10,11);
817 endchar;
818
819 %iff false:
820 beginchar(astro_scorpio,15u#+2appr#,cap_height#,0.5desc_depth#);
821 "Scorpio";
822 % italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
823 % adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
824 % numeric shaved_stem; shaved_stem=hround(mfudged.stem-2stem_corr);
825 pickup crisp.nib;
826 pos1(astro.cap_stem,0); pos2(astro.cap_stem,0);
827 pos3(astro.cap_stem,0); pos4(astro.cap_stem,0);
828 pos5(astro.cap_stem,0); pos6(astro.cap_stem,0);
829 pos6'(astro.cap_stem,180); pos7(astro.vair,-90);
830 lft x1l=appr+hround(1.5u-.5astro.cap_stem);
831 x5-x3=x3-x1=hround 5u; x1=x2; x3=x4; x5=x6;
832 bot y2=0; y2=y4; y6=0.25x_height; y1=y3=y5=0.7h;
833 for $ = 3, 5:
834 pos[$]a(astro.cap_hair, 180); top y[$]b.r-bot y[$]b.l=astro.vair;
835 rt x[$]a.l=x[$-2]r; y[$]a=astro[0.7h,0.55h]; top y[$]b.r=h+o;
836 x[$]b.r=astro[0.5[x[$]a, x[$]], 0.5[rt x[$]a.l, rt x[$]r]];
837 z[$]b.l= whatever[z[$]a.l, z[$]b.r];
838 x[$]b = x[$]b.r; y[$]b=0.5[y[$]b.l, y[$]b.r];
839 filldraw stroke z[$]a.e{up}...z[$]b.e{right}
840 & pulled_arc.e([$]b, [$])..z[$+1]e;
841 endfor
842 lft x1a=appr-hround u; top y1a.r=h+o; pos1a(astro.vair,90);
843 filldraw stroke pulled_arc.e(1a, 1)..z2e;
844 z6=z6'; bot y7r=-d; x7=0.5[x6,w];
845 save rth; rth = astro.hair;
846 arrow_height := vround astro[0.125cap_height, 0.25cap_height]+eps;
847 arrow_width := 3.5u;
848 arrow_head8(z7{right}...(w,0.25x_height){up}, both);
849 filldraw stroke pulled_arc.e(6',7)...{z8a-z8}z8e;
850 if serifs:
851 save beak_jut, bracket, cap_jut;
852 cap_jut = hround astro[0, 1.8u];
853 bracket = 0.5cap_jut;
854 serif(2, 1, bracket, cap_jut, astro.slab, true, dish,
855 cap_jut-0.5u, astro.slab, true, dish);
856 serif(4, 3, bracket, cap_jut-0.5u, astro.slab, true, dish,
857 cap_jut-0.5u, astro.slab, true, dish);
858 fi
859 penlabels(1,1a,2,3,3a,3b,4,5,5a,5b,6,7);
860 endchar;
861
862 beginchar(astro_sagittarius, 13u#+2appr#, cap_height#, 0);
863 "Sagittarius";
864 italcorr 0; % italcorr 0.7x_height#*slant-.5u#;
865 save a, rth; a= angle(w-2appr,h+2o); rth=astro.light_stem;
866 pickup crisp.nib; lft x1l=appr; bot y1r=-o;
867 pos1(astro.light_stem, a-90);
868 arrow_height := vround astro[0.2cap_height, 0.3cap_height]+eps;
869 arrow_width := max(4.9rth, rth+3u);
870 arrow_head2((appr,-o)..(w-appr, h+o), both);
871 pos3(astro.light_stem,a); pos4(astro.light_stem,a);
872 z3-z2c.l=whatever*(z2-z1); z0=1/3[z1,z2]; z3-z0=whatever*dir(a+90);
873 z3-z0=z0-z4;
874 % autorounded;
875 filldraw stroke z1e..z2e;
876 filldraw stroke z3e..z4e;
877 penlabels(1, 2, 3, 4);
878 endchar;
879
880 beginchar(astro_capricorn, 13u#+2appr#, cap_height#, 0);
881 "Capricorn";
882 italcorr 0; % italcorr 0.7x_height#*slant-.5u#;
883 labels(1, 2, 3, 4);
884 endchar;
885
886 beginchar(astro_aquarius, 13u#+2appr#, cap_height#, 0);
887 "Aquarius";
888 italcorr 0; % italcorr 0.7x_height#*slant-.5u#;
889 labels(1, 2, 3, 4);
890 endchar;
891
892 beginchar(astro_pisces, 13u#+2appr#, cap_height#, 0);
893 "Pisces";
894 italcorr 0; % italcorr 0.7x_height#*slant-.5u#;
895 pickup crisp.nib;
896 pos1(astro.vair, 90); pos2(astro.curve,0); pos3(astro.vair, -90);
897 pos4(astro.vair, 90); pos5(astro.curve,180); pos6(astro.vair, -90);
898 pos7(vround astro.light_stem,90); pos8(vround astro.light_stem,90);
899 top y1r=top y4r=h+o; bot y3r=bot y6r=-o;
900 top y7r=top y8r=vround(0.5h+0.5astro.light_stem); y2=y5=y7;
901 lft x3=lft x1=appr; rt x4=rt x6=w-appr;
902 lft x2l=w-rt x5l=appr+hround(4u-.5astro.curve);
903 lft x7=w-rt x8=appr+hround u;
904 filldraw stroke pulled_arc.e(1,2)&pulled_arc.e(2,3);
905 filldraw stroke pulled_arc.e(4,5)&pulled_arc.e(5,6);
906 filldraw stroke z7e..z8e;
907 penlabels(1, 2, 3, 4,5,6,7,8);
908 endchar;
909
910 % The next symbol is intended to figure ``cemetery''
911 % in the theory of Markov processes.
912 % Usualy, this concept is represented by a partial derivative
913 % symbol or a Greek lowercase delta. It seems that
914 % no specific symbol has been designed before.
915
916 use_rule1;
917 beginchar(cemetery, 10u#+2appr#, cap_height#, 0);
918 "Cemetery symbol";
919 pickup rule.nib;
920 ensure_centering_of(rth);
921 x1 = x2 = 0.5w;
922 lft x5 = appr; rt x8 = w-appr; bot y5 = bot y8 = 0;
923 y1 = h; x3 = w-x4 = appr+hround 1.5u;
924 y2 = good.y 0.2[y5, y1]; y3 = y4 = good.y 2/3[top y2, y1];
925 z6 = 0.5[z5, z2]; z7 = 0.5[z8, z2];
926 tmp_path := z5{right}...z6{0.5(x2-x6), y2-y6}...z2{right}
927 ...z7{0.5(x7-x2), y7-y2}...z8{right};
928 draw tmp_path;
929 penpos1(rth, 0); penpos2(rth, 0);
930 penpos3(rth, 90); penpos4(rth, 90);
931 penstroke z1e..z2e; penstroke z3e..z4e;
932 save a, b, c, number_of_slashes; a = max(h, w);
933 pickup crisp.nib;
934 x5' = good.x appr; x8' = good.x w-appr; y5 = y5'; y8 = y8';
935 pos5(rth, 90); pos5'(rth, 90); pos8(rth, 90); pos8'(rth, 90);
936 filldraw stroke z5e..z5'e; filldraw stroke z8e..z8'e;
937 pickup fine.nib;
938 number_of_slashes = 6; c = hround((x8-x5)/(number_of_slashes+1));
939 number_of_slashes := round((x8-x5)/max(c, 1))-1;
940 for i = 1 upto number_of_slashes:
941 bot y[i+8]l = 0; x[i+8]l = x5+i*c;
942 z[i+8]r = tmp_path intersectionpoint (z[i+8]l..z[i+8]l+(a, a));
943 draw z[i+8]l..z[i+8]r; penlabels([i+8]);
944 endfor;
945 penlabels(1, 2, 3, 4, 5, 8, 5', 8'); labels(6, 7);
946 endchar;