Debian Codegraph @

testsuite/systemtap.examples/io/iostat-scsi.stp

raw
1 #! /usr/bin/env stap
2
3 global devices, reads, writes
4
5 /* kernel commit f3fa33acca9f0058157214800f68b10d8e71ab7a */
6 @define __disk_name(__request)
7 %(
8 ( @choose_defined(@__request->rq_disk->disk_name, @__request->q->disk->disk_name ) )
9 %)
10
11 /* data collection: SCSI disk */
12 %{
13 #include <linux/blkdev.h>
14 #include <linux/blk-mq.h>
15 %}
16
17 function get_nr_sectors:long(rq:long)
18 %{ /* pure */
19 STAP_RETVALUE = blk_rq_sectors((const struct request *)(long)STAP_ARG_rq);
20 %}
21
22
23 probe sd_prep_fn = module("sd_mod").function("sd_prep_fn") !,
24 kernel.function("sd_prep_fn")
25 {
26 device = kernel_string(@__disk_name($rq))
27 sector_size = @cast($q->queuedata, "scsi_device", "kernel<scsi/scsi_device.h>")->sector_size
28 nr_sectors = get_nr_sectors($rq)
29
30 _cmd_flags = $rq->cmd_flags
31 }
32
33 function scsi_cmd_to_rq(scmd) {
34 return scmd - @cast_module_sizeof("kernel", "request")
35 }
36
37 probe sd_init_command = module("sd_mod").function("sd_init_command") !,
38 kernel.function("sd_init_command")
39 {
40 sector_size = @choose_defined($cmd, $SCpnt)->device->sector_size
41 # Kernel commits aa8e25e5006aac52c943c84e9056ab488630ee19 2266a2def97ce11ec979b6c58a1b637a16eca7dd
42 if (@defined(@choose_defined($cmd, $SCpnt)->request)) {
43 device = kernel_string(@__disk_name(@choose_defined($cmd, $SCpnt)->request))
44 nr_sectors = get_nr_sectors(@choose_defined($cmd, $SCpnt)->request)
45 _cmd_flags = @choose_defined($cmd, $SCpnt)->request->cmd_flags
46 } else {
47 device = kernel_string(@__disk_name(@cast(scsi_cmd_to_rq(@choose_defined($cmd, $SCpnt)), "request", "kernel")))
48 nr_sectors = get_nr_sectors(scsi_cmd_to_rq(@choose_defined($cmd, $SCpnt)))
49 _cmd_flags = @cast(scsi_cmd_to_rq(@choose_defined($cmd, $SCpnt)), "request", "kernel")->cmd_flags
50 }
51 }
52
53 probe sd_prep_fn !, sd_init_command
54 {
55 devices[device] = 1
56 if (_cmd_flags & 1)
57 writes[device] <<< nr_sectors * sector_size
58 else
59 reads[device] <<< nr_sectors * sector_size
60 }
61
62 /* data collection: SCSI tape */
63 probe module("st").function("st_do_scsi").call !,
64 kernel.function("st_do_scsi").call
65 {
66 # Kernel commit 45938335d0a9773d65a82a7ca722bb76e4b997a8
67 device = kernel_string(@choose_defined($STp->disk->disk_name, $STp->name))
68 devices[device] = 1
69 if ($direction)
70 writes[device] <<< $bytes
71 else
72 reads[device] <<< $bytes
73 }
74 /*
75 * Handle inlined version of function separately, since on some kernels
76 * (3.10.0-196.el7.ppc64) the variables aren't available (bad
77 * debuginfo). We want to handle this separately from the '.call'
78 * version, so that we'll know if the variable names change.
79 */
80 probe module("st").function("st_do_scsi").inline !,
81 kernel.function("st_do_scsi").inline ?
82 {
83 if (@defined($STp) && @defined($direction) && @defined($bytes)) {
84 device = kernel_string($STp->disk->disk_name)
85 devices[device] = 1
86 if ($direction)
87 writes[device] <<< $bytes
88 else
89 reads[device] <<< $bytes
90 }
91 }
92
93
94 /* reporting */
95 global blksize = 512
96 global hdrcount
97 probe timer.s($1)
98 {
99 if ((hdrcount % 10) == 0)
100 printf("%9s %9s %9s %9s %9s %9s\n",
101 "Device:", "tps", "blk_read/s", "blk_wrtn/s", "blk_read", "blk_wrtn")
102 hdrcount++
103
104 foreach (dev in devices) {
105 rdcount = @count(reads[dev])
106 wrcount = @count(writes[dev])
107 tps = (rdcount + wrcount) * 100 / $1
108 rdblkcount = rdcount ? @sum(reads[dev]) / blksize : 0
109 wrblkcount =wrcount ? @sum(writes[dev]) / blksize : 0
110 rdblkrate = rdblkcount * 100 / $1
111 wrblkrate = wrblkcount * 100 / $1
112 printf("%9s %6d.%02d %6d.%02d %6d.%02d %9d %9d\n",
113 dev, tps / 100, tps % 100,
114 rdblkrate / 100, rdblkrate % 100,
115 wrblkrate / 100, wrblkrate % 100,
116 rdblkcount, wrblkcount)
117 }
118 printf("\n")
119 delete devices
120 delete reads
121 delete writes
122 }