Debian Codegraph @

cmake/FindWolfSSL.cmake

raw
1 # Copyright (C) The libssh2 project and its contributors.
2 # SPDX-License-Identifier: BSD-3-Clause
3 #
4 ###########################################################################
5 # Find the wolfssl library
6 #
7 # Input variables:
8 #
9 # WOLFSSL_INCLUDE_DIR The wolfssl include directory
10 # WOLFSSL_LIBRARY Path to wolfssl library
11 #
12 # Result variables:
13 #
14 # WOLFSSL_FOUND System has wolfssl
15 # WOLFSSL_INCLUDE_DIRS The wolfssl include directories
16 # WOLFSSL_LIBRARIES The wolfssl library names
17 # WOLFSSL_LIBRARY_DIRS The wolfssl library directories
18 # WOLFSSL_CFLAGS Required compiler flags
19 # WOLFSSL_VERSION Version of wolfssl
20
21 if((UNIX OR VCPKG_TOOLCHAIN OR (MINGW AND NOT CMAKE_CROSSCOMPILING)) AND
22 NOT DEFINED WOLFSSL_INCLUDE_DIR AND
23 NOT DEFINED WOLFSSL_LIBRARY)
24 find_package(PkgConfig QUIET)
25 pkg_check_modules(WOLFSSL "wolfssl")
26 endif()
27
28 if(WOLFSSL_FOUND)
29 string(REPLACE ";" " " WOLFSSL_CFLAGS "${WOLFSSL_CFLAGS}")
30 message(STATUS "Found WolfSSL (via pkg-config): ${WOLFSSL_INCLUDE_DIRS} (found version \"${WOLFSSL_VERSION}\")")
31 else()
32 find_path(WOLFSSL_INCLUDE_DIR NAMES "wolfssl/options.h")
33 find_library(WOLFSSL_LIBRARY NAMES "wolfssl")
34
35 if(WOLFSSL_INCLUDE_DIR AND EXISTS "${WOLFSSL_INCLUDE_DIR}/wolfssl/version.h")
36 set(_version_regex "#[\t ]*define[\t ]+LIBWOLFSSL_VERSION_STRING[\t ]+\"([^\"]*)\"")
37 file(STRINGS "${WOLFSSL_INCLUDE_DIR}/wolfssl/version.h" _version_str REGEX "${_version_regex}")
38 string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
39 set(WOLFSSL_VERSION "${_version_str}")
40 unset(_version_regex)
41 unset(_version_str)
42 endif()
43
44 include(FindPackageHandleStandardArgs)
45 find_package_handle_standard_args(WolfSSL
46 REQUIRED_VARS
47 WOLFSSL_INCLUDE_DIR
48 WOLFSSL_LIBRARY
49 VERSION_VAR
50 WOLFSSL_VERSION
51 )
52
53 if(WOLFSSL_FOUND)
54 set(WOLFSSL_INCLUDE_DIRS ${WOLFSSL_INCLUDE_DIR})
55 set(WOLFSSL_LIBRARIES ${WOLFSSL_LIBRARY})
56 endif()
57
58 mark_as_advanced(WOLFSSL_INCLUDE_DIR WOLFSSL_LIBRARY)
59 endif()