Debian Codegraph @

texmf-dist/fonts/source/public/astro/astrosym.xtr

raw
1 % ASTROSYM.XTR : AstroSym (Version 2.20, Aug. 10, 2002) - file 7 of 8
2 % Peter Schmitt eMail: [email protected]
3 % Institute of Mathematics, University of Vienna Vienna, Austria
4 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
5
6 beginchar(O+0,U#,U#,0u#); "(moon face) full moon";
7 corners; centers;
8 VV:=(BC-BL) rotated 90;
9 TC:=CC+VV; BC:=CC-VV; D:=U/9;
10 hh:=(U/6,0); vv:=(0,U/6);
11 PEN; draw TC..CR..BC..CL..TC..cycle; % circle
12 Pen; draw CC--(CC-vv); % nose
13 filldraw fullcircle scaled D shifted (CC-hh+vv/2); % left eye
14 filldraw fullcircle scaled D shifted (CC+hh+vv/2); % right eye
15 draw (CC-vv-hh)..(CC-1.8vv)..(CC-vv+hh); % mouth
16 draw (CC-vv+hh)..(CC-1.5vv)..(CC-vv-hh);
17 endchar;
18
19 beginchar(O+1,U#,U#,0u#); "(moon face) new moon";
20 PEN; fill TC..CR..BC..CL..TC..cycle; % circle
21 Pen; undraw CC--(CC-vv); % nose
22 unfilldraw fullcircle scaled D shifted (CC-hh+vv/2); % left eye
23 unfilldraw fullcircle scaled D shifted (CC+hh+vv/2); % right eye
24 undraw (CC-vv-hh)..(CC-1.8vv)..(CC-vv+hh); % mouth
25 undraw (CC-vv+hh)..(CC-1.5vv)..(CC-vv-hh);
26 endchar;
27
28 path moon;
29 beginchar(O+2,2/3U#,U#,0u#); "(moon face) last quarter";
30 corners; Centers(3/4,1/2);
31 VV:=(TL-BL)/2; HH:=VV rotated -90;
32 BC:=BL+HH; TC:=TL+HH; % CL=BL+VV;
33 R:=length(HH); D:=length(BR-BL);
34 t:=(R+-+(D-R))/2R;
35 RT (1/2-t,1/2+t);
36 rr:=(2u,2u); ll:=(-5u,-3u); mm:=(0,-5u);
37 moon := bR..BC..CL..TC..tR % outer circle
38 & tR..{dir -45}(CC+rr) % forehead
39 & {dir 180}(CC+rr)..(CC+ll)..(CC+2ll){dir 180} % nose
40 & (CC+2ll){dir -10}..(CC+mm)
41 & (CC+mm){dir -135}..bR % mouth
42 & bR--cycle; % chin
43 D:=U/9; filldraw fullcircle scaled D shifted (CC-hh+vv/2); % eye
44 Pen; draw moon;
45 endchar;
46
47 temp := currentpicture;
48 beginchar(O+3,2/3U#,U#,0u#); "(moon face) first quarter";
49 currentpicture := temp xscaled -1 shifted (w,0);
50 endchar;
51
52 beginchar(O+4,2/3U#,U#,0u#); "(moon face) last quarter - inverse";
53 fill moon;
54 D:=U/9; unfilldraw fullcircle scaled D shifted (CC-hh+vv/2); % eye
55 endchar;
56
57 temp := currentpicture;
58 beginchar(O+5,2/3U#,U#,0u#); "(moon face) first quarter - inverse";
59 currentpicture := temp xscaled -1 shifted (w,0);
60 endchar;
61
62 endinput;
63
64 beginchar(O+6,U#,U#,0u#); "full moon";
65 corners; centers;
66 VV:=(BC-BL) rotated 90;
67 TC:=CC+VV; BC:=CC-VV; D:=U/9;
68 hh:=(U/6,0); vv:=(0,U/6);
69 PEN; draw TC..CR..BC..CL..TC..cycle; % circle
70 endchar;
71
72 beginchar(O+7,U#,U#,0u#); "new moon";
73 fill TC..CR..BC..CL..TC..cycle; % disk
74 shade (CL,CR, BC,TC);
75 Pen; draw TC..CR..BC..CL..TC..cycle; % circle
76 endchar;
77
78 temp:=currentpicture;
79 beginchar(O+8,2/3U#,U#,0u#); "Luna 2 = (moon 2) last quarter";
80 corners; Centers(3/4,1/2);
81 VV:=(TL-BL)/2; HH:=VV rotated -90;
82 BC:=BL+HH; TC:=TL+HH; % CL=BL+VV;
83 R:=length(HH); D:=length(BR-BL);
84 t:=(R+-+(D-R))/2R;
85 RT (1/2-t,1/2+t);
86 currentpicture := temp;
87 Pen; unfilldraw tR..TC..CL..BC..bR % outer circle
88 & bR..CC..tR % inner arc
89 & tR--cycle;
90 cullit;
91 Pen; draw tR..TC..CL..BC..bR; % outer circle
92 draw tR..CC..bR; % inner arc
93 endchar;
94
95 temp := currentpicture;
96 beginchar(O+9,2/3U#,U#,0u#); "(moon 2) first quarter";
97 currentpicture := temp xscaled -1 shifted (w,0);
98 endchar;
99
100 beginchar(O+9,2/3U#,U#,0u#); "(moon 2) last quarter - inverse";
101 PEN; filldraw tR..TC..CL..BC..bR % big circle
102 & bR..CC..tR -- cycle; % small circle
103 cullit; addto currentpicture also -temp; cullit;
104 Pen; draw tR..TC..CL..BC..bR % big circle
105 & bR..CC..tR -- cycle; % small circle
106 endchar;
107
108 temp := currentpicture;
109 beginchar(O+10,2/3U#,U#,0u#); "(moon 2) first quarter - inverse";
110 currentpicture := temp xscaled -1 shifted (w,0);
111 endchar;
112
113 endinput;
114 %%%%%%%%%%%%%%%%%%%%%%%%%%%
115 %%% end of ASTROSYM.XTR %%%