Debian Codegraph @

texmf-dist/fonts/source/public/ifsym/ifclk.gen

raw
1 %%%%%%%%%%%%%%%%%% ifclk.gen %%%%%%%%%%%%%%%%%%%%%%%
2 % (c) Ingo Kloeckl
3 % This program can be redistributed and/or modified under the terms
4 % of the LaTeX Project Public License Distributed from CTAN
5 % archives in directory macros/latex/base/lppl.txt; either
6 % version 1 of the License, or any later version.
7
8 % History
9 % 20.12.1999 v1.0 IK
10 %
11 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
12 % generates clock symbols with 5 min increment
13 % by I.Kloeckl, [email protected]
14 % clock for hh:mm -> \symbol{hh*12+mm/5}
15
16 picture clk, % Zifferblatt
17 clkb, % Zifferblatt mit Zeiger 13:00
18 clks; % Stopuhr
19
20 path button; button = (5.5pt,10pt)--(5.5pt,11pt)--(6pt,11pt)..
21 (6.5pt,11.5pt)..(6pt,12pt)--(4pt,12pt)..(3.5pt,11.5pt)..
22 (4pt,11pt)--(4.5pt,11pt)--(4.5pt,10pt)--cycle;
23
24 % Zifferblatt
25 beginchar(149,10pt#,10pt#,0);
26 pickup pencircle scaled .75linewidth;
27 draw fullcircle scaled 10pt shifted (5pt,5pt);
28 path s; s=(8pt,5pt)--(9pt,5pt);
29 for i=0 upto 11:
30 draw s rotatedaround ((5pt,5pt),(i*30));
31 endfor;
32 clk := currentpicture;
33 endchar;
34
35 n := 0;
36 for h=3 downto -8:
37 for m=15 step -5 until -40:
38 beginchar((char n),10pt#,10pt#,0);
39 currentpicture := clk;
40 pickup pencircle scaled .75linewidth;
41 draw (5pt,5pt)--(9pt,5pt) rotatedaround ((5pt,5pt),(m*6));
42 draw (5pt,5pt)--(7pt,5pt) rotatedaround ((5pt,5pt),(h*30-(15-m)/2));
43 endchar;
44 n := n+1;
45 endfor;
46 endfor;
47
48 % Taschenuhr
49 beginchar(150,10pt#,14pt#,0);
50 currentpicture := clk;
51 pickup pencircle scaled .75linewidth;
52 draw (5pt,5pt)--(9pt,5pt) rotatedaround ((5pt,5pt),0);
53 draw (5pt,5pt)--(7pt,5pt) rotatedaround ((5pt,5pt),22.5);
54 clkb := currentpicture;
55 draw fullcircle scaled 4pt shifted (5pt,12pt);
56 fill button;
57 endchar;
58
59 % Taschenuhr2
60 beginchar(148,11pt#,16pt#,0);
61 currentpicture := clkb shifted(0,1pt);
62 pickup pencircle scaled .75linewidth;
63 draw fullcircle scaled 12pt shifted (5pt,6pt);
64 draw fullcircle scaled 4pt shifted (5pt,14pt);
65 fill button shifted(0,2pt);
66 endchar;
67
68 % stop watch start
69 beginchar(151,12pt#,12pt#,0);
70 currentpicture := clk;
71 pickup pencircle scaled .75linewidth;
72 draw fullcircle scaled 2pt shifted (5pt,11pt);
73 fill button rotatedaround((5pt,5pt),40);
74 fill button rotatedaround((5pt,5pt),-40);
75 clks := currentpicture;
76 draw (5pt,5pt)--(9pt,5pt) rotatedaround ((5pt,5pt),90);
77 endchar;
78
79 % stop watch stop
80 beginchar(152,10pt#,12pt#,0);
81 currentpicture := clks;
82 pickup pencircle scaled .75linewidth;
83 draw (5pt,5pt)--(9pt,5pt) rotatedaround ((5pt,5pt),-60);
84 endchar;
85
86 % interval
87 beginchar(153,10pt#,10pt#,0);
88 currentpicture := clk;
89 fill quartercircle scaled 10pt shifted(5pt,5pt)--(5pt,5pt)--cycle;
90 fill quartercircle rotated -30 scaled 10pt shifted(5pt,5pt)
91 --(5pt,5pt)--cycle;
92 endchar;
93
94 % Wecker
95 beginchar(154,14pt#,12pt#,0);
96 fill unitsquare xscaled 14pt yscaled 12pt;
97 unfill fullcircle scaled 10pt shifted(7pt,6pt);
98 currentpicture := currentpicture + clkb shifted(2pt,1pt);
99 endchar;
100
101 % another clock
102 beginchar(155,10pt#,10pt#,0);
103 pickup pencircle scaled .75linewidth;
104 draw fullcircle scaled 10pt shifted (5pt,5pt);
105 fill fullcircle scaled 1pt shifted (5pt,5pt);
106 draw (5pt,5pt)--(9pt,5pt) rotatedaround ((5pt,5pt),90);
107 draw (5pt,5pt)--(7pt,5pt) rotatedaround ((5pt,5pt),60);
108 endchar;
109
110 end.
111 %%%%%%%%%%%%%%%%%% end of ifclk.gen %%%%%%%%%%%%%%%%%%%%%%%