Debian Codegraph @

texmf-dist/fonts/source/public/lxfonts/lasymbols.mf

raw
1 %% Copied and modified from ASYMBOLS by American Mathematical Society
2 %% in order to app;y the necessary modifictions so as to produce the MSAM
3 %% symbols that cope with the slides fonts
4 %%
5 %% Claudio Beccari 2007
6 %%
7 %
8 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
9
10 % Italic corrections have not been computed for most of these characters,
11 % since they are generally not slanted.
12
13 % Changed some assignments for
14 %
15 % cmchar "Circle-R brand"
16 % cmchar "Circle-S brand"
17 %
18 % to avoid rounding problems and the differences in TFM files for
19 % different magnifications
20 %
21 % Changed by Stefan Lindner 15.03.1991
22 %
23 % original: radius=.5(6u++cap_height)+3u; radius=radius#*hppp;
24 % changed: radius#=.5(6u#++cap_height#)+3u#; radius:=radius#*hppp;
25 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
26
27
28
29
30 def makesquare (suffix i,j,k,l) =
31 %% z.j, z.k are the lower left and right corners
32 %% assumed on baseline; ie, y.k=y.j=0
33 %% z.i, z.l are upper left and right corners
34 %% that is, start labeling with upper left corner, and
35 %% proceed to the successive corners counter-clockwise.
36 y.i-y.j=x.k-x.j; y.i:=good.y y.i+o; y.l=y.i
37 %% user must draw the square him/herself.
38 enddef;
39
40
41 cmchar "Square with dot";
42 beginchar(oct"000",14u#,12u#,0);
43 adjust_fit(0,0); pickup rule.nib;
44 lft x1=hround 1.0u; x2=x1; x4=x5=w-x1;
45 bot y2=0; y4=y2;
46 makesquare (1,2,4,5);
47 y3=good.y .5[y1,y2]; x3=good.x .5[x1,x5];
48 draw z1---z2---z4---z5---cycle; % square
49 fill fullcircle scaled dot_size shifted z3; % dot
50 penlabels(1,2,3,4,5); endchar;
51
52 cmchar "Square plus";
53 beginchar(oct"001",14u#,12u#,0);
54 adjust_fit(0,0); pickup rule.nib;
55 lft x1=hround 1.0u; x2=x1; x4=x5=w-x1;
56 bot y2=0; y4=y2; makesquare(1,2,4,5);
57 draw z1---z2---z4---z5---cycle; % square
58 x6=x1; x7=x4; y6=.5[y1,y2]; y7=y6; % cross strut
59 y8=y1; y9=y2; x8=.5[x1, x5]; x9=x8; % vertical strut
60 draw z6---z7; draw z8---z9; % plus
61 penlabels(1,2,4,5,6,7,8,9); endchar;
62
63 cmchar "Square times";
64 beginchar(oct"002",14u#,12u#,0);
65 adjust_fit(0,0); pickup rule.nib;
66 lft x1=hround 1.0u; x2=x1; x4=x5=w-x1;
67 bot y2=0; y4=y2; makesquare(1,2,4,5);
68 draw z1---z2---z4---z5---cycle; % square
69 draw z1---z4; draw z2---z5; % diagonals
70 penlabels(1,2,4,5); endchar;
71
72 cmchar "Square";
73 beginchar(oct"003",14u#,12u#,0);
74 adjust_fit(0,0); pickup rule.nib;
75 lft x1=hround 1.0u; x2=x1;
76 x4=x5=w-x1;
77 bot y2=0; y4=y2; makesquare(1,2,4,5);
78 draw z1---z2---z4---z5---cycle; % square
79 penlabels(1,2,4,5); endchar;
80
81 cmchar "Filled square";
82 beginchar(oct"004",14u#,12u#,0);
83 adjust_fit(0,0); pickup rule.nib;
84 lft x1=hround 1.0u; x2=x1; x4=x5=w-x1;
85 bot y2=0; y4=y2; makesquare(1,2,4,5);
86 filldraw z1---z2---z4---z5---cycle; % square
87 penlabels(1,2,4,5); endchar;
88
89 cmchar "Small filled square";
90 beginchar(oct"005",5u#,.8asc_height#,0);
91 adjust_fit(0,0); pickup rule.nib;
92 lft x1=hround 1.0u; x2=x1; x3=x4=w-x1;
93 bot y2=0; y3=y2; makesquare(1,2,3,4);
94 filldraw z1---z2---z3---z4---cycle; % draw and fill square
95 penlabels(1,2,3,4); endchar;
96
97
98 cmchar "Diamond";
99 beginchar(oct"006",12u#,asc_height#,2u#);
100 adjust_fit(0,0); pickup rule.nib;
101 %% z1, z2 are left & right vertices
102 %% z3, z4 are top and bottom points
103 lft x1=hround u; x2=w-x1; y1=y2;
104 x3=x4=.5[x1, x2]; bot y4=-d-o; top y3= good.y h+o;
105 y1=.5[y4,y3];
106 draw z1---z3---z2---z4---cycle; % draw diamond
107 penlabels(1,2,3,4); endchar;
108
109 cmchar "Filled Diamond";
110 beginchar(oct"007",12u#,asc_height#,2u#);
111 adjust_fit(0,0); pickup rule.nib;
112 %% z1, z2 are left & right vertices
113 %% z3, z4 are top and bottom points
114 lft x1=hround u; x2=w-x1; y1=y2;
115 x3=x4=.5[x1, x2]; bot y4=-d-o; top y3= good.y h+o;
116 y1=.5[y4,y3];
117 filldraw z1---z3---z2---z4---cycle; % draw diamond
118 penlabels(1,2,3,4); endchar;
119
120 % do char "011 before char "010.
121 cmchar "Counter-clockwise-circle indicator";
122 beginarithchar(oct"011"); pickup light_rule.nib;
123 autorounded; lft x6=hround u; x2=w-x6;
124 y2=math_axis; top y8=h;
125 circle_points; % define points on circumference
126 %% see page 487 of vol E
127 path p; numeric t;
128 p=z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
129 ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle;
130 t=xpart(p intersectiontimes ((4.5u,0)--(4.5u,y8)));
131 draw subpath (0,t) of p; % circle with gap
132 z0=.5[z5,z1]; % the origin of the circle
133 %% Now prepare for left arrowhead--see pg E465
134 pickup crisp.nib;
135 pos12(rule_thickness,90); pos13(bar,0); pos14(bar,0);
136 y10=y12=y8; lft x10=hround x8;
137 y13-y10=y10-y14=.19asc_height+eps; x13=x14=x10+3u+eps;
138 pos15(bar,angle(z14-z10)); z15l=z10;
139 pos16(bar,angle(z13-z10)); z16l=z10;
140 z19=.38[.5[z13,z14],z10];
141 numeric t; path p; % re-use t, p
142 p=z14r{z19-z14}..z16r;
143 t=xpart(p intersectiontimes((0,y12l)--(w,y12l)));
144 x12=xpart point t of p;
145 path p;
146 p=z10..{z14-z19}z14l--subpath(0,t) of
147 (z14r{z19-z14}..z16r)--z12l--z12r
148 --subpath(t,0) of (z13r{z19-z13}..z15r)
149 --z13l{z19-z13}..z10&cycle; % arrowhead
150 p:=p shifted -z8; % move back to origin
151 p:=p rotated -16; % rotate down a bit
152 p:=p shifted z8; % move back to tip of circle
153 filldraw p;
154 penlabels(0,1,2,3,5,6,7,8,9,10,11,12,13,14,15,16,19);
155 picture v; v:=currentpicture; endchar;
156
157 cmchar "Clockwise-circle indicator";
158 beginarithchar(oct"010");
159 currentpicture:=v reflectedabout ((w/2,0),(w/2,h));
160 penlabels(0,1,2,3,5,6,7,8,9,10); endchar;
161
162 cmchar "Left-Right Harpoons";
163 compute_spread(.45x_height#,.55x_height#);
164 beginchar(oct"013",18u#,v_center(spread#+.48asc_height#));
165 path topleft; % for top left half arrow (harpoon)
166 adjust_fit(0,0);
167 pickup crisp.nib;
168 pos1(rule_thickness,90); pos2(rule_thickness,90);
169 pos3(bar,0); pos4(bar,0); y0=y1=y2=math_axis;
170 x1+.5rule_thickness=hround(w-u); lft x0=hround u;
171 y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
172 pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0));
173 z6l=z0; numeric t; path p; p=z4r..{2(x0-x4),y0-y4}z6r;
174 t=xpart(p intersectiontimes((0,y2l)--(w,y2l)));
175 x2=xpart point t of p;
176 topleft=z0--(x0,y2l)---z1l..z1r---z2r
177 ..subpath (t,0) of\\(z3r..{2(x0-x3),y0-y3}z5r)
178 --z3l..{2(x0-x3),y0-y3}cycle; % arrowhead and stem
179 topleft:=
180 topleft shifted (0,.5spread); % shift above math_axis
181 path botright; % for bottom right half arrow
182 botright:=topleft reflectedabout ((w/2,0),(w/2,h));
183 botright:=botright reflectedabout
184 ((0,math_axis+eps),(w,math_axis+eps));
185 filldraw topleft; filldraw botright;
186 penlabels(0,1,2,3,4,5,6); endchar;
187
188 cmchar "Right-Left Harpoons";
189 compute_spread(.45x_height#,.55x_height#);
190 beginchar(oct"012",18u#,v_center(spread#+.48asc_height#));
191 path topright, botleft;
192 adjust_fit(0,0);
193 pickup crisp.nib;
194 topright:=topleft reflectedabout((w/2,0),(w/2,h));
195 botleft:=botright reflectedabout((w/2,0),(w/2,h));
196 filldraw topright; filldraw botleft; endchar;
197
198 cmchar "Square minus";
199 beginchar(oct"014",14u#,12u#,0); adjust_fit(0,0);
200 pickup rule.nib; lft x1=hround 1.0u; x2=x1; x4=x5=w-x1; bot
201 y2=0; y4=y2; makesquare(1,2,4,5);
202 draw z1---z2---z4---z5---cycle; % square
203 x6=x1; x7=x4; y6=.5[y1,y2]; y7=y6; % cross strut
204 draw z6---z7; % minus
205 penlabels(1,2,4,5,6,7); endchar;
206
207 cmchar "Forces";
208 beginchar(oct"015",13u#,asc_height#,0);
209 adjust_fit(0,0);; pickup rule.nib;
210 top y1=h; bot y2=0; y3=y4=good.y .5h; y5=y1; y6=y2;
211 lft x5=hround u; x4=w-x5;
212 compute_spread(.45x_height#,.55x_height#);
213 x1=x5+spread; x1=x2=x3; x6=x5;
214 draw z6--z5; draw z2--z1; draw z3--z4;
215 penlabels(1,2,3,4,5,6); endchar;
216
217 cmchar "Forces with extra bar";
218 beginchar(oct"016",16u#, asc_height#,0);
219 adjust_fit(0,0); pickup rule.nib;
220 compute_spread(.42x_height#,.52x_height#);
221 top y1=h; bot y2=0; y3=y4=good.y .5h;
222 y5=y7=y1; y6=y8=y2; lft x7=hround u; x4=w-x7;
223 x5=good.x x7+spread; x1=good.x x5+spread;
224 x1=x2=x3; x6=x5; x7=x8;
225 draw z7--z8; draw z5--z6; draw z1--z2; % verticals
226 draw z3--z4; % horizontal piece
227 penlabels(1,2,3,4,5,6,7,8); endchar;
228
229 cmchar "Satisfies";
230 beginchar(oct"017",11u#,asc_height#,0);
231 adjust_fit(0,0); pickup rule.nib;
232 compute_spread(.45x_height#,.55x_height#);
233 top y1=h; bot y2=0; y0=good.y .5[y1,y2];
234 y3=vround y0+.5spread;
235 y5=vround y0- .5spread; y4=y3; y6=y5;
236 lft x1=hround u; x4=w-x1;
237 x1=x2=x3=x5; x4=x6; x0=x1;
238 draw z1--z2; % vertical line
239 draw z3--z4; % draw top horizontal piece
240 draw z5--z6; % draw bottom horizontal piece
241 penlabels(0,1,2,3,4,5,6); endchar;
242
243 cmchar "Rightward double arrowhead";
244 compute_spread(.45x_height#,.55x_height#);
245 beginchar(oct"020",18u#,v_center(spread#+.48asc_height#)); adjust_fit(0,0);
246 pickup crisp.nib; pos1(rule_thickness,90); pos2(rule_thickness,90);
247 pos3(bar,0); pos4(bar,0); y0=y1=y2=math_axis; x1-.5rule_thickness=hround u;
248 rt x0=hround(w-u); y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0-3u-eps;
249 pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0)); z6l=z0;
250 z9=.381966[.5[z3,z4],z0]; numeric t; path p; p=z4l{z9-z4}..z6r; t=xpart(p
251 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p; path p;
252 p=z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
253 --z2l--z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
254 --z3r{z9-z3}..z0 & cycle;
255 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
256 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
257 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
258 filldraw p shifted (x3l-x0,0);
259 penlabels(0,1,2,3,4,5,6,9); endchar;
260
261 cmchar "Leftward double arrowhead";
262 compute_spread(.45x_height#,.55x_height#);
263 beginchar(oct"021",18u#,v_center(spread#+.48asc_height#));
264 adjust_fit(0,0); pickup crisp.nib;
265 pos1(rule_thickness,90); pos2(rule_thickness,90);
266 pos3(bar,0); pos4(bar,0); y0=y1=y2=math_axis;
267 x1+.5rule_thickness=hround(w-u); lft x0=hround u;
268 y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
269 pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0));
270 z6l=z0; z9=.381966[.5[z3,z4],z0];
271 numeric t; path p;
272 p=z4r{z9-z4}..z6r;
273 t=xpart(p intersectiontimes((0,y2l)--(w,y2l)));
274 x2=xpart point t of p;
275 path p; p=z0..{z4-z9}z4l--subpath (0,t)
276 of\\(z4r{z9-z4}..z6r)
277 --z2l--z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
278 --z3l{z9-z3}..z0 & cycle; % second arrowhead
279 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
280 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
281 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
282 filldraw p shifted (x3r-x0,0);
283 penlabels(0,1,2,3,4,5,6,9); endchar;
284
285 cmchar "Leftward double arrow";
286 compute_spread(.45x_height#,.55x_height#);
287 beginchar(oct"022",18u#,v_center(spread#+.96asc_height#));
288 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90);
289 pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0);
290 y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft
291 x0=hround u; y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
292 pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0));
293 z6l=z0; z9=.381966[.5[z3,z4],z0]; numeric t; path p;
294 p=z4r{z9-z4}..z6r; t=xpart(p
295 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
296 path p; % re-use p
297 p=z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
298 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
299 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
300 p:=p shifted (0,y2-y4+eps); filldraw p; % top arrow
301 p:= p shifted (0,y4-y3-eps); filldraw p; % bottom arrow
302 penlabels(0,1,2,3,4,5,6,9); endchar;
303
304 cmchar "Rightward double arrow";
305 compute_spread(.45x_height#,.55x_height#);
306 beginchar(oct"023",18u#,v_center(spread#+.96asc_height#));
307 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90);
308 pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0);
309 y0=y1=y2=math_axis; x1-.5rule_thickness=hround u; rt
310 x0=hround(w-u); y3-y0=y0-y4=.24asc_height+eps;
311 x3=x4=x0-3u-eps; pos5(bar,angle(z4-z0)); z5l=z0;
312 pos6(bar,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
313 numeric t; path p; p=z4l{z9-z4}..z6r; t=xpart(p
314 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
315 path p; p=z0..{z4-z9}z4r--subpath (0,t)
316 of\\(z4l{z9-z4}..z6r)
317 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
318 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
319 p:=p shifted (0,y2-y4+eps); filldraw p; % top
320 p:=p shifted (0,y4-y3-eps); filldraw p; %bottom
321 penlabels(0,1,2,3,4,5,6,9); endchar;
322
323 cmchar "Double upward arrow";
324 beginchar(oct"024",15u#,asc_height#,asc_depth#); italcorr
325 .76asc_height#*slant+.5crisp#-u#; adjust_fit(0,0); pickup
326 crisp.nib; pos1(rule_thickness,0); pos2(rule_thickness,0);
327 pos3(bar,90); pos4(bar,90); lft
328 x1l=hround(.5w-.5rule_thickness); y1-.5rule_thickness=-d;
329 x0=x1=x2; top y0=h; x0-x3=x4-x0=3u+eps;
330 y3=y4=y0-.24asc_height-eps; pos5(bar,angle(z4-z0)); z5l=z0;
331 pos6(bar,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
332 numeric t; path p; p=z4l{z9-z4}..z6r; t=xpart(p
333 intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of
334 p;
335 path p; p=z0..{z4-z9}z4r--subpath (0,t)
336 of\\(z4l{z9-z4}..z6r)
337 --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3l{z9-z3}..z5r)
338 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
339 p:=p shifted (x0-x4-eps,0); filldraw p; % left arrow
340 p:=p shifted (x4-x3+eps,0); filldraw p;
341 penlabels(0,1,2,3,4,5,6,9); endchar;
342
343 cmchar "Double downward arrow";
344 beginchar(oct"025",15u#,asc_height#,asc_depth#);
345 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,0);
346 pos2(rule_thickness,0); pos3(bar,90); pos4(bar,90); lft
347 x1l=hround(.5w-.5rule_thickness); y1+.5rule_thickness=h;
348 x0=x1=x2; bot y0=-d; x0-x3=x4-x0=3u+eps;
349 y3=y4=y0+.24asc_height+eps; pos5(bar,angle(z4-z0)); z5l=z0;
350 pos6(bar,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
351 numeric t; path p; p=z4r{z9-z4}..z6r; t=xpart(p
352 intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of
353 p;
354 path p; p=z0..{z4-z9}z4l--subpath (0,t)
355 of\\(z4r{z9-z4}..z6r)
356 --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3r{z9-z3}..z5r)
357 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
358 p:=p shifted (x0-x4-eps,0); filldraw p; % left arrow
359 p:=p shifted (x4-x3+eps,0); filldraw p;
360 penlabels(0,1,2,3,4,5,6,9); endchar;
361
362 %%
363 cmchar "Upward rightward harpoon";
364 beginchar(oct"026",7.5u#,asc_height#, asc_depth#);
365 %% see page E431
366 adjust_fit(0,0); pickup crisp.nib;
367 x0=x1=x2; lft x1l=hround(.5w-.5rule_thickness);
368 y1-.5rule_thickness=-d; pos1(rule_thickness,0);
369 pos2(rule_thickness,0); pos3(bar,-90); pos4(bar,-90);
370 top y0=vround h;
371 x3-x0=x0-x4=.24asc_height+eps; y3=y4=y0-3u-eps;
372 pos5(bar,angle(z4-z0)); z5l=z0;
373 pos6(bar,angle(z3-z0)); z6l=z0;
374 z9=.381966[.5[z3,z4],z0];
375 numeric t; path p;
376 p=z4r..{y0-y4,2(x0-x4)}z6r;
377 t=xpart (p intersectiontimes ((x2l,0)--(x2l,h)));
378 y2=ypart point t of p;
379 filldraw z0--(x2l,y0)---z1l..z1r---z2r
380 ..subpath(t,0) of (z3r..{x0-x3,2(y0-y3)}z5r)
381 --z3l..{x0-x3,2(y0-y3)}cycle;
382 picture v; v:=currentpicture;
383 penlabels(0,1,2,3,4,5,6,9); endchar;
384
385 cmchar "Downward rightward harpoon";
386 beginchar(oct"027",7.5u#,asc_height#,asc_depth#);
387 adjust_fit(0,0);
388 currentpicture:=v
389 reflectedabout((0,.5(h-d)*aspect_ratio+eps),(w,.5(h-d)*aspect_ratio+eps));
390 penlabels(0,1,2,3,4,5,6); endchar;
391
392 cmchar "Upward leftward harpoon";
393 beginchar(oct"030",7.5u#,asc_height#, asc_depth#);
394 adjust_fit(0,0);
395 currentpicture:=
396 v reflectedabout((w/2+eps,-d),(w/2+eps,h));
397 picture v; v:=currentpicture;
398 penlabels(0,1,2,3,4,5,6); endchar;
399
400 cmchar "Downward leftward harpoon";
401 beginchar(oct"031",7.5u#,asc_height#,asc_depth#);
402 adjust_fit(0,0);
403 currentpicture:=v
404 reflectedabout((0,.5(h-d)*aspect_ratio+eps),(w,.5(h-d)*aspect_ratio+eps));
405 penlabels(0,1,2,3,4,5,6); endchar;
406
407 cmchar "Rightward arrow with tail";
408 compute_spread(.45x_height#,.55x_height#);
409 beginchar(oct"032",20u#,v_center(spread#+.48asc_height#));
410 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90);
411 pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0);
412 y0=y1=y2=math_axis; x1-.5rule_thickness=hround 1.5u; rt
413 x0=hround(w-3u); y3-y0=y0-y4=.24asc_height+eps;
414 x3=x4=x0-3u-eps; pos5(bar,angle(z4-z0)); z5l=z0;
415 pos6(bar,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
416 numeric t; path p; p=z4l{z9-z4}..z6r; t=xpart(p
417 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
418 path p;
419 p=z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
420 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
421 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
422 path arrow;
423 arrow=z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
424 --z2l---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
425 --z3r{z9-z3}..z0 & cycle;
426 p:=p shifted (2u,0); filldraw p;
427 arrow:=arrow shifted (-13u+bar,0); filldraw arrow;
428 penlabels(0,1,2,3,4,5,6,9); endchar;
429
430 cmchar "Leftward arrow with tail";
431 beginchar(oct"033",20u#,v_center(spread#+.48asc_height#));
432 adjust_fit(0,0); pickup crisp.nib;
433 p:= p reflectedabout ((w/2+eps,-d),(w/2+eps,h));
434 arrow:= arrow reflectedabout ((w/2+eps,-d),(w/2+eps,h));
435 filldraw p; filldraw arrow;
436 penlabels(0,1,2,3,4,5,6,9); endchar;
437
438 cmchar "Leftward-rightward parallel arrows";
439 compute_spread(.45x_height#,.55x_height#);
440 beginchar(oct"034",18u#,v_center(spread#+.96asc_height#));
441 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90);
442 pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0);
443 y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft
444 x0=hround u; y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
445 pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0));
446 z6l=z0; z9=.381966[.5[z3,z4],z0]; numeric t; path p;
447 p=z4r{z9-z4}..z6r; t=xpart(p
448 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
449 path p, q; % re-use p
450 p=z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
451 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
452 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
453 p:=p shifted (0,.5[y3,y4]+eps); filldraw p; % top arrow
454 p:= p shifted (0,y4-y3);
455 q:= p reflectedabout ((w/2+eps,-d),(w/2+eps,h));
456 p:=p shifted (0,y3-y4+eps); % restore p's position
457 filldraw q; % bottom arrow
458 penlabels(0,1,2,3,4,5,6,9); endchar;
459
460 cmchar "Rightward-leftward parallel arrow";
461 compute_spread(.45x_height#,.55x_height#);
462 beginchar(oct"035",18u#,v_center(spread#+.96asc_height#));
463 adjust_fit(0,0); pickup crisp.nib;
464 p:=p reflectedabout ((w/2+eps,-d),(w/2+eps,h));
465 q:=q reflectedabout ((w/2+eps,-d),(w/2+eps,h));
466 filldraw p; filldraw q;
467 penlabels(0,1,2,3,4,5,6,9); endchar;
468
469 cmchar "Leftward shift";
470 beginchar(oct"036",9u#,asc_height#, 0);
471 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90);
472 pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0);
473 y0=y1=y2=.8h; x1+.5rule_thickness=hround(w-u); lft x0=hround
474 u; y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
475 pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0));
476 z6l=z0; z9=.381966[.5[z3,z4],z0];
477 z10=z1; x11=x10; y11-.5rule_thickness =vround -d;
478 pos10(rule_thickness,0); pos11(rule_thickness,0);
479 numeric t; path p; p=z4r{z9-z4}..z6r;
480 t=xpart(p intersectiontimes((0,y2l)--(w,y2l)));
481 x2=xpart point t of p;
482 path p;
483 p=z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
484 --z2l---(x10l,y1l)--z11l..z11r---{up}z10r..{left}z1r---z2r--subpath
485 (t,0) of\\(z3r{z9-z3}..z5r)
486 --z3l{z9-z3}..z0 & cycle; % arrowhead and bent stem
487 filldraw p;
488 penlabels(0,1,2,3,4,5,6,9,10); endchar;
489
490 cmchar "Rightward shift";
491 beginchar(oct"037",9u#,asc_height#, 0);
492 adjust_fit(0,0); pickup crisp.nib;
493 p:=p reflectedabout((w/2+eps,-d),(w/2+eps,h));
494 filldraw p;
495 penlabels(0,1,2,3,4,5,6,9); endchar;
496
497 compute_spread(.45x_height#,.55x_height#);
498 cmchar "Rightward squiggly arrow";
499 beginchar(oct"040",18u#,v_center(spread# +
500 rule_thickness#));
501 adjust_fit(0,0); pickup crisp.nib;
502 pos1(rule_thickness,90); pos2(rule_thickness,90);
503 pos3(bar,0); pos4(bar,0); y0=y1=y2=math_axis;
504 x1-.5rule_thickness=hround 11u; rt x0=hround(w-u);
505 y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0-3u-eps;
506 pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0));
507 z6l=z0; z9=.381966[.5[z3,z4],z0];
508 numeric t; path p;
509 p=z4l{z9-z4}..z6r; t=xpart(p
510 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
511 path p;
512 p=z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
513 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
514 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
515 filldraw p;
516 %% now for squiggle
517 x12-x11=x13-x12=x14-x13=x15-x14=x16-x15=x1-x16;
518 x1-x11=hround (w-2u-x0+x1-.5rule_thickness);
519 y11=y13=y15=y0; y12=y16=.5[y0,y3];
520 y14=.5[y4,y0];
521 pickup pencircle scaled rule_thickness;
522 draw z11---z12---z14---z16---z1;
523 penlabels(0,1,2,3,4,5,6,9,11,12,13,14,15,16); endchar;
524
525 compute_spread(.45x_height#,.55x_height#);
526 cmchar "Leftward rightward squiggly arrow";
527 beginchar(oct"041",25u#,v_center(spread# +
528 rule_thickness#));
529 adjust_fit(0,0); pickup crisp.nib;
530 arrow_length=4.5u+eps;
531 pos1(rule_thickness,90); pos2(rule_thickness,90);
532 pos3(bar,0); pos4(bar,0); y0=y1=y2=math_axis;
533 x1+.5rule_thickness=hround(u+arrow_length);
534 lft x0=hround u; y3-y0=y0-y4=.24asc_height+eps;
535 x3=x4=x0+3u+eps; pos5(bar,angle(z4-z0)); z5l=z0;
536 pos6(bar,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
537 numeric t; path p; p=z4r{z9-z4}..z6r; t=xpart(p
538 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
539 path p; p=z0..{z4-z9}z4l--subpath (0,t)
540 of\\(z4r{z9-z4}..z6r)
541 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
542 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
543 filldraw p; % left arrow
544 p:=p reflectedabout ((w/2+eps,-d),(w/2+eps,h));
545 filldraw p; % right arrow
546 z10=z1 reflectedabout ((w/2+eps,-d),(w/2+eps,h));
547 y11=y15=y19=.5[y0,y3]; y13=y17=.5[y4,y0];
548 y12=y14=y16=y18=y10;
549 x11-x1=x12-x11=x13-x12=x14-x13=x15-x14=x16-x15=x17-x16=x18-x17=
550 x19-x18=x10-x19;
551 pickup pencircle scaled rule_thickness;
552 draw z1---z11---z13---z15---z17---z19---z10;
553 penlabels(0,1,2,3,4,5,6,9,10,11,12,13,14,15,16,17,18,19);
554 endchar;
555
556 cmchar "Leftward curly arrow";
557 beginchar(oct"042",18u#,.8asc_height#,0#);
558 adjust_fit(0,0); pickup crisp.nib;
559 numeric arrow_length; arrow_length=.66*(w-2u+eps);
560 pos1(rule_thickness,90); pos2(rule_thickness,90);
561 pos3(bar,0); pos4(bar,0); y0=y1=y2=math_axis;
562 x1+.5rule_thickness=hround(u+arrow_length);
563 lft x0=hround u; y3-y0=y0-y4=.24asc_height+eps;
564 x3=x4=x0+3u+eps; pos5(bar,angle(z4-z0)); z5l=z0;
565 pos6(bar,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
566 numeric t; path p; p=z4r{z9-z4}..z6r; t=xpart(p
567 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
568 path p; p=z0..{z4-z9}z4l--subpath (0,t)
569 of\\(z4r{z9-z4}..z6r)
570 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
571 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
572 filldraw p; % left arrow
573 z10=z1; x13=x14=hround(u+arrow_length+eps); y13=y1; y14=-o;
574 x12=.5[x11,x13]; y12=h; rt x11=hround(w-u); y11=.5[y10,y12];
575 pickup pencircle scaled rule_thickness;
576 path q;
577 q=z10{right}..tension0.8..{up}z11..tension0.8..{left}z12
578 ..tension0.8..{down}z13--z14;
579 draw q;
580 penlabels(0,1,2,3,4,5,6,9,10,11,12,13,14); endchar;
581
582 cmchar "Rightward curly arrow";
583 beginchar(oct"043",18u#,.8asc_height#,0#);
584 adjust_fit(0,0); pickup crisp.nib;
585 p:=p reflectedabout ((w/2+eps,-d),(w/2+eps,h));
586 filldraw p;
587 pickup pencircle scaled rule_thickness;
588 q:=q reflectedabout ((w/2+eps,-d),(w/2+eps,h));
589 draw q; endchar;
590
591 numeric circ_diam; % diameter of little circle
592 circ_diam=2.5u;
593 cmchar "Equals circle sign";
594 compute_spread(.45x_height#,.55x_height#);
595 beginchar(oct"044",14u#,v_center(4spread#+rule_thickness#+2.5u#));
596 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
597 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; y1=y2; y3=y4;
598 y1-y3=spread; .5[y1,y3]=math_axis; draw z1--z2; % upper bar
599 draw z3--z4; % lower bar %
600 penpos11(rule_thickness,90); penpos13(rule_thickness,-90);
601 penpos12(rule_thickness,180); penpos14(rule_thickness,0);
602 x12r=hround(.5w-.5circ_diam-rule_thickness); %
603 x14r=w-x12r; x11=x13=.5w; y11l=y13l+circ_diam;
604 y12=y14=.5[y11,y13]; y13r=vround(y1+.8spread); %
605 penstroke pulled_arc.e(11,12) & pulled_arc.e(12,13)
606 & pulled_arc.e(13,14) & pulled_arc.e(14,11) & cycle; %
607 penlabels(1,2,3,4,11,12,13,14); endchar;
608
609
610
611 cmchar "Follows or equals sign";
612 compute_spread(.45x_height#,.55x_height#);
613 spread#':=spread#; spread':=spread; % spread of similarity sign
614 compute_spread(.54 x_height#,.66 x_height#);
615 spread#'':=spread#; spread'':=spread; % spread between symbols
616 compute_spread(5/4 x_height#,3/2 x_height#); % spread of follows sign
617 beginchar(oct"045",14u#,v_center(spread#'+spread#+spread#''));
618 adjust_fit(0,0); pickup rule.nib; autorounded;
619 lft x1=hround 1.5u-eps; x1=x3; x2=w-x1;
620 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
621 draw z1{u,-spread}...{right}z2; %upper `diagonal'
622 draw z3{u,spread}...{right}z2; % lower diagonal
623 pickup pencircle xscaled .7rule_thickness yscaled
624 1.4rule_thickness;
625 if vair#>.8curve#: pickup rule.nib; autorounded; fi
626 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
627 bot y11=bot y13; top y12=top y14;
628 top y12-bot y11=spread'';
629 y3-y14=spread';
630 draw z11{up}...z12{right}..{right}z13...{up}z14;
631 penlabels(1,2,3,11,12,13,14); endchar;
632
633 cmchar "Greater than or similar to sign";
634 compute_spread(.45x_height#,.55x_height#);
635 spread#':=spread#; spread':=spread;
636 compute_spread(.54x_height#,.66x_height#);
637 spread#'':=spread#; spread'':=spread;
638 compute_spread(5/4 x_height#,3/2 x_height#);
639 beginchar(oct"046",14u#,v_center(spread#'+spread#+spread#''));
640 adjust_fit(0,0); pickup rule.nib; autorounded;
641 lft x1=hround 1.5u-eps; x1=x3; x2=w-x1;
642 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
643 draw z1--z2--z3;
644 pickup pencircle xscaled .7rule_thickness yscaled
645 1.4rule_thickness;
646 if vair#>.8curve#: pickup rule.nib; autorounded; fi
647 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
648 bot y11=bot y13; top y12=top y14;
649 top y12-bot y11=spread'';
650 y3-y14=spread';
651 draw z11{up}...z12{right}..{right}z13...{up}z14;
652 penlabels(1,2,3,4,11,12,13,14); endchar;
653
654 cmchar "Greater than or approximately equal to sign";
655 compute_spread(.45x_height#,.55x_height#);
656 spread#':=spread#; spread':=spread;
657 compute_spread(.54x_height#,.66x_height#);
658 spread#'':=spread#; spread'':=spread; % spread between similarities
659 compute_spread(1.111 x_height#,1.333 x_height#);
660 beginchar(oct"047",14u#,v_center(spread#+2spread#''+2rule_thickness#));
661 adjust_fit(0,0); pickup rule.nib; autorounded;
662 lft x1=hround 1.5u-eps; x1=x3; x2=w-x1;
663 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
664 draw z1--z2--z3;
665 pickup pencircle xscaled .7rule_thickness yscaled
666 1.4rule_thickness;
667 if vair#>.8curve#: pickup rule.nib; autorounded; fi
668 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
669 bot y11=bot y13; top y12=top y14;
670 top y12-bot y11=spread';
671 bot y3- top y13 = spread'';
672 path p; p=z11{up}...z12{right}..{right}z13...{up}z14;
673 draw p; draw p shifted (0,-spread'');
674 penlabels(1,2,3,4,11,12,13,14); endchar;
675
676 cmchar "Multimap symbol";
677 beginchar(oct"050",20u#,.8asc_height#,0#);
678 adjust_fit(0,0); pickup rule.nib; autorounded;
679 numeric circ_diam; circ_diam=5u;
680 y2=math_axis; y8=y2+.5circ_diam; rt x2=w-u;
681 x6=x2-circ_diam;
682 circle_points; draw_circle;
683 x9=u+.5rule_thickness; y9=y10=y2; x10=x6-.5rule_thickness;
684 draw z9---z10;
685 penlabels(1,2,3,4,5,6,7,8,9,10); endchar;
686
687 cmchar "Therefore";
688 beginchar(oct"051",12u#,asc_height#,0);
689 adjust_fit(0,0);
690 lft x1=hround 1.5u; x2=w-x1; bot y1=-o; y2=y1;
691 z3-z1=(z2-z1)rotated60;
692 fill fullcircle scaled dot_size shifted z1;
693 % left bottom dot
694 fill fullcircle scaled dot_size shifted z2;
695 % rigth bottom
696 fill fullcircle scaled dot_size shifted z3; % top dot
697 penlabels(1,2,3); endchar;
698
699
700 cmchar "Because";
701 beginchar(oct"052",12u#,asc_height#,0);
702 adjust_fit(0,0);
703 lft x1=hround 1.5u; x2=w-x1; y2=y1;
704 x3=w/2; y3=-o;
705 z3-z1=(z2-z1)rotated-60;
706 fill fullcircle scaled dot_size shifted z1; % top left dot
707 fill fullcircle scaled dot_size shifted z2;
708 % top right dot
709 fill fullcircle scaled dot_size shifted z3; % bottom dot
710 penlabels(1,2,3); endchar;
711
712 cmchar "Equals-and-dots sign";
713 beginarithchar(oct"053");
714 compute_spread(.45x_height#,.55x_height#);
715 pickup rule.nib;
716 lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
717 y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
718 draw z1--z2; draw z3--z4; % draw bars
719 pickup light_rule.nib;
720 x5=x6=x7=x8=hround w/2+eps; z5=z6; z7=z8;
721 penpos5(.8dot_size,0); penpos6(.8dot_size,90);
722 penpos7(.8dot_size,0); penpos8(.8dot_size,90);
723 y5-y1=y3-y7=spread;
724 dot(5,6); dot(7,8); % draw dots
725 penlabels(1,2,3,4,5,6,7,8); endchar;
726
727 cmchar "Equals sign with triangle";
728 beginchar(oct"054", 14u#,12u#+math_axis# ,6u#-math_axis#);
729 compute_spread(.45x_height#,.55x_height#);
730 pickup rule.nib;
731 lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
732 y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
733 draw z1--z2; draw z3--z4; % draw bars
734 numeric tri_side; % length of equilateral triangle
735 tri_side=7u;
736 x6-x5=tri_side; .5[x5,x6]=w/2; y5=y6; y5-y1=.8spread;
737 %top y7=body_height;x7=w/2;
738 z7-z5=(z6-z5) rotated 60;
739 draw z5--z6--z7--cycle;
740 penlabels(1,2,3,4,5,6,7); endchar;
741
742
743 cmchar "Precedes or equals sign";
744 compute_spread(.45x_height#,.55x_height#);
745 spread#':=spread#; spread':=spread;
746 compute_spread(.54x_height#,.55x_height#);
747 spread#'':=spread#; spread'':=spread;
748 compute_spread(5/4 x_height#,3/2 x_height#);
749 beginchar(oct"055",14u#,v_center(spread#'+spread#+spread#''));
750 adjust_fit(0,0); pickup rule.nib; autorounded;
751 lft x2=hround 1.5u-eps; x1=x3=w-x2;
752 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
753 draw z1{-u,-spread}...{left}z2; %upper `diagonal'
754 draw z3{-u,spread}...{left}z2; % lower diagonal
755 pickup pencircle xscaled .7rule_thickness yscaled
756 1.4rule_thickness;
757 if vair#>.8curve#: pickup rule.nib; autorounded; fi
758 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
759 bot y11=bot y13; top y12=top y14;
760 top y12-bot y11=spread'';
761 y3-y14=spread';
762 draw z11{up}...z12{right}..{right}z13...{up}z14;
763 penlabels(1,2,3,11,12,13,14); endchar;
764
765 cmchar "Less than or similar to sign";
766 compute_spread(.45x_height#,.55x_height#);
767 spread#':=spread#; spread':=spread;
768 compute_spread(.54x_height#,.55x_height#);
769 spread#'':=spread#; spread'':=spread;
770 compute_spread(5/4 x_height#,3/2 x_height#);
771 beginchar(oct"056",14u#,v_center(spread#'+spread#+spread#''));
772 adjust_fit(0,0); pickup rule.nib; autorounded;
773 lft x2=hround 1.5u-eps; x1=x3=w-x2;
774 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
775 draw z1--z2--z3;
776 pickup pencircle xscaled .7rule_thickness yscaled
777 1.4rule_thickness;
778 if vair#>.8curve#: pickup rule.nib; autorounded; fi
779 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
780 bot y11=bot y13; top y12=top y14;
781 top y12-bot y11=spread'';
782 y3-y14=spread';
783 draw z11{up}...z12{right}..{right}z13...{up}z14;
784 penlabels(1,2,3,4,11,12,13,14); endchar;
785
786 cmchar "Less than or approximately equal to sign";
787 compute_spread(.45x_height#,.55x_height#);
788 spread#':=spread#; spread':=spread;
789 compute_spread(.54x_height#,.66x_height#);
790 spread#'':=spread#; spread'':=spread; % spread between similarities
791 compute_spread(1.111 x_height#,1.333 x_height#);
792 beginchar(oct"057",14u#,v_center(spread#+2spread#''+2rule_thickness#));
793 adjust_fit(0,0); pickup rule.nib; autorounded;
794 lft x2=hround 1.5u-eps; x1=x3=w-x2;
795 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
796 draw z1--z2--z3;
797 pickup pencircle xscaled .7rule_thickness yscaled
798 1.4rule_thickness;
799 if vair#>.8curve#: pickup rule.nib; autorounded; fi
800 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
801 bot y11=bot y13; top y12=top y14;
802 top y12-bot y11=spread';
803 bot y3- top y13 = spread'';
804 path p; p=z11{up}...z12{right}..{right}z13...{up}z14;
805 draw p; draw p shifted (0,-spread'');
806 penlabels(1,2,3,4,11,12,13,14); endchar;
807
808 cmchar "Equal or less than sign";
809 compute_spread(.45x_height#,.55x_height#);
810 spread#':=spread#; spread':=spread;
811 compute_spread(5/4x_height#,3/2x_height#);
812 beginchar(oct"060",14u#,v_center(spread#'+spread#+rule_thickness#));
813 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
814 lft x2=hround 1.5u-eps; x1=x3=w-x2; y1-y3=spread;
815 y2=.5[y1,y3]; y8-y1=y9-y2=spread'; top y8=h;
816 x2=x9; x1=x8;
817 draw z1--z2--z3; % diagonals
818 draw z8--z9; % equal sign
819 penlabels(1,2,3,8,9); endchar;
820
821 cmchar "Equal or greater than sign";
822 compute_spread(.45x_height#,.55x_height#);
823 spread#':=spread#; spread':=spread;
824 compute_spread(5/4x_height#,3/2x_height#);
825 beginchar(oct"061",14u#,v_center(spread#'+spread#+rule_thickness#));
826 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
827 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
828 x2=x9; x1=x8;
829 y2=.5[y1,y3]; y8-y1=y9-y2=spread'; top y8=h;
830 draw z1--z2--z3; % diagonals
831 draw z8--z9;
832 penlabels(1,2,3,8,9); endchar;
833
834 cmchar "Less than or (slanted) equal sign";
835 compute_spread(.45x_height#,.55x_height#);
836 spread#':=spread#; spread':=spread;
837 compute_spread(5/4x_height#,3/2x_height#);
838 beginchar(oct"066",14u#,v_center(spread#'+spread#+rule_thickness#));
839 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
840 lft x2=hround 1.5u-eps; x1=x3=w-x2; y1-y3=spread;
841 y2=.5[y1,y3]; y3-y8=y2-y9=spread'; top y1=h;
842 x2=x9; x1=x8;
843 draw z1--z2--z3; % diagonals
844 draw z8--z9; % equal sign
845 penlabels(1,2,3,8,9); endchar;
846
847 cmchar "Greater than or (slanted) equal sign";
848 compute_spread(.45x_height#,.55x_height#);
849 spread#':=spread#; spread':=spread;
850 compute_spread(5/4x_height#,3/2x_height#);
851 beginchar(oct"076",14u#,v_center(spread#'+spread#+rule_thickness#));
852 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
853 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
854 x2=x9; x1=x8;
855 y2=.5[y1,y3]; y3-y8=y2-y9=spread'; top y1=h;
856 draw z1--z2--z3; % diagonals
857 draw z8--z9;
858 penlabels(1,2,3,8,9); endchar;
859 cmchar "Less than or greater than sign";
860 compute_spread(.4x_height#,.5x_height#);
861 spread#':=spread#; spread':=spread;
862 compute_spread(1.111 x_height#,1.333 x_height#);
863 beginchar(oct"067",14u#,v_center(2spread#'+spread#+rule_thickness#));
864 adjust_fit(0,0); pickup rule.nib; autorounded;
865 lft x1=hround w-1.5u+eps; x1=x3=x5; x2=x4=x6=w-x1;
866 y1-y3=spread; top y1=h; y2-y4=spread'; y4-y6=spread;
867 y2=.5[y1,y3]; y5=.5[y4,y6];
868 draw z1--z2--z3; draw z4--z5--z6;
869 penlabels(1,2,3,4,5,6); endchar;
870
871 cmchar "Greater than or less than sign";
872 compute_spread(.4x_height#,.5x_height#);
873 spread#':=spread#; spread':=spread;
874 compute_spread(1.111 x_height#,1.333x_height#);
875 beginchar(oct"077",14u#,v_center(2spread#'+spread#+rule_thickness#));
876 adjust_fit(0,0); pickup rule.nib; autorounded;
877 lft x1=hround 1.5u-eps; x1=x3=x5; x2=x4=x6=w-x1;
878 y1-y3=spread; top y1=h; y2-y4=spread'; y4-y6=spread;
879 y2=.5[y1,y3]; y5=.5[y4,y6];
880 draw z1--z2--z3; draw z4--z5--z6;
881 penlabels(1,2,3,4,5,6); endchar;
882
883 cmchar "Equals or precedes sign";
884 compute_spread(.45x_height#,.55x_height#);
885 spread#':=spread#; spread':=spread;
886 compute_spread(5/4x_height#,3/2x_height#);
887 beginchar(oct"062",14u#,v_center(spread#'+spread#+rule_thickness#));
888 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
889 lft x2=hround(1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
890 y2=.5[y1,y3]; top y8-bot y1=top y9-bot y2=spread'; bot y3=0;
891 x2=x9;x8=x1-2u;
892 draw z1{-u,-spread}...{left}z2;
893 draw z3{-u, spread}...{left}z2;
894 draw z8{-u,-spread}...{left}z9;
895 penlabels(1,2,3,8,9); endchar;
896
897 cmchar "Equals or follows sign";
898 compute_spread(.45x_height#,.55x_height#);
899 spread#':=spread#; spread':=spread;
900 compute_spread(5/4x_height#,3/2x_height#);
901 beginchar(oct"063",14u#,v_center(spread#'+spread#+rule_thickness#));
902 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
903 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
904 y2=.5[y1,y3]; top y8-bot y1=top y9-bot y2=spread'; bot y3=0;% top y8=h;
905 x2=x9;x8=x1+2u;
906 draw z1{u,-spread}...{right}z2;
907 draw z3{u, spread}...{right}z2;
908 draw z8{u,-spread}...{right}z9;
909 penlabels(1,2,3,8,9); endchar;
910
911 cmchar "Precedes or curvy equals sign";
912 compute_spread(.45x_height#,.55x_height#);
913 spread#':=spread#; spread':=spread;
914 compute_spread(5/4x_height#,3/2x_height#);
915 beginchar(oct"064",14u#,v_center(spread#'+spread#+rule_thickness#));
916 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
917 lft x2=hround(1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
918 y2=.5[y1,y3]; top y3-bot y8=top y2-bot y9=spread'; bot y3=0;
919 x2=x9;x8=x1-2u;
920 %for i=1 upto 3: %lower entire character
921 %y[i]:=y[i]-spread'; endfor
922 %for i=8 upto 9:
923 %y[i]:=y[i]-spread'; endfor
924 draw z1{-u,-spread}...{left}z2;
925 draw z3{-u, spread}...{left}z2;
926 draw z8{-u, spread}...{left}z9;
927 penlabels(1,2,3,8,9); endchar;
928
929 cmchar "Follows or curvy equals sign";
930 compute_spread(.45x_height#,.55x_height#);
931 spread#':=spread#; spread':=spread;
932 compute_spread(5/4x_height#,3/2x_height#);
933 beginchar(oct"074",14u#,v_center(spread#'+spread#+rule_thickness#));
934 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
935 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
936 y2=.5[y1,y3]; top y3-bot y8=top y2-bot y9=spread'; bot y3=0;
937 x2=x9;x8=x1+2u;
938 %for i=1 upto 3: %lower entire character
939 %y[i]:=y[i]-spread'; endfor
940 %for i=8 upto 9:
941 %y[i]:=y[i]-spread'; endfor
942 draw z1{u,-spread}...{right}z2;
943 draw z3{u, spread}...{right}z2;
944 draw z8{u, spread}...{right}z9;
945 penlabels(1,2,3,8,9); endchar;
946
947 cmchar "Less than or (double) equals sign";
948 compute_spread(.45x_height#,.55x_height#);
949 spread#':=spread#; spread':=spread;
950 compute_spread(5/4x_height#,3/2x_height#);
951 beginchar(oct"065",14u#,v_center(2spread#'+spread#+2rule_thickness#));
952 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
953 lft x2=hround 1.5u-eps; x1=x3=w-x2; y1-y3=spread;
954 y2=.5[y1,y3]; top y1=h;
955 x2=x9=x7; x1=x8=x6; y7=y6; y8=y9;
956 y7-y9=spread'; top y3-bot y6=spread';
957 draw z1--z2--z3; % diagonals
958 draw z6--z7; draw z8--z9; % equal sign
959 penlabels(1,2,3,6,7,8,9); endchar;
960
961 cmchar "Greater than or (double) equals sign";
962 compute_spread(.45x_height#,.55x_height#);
963 spread#':=spread#; spread':=spread;
964 compute_spread(5/4x_height#,3/2x_height#);
965 beginchar(oct"075",14u#,v_center(2spread#'+spread#+2rule_thickness#));
966 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
967 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
968 x2=x7=x9; x1=x6=x8; y6=y7; y8=y9;
969 y2=.5[y1,y3]; top y3-bot y6=spread'; top y1=h;
970 y7-y9=spread';
971 draw z1--z2--z3; % diagonals
972 draw z6--z7; draw z8--z9;
973 penlabels(1,2,3,6,7,8,9); endchar;
974
975 cmchar "Reverse prime symbol (superscript only)";
976 beginchar(oct"070",3u#+max(1.75u#,curve#+2(curve#-stem#)),
977 .8asc_height#,0); adjust_fit(0,0); pickup fine.nib; numeric
978 light_stem,heavy_stem; light_stem=hround .5[vair,stem];
979 heavy_stem=hround(bold+2dw); x1-.5heavy_stem=hround(.25u);
980 y1+.5heavy_stem=h; x2+.5light_stem=hround (w-.5u);
981 y2=1/12asc_height;
982 numeric theta; theta=angle(z1-z2)-90;
983 pos1(heavy_stem,theta); pos2(light_stem,theta);
984 filldraw circ_stroke z1e--z2e; % diagonal
985 penlabels(1,2); endchar;
986
987 cmchar "short axis line";
988 beginchar(oct"071",9u#,27/7u#+math_axis#,27/7u#-math_axis#); pickup rule.nib;
989 lft x1=hround 1.5u-eps; x2=w-x1; y1=y2=math_axis;
990 draw z1--z2;
991 labels(1,2); endchar;
992
993 cmchar "Dotted (right-left) equals sign";
994 compute_spread(.45x_height#,.55x_height#);
995 beginchar(oct"072",14u#,v_center(3spread#+2rule_thickness#));
996 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
997 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; y1=y2; y3=y4;
998 y1-y3=spread; .5[y1,y3]=math_axis; draw z1--z2; % upper bar
999 draw z3--z4; % lower bar
1000 pickup tiny.nib;
1001 x6=x5=x2; y6=y5=y1+spread;
1002 pos5(dot_size,0); pos6(dot_size,90);
1003 x7=x8=x3; y7=y8=y4-spread;
1004 pos7(dot_size,0); pos8(dot_size,90);
1005 dot(5,6); dot(7,8);
1006 penlabels(1,2,3,4,5,6,7,8); endchar;
1007
1008 cmchar "Dotted (left-right) equals sign";
1009 compute_spread(.45x_height#,.55x_height#);
1010 beginchar(oct"073",14u#,v_center(3spread#+2rule_thickness#));
1011 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
1012 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; y1=y2; y3=y4;
1013 y1-y3=spread; .5[y1,y3]=math_axis;
1014 draw z1--z2; % upper bar
1015 draw z3--z4; % lower bar
1016 pickup tiny.nib;
1017 x6=x5=x1; y6=y5=y1+spread;
1018 pos5(dot_size,0); pos6(dot_size,90);
1019 x7=x8=x4; y7=y8=y4-spread;
1020 pos7(dot_size,0); pos8(dot_size,90);
1021 dot(5,6); dot(7,8);
1022 penlabels(1,2,3,4,5,6,7,8); endchar;
1023
1024 cmchar "Square subset sign"; % taken from vol E, p533
1025 compute_spread(5/4x_height#,3/2x_height#);
1026 beginchar(oct"100",14u#,v_center(spread#+rule_thickness#));
1027 adjust_fit(0,0); pickup rule.nib; lft x2=hround(1.5u);
1028 x1=x4=hround(w-x2)+eps; x3=x2; y1-y4=spread; y2=y1; y3=y4;
1029 top y1=h; draw z1--z2--z3--z4; % bars and stem x8=x1;
1030 penlabels(1,2,3,4); endchar;
1031
1032 cmchar "Square superset sign";
1033 compute_spread(5/4x_height#,3/2x_height#);
1034 beginchar(oct"101",14u#,v_center(spread#+rule_thickness#));
1035 adjust_fit(0,0); pickup rule.nib;
1036 x2=hround(w-1.5u); x1=x4=hround w-x2-eps; x3=x2;
1037 y1-y4=spread; y2=y1; y3=y4; top y1=h; draw z1--z2--z3--z4;
1038 % bars and stem
1039 penlabels(1,2,3,4); endchar;
1040
1041 cmchar "Rightward pointing isosceles triangle";
1042 compute_spread(.45x_height#,.55x_height#);
1043 spread#':=spread#; spread':=spread; % the spread of `$=$'
1044 compute_spread(5/4x_height#,3/2x_height#);
1045 beginchar(oct"102",14u#,v_center(spread#+rule_thickness#));
1046 adjust_fit(0,0); pickup rule.nib; lft x2=hround(1.5u);
1047 x3=x2; x1=hround(w-x2);
1048 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1049 draw z1--z2--z3--cycle;
1050 penlabels(1,2,3); endchar;
1051
1052 cmchar "Leftward pointing isosceles triangle";
1053 compute_spread(.45x_height#,.55x_height#);
1054 spread#':=spread#; spread':=spread; % the spread of `$=$'
1055 compute_spread(5/4x_height#,3/2x_height#);
1056 beginchar(oct"103",14u#,v_center(spread#+rule_thickness#));
1057 adjust_fit(0,0); pickup rule.nib; rt x2=hround(w-1.5u-eps);
1058 x3=x2; x1=hround(w-x2);
1059 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1060 draw z1--z2--z3--cycle;
1061 penlabels(1,2,3); endchar;
1062
1063 cmchar "Rightward isosceles triangle with lower bar";
1064 compute_spread(.45x_height#,.55x_height#);
1065 spread#':=spread#; spread':=spread; % the spread of `$=$'
1066 compute_spread(5/4x_height#,3/2x_height#);
1067 beginchar(oct"104",14u#,v_center(spread#'+spread#+rule_thickness#));
1068 adjust_fit(0,0); pickup rule.nib; lft x2=hround(1.5u);
1069 x3=x2; x1=hround(w-x2);
1070 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1071 x4=x2; x5=x1; y3-y4=spread'; y5=y4;
1072 draw z1--z2--z3--cycle; draw z4--z5;
1073 penlabels(1,2,3,4,5); endchar;
1074
1075 cmchar "Leftward isosceles triangle with lower bar";
1076 compute_spread(.45x_height#,.55x_height#);
1077 spread#':=spread#; spread':=spread; % the spread of `$=$'
1078 compute_spread(5/4x_height#,3/2x_height#);
1079 beginchar(oct"105",14u#,v_center(spread#'+spread#+rule_thickness#));
1080 adjust_fit(0,0); pickup rule.nib; rt x2=hround(w-1.5u-eps);
1081 x3=x2; x1=hround(w-x2);
1082 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1083 x4=x2; x5=x1; y3-y4=spread'; y5=y4;
1084 draw z1--z2--z3--cycle; draw z4--z5;
1085 penlabels(1,2,3,4,5); endchar;
1086
1087 cmchar "Large, filled, 5-pointed star";
1088 beginchar(oct"106",asc_height#+desc_depth#,asc_height#,desc_depth#);
1089 adjust_fit(.5u#, .5u#); pickup tiny.nib;
1090 numeric theta; theta=360/5;
1091 x0=good.x .5w; y0=good.y .5[h, -d]; x1=x0; top y1=h;
1092 for n=2 upto 5: z[n]=z0+(z1-z0) rotated((n-1)*theta); endfor
1093 % z0 is the `origin'
1094 % z1 thru z5 are the points; z1 at the top going
1095 % counterclockwise
1096 z6=(z1--z3)intersectionpoint(z2--z5);
1097 for n=7 upto10: z[n]=z0+(z6-z0)rotated((n-1)*theta); endfor
1098 filldraw z1--z6--z2--z7--z3--z8--z4--z9--z5--z10--cycle;
1099 penlabels(0,1,2,3,4,5); endchar;
1100
1101 cmchar "Vertical overlapping slurs";
1102 beginchar(oct"107",9u#,body_height#,paren_depth#);
1103 adjust_fit(0,0); pickup fine.nib;
1104 numeric light_stem; light_stem=Vround .5[vair,stem];
1105 y2=.5[h,-d]; x2r=hround w-1.5u; pos2(light_stem,0);
1106 x1-.5hair=hround w-x2; x3=x1; y1+.5hair=h; y3-.5hair=-d;
1107 numeric theta; theta= angle((z2-z1)xscaled3);
1108 numeric theta'; theta'=angle((z3-z2)xscaled3);
1109 pos1(hair, theta+90); pos3(hair, theta'+90);
1110 path p;
1111 p=z1l{dir theta}...z2l...{dir theta'}z3l
1112 ..z3r{-dir theta'}...z2r...{-dir theta}z1r..cycle;
1113 filldraw p;
1114 p:=p reflectedabout((.5w,-d),(.5w,h)); filldraw p;
1115 penlabels(1,2,3); endchar;
1116
1117 cmchar "Filled rightward pointing isosceles triangle";
1118 compute_spread(.45x_height#,.55x_height#);
1119 spread#':=spread#; spread':=spread; % the spread of `$=$'
1120 compute_spread(5/4x_height#,3/2x_height#);
1121 beginchar(oct"111",14u#,v_center(spread#+rule_thickness#));
1122 adjust_fit(0,0); pickup rule.nib; lft x2=hround(1.5u);
1123 x3=x2; x1=hround(w-x2);
1124 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1125 filldraw z1--z2--z3--cycle;
1126 penlabels(1,2,3); endchar;
1127
1128 cmchar "Filled leftward pointing isosceles triangle";
1129 compute_spread(.45x_height#,.55x_height#);
1130 spread#':=spread#; spread':=spread; % the spread of `$=$'
1131 compute_spread(5/4x_height#,3/2x_height#);
1132 beginchar(oct"112",14u#,v_center(spread#+rule_thickness#));
1133 adjust_fit(0,0); pickup rule.nib; rt x2=hround(w-1.5u-eps);
1134 x3=x2; x1=hround(w-x2);
1135 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1136 filldraw z1--z2--z3--cycle;
1137 penlabels(1,2,3); endchar;
1138
1139 cmchar "short axis right arrow";
1140 beginchar(oct"113",9u#,27/7u#+math_axis#,27/7u#-math_axis#);
1141 pickup rule.nib;
1142 penpos1(.25rule_thickness,90); penpos2(.25rule_thickness,90); penpos3(bar,0);
1143 penpos4(bar,0);
1144 y0=y1=y2=math_axis;
1145 x1=hround 1.5u-eps;
1146 rt x0=w-x1;
1147 y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0-3u-eps;
1148 penpos5(bar,angle(z4-z0)); z5l=z0; penpos6(bar,angle(z3-z0)); z6l=z0;
1149 z9=.381966[.5[z3,z4],z0];
1150 numeric t; path p; p=z4l{z9-z4}..z6r;
1151 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
1152 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
1153 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
1154 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
1155 penlabels(0,1,2,3,4,5,6,9); endchar;
1156
1157 cmchar "short axis left arrow";
1158 beginchar(oct"114",9u#,27/7u#+math_axis#,27/7u#-math_axis#);
1159 pickup rule.nib;
1160 penpos1(.25rule_thickness,90); penpos2(.25rule_thickness,90); penpos3(bar,0);
1161 penpos4(bar,0);
1162 y0=y1=y2=math_axis; x0=hround 1.5u-eps;
1163 rt x1=w-x0;
1164 y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
1165 penpos5(bar,angle(z4-z0)); z5l=z0; penpos6(bar,angle(z3-z0)); z6l=z0;
1166 z9=.381966[.5[z3,z4],z0];
1167 numeric t; path p; p=z4r{z9-z4}..z6r;
1168 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
1169 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
1170 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
1171 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
1172 penlabels(0,1,2,3,4,5,6,9); endchar;
1173
1174
1175 cmchar "Filled downward triangle";
1176 beginchar(oct"110",.8asc_height#+3u#,.8asc_height#,0pt#);
1177 adjust_fit(0,0); pickup rule.nib;
1178 y2=0; lft x1=1.5u;
1179 x3=hround w-x1;
1180 y1=y3=vround h-y2; x2=.5[x1,x3];
1181 filldraw z1--z2--z3--cycle;
1182 penlabels(1,2,3); endchar;
1183
1184 cmchar "Downward triangle";
1185 beginchar(oct"117",.8asc_height#+3u#,.8asc_height#,0pt#);
1186 adjust_fit(0,0); pickup rule.nib;
1187 y2=0; lft x1=1.5u;
1188 x3=hround w-x1;
1189 y1=y3=vround h-y2; x2=.5[x1,x3];
1190 draw z1--z2--z3--cycle;
1191 penlabels(1,2,3); endchar;
1192
1193 cmchar "Upward triangle";
1194 beginchar(oct"115",.8asc_height#+3u#,.8asc_height#,0pt#);
1195 adjust_fit(0,0); pickup rule.nib;
1196 y2=h; lft x1=1.5u;
1197 x3=hround w-x1;
1198 y1=y3=vround h-y2; x2=.5[x1,x3];
1199 draw z1--z2--z3--cycle;
1200 penlabels(1,2,3); endchar;
1201
1202 cmchar "Filled upward triangle";
1203 beginchar(oct"116",.8asc_height#+3u#,.8asc_height#,0pt#);
1204 adjust_fit(0,0); pickup rule.nib;
1205 y2=h; lft x1=1.5u;
1206 x3=hround w-x1;
1207 y1=y3=vround h-y2; x2=.5[x1,x3];
1208 filldraw z1--z2--z3--cycle;
1209 penlabels(1,2,3); endchar;
1210
1211 cmchar "Egg sandwich";
1212 compute_spread(.45x_height#,.55x_height#);
1213 beginchar(oct"120",14u#,asc_height#,0);
1214 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
1215 lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
1216 y1=y2; y3=y4;
1217 y1-y3=spread;
1218 .5[y1,y3]=math_axis;
1219 draw z1--z2; % upper bar
1220 draw z3--z4; % lower bar
1221 pickup tiny.nib;
1222 x5=x6=hround w/2; bot y5=bot y1; top y6=top y3;
1223 y7=y8=math_axis;x8-x7=y5-y6;
1224 x6=.5[x7,x8];
1225 draw z5{right}..z8..z6{left}..z7..cycle;
1226 penlabels(1,2,3,4,5,6,7,8); endchar;
1227
1228 cmchar "Stacked symbols: <, bar, >";
1229 compute_spread(.45x_height#,.55x_height#);
1230 spread#':=spread#; spread':=spread;
1231 compute_spread(.98 x_height#,1.176 x_height#);
1232 beginchar(oct"121",14u#,v_center(2spread#'+2spread#+rule_thickness#));
1233 adjust_fit(0,0); pickup rule.nib;
1234 y1=y2; lft x1=hround 1.5u-eps; rt x2=w-x1;
1235 x4=x6=x8=x1; x3=x5=x7=x2;
1236 y5-y1=y1-y6=spread';top y3=h; y3-y5=spread;
1237 y6-y8=spread;
1238 y7=.5[y6,y8]; y4=.5[y3,y5];
1239 draw z3--z4--z5; draw z6--z7--z8; draw z1--z2;
1240 penlabels(1,2,3,4,5,6,7,8); endchar;
1241
1242 cmchar "Stacked symbls: greater than, bar, less than";
1243 compute_spread(.45x_height#,.55x_height#);
1244 spread#':=spread#; spread':=spread;
1245 compute_spread(.98 x_height#,1.176 x_height#);
1246 beginchar(oct"122",14u#,v_center(2spread#'+2spread#+rule_thickness#));
1247 adjust_fit(0,0); pickup rule.nib;
1248 y1=y2; lft x2=hround 1.5u-eps; rt x1=w-x2;
1249 x4=x6=x8=x1; x3=x5=x7=x2;
1250 y5-y1=y1-y6=spread';top y3=h; y3-y5=spread;
1251 y6-y8=spread;
1252 y7=.5[y6,y8]; y4=.5[y3,y5];
1253 draw z3--z4--z5; draw z6--z7--z8; draw z1--z2;
1254 numeric bar_ht; bar_ht=y1; %save height of bar
1255 penlabels(1,2,3,4,5,6,7,8); endchar;
1256
1257 cmchar "Stacked symbls: less than, =, greater than";
1258 compute_spread(.45x_height#,.55x_height#);
1259 spread#':=spread#; spread':=spread;
1260 compute_spread(.98 x_height#,1.176 x_height#);
1261 beginchar(oct"123",14u#,v_center(3spread#'+2spread#+rule_thickness#));
1262 adjust_fit(0,0); pickup rule.nib; autorounded;
1263 lft x1=hround 1.5u-eps; x2=w-x1;
1264 x1'=x1; x2=x2'; x4=x6=x8=x1;
1265 x3=x5=x7=x2;
1266 y1=y2; y1'=y2'; y2-y2'=spread'; bot y2=math_axis+.5spread';
1267 draw z1--z2; draw z1'--z2';
1268 y3-y5=y6-y8=spread;
1269 y5-y2=y2'-y6=spread';
1270 y7=.5[y6,y8]; y4=.5[y3,y5];
1271 draw z3--z4--z5; draw z6--z7--z8;
1272 penlabels(1,1',2,2',3,4,5,6,7,8); endchar;
1273
1274 cmchar "Stacked symbols: greater than, =, less than";
1275 compute_spread(.45x_height#,.55x_height#);
1276 spread#':=spread#; spread':=spread;
1277 compute_spread(.98 x_height#,1.176 x_height#);
1278 beginchar(oct"124",14u#,v_center(3spread#'+2spread#+rule_thickness#));
1279 adjust_fit(0,0); pickup rule.nib;
1280 lft x2=hround 1.5u-eps; x1=w-x2;
1281 x1'=x1; x2=x2'; x4=x6=x8=x1;
1282 x3=x5=x7=x2;
1283 y1=y2; y1'=y2'; y2-y2'=spread'; bot y2=math_axis+.5spread';
1284 draw z1--z2; draw z1'--z2';
1285 y3-y5=y6-y8=spread;
1286 y5-y2=y2'-y6=spread';
1287 y7=.5[y6,y8]; y4=.5[y3,y5];
1288 draw z3--z4--z5; draw z6--z7--z8;
1289 penlabels(1,1',2,2',3,4,5,6,7,8); endchar;
1290
1291 cmchar "Yen symbol";
1292 compute_spread(.45x_height#, .55x_height#);
1293 beginchar(oct"125",13u#,1.35cap_height#,0); %% adapted from "Y"
1294 italcorr cap_height#*slant+.45u#;
1295 adjust_fit(cap_serif_fit#,cap_serif_fit#); numeric
1296 left_stem,right_stem,outer_jut,dy,alpha;
1297 left_stem=cap_stem-stem_corr; right_stem=min(cap_hair if
1298 hefty:-2stem_corr fi,left_stem); outer_jut=.75cap_jut;
1299 x1l=w-x4r=l+letter_fit+outer_jut+.05u;
1300 x2l=x5l=hround(.5w-.5left_stem); x3r=x5r; y1=y4=h;
1301 y2=y3=y5=.4h; dy=y1-y2; alpha=((x2l-x1l)++dy)/dy;
1302 penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
1303 penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
1304 penpos5(left_stem,0); penpos6(left_stem,0); x5=x6; y6=0;
1305 z0=whatever[z1r,z2r]=whatever[z3l,z4l]; if
1306 y0>y2+cap_notch_cut: y0:=y2+cap_notch_cut;
1307 fill
1308 z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)--z5r
1309 --diag_end(5r,6r,1,1,6l,5l)--z5l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
1310 ...{down}z0+.5left--cycle; % diagonals and stem
1311 else: fill z0--diag_end(0,4l,1,1,4r,3r)--z5r
1312 --diag_end(5r,6r,1,1,6l,5l)--z5l
1313 --diag_end(2l,1l,1,1,1r,0)--cycle; fi % diagonals & stem
1314 if serifs: numeric inner_jut; pickup tiny.nib;
1315 prime_points_inside(1,2); prime_points_inside(4,3);
1316 prime_points_inside(6,5);
1317 if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut:
1318 inner_jut=cap_jut;
1319 else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
1320 dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);
1321 %upper lft serif
1322 dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark);
1323 % upper right serif
1324 dish_serif(6',5,e,1/3,cap_jut,f,1/3,cap_jut); fi
1325 % lower serif
1326 pickup pencircle scaled .5[fine, rule_thickness];
1327 x7=x9=x1l; x8=x10=x4r;
1328 y9=y10;
1329 top y7=bar_height; y7=y8; draw z7--z8;
1330 y9-y7=spread;
1331 draw z9--z10;
1332 penlabels(0,1,2,3,4,5,6,1',2',3',4',5',6',7,8,9,10); endchar;
1333
1334 cmchar "Triple rightward arrow";
1335 compute_spread(.45x_height#,.55x_height#);
1336 beginchar(oct"126",18u#,v_center(2spread#+.5asc_height#+rule_thickness#));
1337 adjust_fit(0,0); pickup rule.nib; penpos1(rule_thickness,90);
1338 penpos2(rule_thickness,90); penpos3(1.5bar,0); penpos4(1.5bar,0);
1339 y0=y1=y2=math_axis; x1-.5rule_thickness=u;
1340 rt x0=hround (w-u); x0'=x0''=x0; x1'=x1''=x1;
1341 y1'=y1+spread;y1''=y1-spread; y0'=y1'; y0''=y1'';
1342 draw z0'--z1'; draw z0''--z1''; % draw bars
1343 pickup crisp.nib;
1344 y3-y0'=y0''-y4=.24asc_height+eps; x3=x4=x0-6u-eps;
1345 penpos5(bar,angle(z0-z4)); z5r=z0; penpos6(bar,angle(z0-z3));
1346 z6r=z0; z9=.381966[.5[z3,z4],z0]; erase filldraw
1347 z0..{z3-z9}z3--(w,y3)--(w,y4)--z4{z9-z4}..z0& cycle;
1348 numeric t; path p;
1349 p=z4l{z9-z4}..z6l; t=xpart(p intersectiontimes((0,y2l)--(w,y2l)));
1350 x2=xpart point t of p;
1351 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6l)
1352 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5l)
1353 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
1354 penlabels(0,1,2,3,4,5,6,9,0',0'',1',1''); endchar;
1355
1356
1357 cmchar "Triple leftward arrow";
1358 compute_spread(.45x_height#,.55x_height#);
1359 beginchar(oct"127",18u#,v_center(2spread#+.5asc_height#+rule_thickness#));
1360 adjust_fit(0,0); pickup rule.nib; penpos1(rule_thickness,90);
1361 penpos2(rule_thickness,90); penpos3(1.5bar,0); penpos4(1.5bar,0);
1362 y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft
1363 x0=hround u; x0'=x0''=x0; x1'=x1''=x1;
1364 y1'=y1+spread;y1''=y1-spread; y0'=y1'; y0''=y1''; draw
1365 z0'--z1'; draw z0''--z1''; % draw bars
1366 pickup crisp.nib;
1367 y3-y0'=y0''-y4=.24asc_height+eps; x3=x4=x0+6u+eps;
1368 pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0));
1369 z6l=z0; z9=.381966[.5[z3,z4],z0]; erase filldraw
1370 z0..{z3-z9}z3--(0,y3)
1371 --(0,y4)--z4{z9-z4}..z0& cycle; numeric t; path p;
1372 p=z4r{z9-z4}..z6r; t=xpart(p
1373 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
1374 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
1375 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
1376 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
1377 penlabels(0,1,2,3,4,5,6,9,0',0'',1',1''); endchar;
1378
1379 cmchar "Check mark"; beginchar(oct"130",15u#,asc_height#,
1380 0); adjust_fit(0,0); pickup cal.nib;
1381 lft x1=hround(1.5u);y1=math_axis; y2=0; x2=hround(w/3);
1382 x3=w-x1; y3=asc_height-o;
1383 x4=w-1.5x2; y4=asc_height;
1384 draw z1--z2{z4-z2}..z3;
1385 penlabels(1,2,3,4);
1386 endchar;
1387
1388 cmchar "Vee on bar";
1389 compute_spread(.45x_height#,.55x_height#);
1390 beginchar(oct"131",11u#,asc_height#, desc_depth#);
1391 adjust_fit(0,0); pickup rule.nib;
1392 lft x1=lft x4=hround u; x3=x5=w-x1; x2=hround(w/2);
1393 bot y4=bot y5=0; y2=y4+spread; top y1=top y3=h+o;
1394 draw z1--z2--z3; draw z4--z5;
1395 penlabels(1,2,3,4,5);
1396 endchar;
1397
1398 cmchar "Bar on mountain";
1399 compute_spread(.45x_height#,.55x_height#);
1400 beginchar(oct"132",11u#,asc_height#, desc_depth#); adjust_fit(0,0);
1401 pickup rule.nib;
1402 lft x1=lft x4=hround u; x3=x5=w-x1; x2=hround(w/2);
1403 top y4=top y5=h+o; y2=y4-spread; bot y1=bot y3=0;
1404 draw z1--z2--z3; draw z4--z5;
1405 numeric t; % t is used in char"133, = on mountain
1406 t=y2-y3;
1407 penlabels(1,2,3,4,5);
1408 endchar;
1409
1410 cmchar "Equal sign on mountain";
1411 compute_spread(.45x_height#,.55x_height#);
1412 beginchar(oct"133",11u#,body_height#, desc_depth#); adjust_fit(0,0);
1413 pickup rule.nib;
1414 lft x1=lft x4=lft x6=hround u; x3=x5=x7=w-x1; x2=hround(w/2);
1415 y4=y5; y6=y7; y6-y4=y4-y2=spread; top y4=asc_height+o-.5spread;
1416 y2-y1=t; % t is defined in char "132
1417 y1=y3;
1418 draw z1--z2--z3; draw z4--z5; draw z6--z7;
1419 penlabels(1,2,3,4,5,6,7);
1420 endchar;
1421
1422 cmchar "Angle sign (simple)";
1423 beginchar(oct"134",13u#,asc_height#, 0);
1424 adjust_fit(0,0); pickup rule.nib;
1425 lft x2=hround u; x1=x3=w-x2;
1426 bot y2=bot y3=0; top y1=h;
1427 draw z1--z2--z3;
1428 penlabels(1,2,3);
1429 endchar;
1430
1431 cmchar "Angle sign (with small arc)";
1432 beginchar(oct"135",13u#,asc_height#, 0);
1433 adjust_fit(0,0); pickup rule.nib;
1434 lft x2=hround u; x1=x3=w-x2;
1435 bot y2=bot y3=0; y1=h;
1436 draw z1--z2--z3;
1437 path p; p=quartercircle scaled 15u;
1438 numeric t; t= xpart(p intersectiontimes (z1--z2));
1439 draw subpath (0,t) of p;
1440 penlabels(1,2,3);
1441 endchar;
1442
1443 cmchar "Eye-like angle sign (with small arc)";
1444 beginchar(oct"136",13u#,v_center(.75body_height#));
1445 adjust_fit(0,0); pickup rule.nib;
1446 lft x2=hround u; x1=x3=w-x2;
1447 y2=math_axis; y2=.5[y1,y3]; y1-y3=.75body_height;
1448 draw z1--z2--z3;
1449 path p; p=quartercircle scaled 17u;
1450 numeric t; t= xpart(p intersectiontimes ((z1--z2)shifted
1451 -z2));
1452 draw subpath (0,t) of p shifted z2;
1453 draw subpath (0,t) of p shifted z2
1454 reflectedabout(z2,(w,y2));
1455 penlabels(1,2,3);
1456 endchar;
1457
1458 cmchar "Proportional sign made of circles";
1459 beginchar(oct"137",14u#,asc_height#,0);
1460 adjust_fit(0,0); pickup pencircle scaled rule_thickness;
1461 numeric radius; radius:=w-2u; radius:=radius/3;
1462 radius:=radius-.5rule_thickness;
1463 x2=hround w-u; x1=w-x2+radius;
1464 y1=y2=math_axis;
1465 pair m; m=(rule_thickness,0);
1466 draw fullcircle scaled 2radius shifted (z1+.5m);
1467 draw (halfcircle scaled 2radius rotated 90) shifted
1468 (z2-.5m);
1469 penlabels(1,2);
1470 endchar;
1471
1472 cmchar "Simple slur below (smile)";
1473 beginchar(oct"140",14u#,asc_height#,desc_depth#);
1474 adjust_fit(0,0); pickup rule.nib;
1475 lft x1=hround u; y1=vround(math_axis+.25x_height);
1476 x3=w-x1; y3=y1; penpos2(rule_thickness,90); x2=.5w;
1477 y2l=good.y -(.25x_height-math_axis);
1478 numeric theta; theta=angle((z2-z1)yscaled 3);
1479 penpos1(rule_thickness,90+theta);
1480 penpos3(rule_thickness,90-theta);
1481 draw z1{dir theta}...z2...{dir-theta}z3;
1482 penlabels(1,2,3); endchar;
1483
1484 cmchar "Simple slur above (frown)";
1485 beginchar(oct"141",14u#,asc_height#,desc_depth#);
1486 adjust_fit(0,0); pickup rule.nib;
1487 lft x1=hround u; y1=vround(math_axis-.25x_height);
1488 x3=w-x1; y3=y1;
1489 penpos2(rule_thickness,90); x2=.5w; y2=good.y(.25x_height+math_axis);
1490 numeric theta; theta=angle((z2-z1)yscaled 3);
1491 penpos1(rule_thickness,90+theta);
1492 penpos3(rule_thickness,90-theta);
1493 draw z1{dir theta}...z2...{dir-theta}z3; penlabels(1,2,3);
1494 endchar;
1495
1496 cmchar "Very proper subset sign";
1497 compute_spread(.45x_height#,.55x_height#);
1498 spread#':=spread#; spread':=spread; % the spread of `$=$'
1499 spread':=spread'-rule_thickness;
1500 compute_spread(5/4x_height#,3/2x_height#);
1501 beginchar(oct"142",14u#,v_center(spread#+rule_thickness#));
1502 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
1503 autorounded; lft x2=hround 1.5u-eps; x1=x3=w-x2;
1504 y1-y3=spread; y2=.5[y1,y3]=math_axis; x4=x5=.5w; y4=y1;
1505 y5=y3; draw z1---z4...z2{down}...z5---z3; % arc and bars
1506 x1'=x3'=x1; y1-y1'=y3'-y3=spread';
1507 x4'=x5'=x4; y4-y4'=y5'-y5=spread';
1508 y2'=y2; x2'-x2=spread';
1509 draw z1'--z4'..z2'{down}..z5'--z3';
1510 penlabels(1,2,3,4,5,1',2',3',4',5'); endchar;
1511
1512 cmchar "Very proper superset sign";
1513 compute_spread(.45x_height#,.55x_height#);
1514 spread#':=spread#; spread':=spread; % the spread of `$=$'
1515 spread':=spread'-rule_thickness;
1516 compute_spread(5/4x_height#,3/2x_height#);
1517 beginchar(oct"143",14u#,v_center(spread#+rule_thickness#));
1518 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
1519 autorounded; lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
1520 y1-y3=spread; y2=.5[y1,y3]=math_axis; x4=x5=.5w; y4=y1;
1521 y5=y3; draw z1---z4...z2{down}...z5---z3; % arc and bars
1522 x1'=x3'=x1; y1-y1'=y3'-y3=spread';
1523 x4'=x5'=x4; y4-y4'=y5'-y5=spread';
1524 y2'=y2; x2-x2'=spread';
1525 draw z1'--z4'..z2'..z5'--z3';
1526 penlabels(1,2,3,4,5,1',2',3',4',5'); endchar;
1527
1528 cmchar "Parallel set union sign";
1529 compute_spread(.45x_height#,.55x_height#);
1530 spread#':=spread#; spread':=spread; % the spread of `$=$'
1531 spread':=spread'-rule_thickness;
1532 beginchar(oct"144",12u#,.8asc_height#,0);
1533 italcorr .8asc_height#*slant-.5u#;
1534 adjust_fit(0,0); pickup rule.nib; autorounded;
1535 lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
1536 y1=good.y h+o; bot y3=-o; y2=y4=2/3[y1,y3]; y5=y1;
1537 draw z1---z2...z3...z4---z5; % stems and cup
1538 y1'=y5'=y1; x1'-x1=x5-x5'=spread';
1539 y2'=y4'=y2+u; x2'-x2=x4-x4'=spread';
1540 x3'=x3; y3'-y3=spread';
1541 draw z1'..{down}z2'..z3'{right}..z4'{up}..z5';
1542 penlabels(1,2,3,4,5,1',2',3',4',5'); endchar;
1543
1544 cmchar "Parallel set intersection sign";
1545 compute_spread(.45x_height#,.55x_height#);
1546 spread#':=spread#; spread':=spread; % the spread of `$=$'
1547 spread':=spread'-rule_thickness;
1548 beginchar(oct"145",12u#,.8asc_height#,0);
1549 italcorr .8asc_height#*slant-.5u#; adjust_fit(0,0);
1550 pickup rule.nib; autorounded;
1551 lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
1552 y3=good.y h+o; bot y1=-o; y2=y4=2/3[y1,y3]; y5=y1;
1553 draw z1---z2...z3...z4---z5; % stems and cap
1554 y1'=y5'=y1; x1'-x1=x5-x5'=spread';
1555 y2'=y4'=y2-u; x2'-x2=x4-x4'=spread';
1556 x3'=x3; y3-y3'=spread';
1557 draw z1'..{up}z2'..z3'{right}..z4'{down}..z5';
1558 penlabels(1,2,3,4,5,1',2',3',4',5'); endchar;
1559
1560 cmchar "Subset or (double) equal to sign";
1561 compute_spread(.45x_height#,.55x_height#);
1562 spread#':=spread#; spread':=spread; % the spread of `$=$'
1563 compute_spread(5/4x_height#,3/2x_height#);
1564 beginchar(oct"152",14u#,v_center(2spread#'+spread#+2rule_thickness#));
1565 adjust_fit(0,0); pickup rule.nib; autorounded; lft x2=hround
1566 1.5u-eps; x1=x3=w-x2; y1-y3=spread; y2=.5[y1,y3]; top y1=h;
1567 x4=x5=.5w; y4=y1; y5=y3; draw z1---z4...z2{down}...z5---z3;
1568 % arc and bars
1569 x8=x1; x9=x2;
1570 y8=y9; y3-y9=spread'; draw z8--z9; % lower bar
1571 x9'=x9; x8'=x8; y9'=y8'; y9-y9'=spread'; draw z8'--z9';
1572 penlabels(1,2,3,4,5,8,9,8',9'); endchar;
1573
1574 cmchar "Superset or (double) equal to sign";
1575 compute_spread(.45x_height#,.55x_height#);
1576 spread#':=spread#; spread':=spread; % the spread of `$=$'
1577 compute_spread(5/4x_height#,3/2x_height#);
1578 beginchar(oct"153",14u#,v_center(2spread#'+spread#+2rule_thickness#));
1579 adjust_fit(0,0); pickup rule.nib; autorounded; lft x1=hround
1580 1.5u-eps; x2=w-x1; x3=x1; y1-y3=spread; y2=.5[y1,y3]; top
1581 y1=h; x4=x5=.5w; y4=y1; y5=y3; draw
1582 z1---z4...z2{down}...z5---z3; % arc and bars
1583 x8=x1;
1584 x9=x2;
1585 y8=y9; y3-y9=spread'; draw z8--z9; % lower bar
1586 x9'=x9; x8'=x8; y9'=y8'; y9-y9'=spread'; draw z8'--z9';
1587 labels(1,2,3,4,5,8,9); endchar;
1588
1589 cmchar "Christmas tree symbol";
1590 compute_spread(5/4x_height#,3/2x_height#);
1591 beginchar(oct"146",spread#+4u#,.8asc_height#,0);
1592 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
1593 autorounded;
1594 lft x1=1.5u; x3=w-x1; x2=.5[x1,x3];
1595 bot y1=-d-o; y3=y1; top y2=h+o;
1596 draw z1{spread,u}...{up}z2;
1597 draw z3{-spread,u}...{up}z2;
1598 penlabels(1,2,3); endchar;
1599
1600 cmchar "Inverted Christmas tree symbol";
1601 compute_spread(5/4x_height#,3/2x_height#);
1602 beginchar(oct"147",spread#+4u#,.8asc_height#,0);
1603 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
1604 autorounded;
1605 lft x1=1.5u; x3=w-x1; x2=.5[x1,x3];
1606 top y1=h+o; y3=y1; bot y2=-d-o;
1607 draw z1{spread,-u}...{down}z2;
1608 draw z3{-spread,-u}...{down}z2;
1609 penlabels(1,2,3); endchar;
1610
1611 cmchar "Stylized lambda symbol";
1612 beginchar(oct"150",14u#,1.35asc_height#,0);
1613 adjust_fit(0,0); pickup rule.nib; autorounded;
1614 lft x1=u; top y1=h;
1615 rt x2=w-u; bot y2=-o;
1616 draw z1--z2;
1617 z3=.5[z1,z2];
1618 x4=x1; y4=y2; draw z3--z4;
1619 penlabels(1,2,3,4); endchar;
1620
1621 cmchar "Reflected stylized lambda symbol";
1622 beginchar(oct"151",14u#,1.35asc_height#,0);
1623 adjust_fit(0,0); pickup rule.nib; autorounded;
1624 lft x1=u; bot y1=-o;
1625 rt x2=w-u; top y2=h;
1626 draw z1--z2;
1627 z3=.5[z1,z2];
1628 x4=x2; y4=y1; draw z3--z4;
1629 penlabels(1,2,3,4); endchar;
1630
1631 cmchar "Sunrise symbol";
1632 compute_spread(.45x_height#,.55x_height#);
1633 beginchar(oct "154",14u#,v_center(3spread#+rule_thickness#));
1634 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
1635 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; y1=y2; y3=y4;
1636 y1-y3=spread; .5[y1,y3]=math_axis;
1637 y5=y6=y1; x7=.5[x1,x2]; x5=.3[x1,x2];
1638 x2-x6=x5-x1;
1639 y7-y1=.5(x6-x5);
1640 draw z1--z5{up}...z7...{down}z6--z2; % upper bar
1641 draw z3--z4; % lower bar
1642 penlabels(1,2,3,4,5,6,7); endchar;
1643
1644 cmchar "Sunrise-over-water symbol";
1645 compute_spread(.45x_height#,.55x_height#);
1646 beginchar(oct "155",14u#,v_center(3spread#+rule_thickness#));
1647 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
1648 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; y1=y2; y3=y4;
1649 y1-y3=spread; .5[y1,y3]=math_axis;
1650 y5=y6=y1; x7=.5[x1,x2]; x5=.3[x1,x2];
1651 x2-x6=x5-x1;
1652 y7-y1=.5(x6-x5);
1653 x5'=x5; x7'=x7; x6'=x6; y5'=y6'=y3; y3-y7'=y7-y1;
1654 draw z1--z5{up}...z7...{down}z6--z2; % upper bar
1655 draw z3--z5'{down}...z7'...{up}z6'--z4; % lower bar
1656 penlabels(1,2,3,4,5,6,7); endchar;
1657
1658 cmchar "Much, much less sign";
1659 compute_spread(5/4x_height#,3/2x_height#);
1660 beginchar(oct"156",24u#,v_center(spread#+rule_thickness#));
1661 adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup
1662 rule.nib; lft x2=hround u-epsilon; x1=x3=hround 12.5u-x2;
1663 y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
1664 draw z1--z2--z3; % left diagonals
1665 z4-z1=z5-z2=z6-z3=z7-z4=z8-z5=z9-z6;
1666 x7=w-x2; y4=y1;
1667 draw z4--z5--z6; % middle diagonals
1668 draw z7--z8--z9; % right diagonals
1669 penlabels(1,2,3,4,5,6,7,8,9); endchar;
1670
1671 cmchar "Much, much greater sign";
1672 compute_spread(5/4x_height#,3/2x_height#);
1673 beginchar(oct"157",24u#,v_center(spread#+rule_thickness#));
1674 adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup
1675 rule.nib;
1676 lft x1=hround u-epsilon; x2=hround 12.5u-u; x1=x3;
1677 y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
1678 draw z1--z2--z3; % left diagonals
1679 z4-z1=z5-z2=z6-z3=z7-z4=z8-z5=z9-z6;
1680 x8=w-x1; y4=y1;
1681 draw z4--z5--z6; % middle diagonals
1682 draw z7--z8--z9; % right diagonals
1683 penlabels(1,2,3,4,5,6,7,8,9); endchar;
1684
1685 cmchar "Northwest right angle symbol";
1686 beginchar(oct"160",9u#, asc_height#, 0);
1687 adjust_fit(0,0); pickup rule.nib;
1688 x1=x2; lft x1=u; x3=w-x1; y2=y3; top y2=h;
1689 y2-y1=x3-x2;
1690 draw z1--z2--z3;
1691 penlabels(1,2,3); endchar;
1692
1693 cmchar "Northeast right angle symbol";
1694 beginchar(oct"161",9u#,asc_height#,0);
1695 adjust_fit(0,0); pickup rule.nib;
1696 lft x3=u; x2=w-x3; top y3=h; y3=y2; x1=x2; x2-x3=y2-y1;
1697 draw z1--z2--z3;
1698 penlabels(1,2,3); endchar;
1699
1700 cmchar "Southwest right angle symbol";
1701 beginchar(oct"170", 9u#, 7u#,0);
1702 adjust_fit(0,0); pickup rule.nib;
1703 lft x2=u; x3=w-x2; x1=x2; bot y2=-o; y3=y2;
1704 y1-y2=x3-x2;
1705 draw z1--z2--z3;
1706 penlabels(1,2,3); endchar;
1707
1708 cmchar "Southeast right angle symbol";
1709 beginchar(oct"171", 9u#, 7u#,0);
1710 adjust_fit(0,0); pickup rule.nib;
1711 lft x3=u; x2=w-x3; x1=x2; bot y2=-o; y3=y2;
1712 y1-y2=x2-x3;
1713 draw z1--z2--z3;
1714 penlabels(1,2,3); endchar;
1715
1716 %% include these parameters to `shrink R and S so they
1717 %% fit inside a circle
1718 %
1719 begingroup
1720 save u, width_adj, cap_serif_fit, letter_fit,
1721 body_height, cap_height, x_height, bar_height, comma_depth,
1722 flare, cap_hair, stem, cap_stem, cap_curve, cap_ess,
1723 cap_jut, beak_jut, beak, slab, cap_bar, cap_band, cap_notch_cut,
1724 o, apex_o;
1725 numeric radius;
1726 old.u:=u; old.cap_curve:=cap_curve; old.cap_height:=cap_height;
1727 old.u#:=u#; old.cap_curve#:=cap_curve#; old.cap_height#:=cap_height#;
1728 forsuffixes $=u, width_adj, cap_serif_fit, letter_fit,
1729 body_height, cap_height, x_height, bar_height,
1730 comma_depth, flare, cap_hair,
1731 stem, cap_stem, cap_curve, cap_ess,
1732 cap_jut, beak_jut, beak,
1733 slab, cap_bar,
1734 cap_band, cap_notch_cut,
1735 o, apex_o: $.#:=lower.$.#; endfor
1736 fudge:=lower.fudge;
1737 font_setup;
1738 % Changed by Stefan Lindner 15.03.1991 -sl
1739 % original: radius=.5(6u++cap_height)+3u; radius=radius#*hppp;
1740 radius#=.5(6u#++cap_height#)+3u#; radius:=radius#*hppp;
1741 % end of change
1742 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
1743
1744 cmchar "Circle-R brand";
1745 beginchar(oct"162",13u#, .52cap_height#+radius#,radius#-.52cap_height#);
1746 adjust_fit(4u#,4u#);
1747 pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
1748 lft x1l=lft x2l=hround max(2u,3u-.5cap_stem');
1749 top y1=cap_height; bot y2=0;
1750 filldraw stroke z1e--z2e; % stem
1751 penpos3(cap_band,90); penpos4(cap_band,90);
1752 penpos5(cap_curve,0);
1753 penpos6(vair,-90); penpos7(vair,-90);
1754 z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
1755 x7=x2; y7l=vround(.5cap_height+.5vair); x4=x6;
1756 x4=.5w-.5u; x5r=hround(w-2.25u);
1757 x4l:=x6l:=x4-.125cap_curve;
1758 fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
1759 pos6'(vair,-90); pos0(cap_stem,180);
1760 pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
1761 z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
1762 y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
1763 bot y9r=-o; rt x10r=hround(w-.05u); y10=1/4[y2,y7];
1764 filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up}; % tail
1765 nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1766 dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut); % lower serif
1767 % tail
1768 math_fit(0,.75ic#);
1769 pickup rule.nib;
1770 z100=(hround w/2,.52cap_height); z101=z100+(0,radius); z103=z100-(0,radius);
1771 z102=z100+(radius,0); z104=z100-(radius,0);
1772 draw z101...z102...z103...z104...cycle;
1773 penlabels(0,1,2,3,4,5,6,7,8,9,10,100,101,102,103,104);
1774 endchar;
1775
1776 cmchar "Circle-S brand";
1777 beginchar(oct"163",10u#,radius#+.52cap_height#,radius#-.52cap_height#);
1778 adjust_fit(5u#,5u#);
1779 numeric theta; theta=90-angle(50u,cap_height); slope:=-cap_height/50u; % angle at middle
1780 numeric s_slab; s_slab=slab;
1781 numeric ess'; ess'=max(fine.breadth,cap_ess);
1782 pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-90);
1783 pos0(ess',theta); pos7(s_slab,-90);
1784 x2+x7=2x0=w; x7-x2=u; top y2l=cap_height+o; bot y7r=-o;
1785 y0=.52cap_height; lft x3l=hround u; rt x6r=hround(w-u);
1786 x3r-x3l=x6r-x6l=hround .5[s_slab,ess']-fine;
1787 ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
1788 ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
1789 filldraw stroke super_arc.e(2,3) & z3e{down}
1790 ..z4e---z5e..z6e{down} & super_arc.e(6,7); % main stroke
1791 pos1(hair,180); pos8(hair,180);
1792 rt x1l=hround(w-1.5u); lft x8r=hround u;
1793 bot y1=vround 2/3cap_height+1; top y8=vround 1/3cap_height-1;
1794 filldraw stroke z1e{x2-x1,10(y2-y1)}....{left}z2e; % upper arc
1795 filldraw stroke z7e{left}....{up}z8e; % lower arc
1796 path upper_arc, lower_arc;
1797 upper_arc=z1{x2-x1,10(y2-y1)}....{left}z2;
1798 lower_arc=z7{left}....{up}z8;
1799 pos10(.3[fine.breadth,cap_hair],0);
1800 pos9(.3[fine.breadth,cap_hair],0);
1801 x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
1802 x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
1803 numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
1804 filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle; % upper barb
1805 t:=xpart(lower_arc intersectiontimes(z9r--z8'));
1806 filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle; % lower barb
1807 % lower arc and terminal
1808 math_fit(0,.5ic#);
1809 pickup rule.nib;
1810 z100=(hround w/2,.52cap_height); z101=z100+(0,radius); z103=z100-(0,radius);
1811 z102=z100+(radius,0); z104=z100-(radius,0);
1812 draw z101...z102...z103...z104...cycle;
1813 penlabels(0,1,1',2,3,4,5,6,7,8,8',9,10,100,101,102,103,104);
1814 endchar;
1815 endgroup;
1816
1817
1818 cmchar "Pitchfork symbol";
1819 beginchar(oct"164",12u#,asc_height#,0);
1820 italcorr .8asc_height#*slant-.5u#;
1821 adjust_fit(0,0); pickup rule.nib; autorounded;
1822 lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
1823 y3=good.y .7h+o; bot y1=-o; y2=y4=2/3[y1,y3]; y5=y1;
1824 draw z1---z2...z3...z4---z5; % stems and cap
1825 x6=x7=good.x w/2; y6=y1; y7=h+o;
1826 draw z6--z7; % stem
1827 penlabels(1,2,3,4,5,6,7); endchar;
1828
1829 cmchar "Dotted plus sign";
1830 beginchar(oct"165",14u#,8u#+math_axis#,6u#-math_axis#);
1831 adjust_fit(0,0); pickup rule.nib;
1832 x1=x2=good.x .5w; top y1=h-2.5rule_thickness+eps; .5[y1,y2]=math_axis;
1833 lft x3=hround u-eps; x4=w-x3; y3=y4=math_axis;
1834 draw z1--z2; % stem
1835 draw z3--z4; % crossbar
1836 x5=x1; y5=h+o;
1837 pickup pencircle scaled 2.5rule_thickness; drawdot z5;
1838 penlabels(1,2,3,4,5); endchar;
1839
1840 cmchar "Inverted similarity sign";
1841 compute_spread(.45x_height#,.55x_height#);
1842 beginchar(oct"166",14u#,v_center(spread#+rule_thickness#));
1843 adjust_fit(0,0);
1844 pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
1845 if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
1846 lft x1=hround(u); x2=4u; x3=w-x2; x4=w-x1;
1847 bot y2=bot y4=-d; top y1=top y3=h;
1848 draw z1{down}...z2{right}..{right}z3...{down}z4; % stroke
1849 labels(1,2,3,4); endchar;
1850
1851 cmchar "Inverted similar or equal sign";
1852 compute_spread(.45x_height#,.55x_height#);
1853 beginchar(oct"167",14u#,v_center(2spread#+rule_thickness#));
1854 adjust_fit(0,0);
1855 pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
1856 if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
1857 lft x1=hround(u); x2=4u; x3=w-x2; x4=w-x1;
1858 bot y2=bot y4=floor math_axis; top y1=top y3=h;
1859 draw z1{down}...z2{right}..{right}z3...{down}z4; % stroke
1860 pickup rule.nib; lft x5=hround u-eps; x6=w-x5; y5=y6=math_axis-spread;
1861 draw z5--z6; % bar
1862 labels(1,2,3,4,5,6); endchar;
1863
1864 cmchar "Iron cross";
1865 beginchar(oct"172",15u#,asc_height#,0); adjust_fit(0,0);
1866 pickup pencircle scaled .5rule_thickness;
1867 numeric cross_tension; cross_tension=.9;
1868 numeric cross_foot; cross_foot=4u;
1869 y0=.5[y1,y2]; x0=hround w/2;
1870 x1=x2=x0; bot y1=-o; lft x1l=3.5u; x1r=w-x1l; y1l=y1r=y1;
1871 top y2=h+o; x2r=x1l; x2l=x1r; y2l=y2r=y2;
1872 y3=y4=y0; x3=x0+eps; x4+x3=2x0;
1873 path p; p=z1l--z1r..tension cross_tension..z3..tension cross_tension
1874 ..z2l--z2r..tension cross_tension..z4..tension cross_tension..
1875 z1l..cycle;
1876 filldraw p;
1877 p:=p shifted -z0; p:=p rotated 90; p:=p shifted z0;
1878 filldraw p;
1879 penlabels(0,1,2,3,4); endchar;
1880
1881 cmchar "Bourbaki C symbol";
1882 beginchar(oct"173",9u#, 1.1body_height#, 0);
1883 adjust_fit(0,0); pickup pencircle scaled 2rule_thickness;
1884 lft x4=lft x5=u; x1=x2=x8=x7=w-x4; x3=x6=hround
1885 w/2;
1886 bot y6=-o; top y3=h+o; y2=y4=y3-1.5u; y5=y7=y6+1.5u;
1887 y1=y2-1.5u; y8=y7+1.5u;
1888 draw z1--z2{up}..{left}z3..{down}z4--z5{down}..z6{right}..{up}z7--z8;
1889 labels(1,2,3,4,5,6,7,8); endchar;
1890
1891 cmchar "Bourbaki T symbol";
1892 beginchar(oct "174", 10u#, x_height#, desc_depth#);
1893 adjust_fit(0,0); pickup pencircle scaled 2rule_thickness;
1894 lft x1=u; x2=w-x1; top y1=top y2=h; x3=x4=hround w/2; y3=y1;
1895 bot y4=-1.1d;
1896 draw z1--z2; draw z3--z4;
1897 labels(1,2,3,4); endchar;
1898
1899 cmchar "Circle-in-a-circle operator";
1900 beginarithchar(oct"175"); pickup light_rule.nib; autorounded;
1901 lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
1902 circle_points; draw_circle; % circle
1903 pickup rule.nib;
1904 numeric x[],y[];
1905 lft x6=hround 4.5u; x2=w-x6; y2=math_axis;
1906 top y8=y2+.5(rt x2-lft x6); circle_points; draw_circle;
1907 labels(1,2,3,4,5,6,7,8); endchar;
1908
1909 cmchar "Asterisk-in-a-circle";
1910 beginarithchar(oct"176");
1911 pickup light_rule.nib; autorounded;
1912 y2=math_axis; top y8=6u+math_axis;
1913 lft x6=hround w/2 - 6u; x2=w-x6;
1914 circle_points; draw_circle; % circle
1915 numeric x[], y[];
1916 numeric ast_flare; ast_flare=hround .7[thin_join,stem];
1917 x0=.5w; y0=math_axis; for d=-150 step 60 until 150:
1918 z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
1919 numeric theta; theta=angle(z[d]-z0);
1920 fill z0+.5(0,-thin_join)rotated theta
1921 ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
1922 ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
1923 ---z0+.5(0,thin_join)rotated theta--cycle; endfor % diagonal at angle |d|
1924 labels(0,[-150],[-90],[-30],30,90,150); endchar;
1925
1926 cmchar "Bar-in-a-circle operator";
1927 beginarithchar(oct"177"); pickup light_rule.nib; autorounded;
1928 lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
1929 circle_points; draw_circle; % circle
1930 y9=y10=y2; x9=x6+3u; x10=w-x9;
1931 draw z9--z10;
1932 labels(1,2,3,4,5,6,7,8,9,10); endchar;
1933