Debian Codegraph @

texmf-dist/fonts/source/public/lxfonts/lbigdel.mf

raw
1 % THIS IS THE OFFICIAL COMPUTER MODERN SOURCE FILE bigdel.mf BY D E KNUTH.
2 % IT MUST NOT BE MODIFIED IN ANY WAY UNLESS THE FILE NAME IS CHANGED!
3
4 % This file contains series of large delimiters for math extension fonts.
5
6 % The sizes are `{\tt\char`\\big}' (|2dh#|), `{\tt\char`\\Big}' (|3dh#|),
7 % `{\tt\char`\\bigg}' (|4dh#|), and `{\tt\char`\\Bigg}' (|5dh#|),
8 % followed in most cases by an extensible character that can grow
9 % arbitrarily large in |dh#| steps,
10 % where |dh#| is 60\% of the font design size.
11 % (For example, a 10-point font will have large delimiters in sizes
12 % 12$\,$pt, 18$\,$pt, 24$\,$pt, 30$\,$pt, 36$\,$pt, 42$\,$pt, etc.)
13
14 % Character codes \0000--\0105 and \0150--\0177 are generated.
15
16 charlist oct"000": oct"020": oct"022": oct"040": oct"060"; % left parentheses
17 charlist oct"001": oct"021": oct"023": oct"041": oct"061"; % right parentheses
18 charlist oct"002": oct"150": oct"024": oct"042": oct"062"; % left brackets
19 charlist oct"003": oct"151": oct"025": oct"043": oct"063"; % right brackets
20 charlist oct"004": oct"152": oct"026": oct"044": oct"064"; % left floors
21 charlist oct"005": oct"153": oct"027": oct"045": oct"065"; % right floors
22 charlist oct"006": oct"154": oct"030": oct"046": oct"066"; % left ceilings
23 charlist oct"007": oct"155": oct"031": oct"047": oct"067"; % right ceilings
24 charlist oct"010": oct"156": oct"032": oct"050": oct"070"; % left braces
25 charlist oct"011": oct"157": oct"033": oct"051": oct"071"; % right braces
26 charlist oct"012": oct"104": oct"034": oct"052"; % left angle brackets
27 charlist oct"013": oct"105": oct"035": oct"053"; % right angle brackets
28 charlist oct"016": oct"056": oct"036": oct"054"; % slashes
29 charlist oct"017": oct"057": oct"037": oct"055"; % backslashes
30 charlist oct"160": oct"161": oct"162": oct"163": oct"164"; % radical signs
31
32 extensible oct"014": 0,0,0,oct"014"; % vertical line
33 extensible oct"015": 0,0,0,oct"015"; % double vertical line
34 extensible oct"060": oct"060",0,oct"100",oct"102"; % left parenthesis
35 extensible oct"061": oct"061",0,oct"101",oct"103"; % right parenthesis
36 extensible oct"062": oct"062",0,oct"064",oct"066"; % left bracket
37 extensible oct"063": oct"063",0,oct"065",oct"067"; % right bracket
38 extensible oct"064": 0,0,oct"064",oct"066"; % left floor bracket
39 extensible oct"065": 0,0,oct"065",oct"067"; % right floor bracket
40 extensible oct"066": oct"062",0,0,oct"066"; % left ceiling bracket
41 extensible oct"067": oct"063",0,0,oct"067"; % right ceiling bracket
42 extensible oct"070": oct"070",oct"074",oct"072",oct"076"; % left brace
43 extensible oct"071": oct"071",oct"075",oct"073",oct"076"; % right brace
44 extensible oct"072": oct"070",0,oct"072",oct"076"; % sharp left parenthesis
45 extensible oct"073": oct"071",0,oct"073",oct"076"; % sharp right parenthesis
46 extensible oct"074": 0,0,0,oct"077"; % arrow extension modules only
47 extensible oct"075": 0,0,0,oct"167"; % double arrow extension modules only
48 extensible oct"076": 0,0,0,oct"076"; % brace extension modules only
49 extensible oct"077": oct"170",0,oct"171",oct"077"; % updownarrow
50 extensible oct"100": oct"070",0,oct"073",oct"076"; % left moustache
51 extensible oct"101": oct"071",0,oct"072",oct"076"; % right moustache
52 extensible oct"102": 0,0,0,oct"102"; % left parenthesis extension modules only
53 extensible oct"103": 0,0,0,oct"103"; % right parenthesis extension modules only
54 extensible oct"164": oct"166",0,oct"164",oct"165"; % radical sign
55 extensible oct"167": oct"176",0,oct"177",oct"167"; % double updownarrow
56 extensible oct"170": oct"170",0,0,oct"077"; % uparrow
57 extensible oct"171": 0,0,oct"171",oct"077"; % downarrow
58 extensible oct"176": oct"176",0,0,oct"167"; % double uparrow
59 extensible oct"177": 0,0,oct"177",oct"167"; % double downarrow
60
61 cmchar "\big left parenthesis";
62 beginchar(oct"000",7u#,rule_thickness#,2dh#-rule_thickness#);
63 adjust_fit(1.5u#,-.25u#); left_paren(hair,stem); endchar;
64
65 cmchar "\Big left parenthesis";
66 beginchar(oct"020",9u#,rule_thickness#,3dh#-rule_thickness#);
67 adjust_fit(2u#,-.25u#); left_paren(rule_thickness,.5[stem,bold]); endchar;
68
69 cmchar "\bigg left parenthesis";
70 beginchar(oct"022",11u#,rule_thickness#,4dh#-rule_thickness#);
71 adjust_fit(2.5u#,-.25u#); left_paren(rule_thickness+.2dw,bold); endchar;
72
73 cmchar "\Bigg left parenthesis";
74 beginchar(oct"040",11.5u#,rule_thickness#,5dh#-rule_thickness#);
75 adjust_fit(3u#,-.25u#); left_paren(rule_thickness+.4dw,bold+dw); endchar;
76
77 cmchar "Extensible left parenthesis---top";
78 beginchar(oct"060",12u#,rule_thickness#,3dh#-rule_thickness#);
79 adjust_fit(4u#,-.25u#); pickup fine.nib;
80 numeric min_breadth,max_breadth;
81 min_breadth=rule_thickness+.6dw; max_breadth=bold+2dw;
82 pos1(hround min_breadth,0); pos2(hround max_breadth,0);
83 rt x1r=hround(w-1.25u+.5min_breadth); lft x2l=hround 1.25u;
84 top y1=h-1; y2=-d-eps;
85 filldraw stroke z1e{3(x2e-x1e),y2-y1}...{down}z2e; % upper arc
86 penlabels(1,2); endchar;
87
88 cmchar "Extensible left parenthesis---bottom";
89 beginchar(oct"100",12u#,rule_thickness#,3dh#-rule_thickness#);
90 adjust_fit(4u#,-.25u#); pickup fine.nib;
91 numeric min_breadth,max_breadth;
92 min_breadth=rule_thickness+.6dw; max_breadth=bold+2dw;
93 pos3(hround min_breadth,0); pos2(hround max_breadth,0);
94 rt x3r=hround(w-1.25u+.5min_breadth); lft x2l=hround 1.25u;
95 bot y3=1-d; y2=h+eps;
96 filldraw stroke z3e{3(x2e-x3e),y2-y3}...{up}z2e; % lower arc
97 penlabels(2,3); endchar;
98
99 cmchar "Extensible left parenthesis---extension module";
100 beginchar(oct"102",12u#,0,dh#);
101 adjust_fit(4u#,-.25u#); pickup fine.nib;
102 numeric max_breadth; max_breadth=bold+2dw;
103 pos2(hround max_breadth,0); pos2'(hround max_breadth,0);
104 lft x2l=lft x2'l=hround 1.25u; y2=h+eps; y2'=-d-eps;
105 filldraw stroke z2e--z2'e; % link
106 penlabels(2,2'); endchar;
107
108 cmchar "\big right parenthesis";
109 beginchar(oct"001",7u#,rule_thickness#,2dh#-rule_thickness#);
110 adjust_fit(-.25u#,1.5u#); right_paren(hair,stem); endchar;
111
112 cmchar "\Big right parenthesis";
113 beginchar(oct"021",9u#,rule_thickness#,3dh#-rule_thickness#);
114 adjust_fit(-.25u#,2u#); right_paren(rule_thickness,.5[stem,bold]); endchar;
115
116 cmchar "\bigg right parenthesis";
117 beginchar(oct"023",11u#,rule_thickness#,4dh#-rule_thickness#);
118 adjust_fit(-.25u#,2.5u#); right_paren(rule_thickness+.2dw,bold); endchar;
119
120 cmchar "\Bigg right parenthesis";
121 beginchar(oct"041",11.5u#,rule_thickness#,5dh#-rule_thickness#);
122 adjust_fit(-.25u#,3u#); right_paren(rule_thickness+.4dw,bold+dw); endchar;
123
124 cmchar "Extensible right parenthesis---top";
125 beginchar(oct"061",12u#,rule_thickness#,3dh#-rule_thickness#);
126 adjust_fit(-.25u#,4u#); pickup fine.nib;
127 numeric min_breadth,max_breadth;
128 min_breadth=rule_thickness+.6dw; max_breadth=bold+2dw;
129 pos1(hround min_breadth,0); pos2(hround max_breadth,0);
130 lft x1l=hround(1.25u-.5min_breadth); rt x2r=hround(w-1.25u);
131 top y1=h-1; y2=-d-eps;
132 filldraw stroke z1e{3(x2e-x1e),y2-y1}...{down}z2e; % upper arc
133 penlabels(1,2); endchar;
134
135 cmchar "Extensible right parenthesis---bottom";
136 beginchar(oct"101",12u#,rule_thickness#,3dh#-rule_thickness#);
137 adjust_fit(-.25u#,4u#); pickup fine.nib;
138 numeric min_breadth,max_breadth;
139 min_breadth=rule_thickness+.6dw; max_breadth=bold+2dw;
140 pos3(hround min_breadth,0); pos2(hround max_breadth,0);
141 lft x3l=hround(1.25u-.5min_breadth); rt x2r=hround(w-1.25u);
142 bot y3=1-d; y2=h+eps;
143 filldraw stroke z3e{3(x2e-x3e),y2-y3}...{up}z2e; % lower arc
144 penlabels(2,3); endchar;
145
146 cmchar "Extensible right parenthesis---extension module";
147 beginchar(oct"103",12u#,0,dh#);
148 adjust_fit(-.25u#,4u#); pickup fine.nib;
149 numeric max_breadth; max_breadth=bold+2dw;
150 pos2(hround max_breadth,0); pos2'(hround max_breadth,0);
151 rt x2r=rt x2'r=hround(w-1.25u); y2=h+eps; y2'=-d-eps;
152 filldraw stroke z2e--z2'e; % link
153 penlabels(2,2'); endchar;
154
155 cmchar "\big left bracket";
156 beginchar(oct"002",6u#,rule_thickness#,2dh#-rule_thickness#);
157 adjust_fit(1.5u#,0); left_bracket(rule_thickness,true,true); endchar;
158
159 cmchar "\Big left bracket";
160 beginchar(oct"150",6.5u#,rule_thickness#,3dh#-rule_thickness#);
161 adjust_fit(2u#,0); left_bracket(.25[rule_thickness,stem],true,true); endchar;
162
163 cmchar "\bigg left bracket";
164 beginchar(oct"024",7u#,rule_thickness#,4dh#-rule_thickness#);
165 adjust_fit(2.5u#,0); left_bracket(.5[rule_thickness,stem],true,true); endchar;
166
167 cmchar "\Bigg left bracket";
168 beginchar(oct"042",7.5u#,rule_thickness#,5dh#-rule_thickness#);
169 adjust_fit(3u#,0); left_bracket(.75[rule_thickness,stem],true,true); endchar;
170
171 cmchar "Extensible left bracket---top";
172 beginchar(oct"062",8u#,rule_thickness#,3dh#-rule_thickness#);
173 adjust_fit(4u#,0); pickup crisp.nib;
174 pos1(stem,0); pos2(stem,0);
175 top y1=h-1; y2=-d-eps; lft x1l=lft x2l=hround(2.5u-.5stem);
176 filldraw stroke z1e--z2e; % stem
177 pos3(stem,90); pos4(stem,90);
178 x3=x1l; rt x4=hround(w-.75u+.5stem); y3r=y4r=y1;
179 filldraw stroke z3e--z4e; % upper bar
180 penlabels(1,2,3,4); endchar;
181
182 cmchar "Extensible left bracket---bottom";
183 beginchar(oct"064",8u#,rule_thickness#,3dh#-rule_thickness#);
184 adjust_fit(4u#,0); pickup crisp.nib;
185 pos1(stem,0); pos2(stem,0);
186 y1=h+eps; bot y2=1-d; lft x1l=lft x2l=hround(2.5u-.5stem);
187 filldraw stroke z1e--z2e; % stem
188 pos5(stem,90); pos6(stem,90);
189 x5=x1l; rt x6=hround(w-.75u+.5stem); y5l=y6l=y2;
190 filldraw stroke z5e--z6e; % lower bar
191 penlabels(1,2,5,6); endchar;
192
193 cmchar "Extensible left bracket---extension module";
194 beginchar(oct"066",8u#,0,dh#);
195 adjust_fit(4u#,0); pickup crisp.nib;
196 pos1(stem,0); pos2(stem,0);
197 y1=h+1+eps; bot y2=-d-1-eps; lft x1l=lft x2l=hround(2.5u-.5stem);
198 filldraw stroke z1e--z2e; % stem
199 penlabels(1,2); endchar;
200
201 cmchar "\big right bracket";
202 beginchar(oct"003",6u#,rule_thickness#,2dh#-rule_thickness#);
203 adjust_fit(0,1.5u#); right_bracket(rule_thickness,true,true); endchar;
204
205 cmchar "\Big right bracket";
206 beginchar(oct"151",6.5u#,rule_thickness#,3dh#-rule_thickness#);
207 adjust_fit(0,2u#); right_bracket(.25[rule_thickness,stem],true,true); endchar;
208
209 cmchar "\bigg right bracket";
210 beginchar(oct"025",7u#,rule_thickness#,4dh#-rule_thickness#);
211 adjust_fit(0,2.5u#); right_bracket(.5[rule_thickness,stem],true,true); endchar;
212
213 cmchar "\Bigg right bracket";
214 beginchar(oct"043",7.5u#,rule_thickness#,5dh#-rule_thickness#);
215 adjust_fit(0,3u#); right_bracket(.75[rule_thickness,stem],true,true); endchar;
216
217 cmchar "Extensible right bracket---top";
218 beginchar(oct"063",8u#,rule_thickness#,3dh#-rule_thickness#);
219 adjust_fit(0,4u#); pickup crisp.nib;
220 pos1(stem,0); pos2(stem,0);
221 top y1=h-1; y2=-d-eps; rt x1r=rt x2r=hround(w-2.5u+.5stem);
222 filldraw stroke z1e--z2e; % stem
223 pos3(stem,90); pos4(stem,90);
224 x3=x1r; lft x4=hround(.75u-.5stem); y3r=y4r=y1;
225 filldraw stroke z3e--z4e; % upper bar
226 penlabels(1,2,3,4); endchar;
227
228 cmchar "Extensible right bracket---bottom";
229 beginchar(oct"065",8u#,rule_thickness#,3dh#-rule_thickness#);
230 adjust_fit(0,4u#); pickup crisp.nib;
231 pos1(stem,0); pos2(stem,0);
232 y1=h+eps; bot y2=1-d; rt x1r=rt x2r=hround(w-2.5u+.5stem);
233 filldraw stroke z1e--z2e; % stem
234 pos5(stem,90); pos6(stem,90);
235 x5=x1r; lft x6=hround(.75u-.5stem); y5l=y6l=y2;
236 filldraw stroke z5e--z6e; % lower bar
237 penlabels(1,2,5,6); endchar;
238
239 cmchar "Extensible right bracket---extension module";
240 beginchar(oct"067",8u#,0,dh#);
241 adjust_fit(0,4u#); pickup crisp.nib;
242 pos1(stem,0); pos2(stem,0);
243 y1=h+1+eps; bot y2=-d-1-eps; rt x1r=rt x2r=hround(w-2.5u+.5stem);
244 filldraw stroke z1e--z2e; % stem
245 penlabels(1,2); endchar;
246
247 cmchar "\big left floor bracket";
248 beginchar(oct"004",7u#,rule_thickness#,2dh#-rule_thickness#);
249 adjust_fit(1.5u#,0); left_bracket(rule_thickness,false,true); endchar;
250
251 cmchar "\Big left floor bracket";
252 beginchar(oct"152",7.5u#,rule_thickness#,3dh#-rule_thickness#);
253 adjust_fit(2u#,0); left_bracket(.25[rule_thickness,stem],false,true); endchar;
254
255 cmchar "\bigg left floor bracket";
256 beginchar(oct"026",8u#,rule_thickness#,4dh#-rule_thickness#);
257 adjust_fit(2.5u#,0); left_bracket(.5[rule_thickness,stem],false,true); endchar;
258
259 cmchar "\Bigg left floor bracket";
260 beginchar(oct"044",8.5u#,rule_thickness#,5dh#-rule_thickness#);
261 adjust_fit(3u#,0); left_bracket(.75[rule_thickness,stem],false,true); endchar;
262
263 cmchar "\big right floor bracket";
264 beginchar(oct"005",7u#,rule_thickness#,2dh#-rule_thickness#);
265 adjust_fit(0,1.5u#); right_bracket(rule_thickness,false,true); endchar;
266
267 cmchar "\Big right floor bracket";
268 beginchar(oct"153",7.5u#,rule_thickness#,3dh#-rule_thickness#);
269 adjust_fit(0,2u#); right_bracket(.25[rule_thickness,stem],false,true); endchar;
270
271 cmchar "\bigg right floor bracket";
272 beginchar(oct"027",8u#,rule_thickness#,4dh#-rule_thickness#);
273 adjust_fit(0,2.5u#); right_bracket(.5[rule_thickness,stem],false,true); endchar;
274
275 cmchar "\Bigg right floor bracket";
276 beginchar(oct"045",8.5u#,rule_thickness#,5dh#-rule_thickness#);
277 adjust_fit(0,3u#); right_bracket(.75[rule_thickness,stem],false,true); endchar;
278
279 cmchar "\big left ceiling bracket";
280 beginchar(oct"006",7u#,rule_thickness#,2dh#-rule_thickness#);
281 adjust_fit(1.5u#,0); left_bracket(rule_thickness,true,false); endchar;
282
283 cmchar "\Big left ceiling bracket";
284 beginchar(oct"154",7.5u#,rule_thickness#,3dh#-rule_thickness#);
285 adjust_fit(2u#,0); left_bracket(.25[rule_thickness,stem],true,false); endchar;
286
287 cmchar "\bigg left ceiling bracket";
288 beginchar(oct"030",8u#,rule_thickness#,4dh#-rule_thickness#);
289 adjust_fit(2.5u#,0); left_bracket(.5[rule_thickness,stem],true,false); endchar;
290
291 cmchar "\Bigg left ceiling bracket";
292 beginchar(oct"046",8.5u#,rule_thickness#,5dh#-rule_thickness#);
293 adjust_fit(3u#,0); left_bracket(.75[rule_thickness,stem],true,false); endchar;
294
295 cmchar "\big right ceiling bracket";
296 beginchar(oct"007",7u#,rule_thickness#,2dh#-rule_thickness#);
297 adjust_fit(0,1.5u#); right_bracket(rule_thickness,true,false); endchar;
298
299 cmchar "\Big right ceiling bracket";
300 beginchar(oct"155",7.5u#,rule_thickness#,3dh#-rule_thickness#);
301 adjust_fit(0,2u#); right_bracket(.25[rule_thickness,stem],true,false); endchar;
302
303 cmchar "\bigg right ceiling bracket";
304 beginchar(oct"031",8u#,rule_thickness#,4dh#-rule_thickness#);
305 adjust_fit(0,2.5u#); right_bracket(.5[rule_thickness,stem],true,false); endchar;
306
307 cmchar "\Bigg right ceiling bracket";
308 beginchar(oct"047",8.5u#,rule_thickness#,5dh#-rule_thickness#);
309 adjust_fit(0,3u#); right_bracket(.75[rule_thickness,stem],true,false); endchar;
310
311 cmchar "\big left curly brace";
312 beginchar(oct"010",9u#,rule_thickness#,2dh#-rule_thickness#);
313 adjust_fit(.75u#,.75u#); left_curly(hair,stem); endchar;
314
315 cmchar "\Big left curly brace";
316 beginchar(oct"156",10u#,rule_thickness#,3dh#-rule_thickness#);
317 adjust_fit(u#,u#); left_curly(rule_thickness,.5[stem,bold]); endchar;
318
319 cmchar "\bigg left curly brace";
320 beginchar(oct"032",11u#,rule_thickness#,4dh#-rule_thickness#);
321 adjust_fit(1.25u#,1.25u#); left_curly(rule_thickness+.2dw,bold); endchar;
322
323 cmchar "\Bigg left curly brace";
324 beginchar(oct"050",11.5u#,rule_thickness#,5dh#-rule_thickness#);
325 adjust_fit(1.5u#,1.5u#); left_curly(rule_thickness+.4dw,bold+dw); endchar;
326
327 cmchar "Extensible left curly brace---top";
328 beginchar(oct"070",12u#,0,1.5dh#);
329 adjust_fit(2u#,2u#); pickup fine.nib;
330 numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
331 pos1(min_breadth,0); pos1'(min_breadth,0);
332 pos2(heavy_rule_thickness,0); pos3(heavy_rule_thickness,0);
333 rt x1r=rt x1'r=hround(w-1.5u+.5min_breadth);
334 lft x2l=lft x3l=hround(.5w-.5heavy_rule_thickness);
335 top y1=h-1; y3=-d-eps; y2=.5[y1,y3]; y1-y1'=min_breadth-fine;
336 filldraw z1l{3(x2l-x1l),y2-y1}...z2l---z3l
337 --z3r---z2r...{3(x1r-x2r),y1'-y2}z1'r--z1r--cycle; % stroke
338 penlabels(1,2,3); endchar;
339
340 cmchar "Extensible left curly brace---bottom";
341 beginchar(oct"072",12u#,0,1.5dh#);
342 adjust_fit(2u#,2u#); pickup fine.nib;
343 numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
344 pos7(min_breadth,0); pos7'(min_breadth,0);
345 pos5(heavy_rule_thickness,0); pos6(heavy_rule_thickness,0);
346 rt x7r=rt x7'r=hround(w-1.5u+.5min_breadth);
347 lft x5l=lft x6l=hround(.5w-.5heavy_rule_thickness);
348 y5=h+eps; bot y7=1-d; y6=.5[y5,y7]; y7'-y7=min_breadth-fine;
349 filldraw z5l---z6l...{3(x7l-x6l),y7-y6}z7l
350 --z7r--z7'r{3(x6r-x7r),y6-y7'}...z6r---z5r--cycle; % stroke
351 penlabels(5,6,7); endchar;
352
353 cmchar "Extensible left curly brace---middle";
354 beginchar(oct"074",12u#,0,3dh#);
355 adjust_fit(2u#,2u#); pickup fine.nib;
356 numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
357 pos4(min_breadth,0); pos4'(min_breadth,0);
358 forsuffixes $=2,3,5,6: pos$(heavy_rule_thickness,0); endfor
359 lft x4l=lft x4'l=hround(1.5u-.5min_breadth);
360 x2=x3=x5=x6; lft x2l=hround(.5w-.5heavy_rule_thickness);
361 y2=h+eps; y6=-d-eps; .5[y4,y4']=.5[y2,y6]=.5[y3,y5];
362 y3-y4=(y2-y6)/4; y4-y4'=min_breadth-fine;
363 filldraw z2l---z3l...{3(x4l-x3l),y4-y3}z4l
364 --z4'l{3(x5l-x4l),y5-y4'}...z5l---z6l--z6r---z5r
365 ...{3(x4r-x5r),.5[y4,y4']-y5}.5[z4r,z4'r]{3(x3r-x4r),y3-.5[y4,y4']}
366 ...z3r---z2r--cycle; % stroke
367 penlabels(2,3,4,5,6); endchar;
368
369 cmchar "Extensible curly brace---extension module";
370 beginchar(oct"076",12u#,0,.5dh#);
371 adjust_fit(2u#,2u#); pickup fine.nib;
372 pos2(heavy_rule_thickness,0); pos3(heavy_rule_thickness,0);
373 lft x2l=lft x3l=hround(.5w-.5heavy_rule_thickness); y2=h+eps; y3=-d-eps;
374 filldraw stroke z2e--z3e; % stem
375 penlabels(2,3); endchar;
376
377 cmchar "\big right curly brace";
378 beginchar(oct"011",9u#,rule_thickness#,2dh#-rule_thickness#);
379 adjust_fit(.75u#,.75u#); right_curly(hair,stem); endchar;
380
381 cmchar "\Big right curly brace";
382 beginchar(oct"157",10u#,rule_thickness#,3dh#-rule_thickness#);
383 adjust_fit(u#,u#); right_curly(rule_thickness,.5[stem,bold]); endchar;
384
385 cmchar "\bigg right curly brace";
386 beginchar(oct"033",11u#,rule_thickness#,4dh#-rule_thickness#);
387 adjust_fit(1.25u#,1.25u#); right_curly(rule_thickness+.2dw,bold); endchar;
388
389 cmchar "\Bigg right curly brace";
390 beginchar(oct"051",11.5u#,rule_thickness#,5dh#-rule_thickness#);
391 adjust_fit(1.5u#,1.5u#); right_curly(rule_thickness+.4dw,bold+dw); endchar;
392
393 cmchar "Extensible right curly brace---top";
394 beginchar(oct"071",12u#,0,1.5dh#);
395 adjust_fit(2u#,2u#); pickup fine.nib;
396 numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
397 pos1(min_breadth,0); pos1'(min_breadth,0);
398 pos2(heavy_rule_thickness,0); pos3(heavy_rule_thickness,0);
399 lft x1l=lft x1'l=hround(1.5u-.5min_breadth);
400 lft x2l=lft x3l=hround(.5w-.5heavy_rule_thickness);
401 top y1=h-1; y3=-d-eps; y2=.5[y1,y3]; y1-y1'=min_breadth-fine;
402 filldraw z1r{3(x2r-x1r),y2-y1}...z2r---z3r
403 --z3l---z2l...{3(x1l-x2l),y1'-y2}z1'l--z1l--cycle; % stroke
404 penlabels(1,2,3); endchar;
405
406 cmchar "Extensible right curly brace---bottom";
407 beginchar(oct"073",12u#,0,1.5dh#);
408 adjust_fit(2u#,2u#); pickup fine.nib;
409 numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
410 pos7(min_breadth,0); pos7'(min_breadth,0);
411 pos5(heavy_rule_thickness,0); pos6(heavy_rule_thickness,0);
412 lft x7l=lft x7'l=hround(1.5u-.5min_breadth);
413 lft x5l=lft x6l=hround(.5w-.5heavy_rule_thickness);
414 y5=h+eps; bot y7=1-d; y6=.5[y5,y7]; y7'-y7=min_breadth-fine;
415 filldraw z5r---z6r...{3(x7r-x6r),y7-y6}z7r
416 --z7l--z7'l{3(x6l-x7l),y6-y7'}...z6l---z5l--cycle; % stroke
417 penlabels(5,6,7); endchar;
418
419 cmchar "Extensible right curly brace---middle";
420 beginchar(oct"075",12u#,0,3dh#);
421 adjust_fit(2u#,2u#); pickup fine.nib;
422 numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
423 pos4(min_breadth,0); pos4'(min_breadth,0);
424 forsuffixes $=2,3,5,6: pos$(heavy_rule_thickness,0); endfor
425 rt x4r=rt x4'r=hround(w-1.5u+.5min_breadth);
426 x2=x3=x5=x6; lft x2l=hround(.5w-.5heavy_rule_thickness);
427 y2=h+eps; y6=-d-eps; .5[y4,y4']=.5[y2,y6]=.5[y3,y5];
428 y3-y4=(y2-y6)/4; y4-y4'=min_breadth-fine;
429 filldraw z2r---z3r...{3(x4r-x3r),y4-y3}z4r
430 --z4'r{3(x5r-x4r),y5-y4'}...z5r---z6r--z6l---z5l
431 ...{3(x4l-x5l),.5[y4,y4']-y5}.5[z4l,z4'l]{3(x3l-x4l),y3-.5[y4,y4']}
432 ...z3l---z2l--cycle; % stroke
433 penlabels(2,3,4,5,6); endchar;
434
435 cmchar "Horizontal curly brace tip---down and left";
436 beginchar(oct"172",.75dh#,3rule_thickness#,0);
437 adjust_fit(0,0); pickup fine.nib;
438 numeric min_breadth; min_breadth=vround(rule_thickness+.6dw);
439 pos1(min_breadth,90); pos1'(min_breadth,90);
440 pos2(heavy_rule_thickness,90);
441 bot y2l=0; bot y1l=bot y1'l=vround(y2-4.5u-.5min_breadth);
442 .5[x1,x1']=-eps; x2=w+shrink_fit+eps; x1'-x1=min_breadth-fine;
443 filldraw z1r{x2-x1,3(y2r-y1r)}...{right}z2r
444 --z2l{left}...{x1'-x2,3(y1-y2)}z1'l--z1l--cycle; % stroke
445 penlabels(1,2); endchar;
446
447 cmchar "Horizontal curly brace tip---down and right";
448 beginchar(oct"173",.75dh#,3rule_thickness#,0);
449 adjust_fit(0,0); pickup fine.nib;
450 numeric min_breadth; min_breadth=vround(rule_thickness+.6dw);
451 pos1(min_breadth,90); pos1'(min_breadth,90);
452 pos2(heavy_rule_thickness,90);
453 bot y2l=0; bot y1l=bot y1'l=vround(y2-4.5u-.5min_breadth);
454 .5[x1,x1']=w+shrink_fit+eps; x2=-eps; x1-x1'=min_breadth-fine;
455 filldraw z1r{x2-x1,3(y2r-y1r)}...{left}z2r
456 --z2l{right}...{x1'-x2,3(y1-y2)}z1'l--z1l--cycle; % stroke
457 penlabels(1,2); endchar;
458
459 cmchar "Horizontal curly brace tip---up and left";
460 beginchar(oct"174",.75dh#,3rule_thickness#,0);
461 adjust_fit(0,0); pickup fine.nib;
462 numeric min_breadth; min_breadth=vround(rule_thickness+.6dw);
463 pos1(min_breadth,90); pos1'(min_breadth,90);
464 pos2(heavy_rule_thickness,90);
465 bot y2l=0; top y1r=top y1'r=vround(y2+4.5u+.5min_breadth);
466 .5[x1,x1']=-eps; x2=w+shrink_fit+eps; x1'-x1=min_breadth-fine;
467 filldraw z1l{x2-x1,3(y2l-y1l)}...{right}z2l
468 --z2r{left}...{x1'-x2,3(y1-y2)}z1'r--z1r--cycle; % stroke
469 penlabels(1,2); endchar;
470
471 cmchar "Horizontal curly brace tip---up and right";
472 beginchar(oct"175",.75dh#,3rule_thickness#,0);
473 adjust_fit(0,0); pickup fine.nib;
474 numeric min_breadth; min_breadth=vround(rule_thickness+.6dw);
475 pos1(min_breadth,90); pos1'(min_breadth,90);
476 pos2(heavy_rule_thickness,90);
477 bot y2l=0; top y1r=top y1'r=vround(y2+4.5u+.5min_breadth);
478 .5[x1,x1']=w+shrink_fit+eps; x2=-eps; x1-x1'=min_breadth-fine;
479 filldraw z1l{x2-x1,3(y2l-y1l)}...{left}z2l
480 --z2r{right}...{x1'-x2,3(y1-y2)}z1'r--z1r--cycle; % stroke
481 penlabels(1,2); endchar;
482
483 cmchar "\big left angle bracket";
484 beginchar(oct"012",7u#,rule_thickness#,2dh#-rule_thickness#);
485 adjust_fit(.75u#,.75u#); left_angle(rule_thickness); endchar;
486
487 cmchar "\Big left angle bracket";
488 beginchar(oct"104",9u#,rule_thickness#,3dh#-rule_thickness#);
489 adjust_fit(u#,u#); left_angle(.25[rule_thickness,stem]); endchar;
490
491 cmchar "\bigg left angle bracket";
492 beginchar(oct"034",11u#,rule_thickness#,4dh#-rule_thickness#);
493 adjust_fit(1.25u#,1.25u#); left_angle(.5[rule_thickness,stem]); endchar;
494
495 cmchar "\Bigg left angle bracket";
496 beginchar(oct"052",11.5u#,rule_thickness#,5dh#-rule_thickness#);
497 adjust_fit(1.5u#,1.5u#); left_angle(.75[rule_thickness,stem]); endchar;
498
499 cmchar "\big right angle bracket";
500 beginchar(oct"013",7u#,rule_thickness#,2dh#-rule_thickness#);
501 adjust_fit(.75u#,.75u#); right_angle(rule_thickness); endchar;
502
503 cmchar "\Big right angle bracket";
504 beginchar(oct"105",9u#,rule_thickness#,3dh#-rule_thickness#);
505 adjust_fit(u#,u#); right_angle(.25[rule_thickness,stem]); endchar;
506
507 cmchar "\bigg right angle bracket";
508 beginchar(oct"035",11u#,rule_thickness#,4dh#-rule_thickness#);
509 adjust_fit(1.25u#,1.25u#); right_angle(.5[rule_thickness,stem]); endchar;
510
511 cmchar "\Bigg right angle bracket";
512 beginchar(oct"053",11.5u#,rule_thickness#,5dh#-rule_thickness#);
513 adjust_fit(1.5u#,1.5u#); right_angle(.75[rule_thickness,stem]); endchar;
514
515 cmchar "\big slash";
516 beginchar(oct"016",10.4u#,rule_thickness#,2dh#-rule_thickness#);
517 big_slash(rule_thickness+.2dw); endchar;
518
519 cmchar "\Big slash";
520 beginchar(oct"056",14.6u#,rule_thickness#,3dh#-rule_thickness#);
521 big_slash(rule_thickness+.6dw); endchar;
522
523 cmchar "\bigg slash";
524 beginchar(oct"036",18.8u#,rule_thickness#,4dh#-rule_thickness#);
525 big_slash(rule_thickness+dw); endchar;
526
527 cmchar "\Bigg slash";
528 beginchar(oct"054",23u#,rule_thickness#,5dh#-rule_thickness#);
529 big_slash(rule_thickness+1.5dw); endchar;
530
531 cmchar "\big backslash";
532 beginchar(oct"017",10.4u#,rule_thickness#,2dh#-rule_thickness#);
533 big_blash(rule_thickness+.2dw); endchar;
534
535 cmchar "\Big backslash";
536 beginchar(oct"057",14.6u#,rule_thickness#,3dh#-rule_thickness#);
537 big_blash(rule_thickness+.6dw); endchar;
538
539 cmchar "\bigg backslash";
540 beginchar(oct"037",18.8u#,rule_thickness#,4dh#-rule_thickness#);
541 big_blash(rule_thickness+dw); endchar;
542
543 cmchar "\Bigg backslash";
544 beginchar(oct"055",23u#,rule_thickness#,5dh#-rule_thickness#);
545 big_blash(rule_thickness+1.5dw); endchar;
546
547 cmchar "Extensible vertical line---extension module";
548 beginchar(oct"014",6u#,0,dh#);
549 adjust_fit(0,0); pickup pencircle scaled(rule_thickness+.2dw);
550 x1=x2=good.x .5w; y1=eps; y2=-d-eps;
551 draw z1--z2; % stem
552 labels(1,2); endchar;
553
554 cmchar "Extensible double vertical line---extension module";
555 beginchar(oct"015",10u#,0,dh#);
556 adjust_fit(0,0); pickup pencircle scaled(rule_thickness+.2dw);
557 x1=x2=good.x .3w; x3=x4=w-x1; y1=y3=eps; y2=y4=-d-eps;
558 draw z1--z2; draw z3--z4; % stems
559 labels(1,2,3,4); endchar;
560
561 cmchar "Extensible vertical arrow--top";
562 beginchar(oct"170",12u#,0,dh#);
563 adjust_fit(0,0); pickup crisp.nib;
564 numeric thickness,barr;
565 thickness=hround(rule_thickness+.2dw); barr=Vround .6[bar,thickness];
566 pos1(thickness,0); pos2(thickness,0); pos3(barr,90); pos4(barr,90);
567 lft x1l=hround(.5w-.5thickness); y1=-d-eps;
568 x0=x1=x2; top y0=h; x0-x3=x4-x0=4u+eps;
569 y3=y4=y0-.29asc_height-eps;
570 pos5(barr,angle(z4-z0)); z5l=z0;
571 pos6(barr,angle(z3-z0)); z6l=z0;
572 z9=.381966[.5[z3,z4],z0];
573 numeric t; path p; p=z4l{z9-z4}..z6r;
574 t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
575 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
576 --z1r--z1l--subpath (t,0) of\\(z3l{z9-z3}..z5r)
577 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
578 penlabels(0,1,2,3,4,5,6,9); endchar;
579
580 cmchar "Extensible vertical arrow--bottom";
581 beginchar(oct"171",12u#,0,dh#);
582 adjust_fit(0,0); pickup crisp.nib;
583 numeric thickness,barr;
584 thickness=hround(rule_thickness+.2dw); barr=Vround .6[bar,thickness];
585 pos1(thickness,0); pos2(thickness,0); pos3(barr,90); pos4(barr,90);
586 lft x1l=hround(.5w-.5thickness); y1=h+eps;
587 x0=x1=x2; bot y0=-d; x0-x3=x4-x0=4u+eps;
588 y3=y4=y0+.29asc_height+eps;
589 pos5(barr,angle(z4-z0)); z5l=z0;
590 pos6(barr,angle(z3-z0)); z6l=z0;
591 z9=.381966[.5[z3,z4],z0];
592 numeric t; path p; p=z4r{z9-z4}..z6r;
593 t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
594 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
595 --z1r--z1l--subpath (t,0) of\\(z3r{z9-z3}..z5r)
596 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
597 penlabels(0,1,2,3,4,5,6,9); endchar;
598
599 cmchar "Extensible vertical arrow--extension module";
600 beginchar(oct"077",12u#,0,dh#);
601 adjust_fit(0,0); pickup crisp.nib;
602 numeric thickness; thickness=hround(rule_thickness+.2dw);
603 pos1(thickness,0); pos2(thickness,0);
604 lft x1l=hround(.5w-.5thickness); x2=x1; y1=h+1+eps; y2=-d-1-eps;
605 filldraw stroke z1e--z2e; % stem
606 penlabels(1,2); endchar;
607
608 cmchar "Extensible double vertical arrow--top";
609 beginchar(oct"176",14u#,0,dh#);
610 adjust_fit(0,0); pickup crisp.nib;
611 numeric thickness; thickness=Vround(rule_thickness+.2dw);
612 pos1(thickness,0); pos2(thickness,0); pos7(thickness,0); pos8(thickness,0);
613 y1=y2=-d-eps; y7=y8=h; top y0=h+eps; x1=x7; x2=x8;
614 rt x1r=hround(.5w+2u+.5thickness); .5[x1,x2]=x0=good.x .5w;
615 filldraw stroke z1e--z7e; filldraw stroke z2e--z8e; % bars
616 pos3(thickness,90); pos4(thickness,90);
617 x2-x3=x4-x1=4u+eps; y3=y4=y0-.48asc_height-eps;
618 pos5(thickness,angle(z4-z0)); z5l=z0;
619 pos6(thickness,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
620 erase filldraw z0..{z3-z9}z3--(x3,h)
621 --(x4,h)--z4{z9-z4}..z0 & cycle; % erase excess
622 numeric t; path p; p=z4l{z9-z4}..z6r;
623 t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
624 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
625 --subpath (t,0) of\\(z3l{z9-z3}..z5r)--z3r{z9-z3}..z0 & cycle; % arrowhead
626 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
627
628 cmchar "Extensible double vertical arrow--bottom";
629 beginchar(oct"177",14u#,0,dh#);
630 adjust_fit(0,0); pickup crisp.nib;
631 numeric thickness; thickness=Vround(rule_thickness+.2dw);
632 pos1(thickness,0); pos2(thickness,0); pos7(thickness,0); pos8(thickness,0);
633 y1=y2=h+eps; y7=y8=-d; bot y0=-d-eps; x1=x7; x2=x8;
634 rt x1r=hround(.5w+2u+.5thickness); .5[x1,x2]=x0=good.x .5w;
635 filldraw stroke z1e--z7e; filldraw stroke z2e--z8e; % bars
636 pos3(thickness,90); pos4(thickness,90);
637 x2-x3=x4-x1=4u+eps; y3=y4=y0+.48asc_height-eps;
638 pos5(thickness,angle(z4-z0)); z5l=z0;
639 pos6(thickness,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
640 erase filldraw z0..{z3-z9}z3--(x3,-d)
641 --(x4,-d)--z4{z9-z4}..z0 & cycle; % erase excess
642 numeric t; path p; p=z4r{z9-z4}..z6r;
643 t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
644 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
645 --subpath (t,0) of\\(z3r{z9-z3}..z5r)--z3l{z9-z3}..z0 & cycle; % arrowhead
646 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
647
648 cmchar "Extensible double vertical arrow--extension module";
649 beginchar(oct"167",14u#,0,dh#);
650 adjust_fit(0,0); pickup crisp.nib;
651 numeric thickness; thickness=Vround(rule_thickness+.2dw);
652 pos1(thickness,0); pos2(thickness,0); pos7(thickness,0); pos8(thickness,0);
653 y1=y2=h+1+eps; y7=y8=-d-1-eps; x1=x7; x2=x8;
654 rt x1r=hround(.5w+2u+.5thickness); .5[x1,x2]=good.x .5w;
655 filldraw stroke z1e--z7e; filldraw stroke z2e--z8e; % bars
656 penlabels(1,2,7,8); endchar;
657
658 cmchar "\big radical sign";
659 beginchar(oct"160",18u#,rule_thickness#,2dh#-rule_thickness#);
660 big_sqrt; endchar;
661
662 cmchar "\Big radical sign";
663 beginchar(oct"161",18u#,rule_thickness#,3dh#-rule_thickness#);
664 big_sqrt; endchar;
665
666 cmchar "\bigg radical sign";
667 beginchar(oct"162",18u#,rule_thickness#,4dh#-rule_thickness#);
668 big_sqrt; endchar;
669
670 cmchar "\Bigg radical sign";
671 beginchar(oct"163",18u#,rule_thickness#,5dh#-rule_thickness#);
672 big_sqrt; endchar;
673
674 cmchar "Extensible radical sign---bottom";
675 beginchar(oct"164",19u#,0,3dh#);
676 adjust_fit(0,-letter_fit#); pickup rule.nib;
677 x1=x2=good.x(w-6u); bot y1=1-d; y2=h+eps;
678 draw z1--z2; % diagonal
679 pickup crisp.nib; pos3(max(curve,rule_thickness),0);
680 x3l=good.x 3u; y3=.9[y1,y2];
681 pos4(rule_thickness,0); x4=x1; bot y4=-d;
682 pos5(vair,-45); x5l=good.x(x3l-u); z5l=whatever[z3r,(x2,body_height)];
683 z6=z5r+whatever*((x2,body_height)-z3r)=whatever[z3l,z4l];
684 z7=whatever[z1,z2]=z3r+whatever*(z4l-z3l);
685 filldraw z5r--z6--z4l--z4--z7--z3r--z5l--cycle; % left diagonal and serif
686 penlabels(1,2,3,4,5,6,7); endchar;
687
688 cmchar "Extensible radical sign---extension module";
689 beginchar(oct"165",19u#,0,dh#);
690 adjust_fit(0,-letter_fit#); pickup rule.nib;
691 x1=x2=good.x(w-6u); y1=-d-eps; y2=h+eps;
692 draw z1--z2; % stem
693 labels(1,2); endchar;
694
695 cmchar "Extensible radical sign---top";
696 beginchar(oct"166",19u#,rule_thickness#,dh#-rule_thickness#);
697 adjust_fit(0,-letter_fit#); pickup rule.nib;
698 x1=x2=good.x(w-6u); x3=good.x(w+.5); y1=-d-eps; bot y2=bot y3=0;
699 draw z1--z2--z3; % stem and link
700 labels(1,2,3); endchar;