Debian Codegraph @

texmf-dist/fonts/source/public/ifsym/ifwea.gen

raw
1 %%%%%%%%%%%%%%%%%% ifwea.gen %%%%%%%%%%%%%%%%%%%%%%%
2 % (c) Ingo Kloeckl
3 % This program can be redistributed and/or modified under the terms
4 % of the LaTeX Project Public License Distributed from CTAN
5 % archives in directory macros/latex/base/lppl.txt; either
6 % version 1 of the License, or any later version.
7
8 % History
9 % 20.12.1999 v1.0 IK
10 %
11 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
12 % weather symbols
13 % by I.Kloeckl, [email protected]
14
15 pen normalpen;
16 normalpen := pencircle scaled .75linewidth;
17
18 %
19 % centers of wind symbol
20 %
21 "BlueSky";
22 beginchar(0,4pt#,4pt#,0);
23 pickup normalpen;
24 draw fullcircle scaled 4pt shifted (2pt,2pt);
25 endchar;
26
27 "BlueSky3/4";
28 beginchar(1,4pt#,4pt#,0);
29 pickup normalpen;
30 draw fullcircle scaled 4pt shifted (2pt,2pt);
31 fill quartercircle scaled 4pt shifted(2pt,2pt)--(2pt,2pt)--cycle;
32 endchar;
33
34 "BlueSky2/4";
35 beginchar(2,4pt#,4pt#,0);
36 pickup normalpen;
37 draw fullcircle scaled 4pt shifted (2pt,2pt);
38 fill halfcircle scaled 4pt shifted (2pt,2pt)--(2pt,2pt)--cycle;
39 endchar;
40
41 "BlueSky1/4";
42 beginchar(3,4pt#,4pt#,0);
43 pickup normalpen;
44 draw fullcircle scaled 4pt shifted (2pt,2pt);
45 fill halfcircle scaled 4pt rotated 180 shifted(2pt,2pt)--(2pt,2pt)--cycle;
46 fill quartercircle scaled 4pt rotated -90 shifted(2pt,2pt)--(2pt,2pt)--cycle;
47 endchar;
48
49 "CloudySky";
50 beginchar(4,4pt#,4pt#,0);
51 pickup normalpen;
52 fill fullcircle scaled 4pt shifted (2pt,2pt);
53 endchar;
54
55 %
56 % nice thermometers
57 %
58 def Thermo(expr n, height) =
59 beginchar((char n),3pt#,10pt#,0);
60 pickup pencircle scaled .5linewidth;
61 fill fullcircle scaled 3pt shifted (1.5pt,1.5pt);
62
63 pickup pencircle scaled .2linewidth;
64 draw (0.5pt,2pt)--(0.5pt,9pt)..(1.5pt,10pt)..(2.5pt,9pt)--(2.5pt,2pt)--cycle;
65 draw (1.5pt,2pt)--(1.5pt,9pt);
66 path p; p := (1pt,1pt)--(2pt,1pt);
67 for i=2 upto 8:
68 draw p shifted(0, i*1pt);
69 endfor;
70
71 fill (1.2pt,2pt)--(1.2pt,height*1pt)--(1.8pt,height*1pt)--(1.8pt,2pt)--cycle;
72 endchar;
73 enddef;
74
75 "Thermoa"; Thermo(5,3);
76 "Thermob"; Thermo(6,4);
77 "Thermoc"; Thermo(7,5);
78 "Thermod"; Thermo(8,6);
79 "Thermoe"; Thermo(9,7);
80 "Thermof"; Thermo(10,8);
81 "Thermog"; Thermo(11,9);
82
83 %
84 % popular weather symbols
85 %
86 "Sun";
87 beginchar(16,10pt#,10pt#,0);
88 pickup normalpen;
89 draw fullcircle scaled 5pt shifted (5pt,5pt);
90 path p;
91 p=(7.5pt,5pt)--(10pt,5pt);
92 for i=0 upto 7:
93 draw p rotatedaround ((5pt,5pt),(i*45));
94 endfor;
95 endchar;
96
97 "Halfsun";
98 beginchar(17,10pt#,10pt#,0);
99 pickup normalpen;
100 draw fullcircle scaled 5pt shifted (5pt,5pt);
101 fill halfcircle--cycle scaled 5pt rotated (180) shifted (5pt,5pt);
102 path p;
103 p=(7.5pt,5pt)--(10pt,5pt);
104 for i=0 upto 4:
105 draw p rotatedaround ((5pt,5pt),(i*45));
106 endfor;
107 endchar;
108
109 "Nosun";
110 beginchar(18,10pt#,10pt#,0);
111 pickup normalpen;
112 fill fullcircle scaled 7pt shifted (5pt,5pt);
113 endchar;
114
115 "Fog";
116 beginchar(19,10pt#,10pt#,0);
117 pickup pencircle scaled 0.5linewidth;
118 for i=.1h step .1h until .9h:
119 for j=0 step .3w until .7w:
120 draw (j,i)--(j+.2w,i);
121 endfor
122 endfor
123 endchar;
124
125
126 "ThinFog";
127 beginchar(20,10pt#,10pt#,0);
128 pickup pencircle scaled .25linewidth;
129 for i=.1h step .1h until .9h:
130 for j=0 step .3w until .7w:
131 draw (j,i)--(j+.2w,i);
132 endfor
133 endfor
134 endchar;
135
136 "Rain";
137 beginchar(21,10pt#,10pt#,0);
138 pickup normalpen;
139 for i=1 step 2 until 7:
140 draw (i*1pt,1pt)--((i+2)*1pt,4pt); draw((i+1)*1pt,5pt)--((i+3)*1pt,8pt);
141 endfor;
142 endchar;
143
144 "WeakRain";
145 beginchar(22,10pt#,10pt#,0);
146 pickup pencircle scaled .5linewidth;
147 for i:=1 step 2 until 7:
148 draw (i*1pt,1pt)--((i+1)*1pt,2pt);
149 draw((i+1)*1pt,4pt)--((i+2)*1pt,5pt);
150 draw((i+2)*1pt,7pt)--((i+3)*1pt,8pt);
151 endfor;
152 endchar;
153
154 "Hagel";
155 beginchar(23,10pt#,10pt#,0);
156 pickup pencircle scaled 4linewidth;
157 drawdot(3pt,3pt); drawdot(1pt,8pt); drawdot(6pt,7pt);
158 drawdot(1pt,1pt); drawdot(8pt,2pt); drawdot(3pt,6pt);
159 drawdot(7pt,3pt); drawdot(3pt,8pt); drawdot(6pt,1pt);
160 endchar;
161
162 "Graupel";
163 beginchar(24,10pt#,10pt#,0);
164 pickup pencircle scaled 2linewidth;
165 drawdot(3pt,3pt); drawdot(1pt,8pt); drawdot(6pt,7pt);
166 drawdot(1pt,1pt); drawdot(8pt,2pt); drawdot(3pt,6pt);
167 drawdot(7pt,3pt); drawdot(3pt,8pt); drawdot(6pt,1pt);
168 endchar;
169
170 "Snow";
171 beginchar(25,10pt#,10pt#,0);
172 pickup normalpen;
173 path p[];
174 p1 = (0,0)--(4pt,0);
175 p2 = (4pt,-1pt)--(3pt,0)--(4pt,1pt);
176 for i:=0 upto 5:
177 draw p1 rotated (i*60) shifted(5pt,5pt);
178 draw p2 shifted(-2pt,0) rotated (i*60) shifted(5pt,5pt);
179 draw p2 shifted(-1pt,0) rotated (i*60) shifted(5pt,5pt);
180 draw p2 rotated (i*60) shifted(5pt,5pt);
181 endfor;
182 endchar;
183
184 "Blitz";
185 beginchar(26,10pt#,10pt#,0);
186 pickup normalpen;
187 fill (6.4pt,10pt)--(8.7pt,8.4pt)--(5.6pt,4.1pt)--(4.4pt,4.9pt)--(2.4pt,2.1pt)--
188 (3.9pt,1.6pt)--(0,0)--(1.1pt,4pt)--(1.6pt,2.4pt)--(3.5pt,8.5pt)--
189 (5pt,6pt)--cycle;
190 endchar;
191
192 path cloud;
193 cloud = (5.0pt,0.0pt){left}..{up}(0.0pt,3.2pt){up}..{right}(2.1pt,5.7pt){right}..
194 {dir -60}(4.0pt,4.2pt){dir 40}..{dir -40}(5.5pt,4.1pt){dir -40}..
195 {dir -80}(6.1pt,2.4pt){dir 60}..{right}(7.8pt,3.3pt){right}..
196 {down}(9.3pt,2.0pt){down}..{left}cycle;
197
198 "Cloud";
199 beginchar(27,10pt#,6pt#,0);
200 pickup normalpen;
201 draw cloud;
202 endchar;
203
204 "RainCloud";
205 beginchar(28,10pt#,10pt#,0);
206 pickup normalpen;
207 draw cloud shifted(0, 4pt);
208 for i=0 step 3 until 6:
209 draw (i*1pt,1pt)--((i+1)*1pt,4pt);
210 draw ((i+1)*1pt,0)--((i+2)*1pt,3pt);
211 endfor;
212 endchar;
213
214 "WeakRainCloud";
215 beginchar(29,10pt#,6pt#,0);
216 pickup normalpen;
217 draw cloud shifted(0, 4pt);
218 for i=0 step 3 until 6:
219 draw (i*1pt,1pt)--((i+1)*1pt,4pt);
220 endfor;
221 endchar;
222
223 "SunCloud";
224 beginchar(30,10pt#,10pt#,0);
225 pickup normalpen;
226 draw fullcircle scaled 4pt shifted (6pt,5pt);
227 path p;
228 p=(8pt,5pt)--(10pt,5pt);
229 for i=0 upto 7:
230 draw p rotatedaround ((6pt,5pt),(i*45));
231 endfor;
232 unfill cloud; draw cloud;
233 endchar;
234
235 "SnowCloud";
236 beginchar(31,10pt#,10pt#,0);
237 pickup normalpen;
238 draw cloud shifted(0, 4pt);
239 pickup pencircle scaled 2linewidth;
240 drawdot(3pt,3pt); drawdot(6pt,2pt); drawdot(2pt,3pt);
241 drawdot(1pt,0); drawdot(8pt,1pt); drawdot(9pt,3pt);
242 drawdot(7pt,3pt); drawdot(4pt,0); drawdot(5pt,2pt);
243 endchar;
244
245 "FilledCloud";
246 beginchar(32,10pt#,6pt#,0);
247 pickup normalpen;
248 fill cloud;
249 endchar;
250
251 "FilledRainCloud";
252 beginchar(33,10pt#,10pt#,0);
253 pickup normalpen;
254 fill cloud shifted(0, 4pt);
255 for i=0 step 3 until 6:
256 draw (i*1pt,1pt)--((i+1)*1pt,4pt);
257 draw ((i+1)*1pt,0)--((i+2)*1pt,3pt);
258 endfor;
259 endchar;
260
261 "FilledWeakRainCloud";
262 beginchar(34,10pt#,6pt#,0);
263 pickup normalpen;
264 fill cloud shifted(0, 4pt);
265 for i=0 step 3 until 6:
266 draw (i*1pt,1pt)--((i+1)*1pt,4pt);
267 endfor;
268 endchar;
269
270 "FilledSunCloud";
271 beginchar(35,10pt#,10pt#,0);
272 pickup normalpen;
273 draw fullcircle scaled 4pt shifted (6pt,5pt);
274 path p;
275 p=(8pt,5pt)--(10pt,5pt);
276 for i=0 upto 7:
277 draw p rotatedaround ((6pt,5pt),(i*45));
278 endfor;
279 fill cloud;
280 endchar;
281
282 "FilledSnowCloud";
283 beginchar(36,10pt#,10pt#,0);
284 pickup normalpen;
285 fill cloud shifted(0, 4pt);
286 pickup pencircle scaled 2linewidth;
287 drawdot(3pt,3pt); drawdot(6pt,2pt); drawdot(2pt,3pt);
288 drawdot(1pt,0); drawdot(8pt,1pt); drawdot(9pt,3pt);
289 drawdot(7pt,3pt); drawdot(4pt,0); drawdot(5pt,2pt);
290 endchar;
291
292 %HalfWeakRainCloud 165
293 %CloudBlitz 166
294
295 def wind(expr n, strength) =
296 beginchar((char n),0pt#,11pt#,0);
297 pickup normalpen;
298 draw (0,4pt)--(0,10pt);
299 for k=0 upto strength/2:
300 draw (0,(10-k)*1pt)--(-2pt,(11-k)*1pt);
301 endfor
302 if (strength mod 2 = 1):
303 draw (0,(9.5-strength/2)*1pt)--(-1pt,(10-strength/2)*1pt);
304 fi
305 endchar;
306 enddef;
307
308 for j=0 step 1 until 10:
309 wind(48+j,j);
310 endfor;
311
312 end.
313 %%%%%%%%%%%%%%%%%% end of ifwea.gen %%%%%%%%%%%%%%%%%%%%%%%