Debian Codegraph @

texmf-dist/fonts/source/public/mathabx/mathcallgreek.mf

raw
1 % mathematical symbols by Anthony Phan.
2 % file: mathcallgreek.mf (calligraphic font)
3 % last modification: May 16, 2005.
4
5 %
6 % UPPERCASE
7 %
8
9 let math_fit = do_math_fit;
10 math_fitting := true;
11
12 cmchar "Calligraphic Alpha";
13 beginchar(hex"81",14.4u#,cap_height#,0);
14 italcorr .5u#;
15 adjust_fit(-.05w#,0); pickup cal.nib;
16 lft x5=.54w; x7=.9w;
17 top y5=h+.4cap_curve; bot y7=bot_flourish_line;
18 z6=.3[z7,z5]-bend;
19 pickup tilted.nib;
20 lft x1=.05w; x2=.2w; rt x4=x5;
21 y1=y2+.1h; bot y2=bot_flourish_line; top y4=h+.4cap_curve;
22 y3=y6; z3=whatever[z2,z4]+2bend;
23 draw\\(z1..tension 1.2..{right}z2) softjoin flex(z2,z3,z4); % left diagonal
24 pickup cal.nib;
25 erase fill\\(0,bot y5)--(w,bot y5)--(w,top y5)--(0,top y5)--cycle;
26 draw flex(z5,z6,z7) softjoin (z7--z7+cal.extension); % right diagonal
27 draw rt z3--z6; % bar
28 math_fit(.5u#-.1cap_height#*slant,ic#); labels(1,2,3,4,5,6,7);
29 endchar;
30
31 cmchar "Calligraphic Beta";
32 beginchar(hex"82",9.9u#,cap_height#,0);
33 italcorr max(.8h#*slant-.1w#,.3h#*slant)+.5u#;
34 adjust_fit(0,0); pickup cal.nib;
35 lft x1=lft x3=0; x4=.6[x2,x5]; rt x5=.9w; x6=.4w; rt x7=w;
36 x8=.4[x9,x7]; lft x9=rt x3;
37 top y1=h+o; bot y3=-o; z2=.3[z3,z1]+bend;
38 y4=y1; y5=.6[y6,y4]; y6=.55h; y7=.45[y8,y6]; bot y8=-o; y9=.1h;
39 draw z1-cal.extension--flex(z1,z2,z3); % stem
40 draw z2{up}...z4...z5{down}...{dir 200}z6{dir 10}
41 ...z7{down}...z8{left}...z9; % lobes
42 math_fit(.5u#,.3h#*slant+.5u#); labels(1,2,3,4,5,6,7,8,9);
43 endchar;
44
45 cmchar "Calligraphic Gamma";
46 beginchar(hex"83",13.5u#,cap_height#,0);
47 italcorr h#*slant+.5u#;
48 adjust_fit(-.1w#,-u#); pickup cal.nib;
49 x1=.5w; x3=.4w; lft x4=.1w; x5=x2+.35w; x6=.7[x1,x7]; rt x7=w;
50 top y1=top y6=h; z2=.5[z3,z1]+1.2bend;
51 bot y3=-o; y4=.1h; y5=y2; y7=.9h;
52 draw flex(z1,z2,z3) softjoin (z3...{x4-x3,5(y4-y3)}z4); % stem
53 draw z1-flourish_change{up}...(z1-(u,0))---z6...{down}z7; % upper bar
54 math_fit(0,.5ic#); labels(1,2,3,4,5,6,7);
55 endchar;
56
57 cmchar "Calligraphic Epsilon";
58 beginchar(hex"85",8.5u#,cap_height#,0);
59 italcorr max(h#*slant-.1w#,.2h#*slant)+.5u#;
60 adjust_fit(0,0); pickup cal.nib;
61 x1=.9[x3,x2]; rt x2=.9w; x3=.6[x4,x2]; lft x4=.05w;
62 x5=.7[x6,x2]; lft x6=0; x7=.5[x6,x8]; rt x8=w;
63 y1=y2-.1h; y2=.9h+o; top y3=h+o; y4=.5[y5,y3];
64 y5=.55h; y6=.6[y5,y7]; bot y7=-o; y8=.2h;
65 draw\\(z1{2(x2-x1),y2-y1}...z2)
66 softjoin (z2...z3{left}...z4{down}...{right}z5); % upper arc
67 draw z5{left}...z6{down}...z7{right}...z8; % lower arc
68 math_fit(.5u#-.2h#*slant,.2h#*slant+.5u#);
69 labels(1,2,3,4,5,6,7,8);
70 endchar;
71
72 cmchar "Calligraphic Zeta";
73 beginchar(hex"86",10.4u#,cap_height#,0);
74 italcorr h#*slant+.5u#;
75 adjust_fit(0,0); pickup heavy_cal.nib;
76 lft x1=.05w; x2=.4w; rt x3=w; lft x7=0; x8=.8[x7,x9]; rt x9=1.1w;
77 top y1=58/70h; top y2=top y3=h; bot y7=bot y8=0; bot y9=15/70h;
78 z5=.55[z7,z3]+bend;
79 x10=x5-2.5u; x11=x5+2u; x12=.2[x3,x2]; x13=.2[x7,x8];
80 y10=y5; bot y11=y10-6/70h; y12=64/70h; y13=6/70h;
81 draw z1{up}...z2{right}...{right}z12...z3; % upper arm
82 draw flex(z3,z5,z7); % diagonal
83 draw z7...z13{right}...{right}z8...{up}z9; % lower arm
84 pickup light_cal.nib;
85 draw z10...z5{right}...{down}z11; % bar
86 math_fit(.5u#,.6ic#); labels(1,2,3,5,7,8,9,10,11,12,13);
87 endchar;
88
89
90 cmchar "Calligraphic Eta";
91 beginchar(hex"87",12.2u#,cap_height#,0);
92 italcorr max(h#*slant-.2w#,.15h#*slant)+.5u#;
93 adjust_fit(4u#,0); pickup cal.nib;
94 lft x1=lft x3=.5u; rt x4=rt x6=.8w-.6u; rt x9=w;
95 top y1=top y4=h; bot y3=-.06h; bot y6=bot_flourish_line; y9=y6+.1h;
96 z2=.6[z3,z1]+bend; z5=.4[z6,z4]-bend;
97 path p[]; p1=flex(z1,z2,z3); p2=flex(z4,z5,z6);
98 p3=(-w,.45h)--(2w,.45h);
99 rt z7+2bend=p3 intersectionpoint p1; rt z8=p3 intersectionpoint p2;
100 draw (z1-flourish_change-bend{curl2}....z1-(u,0)---z1) softjoin p1; % left stem
101 draw p2 softjoin (z6{right}...{up}z9); % right stem
102 draw z7--z8; % bar
103 math_fit(.5u#-.8h#*slant,.15h#*slant+.5u#);
104 labels(1,2,3,4,5,6,7,8,9);
105 endchar;
106
107 cmchar "Calligraphic Theta";
108 beginchar(hex"88",12.6u#,cap_height#,0);
109 italcorr .7h#*slant+.5u#;
110 adjust_fit(0,0); pickup cal.nib;
111 x1=.3w; lft x2=0; x3=.5w; rt x4=w; x5=.6w; lft x6=.27w;
112 top y1=top y5=h+o; y2=.55h; bot y3=-o; y4=.5h; y6=y2;
113 y9 = good.y 0.65h; y7 = y10 = good.y 0.35h; y8 = good.y 0.5h;
114 x7 = x6; x8 = 0.5w; x9 = x10 = w-x6;
115 draw z1...z2{down}...z3{right}...z4{up}...z5{left}...{down}z6
116 --z7{up}...z8{right}...z9{up}--z10;
117 math_fit(.5u#-.3h#*slant,ic#-.5u#);
118 labels(1,2,3,4,5,6,7,8,9,10);
119 endchar;
120
121 cmchar "Calligraphic Iota";
122 beginchar(hex"89",10.8u#,cap_height#,0);
123 italcorr max(h#*slant+.5cap_curve#-.2w#,.15h#*slant)+.5u#;
124 adjust_fit(0,0); pickup cal.nib;
125 lft x0=0; x1=.9w; x2=x4=.5w; x5=.2w; x6=.8w; rt x7=1.05w;
126 y0=.8h; top y1=top y2=h; z3=.5[z4,z2]+bend;
127 bot y4=bot y5=bot y6=0; y7=.15h;
128 draw z0{up}...z2---z1; % upper bar
129 z8=.5[z2,z1];
130 draw z8{left}...z3{down}...{left}.5[z4,z5]; % stem
131 draw z5---z6...{up}z7; % lower bar
132 math_fit(.5u#-.8h#*slant,.15h#*slant+.5u#);
133 labels(0,1,2,3,4,5,6,7);
134 endchar;
135
136 cmchar "Calligraphic K";
137 beginchar(hex"8A",11u#,cap_height#,0);
138 italcorr max(h#*slant-.2w#,.2h#*slant)+.5u#;
139 adjust_fit(0,.1w#); pickup cal.nib;
140 lft x1=lft x3=0; top y1=h+o; bot y3=-o; z2=.6[z3,z1]+bend;
141 draw z1-cal.extension--flex(z1,z2,z3); % stem
142 pickup light_cal.nib;
143 rt x4=.9w; x5=x4-.1w; x7=.8w; rt x8=1.1w;
144 y4=.9h; top y5=h+o; bot y7=-o; y8=.2h-o;
145 (lft z6)t_=z2.t_+penoffset up of pen_[cal.nib];
146 draw z4{up}...{left}z5..tension atleast 2..{down}z6
147 ..tension atleast 3 and atleast 2..z7{right}...{up}z8; % diagonals
148 math_fit(.5u#,.2h#*slant+.5u#); labels(1,2,3,4,5,6,7,8);
149 endchar;
150
151 cmchar "Calligraphic Lambda";
152 beginchar(hex"8B",14.4u#,cap_height#,0);
153 italcorr .5u#;
154 adjust_fit(-.05w#,0); pickup cal.nib;
155 lft x5=.54w; x7=.9w;
156 top y5=h+.4cap_curve; bot y7=bot_flourish_line;
157 z6=.3[z7,z5]-bend;
158 pickup tilted.nib;
159 lft x1=.05w; x2=.2w; rt x4=x5;
160 y1=y2+.1h; bot y2=bot_flourish_line; top y4=h+.4cap_curve;
161 y3=y6; z3=whatever[z2,z4]+2bend;
162 draw\\(z1..tension 1.2..{right}z2) softjoin flex(z2,z3,z4); % left diagonal
163 pickup cal.nib;
164 erase fill\\(0,bot y5)--(w,bot y5)--(w,top y5)--(0,top y5)--cycle;
165 draw flex(z5,z6,z7) softjoin (z7--z7+cal.extension); % right diagonal
166 math_fit(.5u#-.1cap_height#*slant,ic#); labels(1,2,3,4,5,6,7);
167 endchar;
168
169 cmchar "Calligraphic Mu";
170 beginchar(hex"8C",19.8u#,cap_height#,0);
171 italcorr max(h#*slant-u#,.75cap_curve#)+.5cap_curve#+.5u#;
172 adjust_fit(-.1w#,0); pickup med_cal.nib;
173 (z20)t_=(z5)t_+penoffset down of currentpen
174 =(z4)t_+penoffset down of pen_[tilted.nib];
175 z6=.3[z7,z5]-bend; z9=.3[z8,z10]+.5bend; z12=.3[z13,z11]-bend;
176 x7=.5[x2,x13]; bot y7=.05h; top y5=h+o;
177 (z0)t_=(z7)t_+penoffset right of currentpen
178 =(z8)t_+penoffset right of pen_[tilted.nib];
179 pickup cal.nib;
180 (z30)t_=(z11)t_+penoffset up of currentpen
181 =(z10)t_+penoffset up of pen_[tilted.nib];
182 x13=w; bot y13=bot_flourish_line;
183 pickup tilted.nib;
184 lft x1=.1w; x2=.2w; x4=.2[x2,x7]; x10=.8[x7,x13];
185 y1=.05h+y2; bot y2=bot_flourish_line; top y10=h+o;
186 z3=whatever[z2,z4]+2bend; y3=y6;
187 draw\\(z1..tension1.2..{right}z2) softjoin flex(z2,z3,z4); % left stem
188 erase fill z20--(.5w,y20)--(.5w,top y4)--(x20-4u,top y4)--cycle;
189 pickup med_cal.nib;
190 draw flex(z5,z6,z7); % left diagonal
191 pickup cal.nib;
192 draw flex(z11,z12,z13) softjoin (z13--z13+cal.extension); % right stem
193 pickup tilted.nib;
194 path p; p=flex(z8,z9,z10);
195 erase fill z0--(x0,y0-.5h)--(x9,y0-.5h)--subpath(1,0) of p--cycle;
196 erase fill z30--(x30,y30+.5h)--(x9,y30+.5h)--subpath(1,2) of p--cycle;
197 draw p; % right diagonal
198 math_fit(.5u#-.05h#*slant,ic#);
199 labels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,20,30);
200 endchar;
201
202 cmchar "Calligraphic Nu";
203 beginchar(hex"8D",9u#,cap_height#,0);
204 italcorr h#*slant+.5u#;
205 adjust_fit(2u#,2.5u#); pickup med_cal.nib;
206 (z0)t_=(z5)t_+penoffset down of currentpen
207 =(z4)t_+penoffset down of pen_[tilted.nib];
208 (z20)t_=(z7)t_+penoffset up of currentpen
209 =(z8)t_+penoffset up of pen_[tilted.nib];
210 z6=.3[z7,z5]-bend; rt z7=(w,0); top y5=h+o;
211 pickup tilted.nib;
212 lft x1=x2-2u; x2=-u; x4=0; x10=w; rt x11=w+3u;
213 y1=y2+.05h; bot y2=bot_flourish_line;
214 y3=y6; z3=whatever[z2,z4]+2bend;
215 y10=h; z9=.7[z8,z10]-.5bend; bot y11=h;
216 draw\\(z1..tension1.2..{right}z2) softjoin flex(z2,z3,z4); % left stem
217 draw flex(z8,z9,z10)...{right}z11; % right stem
218 pickup med_cal.nib;
219 erase fill z0--(.5w,y0)--(.5w,1.5h)--(x0-4u,1.5h)--cycle;
220 erase fill z20--(.5w,y20)--(.5w,-.5h)--(x20+4u,-.5h)--cycle;
221 draw flex(z5,z6,z7); % diagonal
222 math_fit(.5u#-.05h#*slant,.3h#*slant);
223 labels(0,1,2,3,4,5,6,7,8,9,10,11,20);
224 endchar;
225
226 cmchar "Calligraphic Omicron";
227 beginchar(hex"8F",12.6u#,cap_height#,0);
228 italcorr .7h#*slant+.5u#;
229 adjust_fit(0,0); pickup cal.nib;
230 x1=.3w; lft x2=0; x3=.5w; rt x4=w; x5=.6w; lft x6=.27w;
231 top y1=top y5=h+o; y2=.55h; bot y3=-o; y4=.5h; y6=y2;
232 path p; p=z1...z2{down}...z3{right}...z4{up}...z5{left}...{down}z6;
233 draw subpath(0,4.8) of p; % bowl
234 math_fit(.5u#-.3h#*slant,ic#-.5u#);
235 labels(1,2,3,4,5,6);
236 endchar;
237
238 %
239 % a revoir
240 %
241
242 cmchar "Calligraphic Pi";
243 beginchar(hex"90",13u#,cap_height#,0);
244 italcorr h#*slant+.5u#;
245 adjust_fit(0,-.5u#);
246 pickup heavy_cal.nib;
247 x1=x3-0.03w; x3=.3w;
248 lft x4=0; x5=.25w; x6=.85w; rt x7=1.05w;
249 top y1=h; y4=3/4h; top y5=top y6=h; top y7=1.05h;
250 draw z4{curl 2}...z5{right}...z6{right}...{up}z7; % arms
251 pickup tilted.nib;
252 bot y3=-.1h;
253 z2=.3[z3,z1]+bend;
254 top y0=y1; x0=x2;
255 draw z0---z2...z3; % left stem
256 pickup cal.nib;
257 x8 = 0.75w; x10 = 0.9w;
258 top y8=y1; bot y10=bot_flourish_line;
259 z9=.3[z10,z8]-bend;
260 draw flex(z8,z9,z10) softjoin (z10--z10+cal.extension); % right stem
261 math_fit(.5u#-5/7h#*slant,-u#); labels(1,2,3,4,5,6,7);
262 endchar;
263
264 cmchar "Calligraphic Rho";
265 beginchar(hex"91",9u#,cap_height#,0);
266 italcorr .8h#*slant+.5u#;
267 adjust_fit(4u#,0); pickup cal.nib;
268 lft x1=lft x3=0; x4=x6=.3[x1,x5]; rt x5=w;
269 top y1=top y4=h; y3=-o; y5=.55[y6,y4]; bot y6=.3h;
270 z2=.5[z3,z1]+bend;
271 draw flex(z1,z2,z3); % stem
272 draw z1{left}...{down}z1-flourish_change; % swash
273 draw z1---z4...z5{down}...{left}z6; % lobe
274 math_fit(.5u#-.8h#*slant,.5ic#); labels(1,2,3,4,5,6);
275 endchar;
276
277 cmchar "Calligraphic Tau";
278 beginchar(hex"93",13u#,cap_height#,0);
279 italcorr h#*slant+.5u#;
280 adjust_fit(0,-.5u#); pickup heavy_cal.nib;
281 x1=.47w; x3=.5w; lft x4=0; x5=.25w; x6=.85w; rt x7=1.05w;
282 top y1=h; bot y3=-.1h; y4=3/4h; top y5=top y6=h; top y7=1.05h;
283 z2=.3[z3,z1]+bend;
284 top y0=y1; x0=x2;
285 z8=(2u,.2h);
286 draw z0---z2...z3; % stem
287 draw z4{curl 2}...z5{right}...z6{right}...{up}z7; % arms
288 math_fit(.5u#-5/7h#*slant,-u#); labels(1,2,3,4,5,6,7);
289 endchar;
290
291 cmchar "Calligraphic Chi";
292 beginchar(hex"96",11.4u#,cap_height#,0);
293 italcorr h#*slant+.5u#;
294 adjust_fit(0,0); pickup cal.nib;
295 lft x1=.08w; lft x2=.2w; x4-x3=x2-x1; rt x4=w;
296 h-y1=y4=1/9h; top y2=h; bot y3=0;
297 draw z1{up}....z2{right}
298 ... .2[z2+(.1w,0),z3-(.1w,0)]---.8[z2+(.1w,0),z3-(.1w,0)]
299 ...{right}z3....{up}z4; % left diagonal
300 x5=x6-u; rt x6=w; lft x7=0; x8=x7+u;
301 top y5=h; y6=.85h; y7=h-y6; bot y8=0;
302 draw z5{right}...z6{down}
303 ..tension atleast 3..{down}z7...{right}z8; % right diagonal
304 math_fit(.5u#,1/7h#*slant+.5u#); labels(1,2,3,4,5,6,7,8);
305 endchar;
306
307 %
308 % LOWERCASE
309 %
310
311 let math_fit = ignore_math_fit;
312 math_fitting := false;
313
314 % just look at italic corection and math fitting
315 cmchar "Calligraphic alpha";
316 beginchar(hex"A1", 11u#, x_height#, 0);
317 italcorr max(0.15x_height#*slant+0.5lower_cal_width#,
318 x_height#*slant+0.5lower_cal_width#-2u#) if math_fitting: -0.5u# fi;
319 adjust_fit(0, 0);
320 %
321 pickup lower_cal.nib;
322 top y1 = vround 0.98h;
323 bot y2 = bot y5 = -oo;
324 top y4 = x_height+oo;
325 y3 = 0.5[y2, y4];
326 y6 = good.y 7/8[x_height, y5];
327 x1 = x5 = good.x(w-2.5u);
328 x3 = good.x 1.25u;
329 x6 = w; x2 = x4 = 0.5[x3, 6.5u];
330 draw z1{down}...z2 left_to_up z3 up_to_right z4...z5{right}...z6;
331 %
332 math_fit(-.3x_height#*slant+0.5curve#-u#, ic#);
333 labels(1, 2, 3, 4, 5, 6);
334 endchar;
335
336 % just look at italic corection and math fitting
337 cmchar "Calligraphic beta";
338 beginchar(hex"A2", 8u#, asc_height#, desc_depth#);
339 italcorr max(.8h#*slant-.1w#, .5x_height#*slant)+.5u#;
340 adjust_fit(0, 0);
341 % see es-zet
342 pickup lower_cal.nib;
343 x2-x1=hround 0.5u; x2 = good.x 1.5u; x4 = .6[x2, x5];
344 x5 = good.x(0.9w-1.25u); lft x6 = x2; x7 = good.x(w-1.25u);
345 x8 = .4[x9, x7]; lft x9 = rt x2;
346 bot y1 = -d-eps; y2 = 0.5x_height;
347 top y4 = h+oo; y5 = .6[y6, y4]; y6 = .55h; y7 = .45[y8, y6];
348 bot y8 = -oo; y9 = .1h;
349 % draw z1-cal.extension--flex(z1, z2, z3); % stem
350 draw z1...z2{up}...z4...z5{down}...{dir 200}z6{dir 10}
351 ...z7{down}...z8{left}...z9; % lobes
352 %
353 math_fit(.5u#, .3h#*slant+.5u#);
354 labels(1, 2, 3, 4, 5, 6, 7, 8, 9);
355 endchar;
356
357 % just look at math fitting
358 cmchar "Calligraphic gamma";
359 beginchar(hex"A3", 10u#, x_height#, desc_depth#);
360 italcorr h#*slant;
361 adjust_fit(0, 0);
362 pickup lower_cal.nib;
363 x1 = good.x 0; x3 = good.x(w-3.4u);
364 x2 = max(1.25u, 0.5[x1, x3]);%0.5[x1, x3];
365 x5 = good.x 3.8u;
366 x4=2/3[x3, x5];
367 rt x6 = hround(w-0.5u);
368 top y2 = x_height+oo; y1 = good.y 7/8[0, y2]; bot y4 = -d-eps;
369 y3 = y5 = 0.825[y2, y4]; top y6=vround 0.98 h;
370 draw z1...z2{right}... z3 down_to_left z4 left_to_up z5...z6{up};
371 math_fit(.5u#, .3h#*slant+.5u#);
372 labels(1, 2, 3, 4, 5, 6);
373 endchar;
374
375 cmchar "Calligraphic epsilon";
376 beginchar(hex"A5", 8u#,x_height#,0);
377 italcorr max(h#*slant-.1w#,.2h#*slant)+.5u#;
378 adjust_fit(0,0); pickup lower_cal.nib;
379 rt x2 = hround(w-1.1u); x3=.6[x4,x2]; x4=good.x(1.5u);
380 x5=.7[x6,x2]; x6= good.x 1.25u; x7=.5[x6,x8]; x8 = good.x w;
381 x1=good.x 0.6[x5, x2];
382 %y1=y2-.1h;
383 y2=.9h+oo; top y3=h+oo; y4=.5[y5,y3];
384 y5=good.y .55h; y6=.5[y5,y7]; bot y7=-oo; y8=good.y 1/4x_height;
385 y1 = good.y 0.6[y5, y3];
386 draw\\(z1{2(x2-x1),y2-y1}...z2)
387 softjoin (z2...z3{left}...z4 down_to_right z5); % upper arc
388 draw z5{left}...z6 down_to_right z7...z8; % lower arc
389 math_fit(.5u#-.2h#*slant,.2h#*slant+.5u#);
390 labels(1,2,3,4,5,6,7,8);
391 endchar;
392
393 cmchar "The letter eta";
394 beginchar(hex"A7", 9u#, x_height#, desc_depth#);
395 italcorr max(0.15x_height#*slant+0.5lower_cal_width#,
396 0.75x_height#*slant+0.5lower_cal_width#);
397 adjust_fit(0, 0);
398 %
399 pickup lower_cal.nib;
400 x1 = 0; x3 = x4 = good.x 2.5u; bot y4 = -oo;
401 x6 = x7 = good.x(w-1.5u); bot y7 = -d-eps;
402 draw hook_in(1, 2, 3)---z4;
403 draw ital_arch(4, 5, 6)...z7{down};
404 %
405 math_fit(-2/3x_height#*slant+0.5hair#+0.5u#, ic#);
406 labels(1, 2, 3, 4, 5, 6, 7, 8);
407 endchar;
408
409 cmchar "The letter theta";
410 beginchar(hex"A8", 8u#, asc_height#, 0);
411 italcorr .7asc_height#*slant+0.5lower_cal_width#-u#
412 if math_fitting: -0.5u# fi;
413 adjust_fit(0, 0);%(-0.25u#, -0.25u#);
414 %
415 pickup lower_cal.nib;
416 top y1 = h+oo; bot y3 = -oo; y2 = y4 = 0.5[y1, y3];
417 x2 = good.x 1.25u; x4 = good.x(w-1.25u); x1 = x3 = 0.5[x2, x4];
418 z5 = z1; x6 = good.x 0.2[x2, x4]; x7 = 0.7[x2, x4];
419 y6 = 0.8[y3, y5]; y7 = good.y 0.43[y3, y5];
420 save p; path p; p = z1 left_to_down z2 down_to_right
421 z3 right_to_up z4 up_to_left z5 left_to_down z6...z7{right}...z4;
422 draw subpath (1.75, 12) of p;
423 math_fit(-.3x_height#*slant+0.5curve#-u#, ic#);
424 labels(1, 2, 3, 4, 5, 6, 7);
425 endchar;
426
427 cmchar "The letter theta (variant)";
428 beginchar(hex"BA", 9.5u#, asc_height#, 0);
429 italcorr .7asc_height#*slant+0.5lower_cal_width#-u#
430 if math_fitting: -0.5u# fi;
431 adjust_fit(0, 0);%(-0.25u#, -0.25u#);
432 %
433 pickup lower_cal.nib;
434 bot y5 = -oo; top y7 = h+oo; y6 = 0.5[y5, y7];
435 y4 = 0.7[y5, 0.57x_height];
436 y8 = 0.8[y5, y7]; y9 = good.y 0.43[y5, y7];
437 top y10 = x_height+oo; y10 := good.y 7/8[0, y10];
438 x1 = 0; x3 = good.x 2.5u;
439 x6 = good.x(w-1.75u);
440 x5 = x7 = 0.5[x3, x6];
441 x8 = good.x 0.2[x3, x6]; x9 = 0.75[x3, x6]; x10 = good.x w;
442 draw hook_in(1,2,3)...
443 z5{right} ... z6 up_to_left z7 left_to_down z8...z9{right}...z10;
444 math_fit(-.3x_height#*slant+0.5curve#-u#, ic#);
445 labels(1,2,3,4,5,6,7,8,9,10);
446 endchar;
447
448 cmchar "The letter kappa";
449 beginchar(hex"A9", 9u#, x_height#, 0);
450 italcorr max(0.2x_height#*slant+0.1w#,
451 0.95x_height#*slant-0.1w#+0.5u#);
452 adjust_fit(0, 0);
453 %
454 pickup lower_cal.nib;
455 top y1 = h; bot y2 = -oo; x1 = x2 = good.x 1.5u;
456 draw z1-cal.extension--z1--z2;
457 %
458 rt x4 = .9w; x5 = x4-.1w; x7 = .8w; rt x8 = 1.1w;
459 y4 = .9x_height; top y5 = x_height+oo; bot y7 = -oo; y8 = .2x_height-oo;
460 (lft z6)t_ = (x2, 0.4x_height).t_+penoffset up of pen_[lower_cal.nib];
461 draw z4{up}...{left}z5..tension atleast 2..{down}z6
462 ..tension atleast 3 and atleast 2..z7{right}...{up}z8; % diagonals
463 %
464 math_fit(0, 1/3x_height#*slant+0.5hair#+0.5u#);
465 labels(1, 2, 3, 4, 5, 6, 7, 8);
466 endchar;
467
468 cmchar "Calligraphic mu";
469 beginchar(hex"AB", 9u#, x_height#, desc_depth#);
470 italcorr max(0.15x_height#*slant+0.5lower_cal_width#,
471 x_height#*slant+0.5lower_cal_width#-2u#);
472 adjust_fit(0, 0);
473 %
474 pickup lower_cal.nib;
475 x1 = x2 = x3 = good.x 1.5u;
476 x4 = 0.5[x2, x5]; x5 = x6 = x7 = good.x(w-2.5u); x9 = w;
477 bot y1 = -d-eps; top y2 = h;
478 y3 = 0.7[y4, y5]; bot y4 = -oo; y5 = 0.57h; top y6 = h;
479 draw z1..z2;
480 draw z3 down_to_right z4...z5{up};
481 draw z6..hook_out(7, 8, 9);
482 %
483 math_fit(-2/3x_height#*slant+0.5hair#+0.5u#, ic#);
484 labels(1, 2, 3, 4, 6, 7, 8, 9);
485 endchar;
486
487 %cmchar "Calligraphic nu";
488 % beginchar(hex"AC", 9u#, x_height#, 0);
489 % italcorr .7x_height#*slant+0.5lower_cal_width#-u#
490 % if math_fitting: -0.5u# fi; % same as "o"
491 % adjust_fit(0, 0);
492 % %
493 % pickup lower_cal.nib;
494 % x1 = good.x 0; x2 = 0.5[x1,x3]; x3 = x4-.25(y3-y4);
495 % x4 = good.x 0.5w; x5 = good.x(w-1.25u); x6 = good.x(w-2u);
496 % top y2 = x_height+oo; y1 = good.y 7/8[0, y2];
497 % y3 = .57x_height;%3/4x_height;
498 % bot y4 = -oo; y5 = 0.57h; top y6 = h+oo;
499 % draw z1...z2{right}...z3---z4;
500 % draw z4{(x5-x4), 1/3(y5-y4)}...z5{up}...z6;
501 % %
502 % math_fit(-2/3x_height#*slant+0.5hair#+0.5u#, ic#);
503 % labels(1, 2, 3, 4, 5, 6);
504 % endchar;
505
506 cmchar "Calligraphic nu";
507 beginchar(hex"AC", 8u#, x_height#, 0);
508 italcorr 0.8x_height#*slant;
509 adjust_fit(0, 0.5u#);
510 %
511 pickup lower_cal.nib;
512 x1 = 0; top y1 = h; z3 = (.48w, 0);
513 z0.t_ = z2.t_+penoffset down of currentpen
514 = z3.t_+penoffset down of pen_[tilted.nib];
515 draw z1{right}..tension atleast 1 and infinity..z2; % left diagonal
516 pickup tilted.nib;
517 rt x4 = w; x5 = x4-.2w; top y4 = .8h; top y5 = h;
518 path p; p = z3..tension atleast 3 and 1..{up}z4;
519 erase fill z0--(x0, y0-0.5h)--(x4, y0-0.5h)--(x4+eps, y4)--reverse p--cycle;
520 draw p...{left}z5; % right diagonal
521 %
522 math_fit(-2/3x_height#*slant+0.5hair#+0.5u#, 2/3ic#);
523 labels(0, 1, 2, 3, 4, 5);
524 endchar;
525
526 cmchar "The letter omicron";
527 beginchar(hex"AF", 9u#, x_height#, 0);
528 italcorr .7x_height#*slant+0.5lower_cal_width#-u#
529 if math_fitting: -0.5u# fi;
530 adjust_fit(0, 0);%(-0.25u#, -0.25u#);
531 %
532 pickup lower_cal.nib;
533 top y1 = h+oo; bot y3 = -oo; y2 = y4 = 0.5[y1, y3];
534 x2 = good.x 1.25u; x4 = good.x(w-1.25u); x1 = x3 = 0.5[x2, x4];
535 draw z1 left_to_down z2 down_to_right
536 z3 right_to_up z4 up_to_left z1;
537 math_fit(-.3x_height#*slant+0.5curve#-u#, ic#);
538 labels(1, 2, 3, 4);
539 endchar;
540
541 cmchar "Calligraphic pi";
542 beginchar(hex"B0", 9u#, x_height#, 0);
543 italcorr x_height#*slant+0.5u# if math_fitting: -0.5u# fi;
544 adjust_fit(0, 0);
545 %
546 pickup lower_cal.nib;
547 top y2 =top y4= h; y2-y1 = vround 0.2h; top y3 = 0.98h;
548 x1 = good.x u; x2 = 3.5u; x3=good.x(w-2.5u); rt x4=w;
549 draw z1...z2{right}...z3{right}...z4;
550 top y9 = vround 0.98h; x9 = x10 = good.x(w-2.5u); x12 = w;
551 draw z9..hook_out(10, 11, 12);
552 bot y6=-oo; x5=0; x6=0.5[x5,x2]; y5-y6=vround 0.1h;
553 z7=0.3[z6,z2];
554 draw z5...z6{right}...z2{up};
555 math_fit(-.3x_height#*slant+0.5curve#-u#, ic#);
556 labels(1, 2, 3, 4, 5, 6, 7, 8,9,10,11,12);
557 endchar;
558
559 cmchar "The letter rho";
560 beginchar(hex"B1", 8u#, x_height#, desc_depth#);
561 italcorr .7x_height#*slant+0.5lower_cal_width#-u#
562 if math_fitting: -0.5u# fi;
563 adjust_fit(0, 0);%(-0.25u#, -0.25u#);
564 % like letter "b"
565 pickup lower_cal.nib;
566 bot y1 = -d-eps; y2 = 0.5x_height; bot y5 = -oo;
567 y4 = 0.5x_height; top y3 = x_height+oo;
568 x1 = x2 = good.x 1.5u; x3 = 0.5[x2, x4];
569 x4 = good.x(w-1.25u); x5 = 0.5[x2, x4];
570 draw z1..z2{up}
571 ...z3{right}...z4{down}...z5{left}...z2{up};
572 %
573 math_fit(-.3x_height#*slant+0.5curve#-u#, ic#);
574 labels(0, 1, 2, 3, 4, 5);
575 endchar;
576
577 cmchar "The letter rho (variant)";
578 beginchar(hex"BD", 8u#, x_height#, desc_depth#);
579 italcorr .7x_height#*slant+0.5lower_cal_width#-u#
580 if math_fitting: -0.5u# fi;
581 adjust_fit(0, 0);%(-0.25u#, -0.25u#);
582 % like letter "b"
583 pickup lower_cal.nib;
584 bot y1 = -d-eps; y2 = 0.5x_height; bot y5 = -oo;
585 y4 = 0.5x_height; top y3 = x_height+oo;
586 rt x1 = w; x2 = good.x 1.5u; x3 = 0.5[x2, x4];
587 x4 = good.x(w-1.25u); x5 = 0.5[x2, x4];
588 draw z1...(x5, good.y 0.25[y1, y5]){left}...z2{up}
589 ...z3{right}...z4{down}...z5{left}...z2{up};
590 %
591 math_fit(-.3x_height#*slant+0.5curve#-u#, ic#);
592 labels(0, 1, 2, 3, 4, 5);
593 endchar;
594
595 cmchar "Calligraphic upsilon";
596 beginchar(hex"B4", 9u#, x_height#, 0);
597 italcorr .7x_height#*slant+0.5lower_cal_width#-u#
598 if math_fitting: -0.5u# fi; % same as "o"
599 adjust_fit(0, 0);
600 %
601 pickup lower_cal.nib;
602 x1 = 0; x3 = good.x(2.80u); x4 = good.x(2.3u);
603 x5 = 0.5[x4, x6]; x6 = good.x(w-1.25u); x7 = good.x(w-2u);
604 y4 = 0.7[y5, y6]; bot y5 = -oo; y6 = 0.57h; top y7 = h+oo;
605 draw hook_in(1, 2, 3)...z4 down_to_right z5...z6{up}...z7;
606 %
607 math_fit(-2/3x_height#*slant+0.5hair#+0.5u#, ic#);
608 labels(1, 2, 3, 4, 5, 6, 7);
609 endchar;
610
611 cmchar "The letter phi";
612 beginchar(hex"B5", 11u#, asc_height#, asc_depth#);
613 italcorr .7x_height#*slant+0.5lower_cal_width#-u#
614 if math_fitting: -0.5u# fi; % same as "o"
615 adjust_fit(0, 0);%(-0.25u#, -0.25u#);
616 %
617 pickup lower_cal.nib;
618 top y1 = x_height+oo; bot y3 = -oo; y2 = y4 = 0.5[y1, y3];
619 x2 = good.x 1.25u; x4 = good.x(w-1.25u); x1 = x3 = 0.5[x2, x4];
620 draw z1 left_to_down z2 down_to_right
621 z3 right_to_up z4 up_to_left z1;
622 pickup fine_cal.nib;
623 x5= x6 =good.x 0.5w; top y5 =h+eps; bot y6=-d-eps;
624 draw z5..z6;
625 math_fit(-.3x_height#*slant+0.5curve#-u#, ic#);
626 labels(1, 2, 3, 4, 5, 6);
627 endchar;
628
629 cmchar "The letter phi (variant)";
630 beginchar(hex"BF", 11u#, x_height#, desc_depth#);
631 italcorr .7x_height#*slant+0.5lower_cal_width#-u#
632 if math_fitting: -0.5u# fi;
633 adjust_fit(0, 0);%(-0.25u#, -0.25u#);
634 %
635 pickup lower_cal.nib;
636 top y1 = h+oo; bot y3 = -oo; y2 = y4 = 0.5[y1, y3];
637 x2 = good.x 1.25u; x4 = good.x(w-1.25u); x1 = x3 = 0.5[x2, x4];
638 x5 = 0.5[x6,x4]; x6 = x7 = good.x 0.5[x2, x4];
639 y5 = y1; y6 = 0.5[y3, y5]; bot y7 = -d-eps;
640 save p; path p; p = z1 left_to_down z2 down_to_right
641 z3 right_to_up z4 up_to_left z5 left_to_down z6..z7;
642 draw subpath (.75, 12) of p;
643 math_fit(-.3x_height#*slant+0.5curve#-u#, ic#);
644 labels(1, 2, 3, 4, 5, 6, 7);
645 endchar;
646
647 cmchar "Calligraphic chi";
648 beginchar(hex"B6",11u#,x_height#,desc_depth#);
649 italcorr h#*slant+.5u#;
650 adjust_fit(0,0); pickup cal.nib;
651 lft x1=.08w; lft x2=.2w; x4-x3=x2-x1; rt x4=w;
652 h-y1=d+y4=1/9(h+d); top y2=h; bot y3=-d-eps;
653 draw z1{up}....z2{right}
654 ... .2[z2+(.1w,0),z3-(.1w,0)]---.8[z2+(.1w,0),z3-(.1w,0)]
655 ...{right}z3....{up}z4; % left diagonal
656 x5=x6-u; rt x6=w; lft x7=0; x8=x7+u;
657 top y5=h; y6=.85[-d,h]; y7=h-d-y6; bot y8=-d-eps;
658 draw z5{right}...z6{down}
659 ..tension atleast 3..{down}z7...{right}z8; % right diagonal
660 math_fit(.5u#,1/7h#*slant+.5u#); labels(1,2,3,4,5,6,7,8);
661 endchar;
662
663 cmchar "Calligraphic psi";
664 beginchar(hex"B7", 11u#, asc_height#, desc_depth#);
665 italcorr .7x_height#*slant+0.5lower_cal_width#-u#
666 if math_fitting: -0.5u# fi; % same as "o"
667 adjust_fit(0, 0);
668 %
669 pickup lower_cal.nib;
670 x1 = 0; x3 = good.x(2.80u); x4 = good.x(2.3u);
671 x5 = 0.5[x4, x6]; x6 = good.x(w-1.25u); x7 = good.x(w-2u);
672 y4 = 0.7[y5, y6]; bot y5 = -oo; y6 = 0.57x_height; top y7 = x_height+oo;
673 draw hook_in(1, 2, 3)...z4 down_to_right z5...z6{up}...z7;
674 pickup fine_cal.nib;
675 x8 = x9 = good.x(0.5[2.5u, w-1.5u]); top y8 = h+eps; bot y9 = -d-eps;
676 draw z8..z9;
677 %
678 math_fit(-2/3x_height#*slant+0.5hair#+0.5u#, ic#);
679 labels(1, 2, 3, 4, 5, 6, 7, 8, 9);
680 endchar;
681
682 endinput.
683
684
685 %
686 % GREEK LOWERCASE
687 %
688
689 apprr:=apprl:=hround u;
690 beginchar(oct"241", 10u#, x_height#, 0);
691 "The letter alpha";
692 italcorr x_height#*slant-0.5u#;
693 pickup lower_cal.nib;
694 top y1 = h+eps; top y5 = h+u_o; bot y2 = -d_o; bot y6 = -eps;
695 0.5[y3, y4] = 0.5[y2, y5]; y4-y3 = loop_squareness*(y5-y2);
696 lft x3 = lft x4 = apprl-ho; rt x1 = rt x6 = w-apprr+eps;
697 x2 = x5 = 0.375[x3, x6];
698 draw z1 hang_to z2 left_to_up z3..z4 up_to_right z5
699 hook_to z6; labels(1, 2, 3, 4, 5, 6);
700 math_fit(0, ic#);
701 endchar;
702
703 beginchar(oct"242", 8u#, asc_height#, desc_depth#);
704 "The letter beta";
705 italcorr 0.8asc_height#*slant-u#+ho#;
706 pickup lower_cal.nib;
707 bot y1 = -d; top y5 = x_height; top y3 = h+u_o; bot y7 = -d_o;
708 0.5[y4', y4] = 0.5[y5, y3]; 0.5[y6', y6] = 0.5[y7, y5]; y8 = hook_h;
709 y4-y4' = loop_squareness*(y3-y5);
710 y6-y6' = loop_squareness*(y5-y7); y2 = y4';
711 lft x1 = apprl; x1 = x2 = x8; rt x4+hround 0.5u = rt x6 = w-apprr+ho;
712 x3 = 0.55[x2, x4]; x7 = 0.5[x8, x6]; lft x5 = rt x1+hround u;
713 x4 = x4'; x6 = x6';
714 draw z1..z2 up_to_right z3 right_to_down z4..z4' down_to_left z5
715 &z5 right_to_down z6..z6' down_to_left z7 left_to_up z8;
716 labels(1, 2, 3, 4, 4', 5, 6, 6', 7, 8);
717 math_fit(0, ic#);
718 endchar;
719
720 beginchar(oct"243", 8u#, x_height#, desc_depth#);
721 "The letter gamma";
722 italcorr x_height#*slant;
723 pickup lower_cal.nib; numeric a; a = 0.60;
724 top y1 = top y7 = h+eps; bot y4 = -d-d_o; y3 = y5 = 0.2[y4, y1];
725 lft x1 = apprl-hround 0.5u; rt x7 = w-apprr+hround 0.5u;
726 x5-x1 = x7-x3 = hround 1.5u; x4 = 0.5[x3, x5];
727 x2 = a[x1, x3]; x6 = a[x7, x5]; y2 = a[y3, y1]; y6 = a[y5, y7];
728 draw z1...z2{z3-z1}...z3 down_to_left
729 z4 left_to_up z5...z6{z7-z5}...z7;
730 labels(1, 2, 3, 4, 5, 6, 7);
731 math_fit(0, ic#);
732 endchar;
733
734 beginchar(oct"244", 8u#, asc_height#, 0);
735 "The letter delta";
736 italcorr 0.9asc_height#*slant-u#;
737 pickup lower_cal.nib;
738 top y1 = top y2 = h; y5 = good.x x_height; bot y8 = -d_o;
739 rt x7-ho = rt x1+hround 0.5u = w-apprr;
740 lft x9+ho = lft x3+eps = apprl;
741 x5 = x8 = 0.5[x9, x7]; x2 = 0.4[x3, x1];
742 slope := -h/17u;
743 ellipse_set(2, 3, 4, 5); ellipse_set(8, 7, 6, 5);
744 y7 = y9; y10 = y6; x6-x5 = x5-x10;
745 draw z1{x2-x1, 2(y2-y1)}
746 ..z2 left_to_down z3 ...z4---z6...z7
747 down_to_left z8 left_to_up z9...z10---z5;
748 labels(1, 2, 3, 4, 5, 6, 7, 8, 9, 10);
749 math_fit(0, ic#);
750 endchar;
751
752 beginchar(oct"245", 7u#, x_height#, 0);
753 "The letter epsilon";
754 italcorr x_height#*slant-0.5u#;
755 pickup lower_cal.nib;
756 top y1 = h; bot y4 = -d_o; y6 = y7 = good.y 0.51[y4, y1];
757 y2-y3 = loop_squareness*(y1-y4); y5 = good.y 0.15h;
758 y6 = 2/3[y3, y2]; x4 = 0.55[x2, x5];
759 rt x1 = rt x7+hround 0.5u = rt x5-hround 0.5u = w-apprr;
760 lft x2 = apprl-ho; x2 = x3 = x6;
761 draw z1 left_to_down z2..z3 down_to_right z4 hook_to z5;
762 draw z6..z7; labels(1, 2, 3, 4, 5, 6, 7);
763 math_fit(0, ic#);
764 endchar;
765
766 % ???
767
768 beginchar(oct"245", 7u#, x_height#, 0);
769 "The letter variant epsilon";
770 italcorr x_height#*slant-0.5u#;
771 pickup lower_cal.nib;
772 top y2 = h+u_o; bot y6 = -d_o;
773 y3 = 0.5[y2, y4]; y5 = 0.5[y4, y6]; y7 = hook_h;
774 y1 = good.y 0.9[y6, y2]; y4 = good.y 0.5[y7, y1];
775 rt x1 = rt x4+hround 1.5u = rt x7-hround 0.5u = w-apprr;
776 lft x3 = lft x5 = apprl-ho; x2 = 0.6[x3, x1]; x6 = 0.5[x5, x7];
777 draw z1{x2-x1, 3(y2-y1)}
778 ...z2 left_to_down z3 down_to_right z4
779 &z4 left_to_down z5 down_to_right z6 hook_to z7;
780 labels(1, 2, 3, 4, 5, 6, 7);
781 math_fit(0, ic#);
782 endchar;
783
784 beginchar(oct"246", 8u#, asc_height#, desc_depth#);
785 "The letter zeta";
786 italcorr x_height#*slant-0.5u#;
787 pickup lower_cal.nib;
788 top y1 = h; top y2 = top y3 = top y4 = vround(y1-0.25(h-x_height));
789 bot y6 = bot y7 = 0; bot y9 = -d;
790 y5 = 0.3[y6, y4]; y8 = 0.5[y9, y7];
791 lft x1 = apprl+hround 1.5u; lft x5 = apprl-ho;
792 rt x3 = w-apprr-hround u; rt x8 = w-apprr+ho;
793 x2 = 0.7[x1, x3];
794 x4 = 0.85[x5, x3];
795 x6-x5 = x8-x7 = 0.4(x8-x5);
796 x9 = good.x(0.5[x5, x8]);
797 draw z1 down_to_right z2..z3&z3..z4 left_to_down z5
798 down_to_right z6...z7right_to_down z8 down_to_left z9;
799 labels(range 1 thru 9);
800 math_fit(0, ic#);
801 endchar;
802
803
804
805 % ?
806
807 beginchar(oct"251", 12u#, asc_height#, 0);
808 "The letter variant theta";
809 italcorr 0.7asc_height#*slant-1.5u#+ho#;
810 pickup lower_cal.nib;
811 lft x1 = lft x3-hook_w = apprl-hround 0.5u;
812 x2 = 1/3[x3, x1];
813 rt x5 = lft x3+hround(6u)+ho;
814 x4 = 0.5[apprl, w-apprr]; x6 = 0.5[x3, x5];
815 x7 = good.x 0.2[x3, x5];
816 x9-x8 = 0.5hook_w;
817 rt x9 = w-apprr+hround 0.5u;
818 y1+hook_h = top y2-eps = x_height; bot y4 = -d_o; top y6 = h+u_o;
819 y5 = y8 = good.y 0.5[y4, y6]; y3 = 0.25[y2, y4]; y7 = 0.7[y5, y6];
820 y8-y9 = vround hook_h;
821 draw z1 hang_to z2 right_to_down z3 down_to_right
822 z4 right_to_up z5 up_to_left z6 left_to_down
823 z7 down_to_right z8 right_to_down z9;
824 labels(1, 2, 3, 4, 5, 6, 7, 8, 9);
825 math_fit(0, ic#);
826 endchar;
827
828 beginchar(oct"252", 2.5u#+curve#, x_height#, 0);
829 "The letter iota";
830 italcorr x_height#*slant-2u#;
831 pickup lower_cal.nib; rt x1 = w-apprr-hround 1.5u; top y1 = h+eps;
832 draw right_hook1;
833 math_fit(0, ic#);
834 endchar;
835
836 beginchar(oct"253", 8u#, x_height#, 0);
837 "The letter kappa";
838 italcorr max(0.2x_height#*slant+0.1w#,
839 0.95x_height#*slant-0.1w#+0.5u#);
840 adjust_fit(0, 0);
841 %
842 pickup lower_cal.nib;
843 top y1 = h; bot y2 = -oo; x1 = x2 = good.x 1.5u;
844 draw z1-cal.extension--z1--z2;
845 %
846 rt x4 = .9w; x5 = x4-.1w; x7 = .8w; rt x8 = 1.1w;
847 y4 = .9x_height; top y5 = x_height+oo; bot y7 = -oo; y8 = .2x_height-oo;
848 (lft z6)t_ = (x2, 0.4x_height).t_+penoffset up of pen_[lower_cal.nib];
849 draw z4{up}...{left}z5..tension atleast 2..{down}z6
850 ..tension atleast 3 and atleast 2..z7{right}...{up}z8; % diagonals
851 %
852 math_fit(0, 1/3x_height#*slant+0.5hair#+0.5u#);
853 labels(1, 2, 3, 4, 5, 6, 7, 8);
854 endchar;
855
856 % ?
857
858 beginchar(oct"253", 10u#, x_height#, 0);
859 "The letter variant kappa";
860 italcorr x_height#*slant-0.75u#;
861 pickup lower_cal.nib;
862 top y1 = top y4-u_o = h; bot y3+d_o = bot y6 = 0;
863 y2 = h-y5 = 1/3[y1, y6];
864 lft x1 = apprl-hround 0.5u-eps;
865 rt x6 = w-apprr+hround 0.5u+eps;
866 x3-x1 = x6-x4 = hround 0.75u;
867 x2-x1 = x6-x5 = hround 2.55u+eps;
868 draw z1 right_to_down z2...{z3-z4}z3
869 --z4{z3-z4}...z5 down_to_right z6;
870 labels(1, 2, 3, 4, 5, 6);
871 math_fit(0, ic#);
872 endchar;
873
874 beginchar(oct"254", 8u#, asc_height#, 0);
875 "The letter lambda";
876 % no italic correction
877 pickup lower_cal.nib;
878 top y1 = h+eps; bot y2 = bot y3 = -eps;
879 top y4 = max(x_height, 0.5h);;
880 apprl-lft x3 = rt x2-(w-apprr) = hround 0.5u-eps;
881 x4 = 0.5[x2, x3]; z1 = whatever[z2, z4];
882 draw z1..z2; draw z3..z4; labels(1, 2, 3, 4);
883 math_fit(0, ic#);
884 endchar;
885
886 beginchar(oct"255", 8u#, x_height#, desc_depth#);
887 "The letter mu";
888 italcorr x_height#*slant-1.5u#;
889 pickup lower_cal.nib;
890 top y1a = h+eps; bot y1b = -d-eps; lft x1a = lft x1b = apprl;
891 draw z1a..z1b;
892 x2a = x1a; rt x2c = rt x2d = w-apprr; x2b = 0.5[x2a, x2c];
893 bot y2b = -d_o; top y2d = h+eps;
894 y2a = 0.5[y2d, y2b]; y2c = 2/3[y2d, y2b];
895 draw z2a down_to_right z2b right_to_up z2c..z2d;
896 labels(1a, 1b, 2a, 2b, 2c, 2d);
897 math_fit(0, ic#);
898 endchar;
899
900 beginchar(oct"256", 7u#, asc_height#, 0);
901 "The letter nu";
902 italcorr 0.7asc_height#*slant-0.5u#+ho#;
903 pickup lower_cal.nib;
904 top y1 = x_height+eps;
905 bot y2 = -d_o; top y4 = h+eps; y3 = 0.5[y2, y4];
906 lft x1 = apprl-hround 0.5u; rt x3 = w-apprr+ho;
907 x2 = x4 = good.x 0.5[x1, x3];
908 draw z1--z2{2(x3-x2), y3-y2}...z3{up}
909 ...{x4-x3, (1-superness)*(y4-y3)}z4;
910 labels(1, 2, 3, 4);
911 math_fit(0, ic#);
912 endchar;
913
914 beginchar(oct"257", 8u#, asc_height#, desc_depth#);
915 "The letter xi";
916 italcorr x_height#*slant-.5u#;
917 pickup lower_cal.nib;
918 top y1 = h; top y2 = top y3 = top y4 = vround(y1-0.25(h-x_height));
919 top y6 = top y7 = top y8 = vround 0.5h; bot y10 = bot y11 = 0; bot y13 = -d;
920 y5 = 0.5[y6, y4]; y9 = 0.4[y10, y8]; y12 = 0.5[y13, y11];
921 lft x1 = apprl+hround 1.5u; lft x5 = apprl; lft x9 = apprl-ho;
922 rt x3 = rt x7 = w-apprr-hround u; rt x12 = w-apprr+ho;
923 x2 = 0.7[x1, x3];
924 x4 = 0.85[x5, x3];
925 x6 = 0.7[x5, x7];
926 x8 = 0.8[x9, x7];
927 x10-x9 = x12-x11 = 0.4(x12-x9);
928 x13 = good.x 0.5[x9, x12];
929 draw z1 down_to_right z2..z3&z3..z4 left_to_down z5
930 down_to_right z6..z7&z7..z8 left_to_down z9 down_to_right z10
931 ...z11 right_to_down z12 down_to_left z13;
932 labels(range 1 thru 13);
933 math_fit(0, ic#);
934 endchar;
935
936 beginchar(oct"261", 9u#, x_height#, desc_depth#);
937 "The letter pi";
938 italcorr x_height#*slant;
939 pickup lower_cal.nib;
940 top y1 = h; y1 = y2 = y3 = y5; bot y4 = bot y6 = -eps;
941 lft x1 = apprl-eps-hround 0.5u;
942 rt x2 = w-apprr+eps+hround 0.5u;
943 x3 = x4; x5 = x6; x3-x1 = x2-x5;
944 x3 = good.x 0.25[apprl, w-apprr];
945 draw z1..z2; draw z3..z4; draw z5..z6;
946 labels(1, 2, 3, 4, 5, 6);
947 math_fit(0, ic#);
948 endchar;
949
950 beginchar(oct"262", 8u#, x_height#, desc_depth#);
951 "The letter rho";
952 italcorr 0.7x_height#*slant-0.5u#+ho#;
953 pickup lower_cal.nib; set_loop1(right); draw_loop1(right);
954 bot y2 = -d-eps; x2 = x1c; draw z1c..z2; labels(2);
955 math_fit(0, ic#);
956 endchar;
957
958 beginchar(oct"263", 8u#, x_height#, desc_depth#);
959 "The letter variant rho";
960 italcorr 0.7x_height#*slant-0.5u#+ho#;
961 pickup lower_cal.nib; set_loop1(right); draw_loop1(right);
962 bot y3 = bot y4 = -d; y2 = 0.5[y1c, y3];
963 x2 = x1c; rt x4 = w-apprr+eps; x3 = 0.5[x2, x4];
964 draw z1c..z2 down_to_right z3..z4; labels(2, 3, 4);
965 math_fit(0, ic#);
966 endchar;
967
968 beginchar(oct"264", 9u#, x_height#, 0);
969 "The letter sigma";
970 italcorr x_height#*slant;
971 save loop_right; loop_right = apprr+hround u;
972 pickup lower_cal.nib; set_loop1(both); draw_loop1(both);
973 rt x3 = w-apprr+hround 0.5u+eps; top y3 = h;
974 z2 = 0.5[z1b, z3];
975 draw z1b...z2{(z3-z2) yscaled 2}...z3; labels(2, 3);
976 math_fit(0, ic#);
977 endchar;
978
979 beginchar(oct"265", 7u#, x_height#, comma_depth#);
980 "The letter variant sigma";
981 italcorr x_height#*slant-0.5u#;
982 pickup lower_cal.nib;
983 top y2 = h+u_o; bot y7 = -d-d_o; bot y4 = bot y5 = 0;
984 y2-y1 = vround 0.06h; y8-y7 = vround 0.08h;
985 y3 = 0.45[y4, y2]; y6 = 0.5[y7, y5];
986 lft x3 = apprl-ho; rt x1-eps = rt x6-ho = w-apprr;
987 x2 = 0.7[x3, x1]; x4 = 0.45[x3, x6]; x5 = 0.55[x3, x6];
988 x7 = 0.7[x3, x6]; x8 = good.x x4;
989 draw z1{x2-x1, 2(y2-y1)}
990 ...z2 left_to_down z3 down_to_right z4
991 ...z5right_to_down z6 down_to_left z7 hook_to z8;
992 labels(1, 2, 3, 4, 5, 6, 7, 8);
993 math_fit(0, ic#);
994 endchar;
995
996 beginchar(oct"266", 8u#, x_height#, desc_depth#);
997 "The letter tau";
998 italcorr x_height#*slant;
999 center_stem(3, 4);
1000 top y1 = h; y1 = y2 = y3; bot y4 = -eps;
1001 lft x1 = apprl-eps-hround 0.5u;
1002 rt x2 = w-apprr+eps+hround 0.5u;
1003 draw z1..z2; draw z3..z4;
1004 labels(1, 2, 3, 4);
1005 math_fit(0, ic#);
1006 endchar;
1007
1008 beginchar(oct"267", 8u#, x_height#, 0);
1009 "The letter upsilon";
1010 italcorr x_height#*slant-0.5u#;
1011 pickup lower_cal.nib;
1012 top y1 = top y5 = h+eps; bot y3 = -d_o; y2 = y4 = 0.5[y3, y1];
1013 lft x1 = lft x2 = apprl; rt x4 = rt x5 = w-apprr; x3 = 0.5[x1, x5];
1014 draw z1..z2 down_to_right z3 right_to_up z4..z5;
1015 labels(1, 2, 3, 4, 5);
1016 math_fit(0, ic#);
1017 endchar;
1018
1019 beginchar(oct"270", 10u#, cap_height#, desc_depth#);
1020 "The letter phi";
1021 italcorr 0.7x_height#*slant-0.5u#+ho#;
1022 pickup lower_cal.nib; set_loop1(both); draw_loop1(both);
1023 top y2 = h+eps; bot y3 = -d-eps; x2 = x3 = good.x 0.5[apprl, w-apprr];
1024 draw z2..z3; labels(2, 3);
1025 math_fit(0, ic#);
1026 endchar;
1027
1028 beginchar(oct"271", 10u#, x_height#, desc_depth#);
1029 "The letter variant phi";
1030 italcorr 0.7x_height#*slant-0.5u#+ho#;
1031 pickup lower_cal.nib;
1032 top y1-eps = top y5-u_o = h; bot y3 = -d_o; bot y7 = -d-eps;
1033 0.5[y2, y2'] = 0.5[y3, y5]; y2-y2' = loop_squareness*(y1-y3);
1034 y2 = y4; y2' = y4'; y6 = 2/3[y3, y5];
1035 lft x2 = lft x2' = apprl-ho; rt x4 = rt x4' = w-apprr+ho;
1036 x3 = x6 = x7 = good.x 0.5[x2, x4];
1037 x5 = 1/3[x6, x4]; x1 = good.x 0.65[x2, x6];
1038 draw z1 left_to_down z2..z2' down_to_right z3 right_to_up
1039 z4'..z4 up_to_left z5 left_to_down z6..z7;
1040 labels(1, 2, 2', 3, 4, 4', 5, 6, 7);
1041 math_fit(0, ic#);
1042 endchar;
1043
1044 beginchar(oct"272", 9u#, x_height#, desc_depth#);
1045 "The letter chi";
1046 italcorr x_height#*slant;
1047 pickup lower_cal.nib;
1048 top y1 = top y3 = h+eps; bot y2 = bot y4 = -d-eps;
1049 lft x1+hround 0.25u = lft x4+hround 0.5u = apprl-eps;
1050 rt x2-hround 0.5u = rt x3-hround 0.25u = w-apprr+eps;
1051 draw z1..z2; draw z3..z4; labels(1, 2, 3, 4);
1052 math_fit(0, ic#);
1053 endchar;
1054
1055 beginchar(oct"273", 10u#, asc_height#, desc_depth#);
1056 "The letter psi";
1057 italcorr x_height#*slant-0.5u#;
1058 center_stem(6, 7);
1059 top y1 = top y5 = x_height+eps; bot y3 = -d_o; y2 = y4 = 0.5[y3, y1];
1060 lft x1 = lft x2 = apprl; rt x4 = rt x5 = w-apprr; x3 = 0.5[x1, x5];
1061 top y6 = h+eps; bot y7 = -d-eps;
1062 draw z1..z2 down_to_right z3 right_to_up z4..z5;
1063 draw z6..z7; labels(1, 2, 3, 4, 5, 6, 7);
1064 math_fit(0, ic#);
1065 endchar;
1066
1067 beginchar(oct"274", 12u#, x_height#, 0);
1068 "The letter omega";
1069 italcorr 0.7x_height#*slant-0.5u#+ho#;
1070 pickup lower_cal.nib;
1071 top y1 = top y9 = h+eps; bot y3 = bot y7 = -d_o; y2 = y8 = 0.5[y3, y1];
1072 y4 = y6 = 0.5[y3, y1]; y5 = good.y 0.75[y3, y1]+eps;
1073 lft x2 = apprl-ho; rt x8 = w-apprr+ho;
1074 x1 = good.x(x2+1.2u); x9 = good.x(x8-1.2u);
1075 x3 = 0.265[x2, x8]; x7 = 0.735[x2, x8]; x5 = good.x 0.5[x2, x8];
1076 x4-x5 = x5-x6 = hround 0.7u+eps;
1077 draw z1{3(x2-x1), y2-y1}
1078 ...z2 down_to_right z3 right_to_up z4 up_to_left
1079 z5 left_to_down z6 down_to_right z7 right_to_up z8
1080 ...{3(x9-x8), y9-y8}z9;
1081 labels(1, 2, 3, 4, 5, 6, 7, 8, 9);
1082 math_fit(0, ic#);
1083 endchar;
1084
1085 beginchar(oct"275", 14u#, x_height#, 0);
1086 "The letter variant pi";
1087 italcorr (x_height#+hook_h#)*slant;
1088 pickup lower_cal.nib;
1089 top y1 = top y9 = h; bot y3 = bot y7 = -d_o; y2 = y8 = 0.5[y3, y1];
1090 y4 = y6 = 0.6[y3, y1]; y5 = good.y 0.7[y3, y1]+eps;
1091 lft x2 = apprl+hround 2u-ho; rt x8 = w-apprr-hround 0.4u+ho;
1092 x1 = good.x(x2+1.2u); x9 = good.x(x8-1.2u);
1093 x3 = 0.265[x2, x8]; x7 = 0.735[x2, x8]; x5 = good.x 0.5[x2, x8];
1094 x4-x5 = x5-x6 = hround 0.25u+eps;
1095 draw z1{3(x2-x1), y2-y1}
1096 ...z2 down_to_right z3 right_to_up z4 up_to_left
1097 z5 left_to_down z6 down_to_right z7 right_to_up z8
1098 ...{3(x9-x8), y9-y8}z9;
1099 y10 = hang_h; top y11 = h; y11 = y12; y13 = y12;
1100 apprl-lft x10 = rt x13-(w-apprr) = hround 0.5u;
1101 x11 = min(x10+pi_hang_w, x1); x12 = max(x13-pi_hang_w, x9);
1102 draw z10--z11..z12 right_to_up z13;
1103 labels(1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13);
1104 math_fit(0, ic#);
1105 endchar;