Debian Codegraph @

texmf-dist/fonts/source/public/astro/astrosym.cmn

raw
1 % ASTROSYM.CMN : AstroSym (Version 2.20, Aug. 10, 2002) - file 4 of 8
2 % Peter Schmitt eMail: [email protected]
3 % Institute of Mathematics, University of Vienna Vienna, Austria
4 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
5
6 beginchar(O+2,52u#,80u#,0u#); "Venus";
7 corners; centers;
8 VV:=(TC-TL) rotated -90;
9 CL:=TL+VV; CR:=TR+VV; bC:=TC+2VV;
10 PEN; draw TC..CR..bC..CL..TC..cycle; % top circle
11 SPEN; cross (bC,BC, 4/3,-2P); % bottom cross
12 endchar;
13
14 beginchar(O+3,52u#,80u#,0u#); "Terra";
15 corners; centers;
16 VV:=(BC-BL) rotated 90;
17 CL:=BL+VV; CR:=BR+VV; tC:=BC+2VV;
18 PEN; draw tC..CR..BC..CL..tC..cycle; % bottom circle
19 SPEN; cross (tC,TC, 1,2P); % top cross
20 endchar;
21
22 beginchar(O+4,52u#,88u#,0u#); "Mars";
23 corners; centers;
24 VV:=(BC-BL) rotated 90;
25 CL:=BL+VV; CR:=BR+VV; tC:=BC+2VV;
26 CC:=BC+VV;
27 Cr:=(tC+2vP) rotatedaround (CC,-15); % temporary
28 TR:=TR+vd+hd; % top arrow: top
29 tr:=.45[Cr,TR]; % top arrow: base
30 Cr:=Cr-(2hP rotated angle(TR-Cr)); % top arrow: stem base
31 a:=angle(TR-tr); b:=cosd(a)/sind(a); % arrow: calculate breadth
32 PEN; draw tC..CR..BC..CL..tC..cycle; % bottom circle
33 PEN; draw Cr--tr; % top arrow: stem
34 Pen; arrow (tr,TR, 2b, .1,.5); % top arrow
35 endchar;
36
37 beginchar(O+7,52u#,74u#,10u#); "Uranus";
38 corners; centers;
39 VV:=(BC-BL) rotated 90;
40 bL:=BL+VV; bR:=BR+VV; CC:=BC+2VV;
41 bC:=BC+VV;
42 TC:=TC+vd; tC:=.4[CC,TC];
43 PEN; draw CC..bR..BC..bL..CC..cycle; % bottom circle
44 fill fullcircle scaled 2P shifted bC; % bottom circle: dot
45 draw CC--tC; % top arrow: stem
46 Pen; arrow (tC,TC, 1.2, .1,.5); % top arrow
47 endchar;
48
49 beginchar(O+8,88u#,80u#,0u#); "Neptunus";
50 Corners(p,p,P,p); Centers(.5,.2);
51 HOR (9/88,79/88);
52 Top(.725); Bot(.2);
53 b:=length(Tl-TL)/length(Tl-tl); % arrows: breadth of points
54 SPEN; draw bl--br; % horizontal bar
55 draw bC--BC; % vertical stem
56 draw bl--tl; draw bC--tC; draw br--tr; % three arrows: arms
57 Pen; arrow (tl,Tl, 2b, .2,.5); % three arrows: points
58 arrow (tC,TC, 2b, .2,.5);
59 arrow (tr,Tr, 2b, .2,.5);
60 endchar;
61
62 beginchar(O+9,52u#,80u#,0u#); "Pluto";
63 corners; centers;
64 VV:=(TC-TL) rotated -90;
65 bC:=TC+2VV; bL:=TL+2VV;
66 BOT (0,2/3); % Br : bottom bar (right end)
67 PEN; draw TL--TC{right}..{left}bC--bL; % top right arc
68 SPEN; draw BL--TL; draw BL--Br; % left bar and bottom bar
69 endchar;
70
71 beginchar(O+21,76u#,58u#,-6u#); "Aquarius";
72 Corners(P,P,(h+d)/2+P,P);
73 % upper strokes:
74 centers; % CL and CR : left and right end
75 BOT (3/12,11/12); BC:=.5[Bl,Br]; % Bl,BC,Br : upper endpoints
76 TOP (1/12,9/12); TC:=.5[Tl,Tr]; % Tl,TC,Tr : lower endpoints
77 % PEN yscaled (p/P) rotated (90-angle(Tl-CL));
78 PEN yscaled (p/P) rotated angle(Tl-CL);
79 draw CL--Tl--Bl--TC--BC--Tr--Br--CR;
80 picture upper; upper:= currentpicture; % lower strokes
81 addto currentpicture also upper shifted (0,-(h+d)/2);
82 endchar;
83
84 beginchar(O+24,88u#,80u#,0u#); "Neptunus 2";
85 Corners(p,p,P,p); Centers(.5,.2);
86 HOR (9/88,79/88);
87 Top(.725); Bot(.2);
88 b:=length(Tl-TL)/length(Tl-tl); % arrows: breadth of points
89 SPEN; draw bC--tC; % middle arm
90 cross (BC,bC, 1, -P); % lower cross
91 PEN; draw tl{down}..{up}tr; % arc from left to right arm
92 Pen; arrow (tl,Tl, 2b, .2,.5); % three arrows: points
93 arrow (tC,TC, 2b, .2,.5);
94 arrow (tr,Tr, 2b, .2,.5);
95 endchar;
96
97 beginchar(O+25,68u#,80u#,0u#); "Pluto 2";
98 Corners(p,p,P,p); Centers(.5,.2);
99 HOR (2/17,15/17);
100 Top(.725); Bot(.2)
101 b:=length(Tl-TL)/length(Tl-tl); % arrows: breadth of points
102 SPEN; draw bl--br; % horizontal bar
103 draw bC--BC; % vertical stem
104 draw bl--tl; draw br--tr; % two arrows: arms
105 Pen; arrow (tl,Tl, 2b, .2,.5); % two arrows; points
106 arrow (tr,Tr, 2b, .2,.5);
107 endchar;
108
109 beginchar(O+26,1U#,1U#,0); "Libra 2";
110 corners; Centers (1/2,2/3-1/12);
111 LFT (1/3,1); RT (1/3,1);
112 PEN; draw CC{right}..TC..{right}CC; % top circle
113 SPEN; draw bL--bR; draw CL--CR; % lower and upper bar
114 endchar;
115
116 beginchar(O+30,74u#,88u#,0u#); "Mars 2";
117 corners; Centers (1/2,11/40);
118 VV:=(CL-BL); HH := VV rotated -90;
119 BC:=BL+HH; CR:=CL+2HH; tC:=BC+2VV;
120 CC:=BC+VV;
121 TR:=TR+vd+hd; % top arrow: top
122 Cr:=(tC+2vP) rotatedaround (CC,angle(TR-CC)-90); % temporary
123 tr:=.45[Cr,TR]; % top arrow: base
124 Cr:=Cr-(2hP rotated angle(TR-Cr)); % top arrow: stem base
125 a:=angle((TR-tr) rotated .5(90-angle(TR-(CR+hd))));
126 b:=cosd(a)/sind(a); % arrow: calculate breadth
127 PEN; draw tC..CR..BC..CL..cycle; % bottom circle
128 PEN; draw Cr--tr; % top arrow: stem
129 Pen; arrow (tr,TR, 2b, .1,.5); % top arrow
130 endchar;
131
132 beginchar(O+31,52u#,80u#,0u#); "Pluto 3"; % variation of Pluto (1)
133 corners; centers;
134 VV:=(TC-TL) rotated -90;
135 bC:=TC+2VV; bL:=TL+2VV;
136 HOR (2/5,1); % Bl : bottom bar (left end)
137 Cl := Tl+VV; % Cl : vertical bar (top end)
138 PEN; draw TL--TC{right}..{left}bC--bL; % letter P : top right arc
139 SPEN; draw BL--TL; % letter P : left bar
140 SPEN; draw Bl--Cl; draw Bl--BR; % letter L : left bar and bottom bar
141 endchar;
142
143 beginchar(O+33,U#,U#,0u#); "Star";
144 corners; centers;
145 RR:=length(BC-CC)*(1,sind15/cosd15);
146 for i:= 0 upto 5 : SPEN rotated (60i+45);
147 draw CC--(CC+(RR rotated 60i)); endfor;
148 endchar;
149
150 beginchar(O+34,88u#,88u#,0u#); "Comet";
151 corners;
152 BOT (11/40,2/3);
153 HH:=(Bl-BL); VV:=HH rotated 90;
154 CC:=Bl+VV;
155 TOP (1/3,2/3); RT (1/3,2/3);
156 PEN; Circle ( CC, HH,VV ); % bottom circle
157 a := angle (Tr-CC);
158 RPEN rotated (a+90); draw ( CC + ( HH rotated a ) ) -- Tr;
159 a := angle (TR-CC);
160 SPEN rotated (a+90);
161 draw ( CC + ( HH rotated a ) ) -- ( TR - ( HH rotated a )/4 );
162 a := angle (tR-CC);
163 RPEN rotated (a+90); draw ( CC + ( HH rotated a ) ) -- tR;
164 endchar;
165
166 beginchar(O+35,74u#,88u#,0u#); "Meteor";
167 corners; Centers (4/5,2/3);
168 BL:=BL-vd-hd; % bot arrow: top
169 CC:=CR; % better?
170 bl:=1/5[BL,CC]; % bot arrow: base
171 a:=angle((BL-bl) rotated .5(90-angle(BL-(CL-hd))));
172 b:=cosd(a)/sind(a); % arrow: calculate breadth
173 SPEN; drawdot TR; PEN; draw TR--CC--bl; % bot arrow: stem
174 Pen; arrow (bl,BL, 2b, .1,.5); % bot arrow
175 endchar;
176
177 beginchar(O+36,74u#,88u#,0u#); "Conjunction";
178 corners; Centers (1/2,11/40);
179 VV:=(CL-BL); HH := VV rotated -90;
180 BC:=BL+HH; CR:=CL+2HH; tC:=BC+2VV;
181 CC:=BC+VV;
182 Cr:=(tC+vP/2) rotatedaround (CC,angle(TR-CC)-90); % temporary
183 PEN; draw tC..CR..BC..CL..cycle; % bottom circle
184 RPEN rotated (90+angle(TR-Cr)); draw Cr--TR; % top arrow: stem
185 endchar;
186
187 beginchar(O+37,72u#,72u#,0u#); "Opposition";
188 corners;
189 HH:=(BR-BL)/6; VV:=HH rotated 90;
190 HH:=(BR-BL)/5; VV:=HH rotated 90;
191 TT:=HH rotated 45;
192 bC:=BL+HH+VV; tC:=TR-HH-VV;
193 PEN; Circle (bC,HH,VV);
194 Circle (tC,HH,VV);
195 draw (bC+TT)--(tC-TT);
196 endchar;
197
198 beginchar(O+38,U#,U#,0u#); "Quadrature";
199 corners;
200 SPEN; draw TL--TR--BR--BL--TL ; % square
201 endchar;
202
203 beginchar(O+39,U#,U#,0u#); "full moon";
204 corners; centers;
205 VV:=(BC-BL) rotated 90;
206 TC:=CC+VV; BC:=CC-VV; D:=U/9;
207 hh:=(U/6,0); vv:=(0,U/6);
208 PEN; draw TC..CR..BC..CL..TC..cycle; % circle
209 endchar;
210
211 beginchar(O+40,U#,U#,0u#); "new moon";
212 fill TC..CR..BC..CL..TC..cycle; % circle
213 endchar;
214
215 beginchar(O+44,2/3U#,U#,0u#); "Luna 2 = (moon 2) last quarter";
216 corners; Centers(3/4,1/2);
217 VV:=(TL-BL)/2; HH:=VV rotated -90;
218 BC:=BL+HH; TC:=TL+HH; % CL=BL+VV;
219 R:=length(HH); D:=length(BR-BL);
220 t:=(R+-+(D-R))/2R;
221 RT (1/2-t,1/2+t);
222 PEN; draw tR..TC..CL..BC..bR; % outer circle
223 Pen; draw tR..CC..bR; % inner arc
224 endchar;
225
226 temp := currentpicture;
227 beginchar(O+45,2/3U#,U#,0u#); "(moon 2) first quarter";
228 currentpicture := temp xscaled -1 shifted (w,0);
229 endchar;
230
231 beginchar(O+46,2/3U#,U#,0u#); "(moon 2) last quarter - inverse";
232 Pen; filldraw tR..TC..CL..BC..bR % big circle
233 & bR..CC..tR -- cycle; % small circle
234 endchar;
235
236 temp := currentpicture;
237 beginchar(O+47,2/3U#,U#,0u#); "(moon 2) first quarter - inverse";
238 currentpicture := temp xscaled -1 shifted (w,0);
239 endchar;
240
241 beginchar(O+48,U#,78u#,16u#); "Ceres";
242 corners; Centers (2/5,1/4);
243 Tl := (TL+TC)/2 - vP; % arc : upper end
244 tR := (CR+TR)/2; % arc : midpoint (right)
245 Cl := (CL+CC)/2 + vP; % arc : lower end
246 Bl := (BL+BC)/2; % cross : base
247 bL := .4[BL,CL]; bC := .4[BC,CC]; % for bar of cross
248 PEN; draw Tl..TC..tR..CC..Cl; % (inverted) C shape
249 REND ( Tl, 2 angle ( TC-Tl ) + 180 );
250 SPEN; draw Cl--Bl; % cross : vertical stem
251 draw bL--bC; % cross : horizontal bar
252 endchar;
253
254 beginchar(O+49,U#,68u#,20u#); "Ceres 2";
255 corners; centers;
256 HOR (3/8,3/4); % Tl Br
257 LFT (1/4,3/4); RT (1/4,3/4); % tL ; bR
258 Bot (1/4); Top (3/4); % bC ; tr
259 Cl := .5[Bl,Tl]; % C shape : bottom point
260 PEN; draw Tl{left}..tL..Cl..tr; % C shaped arc
261 REND ( Tl,0 );
262 SPEN; draw tr--Br; % cross : vertical stem
263 draw bC--bR; % cross : horizontal bar
264 endchar;
265
266 beginchar(O+50,40u#,80u#,16u#); "Juno";
267 corners; centers;
268 RR:=(TC-TL); VV:=RR rotated -90;
269 CC:=TC+VV; % center top star
270 bL := BL-VV; bR := BR-VV; % for lower bar
271 % or : LFT (1/6,1); RT (1/6,1) % or 1/5
272 for i:= 0 upto 6 : SPEN rotated (45i+45); % top star
273 draw CC--(CC+(RR rotated (45i-45))); endfor;
274 SPEN; draw CC--BC; % stem
275 draw bL--bR; % lower horizontal bar
276 endchar;
277
278 beginchar(O+51,56u#,80u#,24u#); "Juno 2";
279 corners; centers;
280 HOR (1/5,4/5); Bot (1/5) % or : 1/3 3/4 ; 1/4
281 LFT (1/4,7/8); RT (1/4,7/8);
282 SPEN rotated angle(tR-CL) ; draw tR--CL; % upper cross ( X )
283 SPEN rotated angle(tL-CR) ; draw tL--CR; % upper cross ( X )
284 SPEN; draw TC--BC; % stem
285 draw bl--br; % bottom horizontal bar
286 endchar;
287
288 beginchar(O+53,52u#,80u#,0u#); "Vesta";
289 corners; centers;
290 VV:=(BR-BL) rotated 90;
291 CL:=BL+VV; CR:=BR+VV; CC:=BC+VV; % vertices of square
292 TOP (.2,.8); % endpoints of upper V
293 SPEN; draw CL--CR--BR--BL--CL; % bottom square
294 PEN; draw Tl--CC--Tr; % upper V
295 endchar;
296
297 beginchar(O+54,U#,U#,0#); "Vesta 2";
298 Corners (P,P,P,p); centers;
299 HOR (1/5,4/5); Top (5/8); Cl := tl; Cr := tr;
300 HOR (3/8,5/8); Bot (1/2); Top (7/8);
301 TOP (1/5,4/5);
302 RPEN rotated 20; % left horn
303 draw (bl+(vP-vp)/2+hP){left}..Cl..tl..{dir 200}Tl;
304 RPEN rotated -20; % right horn
305 draw (br+(vP-vp)/2-hP){right}..Cr..tr..{dir -20}Tr;
306 SPEN; draw CL--CR; % middle bar
307 draw bl--Bl; % left foot
308 draw br--Br; % right foot
309 endchar;
310
311 beginchar(O+55,52u#,96u#,0u#); "Chiron";
312 corners; centers;
313 RR:=(BC-BL) rotated 90;
314 bL:=BL+RR; bR:=BR+RR; bC:=BC+2RR;
315 CC := bC+vP;
316 TOP (1/6,5/6); rr := (Tr-TC) rotated 90;
317 tC := TC-rr; tr := Tr-2rr;
318 PEN; draw bC..bR..BC..bL..bC..cycle; % bottom circle
319 SPEN; draw CC--TC; % top stem
320 PEN; draw Tr--tC--tr; % top arms
321 endchar;
322
323 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
324 %% reset O if 200 + char number > 255 ( uniform (thin) )
325 if O = 200 : O := 122 fi ;
326
327 beginchar(O+56,U#,80u#,16u#); "Pluto 4 (tree)";
328 corners; Centers (1/2,1/3);
329 HOR (1/4,3/4); Bot (1/6);
330 bC := CC-vP;
331 PEN; draw TL{right}..{down}CC; draw TR{left}..{down}CC; % top arcs
332 REND (TL,180); REND (TR,0); %
333 SPEN; draw bC--BC; draw bl--br; % bottom cross
334 endchar;
335
336 beginchar(O+57,2U#,U#+P#,0); "Pluto 5 (cup)";
337 % beginchar(O+57,2U#,U#,0); "Pluto 5 (cup)";
338 corners; centers;
339 aa := (2-sqrt3)/4;
340 Cl := aa[CL,CR]; Cr := aa[CR,CL];
341 % TC := TC-vP; % potential correction : lowered contents
342 PEN; draw TL{down}..Cl..BC..Cr..{up}TR; % half circle : "cup"
343 draw Cl..TC..Cr; % "contents"
344 REND (TL,90); REND (TR,90);
345 endchar;
346
347 a:=(sqrt3)/2; % ratio (equilateral triangle)
348 % used chars 58 60 ( 61 ) 63
349 beginchar(O+58,U#/a+2*(P#-(1-a)*Pp),U#+2*P#-Pp,P#-Pp); "Semi-sextile";
350 Corners (P-(1-a)*Pp,P-(1-a)*Pp,P,P-Pp/2); centers;
351 RLine ( BL,BR ); % base
352 RLine ( TL,BC ); % left stroke (down)
353 RLine ( TR,BC ); % right stroke (up)
354 endchar;
355
356 beginchar(O+59,U#,U#,0u#); "Semi-quadrature";
357 corners;
358 SPEN; draw TL--BL--BR; % L shape ( of square )
359 endchar;
360
361 beginchar(O+60,a*U#+2*P#-Pp,U#+P#-Pp,P#-Pp); "Sextile";
362 Corners (P-Pp/2,P-Pp/2,P-Pp,P-Pp); centers;
363 LFT (1/4,3/4); RT (1/4,3/4);
364 RPEN; draw TC--BC; % stem
365 RLine (bL,tR); % stem turned 60
366 RLine (tL,bR); % stem turned -60
367 endchar;
368
369 beginchar(O+62,U#,U#,U#/2); "one and a half quadrature";
370 corners; Centers (1/2,1/3);
371 tC := (TC+CC)/2;
372 SPEN; draw TL--CL--CR--TR--TL; % square
373 draw tC--BC--BR; % L shaped cedilla
374 endchar;
375
376 beginchar(O+63,U#/a+2*(P#-(1-a)*Pp),U#+2*P#-Pp,P#-Pp); "Quincunx";
377 Corners (P-(1-a)*Pp,P-(1-a)*Pp,P-Pp/2,P); centers;
378 RLine ( TL,TR ); % top
379 RLine ( BL,TC ); % left stroke (up)
380 RLine ( BR,TC ); % right stroke (down)
381 endchar; % horizontal mirror image of semi-sextile
382
383 beginchar(O+66,52u#,96u#,0u#); "Chiron 2";
384 corners; centers;
385 BC := BC-hP/3 ; % bottom circle slightly off centre
386 rr := (BC-BL) ; RR := rr rotated 90 ; % radii of circle
387 bL := BL+RR; bR := bL+2rr; bC := BC+2RR; % points on circle
388 TC := TL+rr; % top of stem
389 CC := bC+vP; % base of stem
390 tR := (CR+TR)/2; rr := (TR-tR) rotated -90 ;
391 tC := tR-rr ; % base of arms (right angle)
392 % calligraphic style : fit arms into corner
393 a := (sqrt2-1); mm := Pp*(a,a) ; nn := Pp*(a,-a) ;
394 PEN; draw bC..bR..BC..bL..bC..cycle; % bottom circle
395 SPEN; draw CC--TC; % top stem
396 RLine ( TR+mm,tC ); RLine ( tC,CR+nn ); % top arms
397 endchar;
398
399 beginchar(O+67,U#,56u#,8u#); "Lilith";
400 Corners (P,P,p,p); centers;
401 LFT (1/8,2/3) ; RT (1/8,2/3) ; % bL bR : for bottom stroke
402 HOR (1/4,3/4); Bot (1/8); % bC : for bottom stroke
403 br := Br; % br : lowest point on bottom stroke (saved!)
404 HOR (2/5,7/8); Top (2/3); % tl tr : for top stroke
405 TOP (0,8/12); % Tr : highest point on top stroke
406 pickup pencircle xscaled 2P yscaled 2p ; % special pen
407 draw bL{dir 70}..bC..br{dir 0}..bR ; % bottom stroke
408 draw bL{dir 0}..tl..Tr{dir 0}..tr..{dir 180}(CC+hP) ; % top stroke
409 endchar;
410
411 beginchar(O+68,U#,U#,22u#); "Pluto 6";
412 corners; centers;
413 LFT (1/4,4/5); RT (1/4,4/5); % tL tR : for cup
414 HOR (1/6 , 5/6 ); Bot (1/4) ; % bl br : )
415 HOR (5/16,11/16); Top (4/5) ; % tl tr : circle (left,right)
416 rr := tr-tC ; TC := tC+(rr rotated 90) ; % TC : circle (top) [ centre tC ]
417 tC := tC+(rr rotated -90) ; % tC : circle (bot)
418 SPEN; draw TL; draw TR; % endpoints of cup
419 PEN; draw TL--tL{dir -90}..CC..{dir 90}tR--TR; % cup
420 draw tC..tr..TC..tl..tC..cycle ; % circle
421 SPEN; draw bl--br; % cross: horizontal bar
422 draw (CC-vP)--BC; % cross: vertical bar
423 endchar;
424
425
426 beginchar(O+69,U#,U#,0u#); "Sextile 2";
427 corners; centers;
428 RR:=(CR-CC) rotated 45;
429 tr:=CC+RR; tl:=CC+(RR rotated 90);
430 bl:=CC-RR; br:=CC+(RR rotated -90);
431 SPEN; draw CL--CR; draw TC--BC; % horizontal cross
432 DPEN; draw bl--tr; draw tl--br; % diagonal cross
433 endchar;
434
435 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
436 %% reset O back to 200 if 122 ( uniform (thin) )
437 if O = 122 : O := 200 fi ;
438
439 endinput;
440 %%%%%%%%%%%%%%%%%%%%%%%%%%%
441 %%% end of ASTROSYM.CMN %%%