| 1 |
% ASTROSYM.CAL : AstroSym (Version 2.20, Aug. 10, 2002) - file 5 of 8 |
| 2 |
% Peter Schmitt eMail: [email protected] |
| 3 |
% Institute of Mathematics, University of Vienna Vienna, Austria |
| 4 |
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% |
| 5 |
|
| 6 |
beginchar(O+0,U#,U#,0u#); "Sol"; |
| 7 |
D:=2P; % diameter of central circle |
| 8 |
corners; centers; |
| 9 |
PEN; draw BC..CL..TC..CR..BC..cycle; % main circle |
| 10 |
Pen; draw fullcircle scaled D shifted CC; % central circle |
| 11 |
endchar; |
| 12 |
|
| 13 |
beginchar(O+1,46u#,80u#,16u#); "Mercurius"; |
| 14 |
corners; centers; |
| 15 |
VV:=(CC-CL) rotated 90; |
| 16 |
bC := CC-VV; |
| 17 |
VV:=2VV+vP/3; |
| 18 |
tL:=CL+VV; tC:=CC+VV; tR:=CR+VV; |
| 19 |
R:=length(tL-hd-tC); % upper circle: outer radius |
| 20 |
s:=length(TC+vd-tC); a:= angle(R+-+s,s); % upper partial sector: angle |
| 21 |
Tl:= (tL-hd) rotatedaround (tC,-a); % upper circle: outer endpoints |
| 22 |
Tr:= (tR+hd) rotatedaround (tC, a); |
| 23 |
tl:= (tL+hd) rotatedaround (tC,-a+10); % upper circle: inner endpoints |
| 24 |
tr:= (tR-hd) rotatedaround (tC, a-10); |
| 25 |
D:=length(CR-CL); % central circle: diameter |
| 26 |
SPEN; cross (bC,BC, 3/2,-2P); % bottom cross |
| 27 |
PEN; |
| 28 |
draw fullcircle scaled D shifted CC; % central circle |
| 29 |
Pen; Fill |
| 30 |
( Tl..(tL-hd){down}..{up}(tR+hd)..Tr % upper circle: outside |
| 31 |
& Tr--tr |
| 32 |
& tr..(tR-hd){down}..{up}(tL+hd)..tl % upper circle: inside |
| 33 |
& tl--Tl--cycle |
| 34 |
); |
| 35 |
endchar; |
| 36 |
|
| 37 |
beginchar(O+5,44u#,70u#,0u#); "Iuppiter"; |
| 38 |
Corners (P,0,0,P); Centers (2/3,2/7); Top (6/7); |
| 39 |
RPEN; draw tC--BC; % right vertical bar |
| 40 |
RPEN rotated 90; draw (CL+hd)--CR; % horizontal bar |
| 41 |
Pen; Fill % left vertical arc |
| 42 |
( (CL-vd-hd){tC-CL}..{TL-CC}(TL+(1-sqrt2)*vP-hd) % - left |
| 43 |
& (TL+(1-sqrt2)*vP-hd)--(TL+vd-(1-sqrt2)*hP) % - top |
| 44 |
& (TL+vd-(1-sqrt2)*hP){CC-TL}..{CL-tC}(CL-vd+hd) % - right |
| 45 |
& (CL-vd+hd)--(CL-vd-hd) % - bottom |
| 46 |
& (CL-vd-hd)..cycle |
| 47 |
); |
| 48 |
endchar; |
| 49 |
|
| 50 |
beginchar(O+6,44u#,72u#,12u#); "Saturnus"; |
| 51 |
Corners (P,P,d+P,P); |
| 52 |
Centers (1/6,5/9); % BC and TC : left vertical bar |
| 53 |
RT (1/2,1); % bR : right arc (right) |
| 54 |
HOR (0,1/3); Top (6/7); % tl and tr : upper horizontal bar |
| 55 |
BOT (2/3,7/9); Bl:=Bl-vd; % Bl |
| 56 |
Br:=Br-(0,d)+((P-(P*sqrt(2))*sind(45+20),0) rotated -70); % Br |
| 57 |
SPEN; draw tl--tr; draw BC--TC; % left cross |
| 58 |
PEN; draw CC{dir 20}..{down}bR..{dir250}Bl..{dir-70}Br; % right arc |
| 59 |
RPEN rotated 20; draw Br--(Br+(hP rotated -70)); % sharpen arc end |
| 60 |
endchar; |
| 61 |
|
| 62 |
beginchar(O+11,1U#,72u#,2u#); "Aries"; |
| 63 |
Corners(p,p,p+d,p); |
| 64 |
BOT (1/2,1/2); |
| 65 |
% upper boundary : |
| 66 |
vv:=7vd; % estimated correction |
| 67 |
bl:=Bl+vv; br:=Br+vv; % bl = br : lower middle point |
| 68 |
TOP (1/6,5/6); % (temporary) Tl and Tr : upper arcs (tops) |
| 69 |
HH:= Tl-TL; VV:= HH rotated -90; |
| 70 |
tr:=Tr+VV; % tr : right upper halfcircle (centre) |
| 71 |
D:=length(tr-br); R:=length(HH); s:=D+-+R; % calculating direction of bar |
| 72 |
b:=angle(s,R); b:=b+angle(tr-br); |
| 73 |
Tr:=tr+(HH rotated (b+90)); % Tr : (left endpoint) |
| 74 |
tR:=tr+(HH rotated (b-90)); % tR : (right endpoint) |
| 75 |
tl:=Tl+VV; a:=180-b; % tl : left upper halfcircle (centre) |
| 76 |
Tl:=tl+(HH rotated (a-90)); % Tl : (right endpoint) |
| 77 |
tL:=tl+(HH rotated (a+90)); % tL : (left endpoint) |
| 78 |
% lower boundary : |
| 79 |
s:=2(P-p)/sind(90-b); % caculating |Bl-bl| |
| 80 |
Bl:= bl-(0,s); Br:=br-(0,s); |
| 81 |
t:=2(P-p)/length(HH); |
| 82 |
tl:=Tl-t*(HH rotated (a-90)); % left upper halfcircle: right endpoint |
| 83 |
tr:=Tr-t*(HH rotated (b+90)); % right upper halfcircle: left endpoint |
| 84 |
Pen; Fill |
| 85 |
( bl--Tl{dir a}..{dir (a-180)}tL % left part: upper boundary |
| 86 |
& tL..(tL+(1,0)) % avoiding strange path |
| 87 |
{dir (a-6)}..{dir (a-180)}tl--Bl % left part: lower boundary |
| 88 |
& Bl--bl..cycle |
| 89 |
); |
| 90 |
Fill |
| 91 |
( br--Tr{dir b}..{dir (b-180)}tR % right part: upper boundary |
| 92 |
& tR..(tR-(1,0)) % avoiding strange path |
| 93 |
{dir (b+6)}..{dir (b-180)}tr--Br % right part: lower boundary |
| 94 |
& Br--br..cycle |
| 95 |
); |
| 96 |
endchar; |
| 97 |
|
| 98 |
beginchar(O+12,1U#,72u#,8u#); "Taurus"; |
| 99 |
Corners(P,P,P,p); |
| 100 |
Centers (1/2,5/9); % BC and CC : lower circle (top and bottom) |
| 101 |
HOR (1/8,7/8); % Tl and Tr : upper arcs (tops) |
| 102 |
Bot (5/18); % bl and br : lower circle (left and right) |
| 103 |
LFT (0,4/5); RT (0,4/5); % tL and tR : upper arcs (left and right) |
| 104 |
Pen; Fill |
| 105 |
( Tl{dir 223}..{down}(tL-hd)..(CC-vd) % left upper arc: outside |
| 106 |
..(br-hd)..(BC+vd)..(bl+hd)..(CC-vd) % lower circle: inside |
| 107 |
..{up}(tR+hd)..{dir 137}Tr % right upper arc: outside |
| 108 |
& Tr{dir -47}..{down}(tR-hd/2+vd/2)..(CC+vd) % right upper arc: inside |
| 109 |
..(bl-hd)..(BC-vd)..(br+hd)..(CC+vd) % lower circle: outside |
| 110 |
..{up}(tL+hd/2+vd/2)..{dir 47}Tl % left upper arc: inside |
| 111 |
& Tl..Tl..cycle |
| 112 |
); |
| 113 |
endchar; |
| 114 |
|
| 115 |
beginchar(O+13,56u#,72u#,8u#); "Gemini"; |
| 116 |
Corners (p,p,p,p); |
| 117 |
HOR (2/7,5/7); |
| 118 |
Top (7/8); Bot (1/8); |
| 119 |
Pen; Fill ( BL..(bl-vd)..(br-vd)..BR % bottom arc: lower boundary |
| 120 |
& BR..(br+vd)..(bl+vd)..BL % bottom arc: upper boundary |
| 121 |
& BL--cycle |
| 122 |
); |
| 123 |
Fill ( TL..(tl-vd)..(tr-vd)..TR % top arc: lower boundary |
| 124 |
& TR..(tr+vd)..(tl+vd)..TL % top arc: upper boundary |
| 125 |
& TL--cycle |
| 126 |
); |
| 127 |
RPEN; draw tl--bl; draw tr--br; % left and right vertical bar |
| 128 |
endchar; |
| 129 |
|
| 130 |
beginchar(O+14,80u#,68u#,0u#); "Cancer"; |
| 131 |
corners; centers; |
| 132 |
Cl:=2/7[CL,CR]; RT (0,4/5); |
| 133 |
PEN; draw CL{up}..{down}Cl..{up}CL; % left circle |
| 134 |
Pen; Fill ( (CL-hd){up}..{right}(TC+vd)..tR % upper arc: upper boundary |
| 135 |
& tR..{left}(TC-vd/2)..{down}(CL+hd) % upper arc: lower boundary |
| 136 |
& (CL+hd)--(CL-hd)..cycle |
| 137 |
); |
| 138 |
picture upper; upper := currentpicture; % adding rotated copy |
| 139 |
addto currentpicture also upper rotated 180 shifted 2CC; |
| 140 |
endchar; |
| 141 |
|
| 142 |
beginchar(O+15,68u#,80u#,10u#); "Leo"; |
| 143 |
Corners(P,p,d+P,P); centers; % TC |
| 144 |
HOR (1/6,17/20); Top (3/4); % tl and tr : main arc (left and right) |
| 145 |
BOT (1/3,2/3); rr:=(Bl-BL)/2; |
| 146 |
bL:=BL+(rr rotated 90); bl:=bL+2rr; % bL and bl : lower left circle |
| 147 |
Br:=BR+hd-(2d,0)-vP; BR:=BR-vP; % Br and BR : lower right arc |
| 148 |
PEN; draw bL{down}..{up}bl % lower left circle: lower arc |
| 149 |
..{up}tl..{right}TC..{down}tr..{down}Br; % main arc |
| 150 |
Pen; Fill % lower right arc |
| 151 |
( (Br-hd){down}..{up}BR % outside |
| 152 |
& BR{dir265}..{up}(Br+hd) % inside |
| 153 |
& (Br+hd)--(Br-hd)..cycle |
| 154 |
); |
| 155 |
Fill ( (bL+hd){up}..bl % lower left circle: upper arc, ouside |
| 156 |
& bl{up}..{down}(bL-hd) % inside |
| 157 |
& (bL-hd)--(bL+hd)..cycle |
| 158 |
); |
| 159 |
endchar; |
| 160 |
|
| 161 |
beginchar(O+16,100u#,68u#,10u#); "Virgo"; |
| 162 |
Corners (P,P,d,0); |
| 163 |
LFT (0,3/4); % tL : left upper arc (left end) |
| 164 |
HOR (1/3,2/3); Top (3/4); % tl and tr : upper arcs (endpoints) |
| 165 |
TOP (4/14,4/14+1/3); % Tl and Tr : upper arcs (tops) |
| 166 |
RT (1/5,3/4); % tR : right upper arc (right end) |
| 167 |
% bR and tR : right vertical bar (ends) |
| 168 |
TR:=(4/14+2/3)[TL,TR]; % TR : right upper arc (top) |
| 169 |
bC:=.5[Bl,Br]-(0,d/2); % bC : lower right stroke (endpoint) |
| 170 |
br:=Br-(0,d); % br : middle right bar (lower end) |
| 171 |
Br:=Br+vP; % Br : lower right vertical stroke (left) |
| 172 |
BR:=2/3[Br,BR+vP]; % BR : lower right vertical stroke (right) |
| 173 |
RPEN; draw TL--BL; draw tl--Bl; draw tr--br; draw tR--bR; % vertical bars |
| 174 |
Pen; Fill % left upper arc |
| 175 |
( tL{dir 42}..{right}(Tl-4vp)..{down}(tl+hd) % upper boundary |
| 176 |
& (tl+hd)--(tl-hd) |
| 177 |
& (tl-hd){up}..(Tl-2vP-2vp)..{dir 215}tL..cycle % lower boundary |
| 178 |
); |
| 179 |
Fill % middle upper arc |
| 180 |
( tl{dir 42}..{right}(Tr-4vp)..{down}(tr+hd) % upper boundary |
| 181 |
& (tr+hd)--(tr-hd) |
| 182 |
& (tr-hd){up}..(Tr-2vP-2vp)..{dir 215}tl..cycle % lower boundary |
| 183 |
); |
| 184 |
Fill % right upper arc |
| 185 |
( tr{dir 45}..{right}(TR-1vp)..{down}(tR+hd) % upper boundary |
| 186 |
& (tR+hd)--(tR-hd) |
| 187 |
& (tR-hd){up}..(TR-2vd-0vp)..{dir 215}tr..cycle % lower boundary |
| 188 |
); |
| 189 |
PEN; draw bR{dir250}..{dir190}BR--Br; % lower right stroke: right part |
| 190 |
Pen; Fill |
| 191 |
( (Br+vd){left}..{dir 235}bC % lower right stroke: left part |
| 192 |
& bC{dir 50}..{right}(Br-vd) |
| 193 |
& (Br-vd)--(Br+vd)..cycle |
| 194 |
); |
| 195 |
endchar; |
| 196 |
|
| 197 |
beginchar(O+17,64u#,56u#,-8u#); "Libra"; |
| 198 |
corners; |
| 199 |
Centers (1/2,7/15); % CL and CR : upper bars (outer ends) |
| 200 |
TOP (1/4,3/4); |
| 201 |
VV:=(TC-Tl) rotated -90; |
| 202 |
tl:=Tl+VV; tr:=Tr+VV; % tl and tr : upper arc (left and right) |
| 203 |
R:=length(VV); D:=length(TC-CC); % calculating intersection of |
| 204 |
t:=(R+-+(D-R))/length(BR-BL); % upper arc with upper bars |
| 205 |
HOR (1/2-t,1/2+t); Bot (7/15); % (bl and cl renamed:) |
| 206 |
Cl:=bl; Cr:=br; % Cl and Cr : upper arc (inner ends) |
| 207 |
% Cl:=bl+hP; Cr:=br-hP; % Cl and Cr : upper arc (inner ends) |
| 208 |
bL:=CL-vP; bl:=Cl-vP; br:=Cr-vP; bR:=CR-vP; % shift upper bars slightly down |
| 209 |
% bL:=CL; bl:=Cl; br:=Cr; bR:=CR; % shift upper bars slightly down |
| 210 |
SPEN; draw BL--BR; % bottom bar |
| 211 |
SPEN; draw bL--bl; draw br--bR; % left and right upper bars |
| 212 |
Pen; Fill % left upper bar: left end |
| 213 |
( CL{dir 170}..{dir 105}(CL+vd-hd) % inner boundary |
| 214 |
& (CL+vd-hd)--(CL-hd)--CL % left and lower boundary |
| 215 |
& CL.. cycle |
| 216 |
); |
| 217 |
Pen; Fill % right upper bar: right end |
| 218 |
( CR{dir 10}..{dir 75}(CR+vd+hd) % inner boundary |
| 219 |
& (CR+vd+hd)--(CR+hd)--CR % right and lower boundary |
| 220 |
& CR.. cycle |
| 221 |
); |
| 222 |
PEN; draw Cl..{up}tl..{right}TC..{down}tr..Cr; % upper arc |
| 223 |
endchar; |
| 224 |
|
| 225 |
beginchar(O+18,(14/15)*100u#-(13/15)*P#+p#,68u#,10u#); "Scorpio"; |
| 226 |
Corners (P,p,d,0); |
| 227 |
LFT (0,3/4); % tL : left upper arc (left end) |
| 228 |
HOR (5/14,10/14); Top (3/4); % tl and tr : upper arcs (endpoints) |
| 229 |
TOP (4/14,9/14); % Tl and Tr : upper arcs (tops) |
| 230 |
RT (1/6,1); % bR : lower right arrow (point) |
| 231 |
br:=1/3[Br,BR]-(0,d)+vp; % br : lower right arc (bottom) |
| 232 |
BR:=2/3[Br,BR]+vp; % Br and BR : lower right arc (endpoints) |
| 233 |
RPEN; draw TL--BL; draw tl--Bl; draw tr--Br; % vertical bars |
| 234 |
Pen; Fill % left upper arc |
| 235 |
( tL{dir 42}..{right}(Tl-4vp)..{down}(tl+hd) % upper boundary |
| 236 |
& (tl+hd)--(tl-hd) |
| 237 |
& (tl-hd){up}..(Tl-2vP-2vp)..{dir 215}tL..cycle % lower boundary |
| 238 |
); |
| 239 |
Fill % right upper arc |
| 240 |
( tl{dir 42}..{right}(Tr-4vp)..{down}(tr+hd) % upper boundary |
| 241 |
& (tr+hd)--(tr-hd) |
| 242 |
& (tr-hd){up}..(Tr-2vP-2vp)..{dir 215}tl..cycle % lower boundary |
| 243 |
); |
| 244 |
Fill % lower right arc |
| 245 |
( (Br+hd){down}..{right}(br+vd)..{dir angle((br-BR) rotated 0)}BR |
| 246 |
& BR{dir angle((BR-br) rotated 6)}..{left}br..{up}(Br-hd) |
| 247 |
& (Br-hd)--(Br+hd)..cycle |
| 248 |
); |
| 249 |
arrow (BR+2hp,bR, 1, 1/4,1/2); % lower right arrow |
| 250 |
endchar; |
| 251 |
|
| 252 |
beginchar(O+19,56u#,80u#,8u#); "Sagittarius"; |
| 253 |
Corners(P*(h+d)/((h+d)++w),p,P*w/((h+d)++w),p); |
| 254 |
bl:=(1/5)[BL,TR]; tr:=(3/4)[BL,TR]; |
| 255 |
VV:=TR-BL; a:=angle(VV); |
| 256 |
HH:= VV/8 rotated 90; |
| 257 |
bL:= bl+HH; Bl:= bl-HH; |
| 258 |
RPEN rotated (a+90); draw BL--tr; % shaft |
| 259 |
RPEN rotated a; draw bL--Bl; % short bar |
| 260 |
Pen; arrow (tr,TR, 6/7, .3,.6); % point |
| 261 |
endchar; |
| 262 |
|
| 263 |
beginchar(O+20,56u#,1U#,0); "Capricornus"; |
| 264 |
Corners(p,p,p,p); % TR: top bar (right end) |
| 265 |
Centers (2/3,2/3); % BC and CC: loop (bottom and top) |
| 266 |
HOR (1/3,1); Bot (1/3); % bl and br: loop (left and right) |
| 267 |
TOP(1/4,1); Tl:=Tl-hd; % Tl: top bar (left end) |
| 268 |
LFT (.45,1); % bL: end of loop |
| 269 |
Pen; Fill |
| 270 |
( Tl--TR % top bar: upper boundary |
| 271 |
& TR{dir225}..{down}(bl+hd)..{right}(BC+2vd) % loop from TR to bL |
| 272 |
..{up}(br-2hd)..{left}(CC-.5vd-hd)..bL |
| 273 |
& bL..{right}(CC+.5vd)..{down}br..{left}BC % loop back from bL to TR |
| 274 |
..{up}(bl-hd)..{dir45}(TR-2vd-3hd) |
| 275 |
& (TR-2vd-3hd)--(Tl-2vd)--Tl % top bar: lower boundary |
| 276 |
& Tl..Tl..cycle |
| 277 |
); |
| 278 |
endchar; |
| 279 |
|
| 280 |
beginchar(O+22,56u#,72u#,8u#); "Pisces"; |
| 281 |
Corners(p,p,p,p); |
| 282 |
HOR (1/4,3/4); Top (1/2); |
| 283 |
Pen; Fill ( BL..(tl-hd)..TL % left arc: left boundary |
| 284 |
& TL..(tl+hd)..BL % left arc: right boundary |
| 285 |
& BL--cycle |
| 286 |
); |
| 287 |
Fill ( BR..(tr-hd)..TR % right arc: left boundary |
| 288 |
& TR..(tr+hd)..BR % right arc: right boundary |
| 289 |
& BR--cycle |
| 290 |
); |
| 291 |
PEN; draw tl--tr; % vertical bar |
| 292 |
endchar; |
| 293 |
|
| 294 |
beginchar(O+23,44u#,72u#,12u#); "Saturnus 2"; |
| 295 |
corners; Centers (4/9,8/11); |
| 296 |
HOR (0,8/9); Top (19/22); |
| 297 |
RT (6.3/11,1); % bR |
| 298 |
Bl:=2/9[BL,BR]; Bot(.8/12); % bl |
| 299 |
bC:=1/5[BC,TC]; % bC |
| 300 |
Bl:=Bl+((P-(P*sqrt(2))*sind(45+20),0) rotated -70); % Bl |
| 301 |
SPEN; draw tl--tr; draw CC--TC; % upper cross |
| 302 |
PEN; draw CC{right}..{down}bR..bC..{dir250}bl..{dir-70}Bl; % lower arc |
| 303 |
RPEN rotated 20; draw Bl--(Bl+(hP rotated -70)); % sharpen arc end |
| 304 |
endchar; |
| 305 |
|
| 306 |
beginchar(O+27,76u#,50u#,-22u#); "Aquarius 2"; |
| 307 |
Corners (p,p,p,p); |
| 308 |
% upper strokes: |
| 309 |
Centers (3/5,1/2); % CL and CC : left stroke (left end, right bottom) |
| 310 |
TOP (1/4,4/5); % Tl and Tr : left stroke (left top, right end) |
| 311 |
Pen; |
| 312 |
Fill ( (CL+vp)..{right}Tl..{right}(CC+vd)..(Tr-vP) % left stroke: upper |
| 313 |
& (Tr-vP)..{left}(CC+vp)..{left}(Tl-2vd)..(CL+vp) % left stroke: lower |
| 314 |
& (CL+vp)..cycle |
| 315 |
); |
| 316 |
Fill ( (Tr+hP/2)..{right}(CR+2vd) % right stroke: upper |
| 317 |
& (CR+2vd){-hP/2-2vd}..{left}(CR-hP+vp) % right stroke: lower |
| 318 |
..(Tr-2vd-hP/2) % ( from Tr to CR ) |
| 319 |
& (Tr-2vd-hP/2)--(Tr+hP/2) % right stroke: left end |
| 320 |
& (Tr+hP/2)..cycle |
| 321 |
); |
| 322 |
picture upper; upper:= currentpicture; % lower strokes |
| 323 |
addto currentpicture also upper shifted (0,-(h+d)/2); |
| 324 |
endchar; |
| 325 |
|
| 326 |
beginchar(O+28,78u#,56u#,-9u#); "Aquarius 3"; |
| 327 |
Corners(p,p,(h+d)/2+P,P); |
| 328 |
% upper stroke : points on central line: |
| 329 |
centers; % CL and CR : ends |
| 330 |
HOR (1/5,3/5); Bot(1/2); % bl and br : down crossing |
| 331 |
HOR (2/5,4/5); Top(1/2); % tl and tr : up crossing |
| 332 |
PEN; |
| 333 |
draw bl{down}..tl{up}..br{down}..tr{up}; % middle part |
| 334 |
Pen; Fill |
| 335 |
( CL{up}..{down}(bl+hd) % left end : upper boundary |
| 336 |
& (bl+hd)--(bl-hd) |
| 337 |
& (bl-hd){up}..{dir 225}CL % lower boundary |
| 338 |
& CL..cycle |
| 339 |
); |
| 340 |
Fill ( CR{up}..{down}(tr-hd) % right end : upper boundary |
| 341 |
& (tr-hd)--(tr+hd) |
| 342 |
& (tr+hd){up}..{dir -45}CR % lower boundary |
| 343 |
& CR..cycle |
| 344 |
); |
| 345 |
picture upper; upper:= currentpicture; % lower stroke |
| 346 |
addto currentpicture also upper shifted (0,-(h+d)/2); |
| 347 |
endchar; |
| 348 |
|
| 349 |
beginchar(O+29,U#,U#,0u#); "Terra 2"; % for smaller circle : 52u#,U#,0# |
| 350 |
corners; centers; |
| 351 |
VV:=(BC-BL) rotated 90; |
| 352 |
TC:=CC+VV; BC:=CC-VV; |
| 353 |
PEN; draw TC..CR..BC..CL..TC..cycle; % circle |
| 354 |
draw BC--TC; draw CL--CR; % cross in circle |
| 355 |
s:=1+1/2; |
| 356 |
CL:=CL+s*hP; CR:=CR-s*hP; |
| 357 |
BC:=BC+s*vP; TC:=TC-s*vP; |
| 358 |
PEN scaled 1/2; undraw TC..CR..BC..CL..TC..cycle; |
| 359 |
endchar; |
| 360 |
|
| 361 |
beginchar(O+32,88u#,56u#,0); "Libra 3"; % larger variant |
| 362 |
corners; |
| 363 |
Centers (1/2,7/15); % CL and CR : upper bars (outer ends) |
| 364 |
TOP (1/4,3/4); |
| 365 |
VV:=(TC-Tl) rotated -90; |
| 366 |
tl:=Tl+VV; tr:=Tr+VV; % tl and tr : upper arc (left and right) |
| 367 |
R:=length(VV); D:=length(TC-CC); % calculating intersection of |
| 368 |
t:=(R+-+(D-R))/length(BR-BL); % upper arc with upper bars |
| 369 |
HOR (1/2-t,1/2+t); Bot (7/15); % (bl and cl renamed:) |
| 370 |
Cl:=bl; Cr:=br; % Cl and Cr : upper arc (inner ends) |
| 371 |
bL:=CL-vP; bl:=Cl-vP; br:=Cr-vP; bR:=CR-vP; % shift upper bars slightly down |
| 372 |
%% CL:=CL+8u;CR:=CR+8u; % left and right points |
| 373 |
CL:=1/3[bL,TL];CR:=1/3[bR,TR]; % left and right points |
| 374 |
SPEN; draw BL--BR; % bottom bar |
| 375 |
SPEN; draw bL--bl; draw br--bR; % left and right upper bars |
| 376 |
Pen; Fill % left upper bar: left end |
| 377 |
( bl{dir 175}..{dir 100}(CL+vd-hd) % inner boundary |
| 378 |
& (CL+vd-hd)--(bL-hd)--bl % left and lower boundary |
| 379 |
& bl.. cycle |
| 380 |
); |
| 381 |
Pen; Fill % right upper bar: right end |
| 382 |
( br{dir 5}..{dir 80}(CR+vd+hd) % inner boundary |
| 383 |
& (CR+vd+hd)--(bR+hd)--br % right and lower boundary |
| 384 |
& br.. cycle |
| 385 |
); |
| 386 |
PEN; draw Cl..{up}tl..{right}TC..{down}tr..Cr; % upper arc |
| 387 |
endchar; |
| 388 |
|
| 389 |
beginchar(O+42,10/11U#,U#,0u#); "(moon) last quarter - inverse"; |
| 390 |
Corners(p,p,p,p); Centers(4/11,1/2); |
| 391 |
b:=1; % reduction of stroke breadth |
| 392 |
% outer circumference: big circle |
| 393 |
VV:=(TL-BL)/2; HH:=VV rotated -90; |
| 394 |
BC:=BL+HH; TC:=TL+HH; % CL=BL+VV; |
| 395 |
MM:=CL+HH; |
| 396 |
% outer circumference: calculating small circle |
| 397 |
R:=length(HH); D:=length(BR-BL); |
| 398 |
s:=(R+-+(D-R)); t:=s/2R; |
| 399 |
CC:=CC+hP; |
| 400 |
D:=length(CR-CC); |
| 401 |
r := D/2 + s*s/2D; |
| 402 |
RT (1/2-t,1/2+t); |
| 403 |
mm:=CC+(r,0); |
| 404 |
% inner circumference: |
| 405 |
D:=length(mm-MM); R:=R-2(b*P-p); r:=r+2b*(P-p); |
| 406 |
a:=(R*R-r*r+D*D)/2D; |
| 407 |
tr:=MM+(a,R+-+a); |
| 408 |
br:=MM+(a,-(R+-+a)); |
| 409 |
Fill ( tR..CL..bR |
| 410 |
& bR..CC..tR |
| 411 |
& tR..cycle |
| 412 |
); |
| 413 |
% unfill tr..(CL+2b*hd)..br % for standard variant \char10 |
| 414 |
% & br..(CC-2b*hd)..tr |
| 415 |
% & tr..cycle; |
| 416 |
endchar; |
| 417 |
|
| 418 |
temp := currentpicture; |
| 419 |
beginchar(O+43,10/11U#,U#,0u#); "(moon) first quarter - inverse"; |
| 420 |
currentpicture := temp xscaled -1 shifted (w,0); |
| 421 |
endchar; |
| 422 |
|
| 423 |
beginchar(O+10,10/11U#,U#,0u#); "Luna = (moon) last quarter"; |
| 424 |
currentpicture := temp; |
| 425 |
unfill tr..(CL+2b*hd)..br |
| 426 |
& br..(CC-2b*hd)..tr |
| 427 |
& tr..cycle; |
| 428 |
endchar; |
| 429 |
|
| 430 |
temp := currentpicture; |
| 431 |
beginchar(O+41,10/11U#,U#,0u#); "(moon) first quarter"; |
| 432 |
currentpicture := temp xscaled -1 shifted (w,0); |
| 433 |
endchar; |
| 434 |
|
| 435 |
beginchar(O+52,1.4U#,1.05U#,.35U#); "Pallas"; |
| 436 |
Corners (p,p,P,p); Centers (.5,.4); |
| 437 |
numeric aa[]; pair Cl,Cr,tC; |
| 438 |
RR:= 2(vP-vp); |
| 439 |
Cl = aa1[CL,TC] + ( RR rotated -120 ) = aa2[CL,CR] + RR; |
| 440 |
Cr = aa3[CR,TC] + ( RR rotated 120 ) = aa4[CL,CR] + RR; |
| 441 |
tC = aa5[CR,TC] + ( RR rotated 120 ) = aa6[CL,TC] + ( RR rotated -120 ); |
| 442 |
Pen; Fill ( |
| 443 |
TC--CL--CR--TC & TC--tC % top triangle : outside |
| 444 |
& tC--Cr--Cl--tC & tC--TC & cycle % top triangle : inside |
| 445 |
) ; |
| 446 |
SPEN; cross (CC,BC, 1,-P); % bottom cross |
| 447 |
endchar; |
| 448 |
|
| 449 |
a:=(sqrt3)/2; % ratio (equilateral triangle) |
| 450 |
% used chars ( 58 60 ) 61 ( 63 ) |
| 451 |
beginchar(O+61,(U#+2P#)/a+2P#,U#+2a*P#,2P#); "Trigon"; |
| 452 |
Corners (p,p,p,p); centers; |
| 453 |
numeric aa[]; pair Bl,Br,tC; |
| 454 |
RR:= 2(vP-vp); |
| 455 |
Bl = aa1[BL,TC] + ( RR rotated -120 ) = aa2[BL,BR] + RR; |
| 456 |
Br = aa3[BR,TC] + ( RR rotated 120 ) = aa4[BL,BR] + RR; |
| 457 |
tC = aa5[BR,TC] + ( RR rotated 120 ) = aa6[BL,TC] + ( RR rotated -120 ); |
| 458 |
Pen; Fill ( |
| 459 |
TC--BL--BR--TC & TC--tC % triangle : outside |
| 460 |
& tC--Br--Bl--tC & tC--TC & cycle % triangle : inside |
| 461 |
) ; |
| 462 |
endchar; |
| 463 |
|
| 464 |
beginchar(O+64,68u#,80u#,0); "ascending node of moon"; |
| 465 |
Corners(P,P,P,P); centers; % TC |
| 466 |
HOR (1/6,5/6); Top (3/4); % tl and tr : main arc (left and right) |
| 467 |
BOT (1/3,2/3); rr:=(Bl-BL)/2; |
| 468 |
bL:=BL+(rr rotated 90); bl:=bL+2rr; % bL and bl : lower left circle |
| 469 |
bR:=BR+(rr rotated 90); br:=bR-2rr; % bR and br : lower right circle |
| 470 |
PEN; draw bL{down}..{up}bl % lower left half circle |
| 471 |
..{up}tl..{right}TC..{down}tr % main arc |
| 472 |
..{down}br..{up}bR; % lower right half circle |
| 473 |
Pen; |
| 474 |
Fill ( (bL+hd){up}..bl-(1,0)--bl % lower left circle: upper arc, outside |
| 475 |
& bl{up}..{down}(bL-hd) % inside |
| 476 |
& (bL-hd)--(bL+hd)..cycle |
| 477 |
); |
| 478 |
Fill ( (bR-hd){up}..br+(1,0)--br % lower right circle: upper arc, outside |
| 479 |
& br{up}..{down}(bR+hd) % inside |
| 480 |
& (bR+hd)--(bR-hd)..cycle |
| 481 |
); |
| 482 |
endchar; |
| 483 |
|
| 484 |
temp := currentpicture; |
| 485 |
beginchar(O+65,68u#,80u#,0); "descending node of moon"; |
| 486 |
currentpicture := ( temp yscaled -1 ) shifted ( 0,h ); |
| 487 |
endchar; |
| 488 |
|
| 489 |
endinput; |
| 490 |
%%%%%%%%%%%%%%%%%%%%%%%%%%% |
| 491 |
%%% end of ASTROSYM.CAL %%% |