Debian Codegraph @

testsuite/systemtap.examples/io/iodevstats.stp

raw
1 #! /usr/bin/env stap
2 global reads, writes, totals
3
4 probe begin { printf("starting probe\n") }
5
6 probe vfs.read.return {
7 count = returnval()
8 if ( count >= 0 ) {
9 reads[execname(),dev] <<< count # statistics array
10 totals[execname(),dev] <<< count
11 }
12 }
13
14 probe vfs.write.return {
15 count = returnval()
16 if (count >= 0 ) {
17 writes[execname(),dev] <<< count # statistics array
18 totals[execname(),dev] <<< count
19 }
20 }
21
22 probe end {
23 printf("\n%16s %8s %8s %8s %8s %8s %8s %8s\n",
24 "", "", "", "read", "read", "", "write", "write")
25 printf("%16s %8s %8s %8s %8s %8s %8s %8s\n",
26 "name", "device", "read", "KB tot", "B avg", "write", "KB tot", "B avg")
27 foreach ([name,dev] in totals @sum- limit 20) { # sort by total io
28 printf("%16s %3d, %4d %8d %8d %8d %8d %8d %8d\n",
29 name, MAJOR(dev), MINOR(dev),
30 @count(reads[name,dev]),
31 (@count(reads[name,dev]) ? @sum(reads[name,dev])>>10 : 0 ),
32 (@count(reads[name,dev]) ? @avg(reads[name,dev]) : 0 ),
33 @count(writes[name,dev]),
34 (@count(writes[name,dev]) ? @sum(writes[name,dev])>>10 : 0 ),
35 (@count(writes[name,dev]) ? @avg(writes[name,dev]) : 0 ))
36 }
37 }