Debian Codegraph @

src/shaders/vme/mpeg2_inter_ivb.asm

raw
1 /*
2 * Copyright © <2010>, Intel Corporation.
3 *
4 * Permission is hereby granted, free of charge, to any person obtaining a
5 * copy of this software and associated documentation files (the
6 * "Software"), to deal in the Software without restriction, including
7 * without limitation the rights to use, copy, modify, merge, publish,
8 * distribute, sub license, and/or sell copies of the Software, and to
9 * permit persons to whom the Software is furnished to do so, subject to
10 * the following conditions:
11 *
12 * The above copyright notice and this permission notice (including the
13 * next paragraph) shall be included in all copies or substantial portions
14 * of the Software.
15 *
16 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
17 * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
18 * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
19 * IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
20 * ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
21 * TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
22 * SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
23 * Authors: Zhao Yakui <[email protected]>
24 *
25 */
26 // Modual name: mpeg2_inter_ivb.asm
27 //
28 // Make inter predition estimation for Mpeg2 Inter frame on Ivy
29 //
30
31 //
32 // Now, begin source code....
33 //
34
35 #define SAVE_RET add (1) RETURN_REG<1>:ud ip:ud 32:ud
36 #define RETURN mov (1) ip:ud RETURN_REG<0,1,0>:ud
37
38 /*
39 * __START
40 */
41 __INTER_START:
42 mov (16) tmp_reg0.0<1>:UD 0x0:UD {align1};
43 mov (16) tmp_reg2.0<1>:UD 0x0:UD {align1};
44 mov (16) tmp_reg4.0<1>:UD 0x0:UD {align1} ;
45 mov (16) tmp_reg6.0<1>:UD 0x0:UD {align1} ;
46
47 shl (2) vme_m0.8<1>:UW orig_xy_ub<2,2,1>:UB 4:UW {align1}; /* (x, y) * 16 */
48 mov (1) vme_m0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
49
50 mul (1) obw_m0.8<1>:UD w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
51 add (1) obw_m0.8<1>:UD obw_m0.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
52 mul (1) obw_m0.8<1>:UD obw_m0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
53 mov (1) obw_m0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
54
55 shl (2) pic_ref.0<1>:uw r4.24<2,2,1>:uw 4:uw {align1};
56 mov (2) pic_ref.16<1>:uw r4.20<2,2,1>:uw {align1};
57
58 mov (8) mb_mvp_ref.0<1>:ud 0:ud {align1};
59 mov (8) mb_ref_win.0<1>:ud 0:ud {align1};
60 mov (8) mba_result.0<1>:ud 0x0:ud {align1};
61 mov (8) mbb_result.0<1>:ud 0x0:ud {align1};
62 mov (8) mbc_result.0<1>:ud 0x0:ud {align1};
63 and.z.f0.0 (1) null:uw mb_hwdep<0,1,0>:uw 0x04:uw {align1};
64 (f0.0) jmpi (1) __mb_hwdep_end;
65 /* read back the data for MB A */
66 /* the layout of MB result is: rx.0(Available). rx.4(MVa), rX.8(MVb), rX.16(Pred_L0 flag),
67 * rX.18 (Pred_L1 flag), rX.20(Forward reference ID), rX.22(Backwared reference ID)
68 */
69 mba_start:
70 mov (8) mb_msg0.0<1>:ud 0:ud {align1};
71 and.z.f0.0 (1) null:uw input_mb_intra_ub<0,1,0>:ub INTRA_PRED_AVAIL_FLAG_AE:uw {align1};
72 /* MB A doesn't exist. Zero MV. mba_flag is zero and ref ID = -1 */
73 (f0.0) mov (2) mba_result.20<1>:w -1:w {align1};
74 (f0.0) jmpi (1) mbb_start;
75 mov (1) mba_result.0<1>:d MB_AVAIL {align1};
76 mov (2) tmp_reg0.0<1>:UW orig_xy_ub<2,2,1>:UB {align1};
77 add (1) tmp_reg0.0<1>:w tmp_reg0.0<0,1,0>:w -1:w {align1};
78 mul (1) mb_msg0.8<1>:UD w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
79 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD tmp_reg0.0<0,1,0>:uw {align1};
80 mul (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
81 mov (1) mb_msg0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
82 mov (1) mb_msg_tmp.8<1>:ud mb_msg0.8<0,1,0>:ud {align1};
83
84 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
85 /* bind index 3, read 1 oword (16bytes), msg type: 0(OWord Block Read) */
86 send (16)
87 mb_ind
88 mb_wb.0<1>:ud
89 NULL
90 data_port(
91 OBR_CACHE_TYPE,
92 OBR_MESSAGE_TYPE,
93 OBR_CONTROL_0,
94 OBR_BIND_IDX,
95 OBR_WRITE_COMMIT_CATEGORY,
96 OBR_HEADER_PRESENT
97 )
98 mlen 1
99 rlen 1
100 {align1};
101
102 /* TODO: RefID is required after multi-references are added */
103 and.z.f0.0 (1) null<1>:ud mb_mode_wb.0<0,1,0>:ud INTRAMBFLAG_MASK:ud {align1} ;
104 (-f0.0) mov (2) mba_result.20<1>:w -1:w {align1};
105 (-f0.0) jmpi (1) mbb_start;
106
107 mov (1) mb_msg0.8<1>:UD mb_msg_tmp.8<0,1,0>:ud {align1};
108 /* Read MV for MB A */
109 /* bind index 3, read 2 oword (16bytes), msg type: 0(OWord Block Read) */
110 send (16)
111 mb_ind
112 mb_mv0.0<1>:ud
113 NULL
114 data_port(
115 OBR_CACHE_TYPE,
116 OBR_MESSAGE_TYPE,
117 OBR_CONTROL_2,
118 OBR_BIND_IDX,
119 OBR_WRITE_COMMIT_CATEGORY,
120 OBR_HEADER_PRESENT
121 )
122 mlen 1
123 rlen 1
124 {align1};
125 /* TODO: RefID is required after multi-references are added */
126 /* MV */
127 mov (2) mba_result.4<1>:ud mb_mv0.0<2,2,1>:ud {align1};
128 mov (1) mba_result.16<1>:w MB_PRED_FLAG {align1};
129
130 mbb_start:
131 mov (8) mb_msg0.0<1>:ud 0:ud {align1};
132 and.z.f0.0 (1) null:uw input_mb_intra_ub<0,1,0>:ub INTRA_PRED_AVAIL_FLAG_B:uw {align1};
133 /* MB B doesn't exist. Zero MV. mba_flag is zero */
134 /* If MB B doesn't exist, neither MB C nor D exists */
135 (f0.0) mov (2) mbb_result.20<1>:w -1:w {align1};
136 (f0.0) mov (2) mbc_result.20<1>:w -1:w {align1};
137 (f0.0) jmpi (1) mb_mvp_start;
138 mov (1) mbb_result.0<1>:d MB_AVAIL {align1};
139 mov (2) tmp_reg0.0<1>:UW orig_xy_ub<2,2,1>:UB {align1};
140 add (1) tmp_reg0.2<1>:w tmp_reg0.2<0,1,0>:w -1:w {align1};
141 mul (1) mb_msg0.8<1>:UD w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
142 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD tmp_reg0.0<0,1,0>:uw {align1};
143 mul (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
144 mov (1) mb_msg0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
145 mov (1) mb_msg_tmp.8<1>:ud mb_msg0.8<0,1,0>:ud {align1};
146
147 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
148
149 /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
150 send (16)
151 mb_ind
152 mb_wb.0<1>:ud
153 NULL
154 data_port(
155 OBR_CACHE_TYPE,
156 OBR_MESSAGE_TYPE,
157 OBR_CONTROL_0,
158 OBR_BIND_IDX,
159 OBR_WRITE_COMMIT_CATEGORY,
160 OBR_HEADER_PRESENT
161 )
162 mlen 1
163 rlen 1
164 {align1};
165
166 /* TODO: RefID is required after multi-references are added */
167 and.z.f0.0 (1) null<1>:ud mb_mode_wb.0<0,1,0>:ud INTRAMBFLAG_MASK:ud {align1} ;
168 (-f0.0) mov (2) mbb_result.20<1>:w -1:w {align1};
169 (-f0.0) jmpi (1) mbc_start;
170
171 mov (1) mb_msg0.8<1>:UD mb_msg_tmp.8<0,1,0>:ud {align1};
172 /* Read MV for MB B */
173 /* bind index 3, read 2 oword (16bytes), msg type: 0(OWord Block Read) */
174 send (16)
175 mb_ind
176 mb_mv0.0<1>:ud
177 NULL
178 data_port(
179 OBR_CACHE_TYPE,
180 OBR_MESSAGE_TYPE,
181 OBR_CONTROL_2,
182 OBR_BIND_IDX,
183 OBR_WRITE_COMMIT_CATEGORY,
184 OBR_HEADER_PRESENT
185 )
186 mlen 1
187 rlen 1
188 {align1};
189 /* TODO: RefID is required after multi-references are added */
190 mov (2) mbb_result.4<1>:ud mb_mv0.0<2,2,1>:ud {align1};
191 mov (1) mbb_result.16<1>:w MB_PRED_FLAG {align1};
192
193 mbc_start:
194 mov (8) mb_msg0.0<1>:ud 0:ud {align1};
195 and.z.f0.0 (1) null:uw input_mb_intra_ub<0,1,0>:ub INTRA_PRED_AVAIL_FLAG_C:uw {align1};
196 /* MB C doesn't exist. Zero MV. mba_flag is zero */
197 /* Based on h264 spec the MB D will be replaced if MB C doesn't exist */
198 (f0.0) jmpi (1) mbd_start;
199 mov (1) mbc_result.0<1>:d MB_AVAIL {align1};
200 mov (2) tmp_reg0.0<1>:UW orig_xy_ub<2,2,1>:UB {align1};
201 add (1) tmp_reg0.2<1>:w tmp_reg0.2<0,1,0>:w -1:w {align1};
202 add (1) tmp_reg0.0<1>:w tmp_reg0.0<0,1,0>:w 1:w {align1};
203 mul (1) mb_msg0.8<1>:UD w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
204 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD tmp_reg0.0<0,1,0>:uw {align1};
205 mul (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
206 mov (1) mb_msg0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
207
208 mov (1) mb_msg_tmp.8<1>:ud mb_msg0.8<0,1,0>:ud {align1};
209
210 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
211 /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
212 send (16)
213 mb_ind
214 mb_wb.0<1>:ud
215 NULL
216 data_port(
217 OBR_CACHE_TYPE,
218 OBR_MESSAGE_TYPE,
219 OBR_CONTROL_0,
220 OBR_BIND_IDX,
221 OBR_WRITE_COMMIT_CATEGORY,
222 OBR_HEADER_PRESENT
223 )
224 mlen 1
225 rlen 1
226 {align1};
227
228 /* TODO: RefID is required after multi-references are added */
229 and.z.f0.0 (1) null<1>:ud mb_mode_wb.0<0,1,0>:ud INTRAMBFLAG_MASK:ud {align1} ;
230 (-f0.0) mov (2) mbc_result.20<1>:w -1:w {align1};
231 (-f0.0) jmpi (1) mb_mvp_start;
232 mov (1) mb_msg0.8<1>:UD mb_msg_tmp.8<0,1,0>:ud {align1};
233 /* Read MV for MB C */
234 /* bind index 3, read 2 oword (16bytes), msg type: 0(OWord Block Read) */
235 send (16)
236 mb_ind
237 mb_mv0.0<1>:ud
238 NULL
239 data_port(
240 OBR_CACHE_TYPE,
241 OBR_MESSAGE_TYPE,
242 OBR_CONTROL_2,
243 OBR_BIND_IDX,
244 OBR_WRITE_COMMIT_CATEGORY,
245 OBR_HEADER_PRESENT
246 )
247 mlen 1
248 rlen 1
249 {align1};
250 /* TODO: RefID is required after multi-references are added */
251 /* Forward MV */
252 mov (2) mbc_result.4<1>:ud mb_mv0.0<2,2,1>:ud {align1};
253 mov (1) mbc_result.16<1>:w MB_PRED_FLAG {align1};
254
255 jmpi (1) mb_mvp_start;
256 mbd_start:
257 mov (8) mb_msg0.0<1>:ud 0:ud {align1};
258 and.z.f0.0 (1) null:uw input_mb_intra_ub<0,1,0>:ub INTRA_PRED_AVAIL_FLAG_D:uw {align1};
259 (f0.0) jmpi (1) mb_mvp_start;
260 mov (1) mbc_result.0<1>:d MB_AVAIL {align1};
261 mov (2) tmp_reg0.0<1>:UW orig_xy_ub<2,2,1>:UB {align1};
262 add (2) tmp_reg0.0<1>:w tmp_reg0.0<2,2,1>:w -1:w {align1};
263 mul (1) mb_msg0.8<1>:UD w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
264 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD tmp_reg0.0<0,1,0>:uw {align1};
265
266 mul (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
267 mov (1) mb_msg0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
268 mov (1) mb_msg_tmp.8<1>:ud mb_msg0.8<0,1,0>:ud {align1};
269
270 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
271 /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
272 send (16)
273 mb_ind
274 mb_wb.0<1>:ud
275 NULL
276 data_port(
277 OBR_CACHE_TYPE,
278 OBR_MESSAGE_TYPE,
279 OBR_CONTROL_0,
280 OBR_BIND_IDX,
281 OBR_WRITE_COMMIT_CATEGORY,
282 OBR_HEADER_PRESENT
283 )
284 mlen 1
285 rlen 1
286 {align1};
287
288 and.z.f0.0 (1) null<1>:ud mb_mode_wb.0<0,1,0>:ud INTRAMBFLAG_MASK:ud {align1} ;
289 (-f0.0) mov (2) mbc_result.20<1>:w -1:w {align1};
290 (-f0.0) jmpi (1) mb_mvp_start;
291
292 mov (1) mb_msg0.8<1>:UD mb_msg_tmp.8<0,1,0>:ud {align1};
293 /* Read MV for MB D */
294 /* bind index 3, read 2 oword (16bytes), msg type: 0(OWord Block Read) */
295 send (16)
296 mb_ind
297 mb_mv0.0<1>:ub
298 NULL
299 data_port(
300 OBR_CACHE_TYPE,
301 OBR_MESSAGE_TYPE,
302 OBR_CONTROL_2,
303 OBR_BIND_IDX,
304 OBR_WRITE_COMMIT_CATEGORY,
305 OBR_HEADER_PRESENT
306 )
307 mlen 1
308 rlen 1
309 {align1};
310
311 /* TODO: RefID is required after multi-references are added */
312
313 /* Forward MV */
314 mov (2) mbc_result.4<1>:ud mb_mv0.0<2,2,1>:ud {align1};
315 mov (1) mbc_result.16<1>:w MB_PRED_FLAG {align1};
316
317 mb_mvp_start:
318 /*TODO: Add the skip prediction */
319 /* Check whether both MB B and C are invailable */
320 add (1) tmp_reg0.0<1>:d mbb_result.0<0,1,0>:d mbc_result.0<0,1,0>:d {align1};
321 cmp.z.f0.0 (1) null:d tmp_reg0.0<0,1,0>:d 0:d {align1};
322 (-f0.0) jmpi (1) mb_median_start;
323 cmp.nz.f0.0 (1) null:d mba_result.0<0,1,0>:d 0:d {align1};
324 (f0.0) mov (1) mbb_result.4<1>:ud mba_result.4<0,1,0>:ud {align1};
325 (f0.0) mov (1) mbc_result.4<1>:ud mba_result.4<0,1,0>:ud {align1};
326 (f0.0) mov (1) mbb_result.20<1>:uw mba_result.20<0,1,0>:uw {align1};
327 (f0.0) mov (1) mbc_result.20<1>:uw mba_result.20<0,1,0>:uw {align1};
328 (f0.0) mov (1) mb_mvp_ref.0<1>:ud mba_result.4<0,1,0>:ud {align1};
329 (-f0.0) mov (1) mb_mvp_ref.0<1>:ud 0:ud {align1};
330 jmpi (1) __mb_hwdep_end;
331
332 mb_median_start:
333 /* check whether only one neighbour MB has the same ref ID with the current MB */
334 mov (8) tmp_reg0.0<1>:ud 0:ud {align1};
335 cmp.z.f0.0 (1) null:d mba_result.20<1>:w 0:w {align1};
336 (f0.0) add (1) tmp_reg0.0<1>:w tmp_reg0.0<1>:w 1:w {align1};
337 (f0.0) mov (1) tmp_reg0.4<1>:ud mba_result.4<0,1,0>:ud {align1};
338 cmp.z.f0.0 (1) null:d mbb_result.20<1>:w 0:w {align1};
339 (f0.0) add (1) tmp_reg0.0<1>:w tmp_reg0.0<1>:w 1:w {align1};
340 (f0.0) mov (1) tmp_reg0.4<1>:ud mbb_result.4<0,1,0>:ud {align1};
341 cmp.z.f0.0 (1) null:d mbc_result.20<1>:w 0:w {align1};
342 (f0.0) add (1) tmp_reg0.0<1>:w tmp_reg0.0<1>:w 1:w {align1};
343 (f0.0) mov (1) tmp_reg0.4<1>:ud mbc_result.4<0,1,0>:ud {align1};
344 cmp.e.f0.0 (1) null:d tmp_reg0.0<1>:w 1:w {align1};
345 (f0.0) mov (1) mb_mvp_ref.0<1>:ud tmp_reg0.4<0,1,0>:ud {align1};
346 (f0.0) jmpi (1) __mb_hwdep_end;
347
348 mov (1) INPUT_ARG0.0<1>:w mba_result.4<0,1,0>:w {align1};
349 mov (1) INPUT_ARG0.4<1>:w mbb_result.4<0,1,0>:w {align1};
350 mov (1) INPUT_ARG0.8<1>:w mbc_result.4<0,1,0>:w {align1};
351 SAVE_RET {align1};
352 jmpi (1) word_imedian;
353 mov (1) mb_mvp_ref.0<1>:w RET_ARG<0,1,0>:w {align1};
354 mov (1) INPUT_ARG0.0<1>:w mba_result.6<0,1,0>:w {align1};
355 mov (1) INPUT_ARG0.4<1>:w mbb_result.6<0,1,0>:w {align1};
356 mov (1) INPUT_ARG0.8<1>:w mbc_result.6<0,1,0>:w {align1};
357 SAVE_RET {align1};
358 jmpi (1) word_imedian;
359 mov (1) mb_mvp_ref.2<1>:w RET_ARG<0,1,0>:w {align1};
360
361 __mb_hwdep_end:
362
363 mov (2) mv_cc_ref.0<1>:w mba_result.4<2,2,1>:w {align1};
364
365 /* Calibrate the ref window for MPEG2 */
366 mov (1) vme_m0.0<1>:W -16:W {align1};
367 mov (1) vme_m0.2<1>:W -12:W {align1};
368 mov (1) INPUT_ARG0.0<1>:ud vme_m0.0<0,1,0>:ud {align1};
369 mov (1) INPUT_ARG0.8<1>:ud vme_m0.8<0,1,0>:ud {align1};
370 mov (8) INPUT_ARG1.0<1>:ud pic_ref.0<8,8,1>:ud {align1};
371
372 SAVE_RET {align1};
373 jmpi (1) ref_boundary_check;
374 mov (2) vme_m0.0<1>:w RET_ARG<2,2,1>:w {align1};
375
376 /* m2 */
377 mov (8) vme_msg_2<1>:UD 0x0:UD {align1};
378
379 /* m3 */
380 mov (8) vme_msg_3<1>:UD 0x0:UD {align1};
381 /* Use the Luma mode */
382 mov (1) tmp_reg0.0<1>:UW INTRA16_DC_PRED:UW {align1};
383 mov (1) vme_msg_3.4<1>:ub tmp_reg0.0<0,1,0>:UB {align1};
384
385 /* m4 */
386 mov (8) vme_msg_4<1>:UD 0x0:UD {align1};
387 mov (1) vme_msg_4.16<1>:UD INTRA_PREDICTORE_MODE {align1};
388
389
390 /* m1 */
391 mov (8) vme_m1.0<1>:ud 0x0:ud {align1};
392 mov (1) intra_flag<1>:UW 0x0:UW {align1} ;
393 mov (1) tmp_reg0.0<1>:uw LUMA_INTRA_8x8_DISABLE:uw {align1};
394 add (1) tmp_reg0.0<1>:uw tmp_reg0.0<0,1,0>:uw LUMA_INTRA_4x4_DISABLE:uw {align1};
395 mov (1) intra_part_mask_ub<1>:UB tmp_reg0.0<0,1,0>:ub {align1};
396 /* m1 */
397 /* assign MB intra struct from the thread payload*/
398 mov (1) mb_intra_struct_ub<1>:UB input_mb_intra_ub<0,1,0>:UB {align1};
399
400
401 /* M0 */
402 /* IME search */
403 mov (1) vme_m0.12<1>:UD SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR + SUB_PEL_MODE_HALF:UD {align1};
404 /* 16x16 Source, 1/2 pixel, harr */
405 mov (1) vme_m0.22<1>:UW REF_REGION_SIZE {align1}; /* Reference Width&Height, 48x40 */
406
407 mov (1) vme_m0.4<1>:UD vme_m0.0<0,1,0>:UD {align1};
408 add (2) vme_m0.0<1>:w vme_m0.0<2,2,1>:w mb_ref_win.16<2,2,1>:w {align1};
409 add (2) vme_m0.4<1>:w vme_m0.4<2,2,1>:w mb_ref_win.16<2,2,1>:w {align1};
410 mov (8) vme_msg_0.0<1>:UD vme_m0.0<8,8,1>:UD {align1};
411
412 /* m1 */
413
414 mov (1) vme_m1.0<1>:UD ADAPTIVE_SEARCH_ENABLE:ud {align1} ;
415 /* MV num is passed by constant buffer. R4.28 */
416 mov (1) vme_m1.4<1>:UB r4.28<0,1,0>:UB {align1};
417 add (1) vme_m1.4<1>:UD vme_m1.4<0,1,0>:UD FB_PRUNING_DISABLE:UD {align1};
418 mov (1) vme_m1.8<1>:UD START_CENTER + SEARCH_PATH_LEN:UD {align1};
419
420 /* Bilinear filter */
421 mov (1) tmp_reg0.0<1>:uw 0x04:uw {align1};
422 add (1) vme_m1.30<1>:ub vme_m1.30<0,1,0>:ub tmp_reg0.0<0,1,0>:ub {align1};
423
424 /* Set the MV cost center */
425 mov (1) vme_m1.16<1>:ud mv_cc_ref.0<0,1,0>:ud {align1};
426 mov (1) vme_m1.20<1>:ud mv_cc_ref.0<0,1,0>:ud {align1};
427 mov (8) vme_msg_1.0<1>:UD vme_m1.0<8,8,1>:UD {align1};
428
429
430 send (8)
431 vme_msg_ind
432 vme_wb
433 null
434 vme(
435 BIND_IDX_VME,
436 0,
437 0,
438 VME_MESSAGE_TYPE_MIXED
439 )
440 mlen vme_msg_length
441 rlen vme_inter_wb_length
442 {align1};
443
444 and.z.f0.0 (1) null:uw mb_hwdep<0,1,0>:uw 0x04:uw {align1};
445 (-f0.0) jmpi (1) vme_run_again;
446
447 vme_mv_output:
448
449 and.z.f0.0 (1) null<1>:ud vme_wb0.0<0,1,0>:ud INTRAMBFLAG_MASK:ud {align1} ;
450
451 (-f0.0)jmpi (1) __INTRA_INFO ;
452
453 __INTER_INFO:
454 /* Write MV pairs */
455 mov (8) msg_reg0.0<1>:UD obw_m0.0<8,8,1>:UD {align1};
456
457 mov (8) msg_reg1.0<1>:UD vme_wb1.0<8,8,1>:UD {align1};
458
459 /* bind index 3, write 8 oword (128 bytes), msg type: 8(OWord Block Write) */
460 send (16)
461 msg_ind
462 obw_wb
463 null
464 data_port(
465 OBW_CACHE_TYPE,
466 OBW_MESSAGE_TYPE,
467 OBW_CONTROL_2,
468 OBW_BIND_IDX,
469 OBW_WRITE_COMMIT_CATEGORY,
470 OBW_HEADER_PRESENT
471 )
472 mlen 2
473 rlen obw_wb_length
474 {align1};
475
476
477 mov (1) msg_reg1.0<1>:ud vme_wb0.0<0,1,0>:ud {align1} ;
478 mov (1) msg_reg1.4<1>:UD vme_wb0.28<0,1,0>:UD {align1};
479 mov (1) msg_reg1.8<1>:ud tmp_ud1<0,1,0>:ud {align1} ;
480 mov (1) msg_reg1.12<1>:ud vme_wb0.0<0,1,0>:ud {align1} ;
481 mov (1) msg_reg1.16<1>:ud 0x25:ud {align1} ;
482 jmpi (1) __OUTPUT_INFO;
483
484 __INTRA_INFO:
485 mov (1) msg_reg1.0<1>:UD vme_wb.0<0,1,0>:UD {align1};
486 mov (1) msg_reg1.4<1>:UD vme_wb.16<0,1,0>:UD {align1};
487 mov (1) msg_reg1.8<1>:UD vme_wb.20<0,1,0>:UD {align1};
488 mov (1) msg_reg1.12<1>:UD vme_wb.24<0,1,0>:UD {align1};
489 mov (1) msg_reg1.16<1>:ud 0x35:ud {align1} ;
490
491 __OUTPUT_INFO:
492
493 mov (1) msg_reg1.20<1>:ud obw_m0.8<0,1,0>:ud {align1};
494 add (1) obw_m0.8<1>:UD obw_m0.8<0,1,0>:UD INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
495 mov (8) msg_reg0.0<1>:ud obw_m0.0<8,8,1>:ud {align1};
496
497
498 /* bind index 3, write 1 oword, msg type: 8(OWord Block Write) */
499 send (16)
500 msg_ind
501 obw_wb
502 null
503 data_port(
504 OBW_CACHE_TYPE,
505 OBW_MESSAGE_TYPE,
506 OBW_CONTROL_2,
507 OBW_BIND_IDX,
508 OBW_WRITE_COMMIT_CATEGORY,
509 OBW_HEADER_PRESENT
510 )
511 mlen 2
512 rlen obw_wb_length
513 {align1};
514
515 /* Issue message fence so that the previous write message is committed */
516 send (16)
517 mb_ind
518 mb_wb.0<1>:ud
519 NULL
520 data_port(
521 OBR_CACHE_TYPE,
522 OBR_MESSAGE_FENCE,
523 OBR_MF_COMMIT,
524 OBR_BIND_IDX,
525 OBR_WRITE_COMMIT_CATEGORY,
526 OBR_HEADER_PRESENT
527 )
528 mlen 1
529 rlen 1
530 {align1};
531
532 __EXIT:
533 /*
534 * kill thread
535 */
536 mov (8) ts_msg_reg0<1>:UD r0<8,8,1>:UD {align1};
537 send (16) ts_msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};
538
539
540 nop ;
541 nop ;
542
543 word_imedian:
544 cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.4<0,1,0>:w {align1};
545 (f0.0) jmpi (1) cmp_a_ge_b;
546 cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
547 (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
548 (f0.0) jmpi (1) cmp_end;
549 cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
550 (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
551 (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
552 jmpi (1) cmp_end;
553 cmp_a_ge_b:
554 cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
555 (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
556 (f0.0) jmpi (1) cmp_end;
557 cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
558 (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
559 (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
560 cmp_end:
561 RETURN {align1};
562
563 nop;
564 nop;
565
566 ref_boundary_check:
567
568 /* The left/up coordinate of reference window */
569 add (2) TEMP_VAR0.0<1>:w INPUT_ARG0.8<2,2,1>:w INPUT_ARG0.0<2,2,1>:w {align1};
570 /* The right/bottom coordinate of reference window */
571 add (1) TEMP_VAR0.16<1>:w TEMP_VAR0.0<0,1,0>:w 48:w {align1};
572 add (1) TEMP_VAR0.18<1>:w TEMP_VAR0.2<0,1,0>:w 40:w {align1};
573
574 /* Firstly the MV range is checked */
575 mul (2) TEMP_VAR1.16<1>:w INPUT_ARG1.16<2,2,1>:w -1:w {align1};
576 add (2) TEMP_VAR1.0<1>:w INPUT_ARG0.8<2,2,1>:w TEMP_VAR1.16<2,2,1>:w {align1};
577 add (2) TEMP_VAR1.4<1>:w INPUT_ARG0.8<2,2,1>:w INPUT_ARG1.16<2,2,1>:w {align1};
578
579 cmp.l.f0.0 (1) null:w TEMP_VAR0.0<0,1,0>:w TEMP_VAR1.0<0,1,0>:w {align1};
580 (f0.0) mov (1) TEMP_VAR0.0<1>:w TEMP_VAR1.0<0,1,0>:w {align1};
581 cmp.g.f0.0 (1) null:w TEMP_VAR0.16<0,1,0>:w TEMP_VAR1.4<0,1,0>:w {align1};
582 (f0.0) add (1) TEMP_VAR0.0<1>:w TEMP_VAR1.4<0,1,0>:w -48:w {align1};
583 cmp.l.f0.0 (1) null:w TEMP_VAR0.2<0,1,0>:w TEMP_VAR1.2<0,1,0>:w {align1};
584 (f0.0) mov (1) TEMP_VAR0.2<1>:w TEMP_VAR1.2<0,1,0>:w {align1};
585 cmp.g.f0.0 (1) null:w TEMP_VAR0.18<0,1,0>:w TEMP_VAR1.6<0,1,0>:w {align1};
586 (f0.0) add (1) TEMP_VAR0.2<1>:w TEMP_VAR1.6<0,1,0>:w -40:w {align1};
587
588
589 x_left_cmp:
590 cmp.l.f0.0 (1) null:w TEMP_VAR0.0<0,1,0>:w 0:w {align1};
591 (-f0.0) jmpi (1) x_right_cmp;
592 (f0.0) mov (1) TEMP_VAR0.0<1>:w 0:w {align1};
593 jmpi (1) y_top_cmp;
594 x_right_cmp:
595 cmp.g.f0.0 (1) null:w TEMP_VAR0.16<0,1,0>:w INPUT_ARG1.0<0,1,0>:w {align1};
596 (-f0.0) jmpi (1) y_top_cmp;
597 (f0.0) add (1) TEMP_VAR0.0<1>:w INPUT_ARG1.0<0,1,0>:w -48:w {align1};
598 y_top_cmp:
599 cmp.l.f0.0 (1) null:w TEMP_VAR0.2<0,1,0>:w 0:w {align1};
600 (-f0.0) jmpi (1) y_bottom_cmp;
601 (f0.0) mov (1) TEMP_VAR0.2<1>:w 0:w {align1};
602 jmpi (1) y_bottom_end;
603 y_bottom_cmp:
604 cmp.g.f0.0 (1) null:w TEMP_VAR0.18<0,1,0>:w INPUT_ARG1.2<0,1,0>:w {align1};
605 (f0.0) add (1) TEMP_VAR0.2<1>:w INPUT_ARG1.2<0,1,0>:w -40:w {align1};
606
607 y_bottom_end:
608 mul (2) TEMP_VAR1.0<1>:w INPUT_ARG0.8<2,2,1>:w -1:w {align1};
609 add (2) RET_ARG<1>:w TEMP_VAR0.0<2,2,1>:w TEMP_VAR1.0<2,2,1>:w {align1};
610 RETURN {align1};
611 nop;
612 nop;
613
614 vme_run_again:
615
616 asr (2) mb_ref_win.0<1>:w mb_mvp_ref.0<2,2,1>:w 2:w {align1};
617 mov (2) tmp_reg0.0<1>:w mb_ref_win.0<2,2,1>:w {align1};
618 add (2) mb_ref_win.8<1>:w mb_ref_win.0<2,2,1>:w 3:w {align1};
619 and (2) mb_ref_win.16<1>:uw mb_ref_win.8<2,2,1>:uw 0xFFFC:uw {align1};
620
621 cmp.l.f0.0 (1) null:w tmp_reg0.0<0,1,0>:w 0:w {align1};
622 (f0.0) mul (1) tmp_reg0.0<1>:w tmp_reg0.0<0,1,0>:w -1:w {align1};
623 cmp.l.f0.0 (1) null:w tmp_reg0.2<0,1,0>:w 0:w {align1};
624 (f0.0) mul (1) tmp_reg0.2<1>:w tmp_reg0.2<0,1,0>:w -1:w {align1};
625
626 cmp.ge.f0.0 (1) null:w tmp_reg0.0<0,1,0>:w 4:w {align1};
627 (f0.0) jmpi (1) vme_start;
628 cmp.ge.f0.0 (1) null:w tmp_reg0.2<0,1,0>:w 4:w {align1};
629 (f0.0) jmpi (1) vme_start;
630
631 jmpi (1) vme_done;
632
633 vme_start:
634 mov (8) tmp_vme_wb0.0<1>:ud vme_wb0.0<8,8,1>:ud {align1};
635 mov (8) tmp_vme_wb1.0<1>:ud vme_wb1.0<8,8,1>:ud {align1};
636
637 /* Calibrate the ref window for MPEG2 */
638 mov (1) vme_m0.0<1>:W -16:W {align1};
639 mov (1) vme_m0.2<1>:W -12:W {align1};
640 mov (1) INPUT_ARG0.8<1>:ud vme_m0.8<0,1,0>:ud {align1};
641 add (2) INPUT_ARG0.0<1>:w vme_m0.0<2,2,1>:w mb_ref_win.16<2,2,1>:w {align1};
642 mov (8) INPUT_ARG1.0<1>:ud pic_ref.0<8,8,1>:ud {align1};
643
644 SAVE_RET {align1};
645 jmpi (1) ref_boundary_check;
646 mov (2) vme_m0.0<1>:w RET_ARG<2,2,1>:w {align1};
647
648 /* m2 */
649 mov (8) vme_msg_2<1>:UD 0x0:UD {align1};
650
651 /* m3 */
652 mov (8) vme_msg_3<1>:UD 0x0:UD {align1};
653
654 /* m4 */
655 mov (8) vme_msg_4<1>:UD 0x0:UD {align1};
656
657
658 /* m1 */
659 mov (8) vme_m1.0<1>:ud 0x0:ud {align1};
660 mov (1) intra_flag<1>:UW 0x0:UW {align1} ;
661 mov (1) tmp_reg0.0<1>:uw LUMA_INTRA_8x8_DISABLE:uw {align1};
662 add (1) tmp_reg0.0<1>:uw tmp_reg0.0<0,1,0>:uw LUMA_INTRA_4x4_DISABLE:uw {align1};
663 mov (1) intra_part_mask_ub<1>:UB tmp_reg0.0<0,1,0>:ub {align1};
664 /* m1 */
665 /* assign MB intra struct from the thread payload*/
666 mov (1) mb_intra_struct_ub<1>:UB input_mb_intra_ub<0,1,0>:UB {align1};
667
668
669 /* M0 */
670 /* IME search */
671 mov (1) vme_m0.12<1>:UD SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR + SUB_PEL_MODE_HALF:UD {align1};
672 /* 16x16 Source, 1/2 pixel, harr */
673 mov (1) vme_m0.22<1>:UW REF_REGION_SIZE {align1}; /* Reference Width&Height, 48x40 */
674
675 mov (1) vme_m0.4<1>:UD vme_m0.0<0,1,0>:UD {align1};
676 mov (8) vme_msg_0.0<1>:UD vme_m0.0<8,8,1>:UD {align1};
677
678 /* m1 */
679
680 mov (1) vme_m1.0<1>:UD ADAPTIVE_SEARCH_ENABLE:ud {align1} ;
681 /* MV num is passed by constant buffer. R4.28 */
682 mov (1) vme_m1.4<1>:UB r4.28<0,1,0>:UB {align1};
683 add (1) vme_m1.4<1>:UD vme_m1.4<0,1,0>:UD FB_PRUNING_DISABLE:UD {align1};
684 mov (1) vme_m1.8<1>:UD START_CENTER + SEARCH_PATH_LEN:UD {align1};
685
686 /* Bilinear filter */
687 mov (1) tmp_reg0.0<1>:uw 0x04:uw {align1};
688 add (1) vme_m1.30<1>:ub vme_m1.30<0,1,0>:ub tmp_reg0.0<0,1,0>:ub {align1};
689
690 /* Set the MV cost center */
691 mov (1) vme_m1.16<1>:ud mv_cc_ref.0<0,1,0>:ud {align1};
692 mov (1) vme_m1.20<1>:ud mv_cc_ref.0<0,1,0>:ud {align1};
693 mov (8) vme_msg_1.0<1>:UD vme_m1.0<8,8,1>:UD {align1};
694
695
696 send (8)
697 vme_msg_ind
698 vme_wb
699 null
700 vme(
701 BIND_IDX_VME,
702 0,
703 0,
704 VME_MESSAGE_TYPE_INTER
705 )
706 mlen vme_msg_length
707 rlen vme_inter_wb_length
708 {align1};
709
710
711 cmp.l.f0.0 (1) null:uw vme_wb0.6<0,1,0>:uw tmp_vme_wb0.6<0,1,0>:uw {align1};
712 (f0.0) jmpi (1) vme_done;
713 mov (8) vme_wb0.0<1>:ud tmp_vme_wb0.0<8,8,1>:ud {align1};
714 mov (8) vme_wb1.0<1>:ud tmp_vme_wb1.0<8,8,1>:ud {align1};
715
716 vme_done:
717 jmpi (1) vme_mv_output;
718 nop;
719 nop;
720 nop;
721