Debian Codegraph @

testsuite/systemtap.examples/io/iostats.stp

raw
1 #! /usr/bin/env stap
2 global opens, reads, writes, totals
3
4 probe begin { printf("starting probe\n") }
5
6 probe syscall.open {
7 opens[execname()] <<< 1 # statistics array
8 }
9
10 probe syscall.read.return {
11 count = retval
12 if ( count >= 0 ) {
13 reads[execname()] <<< count # statistics array
14 totals[execname()] <<< count
15 }
16 }
17
18 probe syscall.write.return {
19 count = retval
20 if (count >= 0 ) {
21 writes[execname()] <<< count # statistics array
22 totals[execname()] <<< count
23 }
24 }
25
26 probe end {
27 printf("\n%16s %8s %8s %8s %8s %8s %8s %8s\n",
28 "", "", "", "read", "read", "", "write", "write")
29 printf("%16s %8s %8s %8s %8s %8s %8s %8s\n",
30 "name", "open", "read", "KB tot", "B avg", "write", "KB tot", "B avg")
31 foreach (name in totals @sum- limit 20) { # sort by total io
32 printf("%16s %8d %8d %8d %8d %8d %8d %8d\n",
33 name, @count(opens[name]),
34 @count(reads[name]),
35 (@count(reads[name]) ? @sum(reads[name])>>10 : 0 ),
36 (@count(reads[name]) ? @avg(reads[name]) : 0 ),
37 @count(writes[name]),
38 (@count(writes[name]) ? @sum(writes[name])>>10 : 0 ),
39 (@count(writes[name]) ? @avg(writes[name]) : 0 ))
40 }
41 }