| 1 |
# Copyright (C) The libssh2 project and its contributors. |
| 2 |
# SPDX-License-Identifier: BSD-3-Clause |
| 3 |
# |
| 4 |
########################################################################### |
| 5 |
# Find the libgcrypt library |
| 6 |
# |
| 7 |
# Input variables: |
| 8 |
# |
| 9 |
# LIBGCRYPT_INCLUDE_DIR The libgcrypt include directory |
| 10 |
# LIBGCRYPT_LIBRARY Path to libgcrypt library |
| 11 |
# |
| 12 |
# Result variables: |
| 13 |
# |
| 14 |
# LIBGCRYPT_FOUND System has libgcrypt |
| 15 |
# LIBGCRYPT_INCLUDE_DIRS The libgcrypt include directories |
| 16 |
# LIBGCRYPT_LIBRARIES The libgcrypt library names |
| 17 |
# LIBGCRYPT_LIBRARY_DIRS The libgcrypt library directories |
| 18 |
# LIBGCRYPT_CFLAGS Required compiler flags |
| 19 |
# LIBGCRYPT_VERSION Version of libgcrypt |
| 20 |
|
| 21 |
if((UNIX OR VCPKG_TOOLCHAIN OR (MINGW AND NOT CMAKE_CROSSCOMPILING)) AND |
| 22 |
NOT DEFINED LIBGCRYPT_INCLUDE_DIR AND |
| 23 |
NOT DEFINED LIBGCRYPT_LIBRARY) |
| 24 |
find_package(PkgConfig QUIET) |
| 25 |
pkg_check_modules(LIBGCRYPT "libgcrypt") |
| 26 |
endif() |
| 27 |
|
| 28 |
if(LIBGCRYPT_FOUND) |
| 29 |
string(REPLACE ";" " " LIBGCRYPT_CFLAGS "${LIBGCRYPT_CFLAGS}") |
| 30 |
message(STATUS "Found Libgcrypt (via pkg-config): ${LIBGCRYPT_INCLUDE_DIRS} (found version \"${LIBGCRYPT_VERSION}\")") |
| 31 |
else() |
| 32 |
find_path(LIBGCRYPT_INCLUDE_DIR NAMES "gcrypt.h") |
| 33 |
find_library(LIBGCRYPT_LIBRARY NAMES "gcrypt" "libgcrypt") |
| 34 |
|
| 35 |
if(LIBGCRYPT_INCLUDE_DIR AND EXISTS "${LIBGCRYPT_INCLUDE_DIR}/gcrypt.h") |
| 36 |
set(_version_regex "#[\t ]*define[\t ]+GCRYPT_VERSION[\t ]+\"([^\"]*)\"") |
| 37 |
file(STRINGS "${LIBGCRYPT_INCLUDE_DIR}/gcrypt.h" _version_str REGEX "${_version_regex}") |
| 38 |
string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}") |
| 39 |
set(LIBGCRYPT_VERSION "${_version_str}") |
| 40 |
unset(_version_regex) |
| 41 |
unset(_version_str) |
| 42 |
endif() |
| 43 |
|
| 44 |
include(FindPackageHandleStandardArgs) |
| 45 |
find_package_handle_standard_args(Libgcrypt |
| 46 |
REQUIRED_VARS |
| 47 |
LIBGCRYPT_INCLUDE_DIR |
| 48 |
LIBGCRYPT_LIBRARY |
| 49 |
VERSION_VAR |
| 50 |
LIBGCRYPT_VERSION |
| 51 |
) |
| 52 |
|
| 53 |
if(LIBGCRYPT_FOUND) |
| 54 |
set(LIBGCRYPT_INCLUDE_DIRS ${LIBGCRYPT_INCLUDE_DIR}) |
| 55 |
set(LIBGCRYPT_LIBRARIES ${LIBGCRYPT_LIBRARY}) |
| 56 |
endif() |
| 57 |
|
| 58 |
mark_as_advanced(LIBGCRYPT_INCLUDE_DIR LIBGCRYPT_LIBRARY) |
| 59 |
endif() |