Debian Codegraph @

texmf-dist/fonts/source/public/ifsym/ifsym.gen

raw
1 %%%%%%%%%%%%%%%%%% ifsym.gen %%%%%%%%%%%%%%%%%%%%%%%
2 % (c) Ingo Kloeckl
3 % This program can be redistributed and/or modified under the terms
4 % of the LaTeX Project Public License Distributed from CTAN
5 % archives in directory macros/latex/base/lppl.txt; either
6 % version 1 of the License, or any later version.
7
8 % History
9 % 20.12.1999 v1.0 IK
10 % 25.05.2000 v1.1 IK ligtable for pulse diagrams improved
11 %
12 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
13 % miscellaneous and alpinistic symbols
14 % by I.Kloeckl, [email protected]
15
16 pen normalpen, boldpen;
17 normalpen := pencircle scaled 1linewidth;
18 if boldface=1:
19 boldpen = pencircle scaled 2linewidth;
20 else:
21 boldpen = pencircle scaled 4linewidth;
22 fi;
23
24 transform t;
25 if italic=0:
26 t := identity;
27 else:
28 t := identity slanted 0.2;
29 fi;
30
31
32 %
33 % miscellaneous symbols
34 %
35 % sectioning symbols
36 "Diamonds1";
37 beginchar(1,10pt#,10pt#,0);
38 pickup normalpen;
39 path p;
40 p = (2pt,0pt)--(0pt,2pt)--(-2pt,0pt)--(0pt,-2pt)--cycle;
41 draw p shifted (5pt,9pt); draw p shifted (5pt,1pt);
42 draw p shifted (2pt,5pt); draw p shifted (8pt,5pt);
43 endchar;
44
45 "FilledDiamonds1";
46 beginchar(2,10pt#,10pt#,0);
47 pickup normalpen;
48 path p;
49 p = (2pt,0pt)--(0pt,2pt)--(-2pt,0pt)--(0pt,-2pt)--cycle;
50 fill p shifted (5pt,9pt); fill p shifted (5pt,1pt);
51 fill p shifted (2pt,5pt); fill p shifted (8pt,5pt);
52 endchar;
53
54 % paper symbol
55 "Portrait";
56 beginchar(3,6pt#,10pt#,0);
57 pickup normalpen;
58 draw (0pt,0pt)--(6pt,0pt)--(6pt,10pt)--(2pt,10pt)--(0pt,8pt)--cycle;
59 pickup pencircle scaled .7linewidth;
60 draw (2pt,10pt)--(2pt,8pt)--(0pt,8pt);
61 pickup pencircle scaled .3linewidth;
62 for i=1.5 upto 7.5:
63 draw (1pt,i*1pt)--(5pt,i*1pt);
64 endfor
65 endchar;
66
67 "Landscape";
68 beginchar(4,10pt#,6pt#,0);
69 pickup normalpen;
70 draw (0pt,0pt)--(10pt,0pt)--(10pt,6pt)--(2pt,6pt)--(0pt,4pt)--cycle;
71 pickup pencircle scaled .7linewidth;
72 draw (2pt,6pt)--(2pt,4pt)--(0pt,4pt);
73 pickup pencircle scaled .3linewidth;
74 for i=1.5 upto 4.5:
75 draw (2pt,i*1pt)--(8pt,i*1pt);
76 endfor
77 endchar;
78
79 "Envelope";
80 beginchar(0,10pt#,7pt#,0);
81 pickup normalpen;
82 draw unitsquare xscaled w yscaled h;% shifted(w/2,h/2);
83 z0=(0,h); z1=(w/2,h/3); z2=(w,h);
84 z3=(0,0); z4=(w/2,2*h/3); z5=(w,0);
85 numeric s; s[z3,z4] = whatever[z0,z1];
86 draw z0--z1--z2; draw z3--s[z3,z4]; draw z5--s[z5,z4];
87 endchar;
88
89 % seven-segment digits
90 path seg[];
91 seg[0] = (.5pt,8.5pt)--(1pt,9pt)--(4pt,9pt)--(4.5pt,8.5pt)--
92 (4pt,8pt)--(1pt,8pt)--cycle;
93 seg[1] = (4.5pt,8.5pt)--(5pt,8pt)--(5pt,5pt)--(4.5pt,4.5pt)--
94 (4pt,5pt)--(4pt,8pt)--cycle;
95 seg[2] = (4.5pt,4.5pt)--(5pt,4pt)--(5pt,1pt)--(4.5pt,0.5pt)--
96 (4pt,1pt)--(4pt,4pt)--cycle;
97 seg[3] = (.5pt,0.5pt)--(1pt,1pt)--(4pt,1pt)--(4.5pt,0.5pt)--
98 (4pt,0)--(1pt,0)--cycle;
99 seg[5] = (0.5pt,8.5pt)--(1pt,8pt)--(1pt,5pt)--(0.5pt,4.5pt)--
100 (0pt,5pt)--(0pt,8pt)--cycle;
101 seg[4] = (0.5pt,4.5pt)--(1pt,4pt)--(1pt,1pt)--(0.5pt,0.5pt)--
102 (0pt,1pt)--(0pt,4pt)--cycle;
103 seg[6] = (.5pt,4.5pt)--(1pt,5pt)--(4pt,5pt)--(4.5pt,4.5pt)--
104 (4pt,4pt)--(1pt,4pt)--cycle;
105
106 beginchar("0",7pt#,10pt#,0);
107 pickup normalpen;
108 fill seg[0] transformed t; fill seg[1] transformed t;
109 fill seg[2] transformed t; fill seg[3] transformed t;
110 fill seg[4] transformed t; fill seg[5] transformed t;
111 endchar;
112 beginchar("1",7pt#,10pt#,0);
113 pickup normalpen;
114 fill seg[1] transformed t; fill seg[2] transformed t;
115 endchar;
116 beginchar("2",7pt#,10pt#,0);
117 pickup normalpen;
118 fill seg[0] transformed t; fill seg[1] transformed t;
119 fill seg[6] transformed t; fill seg[4] transformed t;
120 fill seg[3] transformed t;
121 endchar;
122 beginchar("3",7pt#,10pt#,0);
123 pickup normalpen;
124 fill seg[0] transformed t; fill seg[1] transformed t;
125 fill seg[6] transformed t; fill seg[2] transformed t;
126 fill seg[3] transformed t;
127 endchar;
128 beginchar("4",7pt#,10pt#,0);
129 pickup normalpen;
130 fill seg[5] transformed t; fill seg[6] transformed t;
131 fill seg[1] transformed t; fill seg[2] transformed t;
132 endchar;
133 beginchar("5",7pt#,10pt#,0);
134 pickup normalpen;
135 fill seg[0] transformed t; fill seg[5] transformed t;
136 fill seg[6] transformed t; fill seg[2] transformed t;
137 fill seg[3] transformed t;
138 endchar;
139 beginchar("6",7pt#,10pt#,0);
140 pickup normalpen;
141 fill seg[0] transformed t; fill seg[5] transformed t;
142 fill seg[4] transformed t; fill seg[3] transformed t;
143 fill seg[2] transformed t; fill seg[6] transformed t;
144 endchar;
145 beginchar("7",7pt#,10pt#,0);
146 pickup normalpen;
147 fill seg[5] transformed t; fill seg[0] transformed t;
148 fill seg[1] transformed t; fill seg[2] transformed t;
149 endchar;
150 beginchar("8",7pt#,10pt#,0);
151 pickup normalpen;
152 fill seg[0] transformed t; fill seg[1] transformed t;
153 fill seg[2] transformed t; fill seg[3] transformed t;
154 fill seg[4] transformed t; fill seg[5] transformed t;
155 fill seg[6] transformed t;
156 endchar;
157 beginchar("9",7pt#,10pt#,0);
158 pickup normalpen;
159 fill seg[6] transformed t; fill seg[5] transformed t;
160 fill seg[0] transformed t; fill seg[1] transformed t;
161 fill seg[2] transformed t; fill seg[3] transformed t;
162 endchar;
163 beginchar("-",7pt#,10pt#,0); % minus
164 pickup normalpen;
165 fill seg[6] transformed t;
166 endchar;
167 beginchar(".",0pt#,10pt#,0);
168 pickup boldpen; drawdot (-1pt,0) transformed t;
169 endchar;
170 beginchar("b",7pt#,10pt#,0);
171 endchar; % space (width of 1 digit)
172
173 def basis_cube =
174 pickup normalpen;
175 draw unitsquare scaled 10pt;
176 pickup boldpen;
177 enddef;
178
179 "Cube1";
180 beginchar(5,10pt#,10pt#,0);
181 basis_cube; drawdot (5pt,5pt);
182 endchar;
183
184 "Cube2";
185 beginchar(6,10pt#,10pt#,0);
186 basis_cube; drawdot (2pt,2pt); drawdot (8pt,8pt);
187 endchar;
188
189 "Cube3";
190 beginchar(7,10pt#,10pt#,0);
191 basis_cube; drawdot (2pt,8pt); drawdot (5pt,5pt); drawdot (8pt,2pt);
192 endchar;
193
194 "Cube4";
195 beginchar(8,10pt#,10pt#,0);
196 basis_cube;
197 drawdot (2pt,2pt); drawdot (2pt,8pt); drawdot (8pt,2pt); drawdot (8pt,8pt);
198 endchar;
199
200 "Cube5";
201 beginchar(9,10pt#,10pt#,0);
202 basis_cube; drawdot (2pt,2pt); drawdot (2pt,8pt);
203 drawdot (8pt,2pt); drawdot (8pt,8pt); drawdot (5pt,5pt);
204 endchar;
205
206 "Cube6";
207 beginchar(10,10pt#,10pt#,0);
208 basis_cube;
209 drawdot (2pt,2pt); drawdot (2pt,5pt); drawdot (2pt,8pt);
210 drawdot (8pt,2pt); drawdot (8pt,5pt); drawdot (8pt,8pt);
211 endchar;
212
213
214 % dangerous symbols
215 "Irritant";
216 beginchar(11,10pt#,10pt#,0);
217 pickup normalpen;
218 fill (0.5pt,1.5pt)--(1.5pt,0.5pt)--(9.5pt,8.5pt)--(8.5pt,9.5pt)--cycle;
219 fill (0.5pt,8.5pt)--(1.5pt,9.5pt)--(9.5pt,1.5pt)--(8.5pt,0.5pt)--cycle;
220 endchar;
221
222 %"Fire";
223 beginchar(12,10pt#,10pt#,0);
224 pickup normalpen;
225 fill (1pt,1.5pt)--(9pt,1.5pt)--(9pt,0.5pt)--(1pt,0.5pt)--cycle;
226 fill (2.2pt,4.9pt){dir -40}..{dir -45}(3.4pt,2.2pt)..(4.8pt,1.5pt)..
227 {dir 120}(6.8pt,4.4pt){dir -90}..{dir -40}(6pt,3pt){dir 100}..
228 (6.3pt,5pt)..{dir 100}(4pt,7.3pt){dir -100}..{dir -135}(4.5pt,3.3pt){dir 120}..
229 {dir 120}(3pt,5.2pt){dir -80}..{dir -100}(3.7pt,2.8pt){dir 90}..{dir 160}cycle;
230 fill (4.7pt,3pt){dir 140}..{dir 110}(3.7pt,6.2pt){dir -40}..{dir -120}cycle;
231 fill (3.5pt,5.9pt){dir 80}..{dir 120}(2.2pt,7.5pt){dir -80}..{dir -50}cycle;
232 fill (2.5pt,5.2pt){dir 90}..{dir 135}(1.5pt,6.5pt){dir -100}..{dir -45}cycle;
233 fill (7.1pt,4.6pt){dir 60}..{dir 160}(6.4pt,6.1pt){dir -60}..{dir -100}cycle;
234 fill (5pt,7.6pt){dir 80}..{dir 140}(4pt,8.6pt){dir -100}..{dir -50}cycle;
235 endchar;
236
237 %"Death";
238 %beginchar(13,10pt#,10pt#,0);
239 % pickup pencircle scaled 1linewidth;
240 % fill (5pt,9.4pt){dir 180}..{dir -90}(1.8pt,7.5pt)..{dir -60}(2.8p,5.4pt)..
241 % {dir 0}(5pt,2.9pt){dir 0}..(7.2pt,5.4pt){dir 60}..
242 % (8.2pt,7.5pt){dir90}..{dir 180}cycle;
243 % unfill (2.9pt,7.6pt)..(3.3pt,7.1pt)..(4.2pt,8pt)..(3.7pt,8.3pt)..cycle;
244 % unfill (7.1pt,7.6pt)..(6.7pt,7.1pt)..(5.8pt,8pt)..(6.3pt,8.3pt)..cycle;
245 % % Nase
246 % unfill (5pt,6.4pt)..{dir -120}(4.7pt,5.8pt)..{dir 0}(5pt,5.4pt){dir 0}..
247 % (5.3pt,8.3pt){dir 120}..cycle;
248 % % Mund
249 % unfill (4.1pt,4.7pt){dir -80}..{dir 0}(5pt,4.4pt}{dir 0}..{dir 80}(5.9pt,4.7pt){dir -90}..
250 % {dir 180}(5pt,3.8pt){dir 180}..{dir 90}cycle;
251 % % Knochen
252 % fill (5pt,2.5pt){dir 180}..{dir 135}(3.1pt,3.6pt)..{dir 180}(1.8pt,5.2pt)..
253 % {dir -90}(1.8pt,4.2pt)..{dir -90}(1.2pt,3.8pt)..{dir -30}(2.2pt,3.3pt)..
254 % {dir -90}(3.4pt,2.2pt)..{dir -135}(2.6pt,1.6pt)..{dir 180}(1.2pt,.6pt)..
255 % {dir -90}(0.8pt,1.2pt)..{dir -45}(1.3pt,0.8pt)..{dir 0}(1.7pt,0pt)..
256 % {dir 30}(2.4pt,0.8pt)..{dir 50}(3.8pt,1.4pt)..{dir 0}(5pt,1.9pt)--cycle;
257 %endchar;
258
259 "Radiation";
260 beginchar(14,10pt#,10pt#,0);
261 pickup normalpen;
262 fill fullcircle scaled 3pt shifted(5pt,5pt);
263 z0=(7pt,5pt); z1=(10pt,5pt);
264 z2=z0 rotatedaround((5pt,5pt),60);
265 z3=z1 rotatedaround((5pt,5pt),60);
266 path p; p := z0--z1{dir 90}..{dir 150}z3--z2{dir -30}..{dir -90}cycle;
267 fill p rotatedaround((5pt,5pt),60);
268 fill p rotatedaround((5pt,5pt),180);
269 fill p rotatedaround((5pt,5pt),300);
270 endchar;
271
272 % telephone
273 beginchar(40,15pt#,10pt#,0);
274 pickup normalpen;
275 numeric x[], y[];
276 z0=(1.8pt,0); z1=(1.8pt,2.25pt); z2=(w/2,3.9pt);
277 z3=(w-1.8pt,2.25pt); z4=(w-1.8pt,0);
278 fill z0--z1..z2..z3--z4--cycle;
279 % Hoerer
280 z5=(0.3pt,3.3pt); z6=(3.3pt,3.3pt); z7=(3.3pt,4.2pt);
281 z8=(7.5pt,4.95pt);
282 z9=(w-3.3pt,4.2pt); z10=(w-3.3pt,3.3pt); z11=(w-0.3pt,3.3pt);
283 z12=(w-0.3pt,4.2pt);
284 z13=(7.5pt,5.7pt);
285 z14=(0.3pt,4.2pt);
286 fill z5--z6--z7..z8..z9--z10--z11--z12..z13..z14--cycle;
287 % keyboard
288 unfill fullcircle xscaled 4.5pt yscaled 2.4pt shifted(7.5pt,2.25pt);
289 endchar;
290
291 % up arrow symbolizing spin +1/2
292 beginchar(41,5pt#,10pt#,0);
293 pickup normalpen;
294 draw (2.5pt,2pt)--(2.5pt,8pt);
295 draw (1pt,6pt)--(2.5pt,8pt)--(4pt,6pt);
296 endchar;
297
298 % down arrow symbolizing spin -1/2
299 beginchar(42,10pt#,10pt#,0);
300 pickup normalpen;
301 draw (7.5pt,2pt)--(7.5pt,8pt);
302 draw (6pt,4pt)--(7.5pt,2pt)--(9pt,4pt);
303 endchar;
304
305 % bar (one stroke for "1")
306 beginchar(58,2pt#,10pt#,0);
307 pickup normalpen;
308 numeric x[], y[]; path p;
309 lft z0=(0,0); lft z1=(0,8pt); p := z0--z1;
310 draw p transformed t;
311 endchar;
312 % bar group (five strokes for "5")
313 beginchar(59,10pt#,10pt#,0);
314 pickup normalpen;
315 path p; p:=(0,0)--(0,8pt);
316 draw p shifted(1pt,0) transformed t; draw p shifted(3pt,0) transformed t;
317 draw p shifted(5pt,0) transformed t; draw p shifted(7pt,0) transformed t;
318 path p; p := (0,2pt)--(8pt,6pt);
319 draw p transformed t;
320 endchar;
321
322
323 %
324 % electronic symbols
325 %
326 %
327 % first, some symbols for pulse/clock diagrams
328 %
329 "RaisingEdge";
330 beginchar(32,8pt#,6pt#,0);
331 pickup normalpen;
332 draw (0pt,0pt)--(4pt,0pt)--(4pt,6pt)--(8pt,6pt);
333 endchar;
334
335 "FallingEdge";
336 beginchar(33,8pt#,6pt#,0);
337 pickup normalpen;
338 draw (0pt,6pt)--(4pt,6pt)--(4pt,0pt)--(8pt,0pt);
339 endchar;
340
341 "ShortPulseHigh";
342 beginchar(34,10pt#,6pt#,0);
343 pickup normalpen;
344 draw (0pt,0pt)--(4pt,0pt)--(4pt,6pt)--(6pt,6pt)--(6pt,0pt)--(10pt,0pt);
345 endchar;
346
347 "ShortPulseLow";
348 beginchar(35,10pt#,6pt#,0);
349 pickup normalpen;
350 draw (0pt,6pt)--(4pt,6pt)--(4pt,0pt)--(6pt,0pt)--(6pt,6pt)--(10pt,6pt);
351 endchar;
352
353 "PulseHigh";
354 beginchar(36,14pt#,6pt#,0);
355 pickup normalpen;
356 draw (0pt,0pt)--(4pt,0pt)--(4pt,6pt)--(10pt,6pt)--(10pt,0pt)--(14pt,0pt);
357 endchar;
358
359 "PulseLow";
360 beginchar(37,14pt#,6pt#,0);
361 pickup normalpen;
362 draw (0pt,6pt)--(4pt,6pt)--(4pt,0pt)--(10pt,0pt)--(10pt,6pt)--(14pt,6pt);
363 endchar;
364
365 "LongPulseHigh";
366 beginchar(38,18pt#,6pt#,0);
367 pickup normalpen;
368 draw (0pt,0pt)--(4pt,0pt)--(4pt,6pt)--(14pt,6pt)--(14pt,0pt)--(18pt,0pt);
369 endchar;
370
371 "LongPulseLow";
372 beginchar(39,18pt#,6pt#,0);
373 pickup normalpen;
374 draw (0pt,6pt)--(4pt,6pt)--(4pt,0pt)--(14pt,0pt)--(14pt,6pt)--(18pt,6pt);
375 endchar;
376
377 %
378 % constructing pulse diagrams out of basic characters
379 %
380 "RaiseFall";
381 beginchar("|",0pt#,10pt#,0);
382 pickup normalpen; draw (0pt,0pt)--(0pt,10pt);
383 endchar;
384
385 "LowLineShort";
386 beginchar("l",5pt#,10pt#,0);
387 pickup normalpen; draw (0pt,0pt)--(5pt,0pt);
388 endchar;
389
390 "MiddleLineShort";
391 beginchar("m",5pt#,10pt#,0);
392 pickup normalpen; draw (0pt,5pt)--(5pt,5pt);
393 endchar;
394
395 "DoubleLineShort";
396 beginchar("d",5pt#,10pt#,0);
397 pickup normalpen; draw (0pt,0pt)--(5pt,0pt); draw (0pt,10pt)--(5pt,10pt);
398 endchar;
399
400 "HighLineShort";
401 beginchar("h",5pt#,10pt#,0);
402 pickup normalpen; draw (0pt,10pt)--(5pt,10pt);
403 endchar;
404
405 "LowLineLong";
406 beginchar("L",10pt#,10pt#,0);
407 pickup normalpen; draw (0pt,0pt)--(10pt,0pt);
408 endchar;
409
410 "MiddleLineLong";
411 beginchar("M",10pt#,10pt#,0);
412 pickup normalpen; draw (0pt,5pt)--(10pt,5pt);
413 endchar;
414
415 "DoubleLineLong";
416 beginchar("D",10pt#,10pt#,0);
417 pickup normalpen; draw (0pt,0pt)--(10pt,0pt); draw (0pt,10pt)--(10pt,10pt);
418 endchar;
419
420 "HighLineLong";
421 beginchar("H",10pt#,10pt#,0);
422 pickup normalpen; draw (0pt,10pt)--(10pt,10pt);
423 endchar;
424
425 "Opening";
426 beginchar("<",5pt#,10pt#,0);
427 pickup normalpen; draw (w,h)--(0,.5h)--(w,0);
428 endchar;
429
430 "Closing";
431 beginchar(">",5pt#,10pt#,0);
432 pickup normalpen; draw (0,h)--(w,.5h)--(0,0);
433 endchar;
434
435 "LongOpening"; % <<
436 beginchar(61,10pt#,10pt#,0);
437 pickup normalpen; draw (w,h)--(0,.5h)--(w,0);
438 endchar;
439
440 "LongClosing"; % >>
441 beginchar(63,10pt#,10pt#,0);
442 pickup normalpen; draw (0,h)--(w,.5h)--(0,0);
443 endchar;
444
445 ligtable "l":
446 "l" =: "L",
447 "h" |=:| "|",
448 "H" |=:| "|";
449 ligtable "h":
450 "h" =: "H",
451 "l" |=:| "|",
452 "L" |=:| "|";
453 ligtable "L":
454 "h" |=:| "|",
455 "H" |=:| "|";
456 ligtable "H":
457 "l" |=:| "|",
458 "L" |=:| "|";
459 ligtable "<":
460 "<" =: 61;
461 ligtable ">":
462 ">" =: 63;
463
464 %
465 % alpine symbols
466 %
467 "SummitSign";
468 beginchar(16,8pt#,9pt#,0);
469 pickup boldpen;
470 draw (4pt,1pt)--(4pt,8pt); draw (1pt,6pt)--(7pt,6pt);
471 endchar;
472
473 "StoneMan";
474 beginchar(17,6pt#,8pt#,0);
475 pickup normalpen;
476 fill (0pt,1pt)--(5pt,1pt)--(2.5pt,8pt)--cycle;
477 endchar;
478
479 "Hut";
480 beginchar(18,8pt#,9pt#,0);
481 pickup normalpen;
482 draw (1pt,5pt)--(1pt,1pt)--(7pt,1pt)--(7pt,5pt)--
483 (8pt,5pt)--(4pt,9pt)--(0pt,5pt)--cycle;
484 endchar;
485
486 "FilledHut";
487 beginchar(19,8pt#,9pt#,0);
488 pickup normalpen;
489 fill (1pt,5pt)--(1pt,1pt)--(7pt,1pt)--(7pt,5pt)--
490 (8pt,5pt)--(4pt,9pt)--(0pt,5pt)--cycle;
491 endchar;
492
493 "Summit";
494 beginchar(20,10pt#,10pt#,0);
495 pickup normalpen;
496 fill (-0.5pt,-0.5pt)--(0.5pt,-0.5pt)--(0pt,0.5pt)--cycle
497 scaled 10 shifted(5pt,5pt);
498 endchar;
499
500 "Mountain";
501 beginchar(21,10pt#,0pt#,0);
502 pickup normalpen;
503 fill (0pt,0pt)--(10pt,0pt)--(7pt,5pt)--cycle;
504 fill (0pt,0pt)--(3pt,8pt)--(7pt,0pt)--cycle;
505 endchar;
506
507 "IceMountain";
508 beginchar(22,10pt#,0pt#,0);
509 pickup normalpen;
510 fill (0pt,0pt)--(10pt,0pt)--(7pt,5pt)--cycle;
511 draw (0pt,0pt)--(3pt,8pt)--(7pt,0pt)--cycle;
512 endchar;
513
514 "Mountain2";
515 beginchar(23,10pt#,0pt#,0);
516 pickup normalpen;
517 fill (0pt,0pt)--(2pt,6.5pt)--(3.4pt,3.3pt)--(5.6pt,4.3pt)--
518 (6.5pt,3pt)--(7.2pt,3.8pt)--(10pt,0pt)--cycle;
519 endchar;
520
521 "IceMountain2";
522 beginchar(24,10pt#,0pt#,0);
523 pickup normalpen;
524 fill (0pt,0pt)--(2pt,6.5pt)--(3.4pt,3.3pt)--(5.6pt,4.3pt)--
525 (6.5pt,3pt)--(7.2pt,3.8pt)--(10pt,0pt)--cycle;
526 unfill (0.6pt,1.6pt)--(1.9pt,6.1pt)--(1.9pt,3.9pt)--(3.2pt,2.9pt)--
527 (5.6pt,4.1pt)--(5.2pt,3.4pt)--(6.2pt,3.1pt)--(4.0pt,2.1pt)--cycle;
528 unfill (3.5pt,1.2pt)--(5.9pt,2.7pt)--(7.2pt,3.6pt)--(6.9pt,1.7pt)--cycle;
529 endchar;
530
531 "Vermessung";
532 beginchar(25,8pt#,8pt#,0);
533 pickup normalpen;
534 draw (0pt,0pt)--(8pt,0pt)--(4pt,8pt)--cycle;
535 pickup boldpen;
536 drawdot (4pt,3pt);
537 endchar;
538
539 "Joch";
540 beginchar(26,6pt#,8pt#,0);
541 pickup normalpen;
542 fill (0pt,0pt)--(2pt,2pt)--(2pt,6pt)--(0pt,8pt)--
543 (1pt,6pt)--(1pt,2pt)--cycle;
544 fill (6pt,0pt)--(4pt,2pt)--(4pt,6pt)--(6pt,8pt)--
545 (5pt,6pt)--(5pt,2pt)--cycle;
546 endchar;
547
548 "Fahne";
549 beginchar(27,10pt#,10pt#,0);
550 pickup normalpen;
551 draw (3pt,0pt)--(3pt,10pt);
552 fill (3pt,10pt)--(0pt,8pt)--(3pt,6pt)--cycle;
553 endchar;
554
555 "varFahne";
556 beginchar(29,10pt#,10pt#,0);
557 pickup normalpen;
558 draw (3pt,0pt)--(3pt,10pt);
559 fill (3pt,10pt)--(0pt,10pt)--(0pt,7pt)--(3pt,7pt)--cycle;
560 endchar;
561
562 "Zelt";
563 beginchar(28,10pt#,10pt#,0);
564 z0 = (0pt,0pt);
565 z1 = (10pt,0pt);
566 z2 = (5pt,7pt);
567 pickup normalpen;
568 fill z0--z1--z2--cycle;
569 draw 1.3[z0,z2]--z0--z1--1.3[z1,z2];
570 unfill (3pt,0pt)--(7pt,0pt)--(5pt,3pt)--cycle;
571 endchar;
572
573 "HalfFilledHut";
574 beginchar(31,8pt#,9pt#,0);
575 pickup normalpen;
576 draw (1pt,5pt)--(1pt,1pt)--(7pt,1pt)--(7pt,5pt)--
577 (8pt,5pt)--(4pt,9pt)--(0pt,5pt)--cycle;
578 fill (1pt,1pt)--(7pt,1pt)--(7pt,5pt)--cycle;
579 endchar;
580
581 "WhiteSummit";
582 beginchar(30,10pt#,10pt#,0);
583 pickup normalpen;
584 path p;
585 p:= (-0.5pt,-0.5pt)--(0.5pt,-0.5pt)--(0pt,0.5pt)--cycle;
586 draw p scaled 10 shifted(5pt,5pt);
587 endchar;
588
589 end.
590
591 %%%%%%%%%%%%%%%%%% end of ifsym.gen %%%%%%%%%%%%%%%%%%%%%%%