Debian Codegraph @

src/shaders/vme/intra_frame.asm

raw
1 /*
2 * Copyright © <2010>, Intel Corporation.
3 *
4 * Permission is hereby granted, free of charge, to any person obtaining a
5 * copy of this software and associated documentation files (the
6 * "Software"), to deal in the Software without restriction, including
7 * without limitation the rights to use, copy, modify, merge, publish,
8 * distribute, sub license, and/or sell copies of the Software, and to
9 * permit persons to whom the Software is furnished to do so, subject to
10 * the following conditions:
11 *
12 * The above copyright notice and this permission notice (including the
13 * next paragraph) shall be included in all copies or substantial portions
14 * of the Software.
15 *
16 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
17 * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
18 * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
19 * IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
20 * ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
21 * TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
22 * SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
23 *
24 */
25 // Modual name: IntraFrame.asm
26 //
27 // Make intra predition estimation for Intra frame
28 //
29
30 //
31 // Now, begin source code....
32 //
33
34 /*
35 * __START
36 */
37 __INTRA_START:
38 mov (16) tmp_reg0.0<1>:UD 0x0:UD {align1};
39 mov (16) tmp_reg2.0<1>:UD 0x0:UD {align1};
40 mov (16) tmp_reg4.0<1>:UD 0x0:UD {align1} ;
41
42 shl (2) read0_header.0<1>:D orig_xy_ub<2,2,1>:UB 4:UW {align1}; /* (x, y) * 16 */
43 add (1) read0_header.0<1>:D read0_header.0<0,1,0>:D -8:W {align1}; /* X offset */
44 add (1) read0_header.4<1>:D read0_header.4<0,1,0>:D -1:W {align1}; /* Y offset */
45 mov (1) read0_header.8<1>:UD BLOCK_32X1 {align1};
46 mov (1) read0_header.20<1>:UB thread_id_ub {align1}; /* dispatch id */
47
48 shl (2) read1_header.0<1>:D orig_xy_ub<2,2,1>:UB 4:UW {align1}; /* (x, y) * 16 */
49 add (1) read1_header.0<1>:D read1_header.0<0,1,0>:D -4:W {align1}; /* X offset */
50 mov (1) read1_header.8<1>:UD BLOCK_4X16 {align1};
51 mov (1) read1_header.20<1>:UB thread_id_ub {align1}; /* dispatch id */
52
53 shl (2) vme_m0.8<1>:UW orig_xy_ub<2,2,1>:UB 4:UW {align1}; /* (x, y) * 16 */
54 mov (1) vme_m0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
55
56 mul (1) obw_m0.8<1>:UD w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
57 add (1) obw_m0.8<1>:UD obw_m0.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
58 mov (1) obw_m0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
59
60 /*
61 * Media Read Message -- fetch neighbor edge pixels
62 */
63 /* ROW */
64 __INTRA_LOOP:
65 mov (8) msg_reg0.0<1>:UD read0_header.0<8,8,1>:UD {align1};
66 send (8) msg_ind INEP_ROW<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 1 {align1};
67
68 /* COL */
69 mov (8) msg_reg0.0<1>:UD read1_header.0<8,8,1>:UD {align1};
70 send (8) msg_ind INEP_COL0<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 2 {align1};
71
72 /*
73 * VME message
74 */
75 /* m0 */
76 mov (8) vme_msg_0.0<1>:UD vme_m0.0<8,8,1>:UD {align1};
77
78 /* m1 */
79 mov (1) intra_flag<1>:UW 0x0:UW {align1} ;
80 and.z.f0.0 (1) null<1>:UW transform_8x8_ub<0,1,0>:UB 1:UW {align1};
81 (f0.0) mov (1) intra_part_mask_ub<1>:UB LUMA_INTRA_8x8_DISABLE {align1};
82
83 cmp.nz.f0.0 (1) null<1>:UW orig_x_ub<0,1,0>:UB 0:UW {align1}; /* X != 0 */
84 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_AE {align1}; /* A */
85
86 cmp.nz.f0.0 (1) null<1>:UW orig_y_ub<0,1,0>:UB 0:UW {align1}; /* Y != 0 */
87 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_B {align1}; /* B */
88
89 mul.nz.f0.0 (1) null<1>:UW orig_x_ub<0,1,0>:UB orig_y_ub<0,1,0>:UB {align1}; /* X * Y != 0 */
90 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_D {align1}; /* D */
91
92 add (1) tmp_x_w<1>:W orig_x_ub<0,1,0>:UB 1:UW {align1}; /* X + 1 */
93 add (1) tmp_x_w<1>:W w_in_mb_uw<0,1,0>:UW -tmp_x_w<0,1,0>:W {align1}; /* width - (X + 1) */
94 mul.nz.f0.0 (1) null<1>:UD tmp_x_w<0,1,0>:W orig_y_ub<0,1,0>:UB {align1}; /* (width - (X + 1)) * Y != 0 */
95 (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_C {align1}; /* C */
96
97 and.nz.f0.0 (1) null<1>:UW slice_edge_ub<0,1,0>:UB 2:UW {align1};
98 (f0.0) and (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB 0xE0 {align1}; /* slice edge disable B,C,D*/
99
100
101 mov (8) vme_msg_1<1>:UD vme_m1.0<8,8,1>:UD {align1};
102
103 /* m2 */
104 mov (8) vme_msg_2<1>:UD 0x0:UD {align1};
105
106 /* m3 */
107 mov (1) INEP_ROW.0<1>:UD 0x0:UD {align1};
108 and (1) INEP_ROW.4<1>:UD INEP_ROW.4<0,1,0>:UD 0xFF000000:UD {align1};
109 mov (8) vme_msg_3<1>:UD INEP_ROW.0<8,8,1>:UD {align1};
110
111 /* m4 */
112 mov (8) vme_msg_4<1>:UD 0x0 {align1};
113 mov (16) vme_msg_4.0<1>:UB INEP_COL0.3<32,8,4>:UB {align1};
114 mov (1) vme_msg_4.16<1>:UD INTRA_PREDICTORE_MODE {align1};
115
116 send (8)
117 vme_msg_ind
118 vme_wb
119 null
120 vme(
121 BIND_IDX_VME,
122 0,
123 0,
124 VME_MESSAGE_TYPE_INTRA
125 )
126 mlen vme_msg_length
127 rlen vme_intra_wb_length
128 {align1};
129
130 /*
131 * Oword Block Write message
132 */
133 mov (8) msg_reg0.0<1>:UD obw_m0<8,8,1>:UD {align1};
134
135 mov (1) msg_reg1.0<1>:UD vme_wb.0<0,1,0>:UD {align1};
136 mov (1) msg_reg1.4<1>:UD vme_wb.16<0,1,0>:UD {align1};
137 mov (1) msg_reg1.8<1>:UD vme_wb.20<0,1,0>:UD {align1};
138 mov (1) msg_reg1.12<1>:UD vme_wb.24<0,1,0>:UD {align1};
139 /* bind index 3, write 1 oword, msg type: 8(OWord Block Write) */
140 send (16)
141 msg_ind
142 obw_wb
143 null
144 data_port(
145 OBW_CACHE_TYPE,
146 OBW_MESSAGE_TYPE,
147 OBW_CONTROL_0,
148 OBW_BIND_IDX,
149 OBW_WRITE_COMMIT_CATEGORY,
150 OBW_HEADER_PRESENT
151 )
152 mlen 2
153 rlen obw_wb_length
154 {align1};
155
156 add (1) read0_header.0<1>:D read0_header.0<0,1,0>:D 16:W {align1}; /* X offset: X += 16 */
157 add (1) read1_header.0<1>:D read1_header.0<0,1,0>:D 16:W {align1}; /* X offset: X += 16 */
158 add (1) vme_m0.8<1>:UW vme_m0.8<0,1,0>:UW 16:UW {align1}; /* Y = Y, X += 16 */
159
160 add (1) orig_x_ub<1>:ub orig_x_ub<0,1,0>:ub 1:uw {align1} ;
161 cmp.e.f0.0 (1) null<1>:uw w_in_mb_uw<0,1,0>:uw orig_x_ub<0,1,0>:ub {align1};
162 (f0.0)mov (1) orig_x_ub<1>:ub 0:uw {align1} ;
163 (f0.0)add (1) orig_y_ub<1>:ub orig_y_ub<0,1,0>:ub 1:uw {align1} ;
164 (f0.0)mov (1) read0_header.0<1>:D -8:W {align1}; /* X offset */
165 (f0.0)add (1) read0_header.4<1>:D read0_header.4<0,1,0>:D 16:W {align1}; /* Y offset */
166 (f0.0)mov (1) read1_header.0<1>:D -4:W {align1}; /* X offset */
167 (f0.0)add (1) read1_header.4<1>:D read1_header.4<0,1,0>:D 16:W {align1}; /* Y offset */
168 /* X = 0, Y += 16 */
169 (f0.0)mov (1) vme_m0.8<1>:UW 0:UW {align1};
170 (f0.0)add (1) vme_m0.10<1>:UW vme_m0.10<0,1,0>:UW 16:UW {align1};
171
172 add (1) obw_m0.8<1>:UD obw_m0.8<0,1,0>:UD 1:uw {align1}; /* the new offset */
173
174 add.z.f0.0 (1) num_macroblocks<1>:w num_macroblocks<0,1,0>:w -1:w {align1} ;
175 (-f0.0)jmpi (1) __INTRA_LOOP ;
176
177 __EXIT:
178 /*
179 * kill thread
180 */
181 mov (8) msg_reg0<1>:UD r0<8,8,1>:UD {align1};
182 send (16) msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};