Debian Codegraph @

src/shaders/vme/mpeg2_inter_gen8.asm

raw
1 /*
2 * Copyright © <2013>, Intel Corporation.
3 *
4 * Permission is hereby granted, free of charge, to any person obtaining a
5 * copy of this software and associated documentation files (the
6 * "Software"), to deal in the Software without restriction, including
7 * without limitation the rights to use, copy, modify, merge, publish,
8 * distribute, sub license, and/or sell copies of the Software, and to
9 * permit persons to whom the Software is furnished to do so, subject to
10 * the following conditions:
11 *
12 * The above copyright notice and this permission notice (including the
13 * next paragraph) shall be included in all copies or substantial portions
14 * of the Software.
15 *
16 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
17 * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
18 * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
19 * IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
20 * ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
21 * TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
22 * SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
23 *
24 */
25 // Modual name: mpeg2_inter_gen8.asm
26 //
27 // Make inter predition estimation for MPEG2 Inter-frame on gen8
28 //
29
30 //
31 // Now, begin source code....
32 //
33
34 #define SAVE_RET add (1) RETURN_REG<1>:ud ip:ud 32:ud
35 #define RETURN mov (1) ip:ud RETURN_REG<0,1,0>:ud
36
37 /*
38 * __START
39 */
40 __INTER_START:
41 mov (16) tmp_reg0.0<1>:UD 0x0:UD {align1};
42 mov (16) tmp_reg2.0<1>:UD 0x0:UD {align1};
43 mov (16) tmp_reg4.0<1>:UD 0x0:UD {align1} ;
44 mov (16) tmp_reg6.0<1>:UD 0x0:UD {align1} ;
45
46
47 shl (2) vme_m0.8<1>:UW orig_xy_ub<2,2,1>:UB 4:UW {align1}; /* (x, y) * 16 */
48 mov (1) vme_m0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
49
50 mul (1) obw_m0.8<1>:UD w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
51 add (1) obw_m0.8<1>:UD obw_m0.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
52 mul (1) obw_m0.8<1>:UD obw_m0.8<0,1,0>:UD 24:UD {align1};
53 mov (1) obw_m0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
54
55
56 shl (2) pic_ref.0<1>:uw r4.24<2,2,1>:uw 4:uw {align1};
57 mov (2) pic_ref.16<1>:uw r4.20<2,2,1>:uw {align1};
58 mov (8) mb_mvp_ref.0<1>:ud 0:ud {align1};
59 mov (8) mb_ref_win.0<1>:ud 0:ud {align1};
60 mov (8) mba_result.0<1>:ud 0x0:ud {align1};
61 mov (8) mbb_result.0<1>:ud 0x0:ud {align1};
62 mov (8) mbc_result.0<1>:ud 0x0:ud {align1};
63
64 and.z.f0.0 (1) null:uw mb_hwdep<0,1,0>:uw 0x04:uw {align1};
65 (f0.0) jmpi (1) __mb_hwdep_end;
66 /* read back the data for MB A */
67 /* the layout of MB result is: rx.0(Available). rx.4(MVa), rX.8(MVb), rX.16(Pred_L0 flag),
68 * rX.18 (Pred_L1 flag), rX.20(Forward reference ID), rX.22(Backwared reference ID)
69 */
70 mba_start:
71 mov (8) mb_msg0.0<1>:ud 0:ud {align1};
72 and.z.f0.0 (1) null:uw input_mb_intra_ub<0,1,0>:ub INTRA_PRED_AVAIL_FLAG_AE:uw {align1};
73 /* MB A doesn't exist. Zero MV. mba_flag is zero and ref ID = -1 */
74 (f0.0) mov (2) mba_result.20<1>:w -1:w {align1};
75 (f0.0) jmpi (1) mbb_start;
76 mov (1) mba_result.0<1>:d MB_AVAIL {align1};
77 mov (2) tmp_reg0.0<1>:UW orig_xy_ub<2,2,1>:UB {align1};
78 add (1) tmp_reg0.0<1>:w tmp_reg0.0<0,1,0>:w -1:w {align1};
79 mul (1) mb_msg0.8<1>:UD w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
80 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD tmp_reg0.0<0,1,0>:uw {align1};
81 mul (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD 24:UD {align1};
82 mov (1) mb_msg0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
83
84 /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
85 send (16)
86 mb_ind
87 mb_wb.0<1>:ud
88 NULL
89 data_port(
90 OBR_CACHE_TYPE,
91 OBR_MESSAGE_TYPE,
92 OBR_CONTROL_4,
93 OBR_BIND_IDX,
94 OBR_WRITE_COMMIT_CATEGORY,
95 OBR_HEADER_PRESENT
96 )
97 mlen 1
98 rlen 2
99 {align1};
100
101 /* TODO: RefID is required after multi-references are added */
102 cmp.l.f0.0 (1) null:w mb_intra_wb.16<0,1,0>:uw mb_inter_wb.8<0,1,0>:uw {align1};
103 (f0.0) mov (2) mba_result.20<1>:w -1:w {align1};
104 (f0.0) jmpi (1) mbb_start;
105
106 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:ud 3:ud {align1};
107 /* Read MV for MB A */
108 /* bind index 3, read 2 oword (32 bytes), msg type: 0(OWord Block Read) */
109 send (16)
110 mb_ind
111 mb_mv0.0<1>:ud
112 NULL
113 data_port(
114 OBR_CACHE_TYPE,
115 OBR_MESSAGE_TYPE,
116 OBR_CONTROL_2,
117 OBR_BIND_IDX,
118 OBR_WRITE_COMMIT_CATEGORY,
119 OBR_HEADER_PRESENT
120 )
121 mlen 1
122 rlen 1
123 {align1};
124 /* TODO: RefID is required after multi-references are added */
125 /* MV */
126 mov (2) mba_result.4<1>:ud mb_mv0.0<2,2,1>:ud {align1};
127 mov (1) mba_result.16<1>:w MB_PRED_FLAG {align1};
128
129 mbb_start:
130 mov (8) mb_msg0.0<1>:ud 0:ud {align1};
131 and.z.f0.0 (1) null:uw input_mb_intra_ub<0,1,0>:ub INTRA_PRED_AVAIL_FLAG_B:uw {align1};
132 /* MB B doesn't exist. Zero MV. mba_flag is zero */
133 /* If MB B doesn't exist, neither MB C nor D exists */
134 (f0.0) mov (2) mbb_result.20<1>:w -1:w {align1};
135 (f0.0) mov (2) mbc_result.20<1>:w -1:w {align1};
136 (f0.0) jmpi (1) mb_mvp_start;
137 mov (1) mbb_result.0<1>:d MB_AVAIL {align1};
138 mov (2) tmp_reg0.0<1>:UW orig_xy_ub<2,2,1>:UB {align1};
139 add (1) tmp_reg0.2<1>:w tmp_reg0.2<0,1,0>:w -1:w {align1};
140 mul (1) mb_msg0.8<1>:UD w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
141 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD tmp_reg0.0<0,1,0>:uw {align1};
142 mul (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD 24:UD {align1};
143 mov (1) mb_msg0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
144
145 /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
146 send (16)
147 mb_ind
148 mb_wb.0<1>:ud
149 NULL
150 data_port(
151 OBR_CACHE_TYPE,
152 OBR_MESSAGE_TYPE,
153 OBR_CONTROL_4,
154 OBR_BIND_IDX,
155 OBR_WRITE_COMMIT_CATEGORY,
156 OBR_HEADER_PRESENT
157 )
158 mlen 1
159 rlen 2
160 {align1};
161
162 /* TODO: RefID is required after multi-references are added */
163 cmp.l.f0.0 (1) null:w mb_intra_wb.16<0,1,0>:uw mb_inter_wb.8<0,1,0>:uw {align1};
164 (f0.0) mov (2) mbb_result.20<1>:w -1:w {align1};
165 (f0.0) jmpi (1) mbc_start;
166 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:ud 3:ud {align1};
167 /* Read MV for MB B */
168 /* bind index 3, read 2 oword (32bytes), msg type: 0(OWord Block Read) */
169 send (16)
170 mb_ind
171 mb_mv0.0<1>:ud
172 NULL
173 data_port(
174 OBR_CACHE_TYPE,
175 OBR_MESSAGE_TYPE,
176 OBR_CONTROL_2,
177 OBR_BIND_IDX,
178 OBR_WRITE_COMMIT_CATEGORY,
179 OBR_HEADER_PRESENT
180 )
181 mlen 1
182 rlen 1
183 {align1};
184 /* TODO: RefID is required after multi-references are added */
185 mov (2) mbb_result.4<1>:ud mb_mv0.0<2,2,1>:ud {align1};
186 mov (1) mbb_result.16<1>:w MB_PRED_FLAG {align1};
187
188 mbc_start:
189 mov (8) mb_msg0.0<1>:ud 0:ud {align1};
190 and.z.f0.0 (1) null:uw input_mb_intra_ub<0,1,0>:ub INTRA_PRED_AVAIL_FLAG_C:uw {align1};
191 /* MB C doesn't exist. Zero MV. mba_flag is zero */
192 /* Based on h264 spec the MB D will be replaced if MB C doesn't exist */
193 (f0.0) jmpi (1) mbd_start;
194 mov (1) mbc_result.0<1>:d MB_AVAIL {align1};
195 mov (2) tmp_reg0.0<1>:UW orig_xy_ub<2,2,1>:UB {align1};
196 add (1) tmp_reg0.2<1>:w tmp_reg0.2<0,1,0>:w -1:w {align1};
197 add (1) tmp_reg0.0<1>:w tmp_reg0.0<0,1,0>:w 1:w {align1};
198 mul (1) mb_msg0.8<1>:UD w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
199 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD tmp_reg0.0<0,1,0>:uw {align1};
200 mul (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD 24:UD {align1};
201 mov (1) mb_msg0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
202
203 /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
204 send (16)
205 mb_ind
206 mb_wb.0<1>:ud
207 NULL
208 data_port(
209 OBR_CACHE_TYPE,
210 OBR_MESSAGE_TYPE,
211 OBR_CONTROL_4,
212 OBR_BIND_IDX,
213 OBR_WRITE_COMMIT_CATEGORY,
214 OBR_HEADER_PRESENT
215 )
216 mlen 1
217 rlen 2
218 {align1};
219
220 /* TODO: RefID is required after multi-references are added */
221 cmp.l.f0.0 (1) null:w mb_intra_wb.16<0,1,0>:uw mb_inter_wb.8<0,1,0>:uw {align1};
222 (f0.0) mov (2) mbc_result.20<1>:w -1:w {align1};
223 (f0.0) jmpi (1) mb_mvp_start;
224 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:ud 3:ud {align1};
225 /* Read MV for MB C */
226 /* bind index 3, read 2 oword (32bytes), msg type: 0(OWord Block Read) */
227 send (16)
228 mb_ind
229 mb_mv0.0<1>:ud
230 NULL
231 data_port(
232 OBR_CACHE_TYPE,
233 OBR_MESSAGE_TYPE,
234 OBR_CONTROL_2,
235 OBR_BIND_IDX,
236 OBR_WRITE_COMMIT_CATEGORY,
237 OBR_HEADER_PRESENT
238 )
239 mlen 1
240 rlen 1
241 {align1};
242 /* TODO: RefID is required after multi-references are added */
243 /* Forward MV */
244 mov (2) mbc_result.4<1>:ud mb_mv0.0<2,2,1>:ud {align1};
245 mov (1) mbc_result.16<1>:w MB_PRED_FLAG {align1};
246
247 jmpi (1) mb_mvp_start;
248 mbd_start:
249 mov (8) mb_msg0.0<1>:ud 0:ud {align1};
250 and.z.f0.0 (1) null:uw input_mb_intra_ub<0,1,0>:ub INTRA_PRED_AVAIL_FLAG_D:uw {align1};
251 (f0.0) mov (2) mbc_result.20<1>:w -1:w {align1};
252 (f0.0) jmpi (1) mb_mvp_start;
253 mov (1) mbc_result.0<1>:d MB_AVAIL {align1};
254 mov (2) tmp_reg0.0<1>:UW orig_xy_ub<2,2,1>:UB {align1};
255 add (2) tmp_reg0.0<1>:w tmp_reg0.0<2,2,1>:w -1:w {align1};
256 mul (1) mb_msg0.8<1>:UD w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
257 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD tmp_reg0.0<0,1,0>:uw {align1};
258 mul (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:UD 24:UD {align1};
259 mov (1) mb_msg0.20<1>:UB thread_id_ub {align1}; /* dispatch id */
260
261 /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
262 send (16)
263 mb_ind
264 mb_wb.0<1>:ud
265 NULL
266 data_port(
267 OBR_CACHE_TYPE,
268 OBR_MESSAGE_TYPE,
269 OBR_CONTROL_4,
270 OBR_BIND_IDX,
271 OBR_WRITE_COMMIT_CATEGORY,
272 OBR_HEADER_PRESENT
273 )
274 mlen 1
275 rlen 2
276 {align1};
277
278 cmp.l.f0.0 (1) null:w mb_intra_wb.16<0,1,0>:uw mb_inter_wb.8<0,1,0>:uw {align1};
279 (f0.0) mov (2) mbc_result.20<1>:w -1:w {align1};
280 (f0.0) jmpi (1) mb_mvp_start;
281
282 add (1) mb_msg0.8<1>:UD mb_msg0.8<0,1,0>:ud 3:ud {align1};
283 /* Read MV for MB D */
284 /* bind index 3, read 2 oword (32bytes), msg type: 0(OWord Block Read) */
285 send (16)
286 mb_ind
287 mb_mv0.0<1>:ub
288 NULL
289 data_port(
290 OBR_CACHE_TYPE,
291 OBR_MESSAGE_TYPE,
292 OBR_CONTROL_2,
293 OBR_BIND_IDX,
294 OBR_WRITE_COMMIT_CATEGORY,
295 OBR_HEADER_PRESENT
296 )
297 mlen 1
298 rlen 1
299 {align1};
300
301 /* TODO: RefID is required after multi-references are added */
302
303 /* Forward MV */
304 mov (2) mbc_result.4<1>:ud mb_mv0.0<2,2,1>:ud {align1};
305 mov (1) mbc_result.16<1>:w MB_PRED_FLAG {align1};
306
307 mb_mvp_start:
308 /*TODO: Add the skip prediction */
309 /* Check whether both MB B and C are inavailable */
310 add (1) tmp_reg0.0<1>:d mbb_result.0<0,1,0>:d mbc_result.0<0,1,0>:d {align1};
311 cmp.z.f0.0 (1) null:d tmp_reg0.0<0,1,0>:d 0:d {align1};
312 (-f0.0) jmpi (1) mb_median_start;
313 cmp.nz.f0.0 (1) null:d mba_result.0<0,1,0>:d 0:d {align1};
314 (f0.0) mov (1) mbb_result.4<1>:ud mba_result.4<0,1,0>:ud {align1};
315 (f0.0) mov (1) mbc_result.4<1>:ud mba_result.4<0,1,0>:ud {align1};
316 (f0.0) mov (1) mbb_result.20<1>:uw mba_result.20<0,1,0>:uw {align1};
317 (f0.0) mov (1) mbc_result.20<1>:uw mba_result.20<0,1,0>:uw {align1};
318 (f0.0) mov (1) mb_mvp_ref.0<1>:ud mba_result.4<0,1,0>:ud {align1};
319 (-f0.0) mov (1) mb_mvp_ref.0<1>:ud 0:ud {align1};
320 jmpi (1) __mb_hwdep_end;
321
322 mb_median_start:
323 /* check whether only one neighbour MB has the same ref ID with the current MB */
324 mov (8) tmp_reg0.0<1>:ud 0:ud {align1};
325 cmp.z.f0.0 (1) null:d mba_result.20<0,1,0>:w 0:w {align1};
326 (f0.0) add (1) tmp_reg0.0<1>:w tmp_reg0.0<0,1,0>:w 1:w {align1};
327 (f0.0) mov (1) tmp_reg0.4<1>:ud mba_result.4<0,1,0>:ud {align1};
328 cmp.z.f0.0 (1) null:d mbb_result.20<0,1,0>:w 0:w {align1};
329 (f0.0) add (1) tmp_reg0.0<1>:w tmp_reg0.0<0,1,0>:w 1:w {align1};
330 (f0.0) mov (1) tmp_reg0.4<1>:ud mbb_result.4<0,1,0>:ud {align1};
331 cmp.z.f0.0 (1) null:d mbc_result.20<0,1,0>:w 0:w {align1};
332 (f0.0) add (1) tmp_reg0.0<1>:w tmp_reg0.0<0,1,0>:w 1:w {align1};
333 (f0.0) mov (1) tmp_reg0.4<1>:ud mbc_result.4<0,1,0>:ud {align1};
334 cmp.e.f0.0 (1) null:d tmp_reg0.0<0,1,0>:w 1:w {align1};
335 (f0.0) mov (1) mb_mvp_ref.0<1>:ud tmp_reg0.4<0,1,0>:ud {align1};
336 (f0.0) jmpi (1) __mb_hwdep_end;
337
338 mov (1) INPUT_ARG0.0<1>:w mba_result.4<0,1,0>:w {align1};
339 mov (1) INPUT_ARG0.4<1>:w mbb_result.4<0,1,0>:w {align1};
340 mov (1) INPUT_ARG0.8<1>:w mbc_result.4<0,1,0>:w {align1};
341 SAVE_RET {align1};
342 jmpi (1) word_imedian;
343 mov (1) mb_mvp_ref.0<1>:w RET_ARG<0,1,0>:w {align1};
344 mov (1) INPUT_ARG0.0<1>:w mba_result.6<0,1,0>:w {align1};
345 mov (1) INPUT_ARG0.4<1>:w mbb_result.6<0,1,0>:w {align1};
346 mov (1) INPUT_ARG0.8<1>:w mbc_result.6<0,1,0>:w {align1};
347 SAVE_RET {align1};
348 jmpi (1) word_imedian;
349 mov (1) mb_mvp_ref.2<1>:w RET_ARG<0,1,0>:w {align1};
350
351 __mb_hwdep_end:
352
353 mov (2) mv_cc_ref.0<1>:w mba_result.4<2,2,1>:w {align1};
354
355 /* Calibrate the ref window for MPEG2 */
356 mov (1) vme_m0.0<1>:W -16:W {align1};
357 mov (1) vme_m0.2<1>:W -12:W {align1};
358
359 mov (1) INPUT_ARG0.0<1>:ud vme_m0.0<0,1,0>:ud {align1};
360 mov (1) INPUT_ARG0.8<1>:ud vme_m0.8<0,1,0>:ud {align1};
361 mov (8) INPUT_ARG1.0<1>:ud pic_ref.0<8,8,1>:ud {align1};
362
363 SAVE_RET {align1};
364 jmpi (1) ref_boundary_check;
365 mov (2) vme_m0.0<1>:w RET_ARG<2,2,1>:w {align1};
366
367 /* m2, get the MV/Mb cost passed from constant buffer when
368 spawning thread by MEDIA_OBJECT */
369 mov (8) vme_m2<1>:UD r1.0<8,8,1>:UD {align1};
370
371 mov (8) vme_msg_2<1>:UD vme_m2.0<8,8,1>:UD {align1};
372
373 /* m3 FWD/BWD cost center*/
374 mov (8) vme_msg_3<1>:UD 0x0:UD {align1};
375
376 /* m4 skip center*/
377 mov (8) vme_msg_4<1>:UD 0x0:UD {align1};
378
379 /* m5 */
380 mov (8) vme_msg_5<1>:UD 0x0:UD {align1};
381
382
383 /* Use the Luma mode */
384 mov (1) tmp_reg0.0<1>:UW LUMA_INTRA_MODE:UW {align1};
385 mov (1) vme_msg_5.5<1>:UB tmp_reg0.0<0,1,0>:UB {align1};
386
387 mov (1) tmp_reg0.0<1>:UW INTRA16_DC_PRED:UW {align1};
388 mov (1) vme_msg_5.4<1>:ub tmp_reg0.0<0,1,0>:UB {align1};
389
390 /* m6 */
391 mov (8) vme_msg_6<1>:UD 0x0:UD {align1};
392 mov (1) vme_msg_6.16<1>:UD INTRA_PREDICTORE_MODE {align1};
393
394 /* the penalty for Intra mode */
395 mov (1) vme_msg_6.28<1>:UD 0x010101:UD {align1};
396
397
398 /* m7 */
399
400 mov (8) vme_msg_7.0<1>:ud 0x0:ud {align1};
401
402 /*
403 * SIC VME message
404 */
405
406 /* Disable Intra8x8/Intra4x4 Intra-prediction */
407 /* m1 */
408 mov (8) vme_m1.0<1>:ud 0x0:UD {align1};
409
410 mov (1) intra_flag<1>:UW 0x0:UW {align1} ;
411 mov (1) tmp_reg0.0<1>:uw LUMA_INTRA_8x8_DISABLE:uw {align1};
412 add (1) tmp_reg0.0<1>:uw tmp_reg0.0<0,1,0>:uw LUMA_INTRA_4x4_DISABLE:uw {align1};
413 mov (1) intra_part_mask_ub<1>:UB tmp_reg0.0<0,1,0>:ub {align1};
414
415 /* assign MB intra struct from the thread payload*/
416 mov (1) mb_intra_struct_ub<1>:UB input_mb_intra_ub<0,1,0>:UB {align1};
417
418 /* Enable DC HAAR component when calculating HARR SATD block */
419 mov (1) tmp_reg0.0<1>:UW DC_HARR_ENABLE:UW {align1};
420 mov (1) vme_m1.30<1>:UB tmp_reg0.0<0,1,0>:UB {align1};
421 mov (8) vme_msg_1<1>:UD vme_m1.0<8,8,1>:UD {align1};
422
423 /* m0 */
424 mov (1) vme_m0.12<1>:UD INTRA_SAD_HAAR:UD {align1}; /* 16x16 Source, Intra_harr */
425 mov (8) vme_msg_0.0<1>:UD vme_m0.0<8,8,1>:UD {align1};
426
427 /* after verification it will be passed by using payload */
428 send (8)
429 vme_msg_ind
430 vme_wb<1>:UD
431 null
432 cre(
433 BIND_IDX_VME,
434 VME_SIC_MESSAGE_TYPE
435 )
436 mlen sic_vme_msg_length
437 rlen vme_wb_length
438 {align1};
439 /*
440 * Oword Block Write message
441 */
442 mov (8) msg_reg0.0<1>:UD obw_m0<8,8,1>:UD {align1};
443
444 mov (1) msg_reg1.0<1>:UD vme_wb.0<0,1,0>:UD {align1};
445 mov (1) msg_reg1.4<1>:UD vme_wb.16<0,1,0>:UD {align1};
446 mov (1) msg_reg1.8<1>:UD vme_wb.20<0,1,0>:UD {align1};
447 mov (1) msg_reg1.12<1>:UD vme_wb.24<0,1,0>:UD {align1};
448
449 /* Distortion, Intra (17-16), */
450 mov (1) msg_reg1.16<1>:UW vme_wb.12<0,1,0>:UW {align1};
451
452 mov (1) msg_reg1.20<1>:UD vme_wb.8<0,1,0>:UD {align1};
453 /* VME clock counts */
454 mov (1) msg_reg1.24<1>:UD vme_wb.28<0,1,0>:UD {align1};
455
456 mov (1) msg_reg1.28<1>:UD obw_m0.8<0,1,0>:UD {align1};
457
458 /* bind index 3, write 2 oword (32bytes), msg type: 8(OWord Block Write) */
459 send (16)
460 msg_ind
461 obw_wb
462 null
463 data_port(
464 OBW_CACHE_TYPE,
465 OBW_MESSAGE_TYPE,
466 OBW_CONTROL_2,
467 OBW_BIND_IDX,
468 OBW_WRITE_COMMIT_CATEGORY,
469 OBW_HEADER_PRESENT
470 )
471 mlen 2
472 rlen obw_wb_length
473 {align1};
474
475 /* IME search */
476 mov (1) vme_m0.12<1>:UD SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR:UD {align1}; /* 16x16 Source, harr */
477 mov (1) vme_m0.22<1>:UW REF_REGION_SIZE {align1}; /* Reference Width&Height, 48x40 */
478
479 mov (1) vme_m0.4<1>:UD vme_m0.0<0,1,0>:UD {align1};
480
481 mov (8) vme_msg_0.0<1>:UD vme_m0.0<8,8,1>:UD {align1};
482
483 mov (1) vme_m1.0<1>:UD ADAPTIVE_SEARCH_ENABLE:ud {align1} ;
484 /* the Max MV number is passed by constant buffer */
485 mov (1) vme_m1.4<1>:UB r4.28<0,1,0>:UB {align1};
486 mov (1) vme_m1.8<1>:UD START_CENTER + SEARCH_PATH_LEN:UD {align1};
487 mov (8) vme_msg_1.0<1>:UD vme_m1.0<8,8,1>:UD {align1};
488
489 /* Setup the Cost center */
490 /* currently four 8x8 share the same cost center */
491 mov (4) vme_m3.0<2>:ud mv_cc_ref.0<0,1,0>:ud {align1};
492 mov (4) vme_m3.4<2>:ud mv_cc_ref.0<0,1,0>:ud {align1};
493
494 mov (8) vme_msg_3<1>:UD vme_m3.0<8,8,1>:UD {align1};
495 mov (8) vme_msg_2<1>:UD vme_m2.0<8,8,1>:UD {align1};
496
497 /* M4/M5 search path */
498 mov (1) vme_msg_4.0<1>:UD 0x01010101:UD {align1};
499 mov (1) vme_msg_4.4<1>:UD 0x10010101:UD {align1};
500 mov (1) vme_msg_4.8<1>:UD 0x0F0F0F0F:UD {align1};
501 mov (1) vme_msg_4.12<1>:UD 0x100F0F0F:UD {align1};
502 mov (1) vme_msg_4.16<1>:UD 0x01010101:UD {align1};
503 mov (1) vme_msg_4.20<1>:UD 0x10010101:UD {align1};
504 mov (1) vme_msg_4.24<1>:UD 0x0F0F0F0F:UD {align1};
505 mov (1) vme_msg_4.28<1>:UD 0x100F0F0F:UD {align1};
506
507 mov (1) vme_msg_5.0<1>:UD 0x01010101:UD {align1};
508 mov (1) vme_msg_5.4<1>:UD 0x10010101:UD {align1};
509 mov (1) vme_msg_5.8<1>:UD 0x0F0F0F0F:UD {align1};
510 mov (1) vme_msg_5.12<1>:UD 0x000F0F0F:UD {align1};
511
512 mov (4) vme_msg_5.16<1>:UD 0x0:UD {align1};
513
514 send (8)
515 vme_msg_ind
516 vme_wb<1>:UD
517 null
518 vme(
519 BIND_IDX_VME,
520 0,
521 0,
522 VME_IME_MESSAGE_TYPE
523 )
524 mlen ime_vme_msg_length
525 rlen vme_wb_length {align1};
526
527 /* Set Macroblock-shape/mode for FBR */
528
529 mov (1) vme_m2.20<1>:UD 0x0:UD {align1};
530 mov (1) vme_m2.21<1>:UB vme_wb.25<0,1,0>:UB {align1};
531 mov (1) vme_m2.22<1>:UB vme_wb.26<0,1,0>:UB {align1};
532
533 and (1) tmp_reg0.0<1>:UW vme_wb.0<0,1,0>:UW 0x03:UW {align1};
534 mov (1) vme_m2.20<1>:UB tmp_reg0.0<0,1,0>:UB {align1};
535
536 /* Send FBR message into CRE */
537
538 mov (8) vme_msg_4.0<1>:UD vme_wb1.0<8,8,1>:UD {align1};
539 mov (8) vme_msg_5.0<1>:ud vme_wb2.0<8,8,1>:ud {align1};
540 mov (8) vme_msg_6.0<1>:ud vme_wb3.0<8,8,1>:ud {align1};
541 mov (8) vme_msg_7.0<1>:ud vme_wb4.0<8,8,1>:ud {align1};
542
543 mov (1) vme_m0.12<1>:UD INTER_SAD_HAAR + SUB_PEL_MODE_HALF + FBR_BME_DISABLE:UD {align1}; /* 16x16 Source, 1/2 pixel, harr, BME disable */
544 /* Bilinear filter */
545 mov (1) tmp_reg0.0<1>:uw 0x04:uw {align1};
546 add (1) vme_m1.30<1>:ub vme_m1.30<0,1,0>:ub tmp_reg0.0<0,1,0>:ub {align1};
547
548 mov (8) vme_msg_0.0<1>:UD vme_m0.0<8,8,1>:UD {align1};
549 mov (8) vme_msg_1.0<1>:UD vme_m1.0<8,8,1>:UD {align1};
550
551 mov (8) vme_msg_2.0<1>:UD vme_m2.0<8,8,1>:UD {align1};
552 mov (8) vme_msg_3.0<1>:UD vme_m3.0<8,8,1>:UD {align1};
553
554 /* after verification it will be passed by using payload */
555 send (8)
556 vme_msg_ind
557 vme_wb<1>:UD
558 null
559 cre(
560 BIND_IDX_VME,
561 VME_FBR_MESSAGE_TYPE
562 )
563 mlen fbr_vme_msg_length
564 rlen vme_wb_length
565 {align1};
566
567 and.z.f0.0 (1) null:uw mb_hwdep<0,1,0>:uw 0x04:uw {align1};
568 (-f0.0) jmpi (1) vme_run_again;
569 nop;
570 vme_mv_output:
571
572 add (1) obw_m0.8<1>:UD obw_m0.8<0,1,0>:UD 0x02:UD {align1};
573 mov (8) msg_reg0.0<1>:UD obw_m0<8,8,1>:UD {align1};
574 /* write FME info */
575 mov (1) msg_reg1.0<1>:UD vme_wb.0<0,1,0>:UD {align1};
576
577 mov (1) msg_reg1.4<1>:UD vme_wb.24<0,1,0>:UD {align1};
578 /* Inter distortion of FME */
579 mov (1) msg_reg1.8<1>:UD vme_wb.8<0,1,0>:UD {align1};
580
581 mov (1) msg_reg1.12<1>:UD vme_m2.20<0,1,0>:UD {align1};
582
583 /* bind index 3, write oword (16bytes), msg type: 8(OWord Block Write) */
584 send (16)
585 msg_ind
586 obw_wb
587 null
588 data_port(
589 OBW_CACHE_TYPE,
590 OBW_MESSAGE_TYPE,
591 OBW_CONTROL_0,
592 OBW_BIND_IDX,
593 OBW_WRITE_COMMIT_CATEGORY,
594 OBW_HEADER_PRESENT
595 )
596 mlen 2
597 rlen obw_wb_length
598 {align1};
599
600 /* Write FME/BME MV */
601 add (1) obw_m0.8<1>:UD obw_m0.8<0,1,0>:UD 0x01:UD {align1};
602 mov (8) msg_reg0.0<1>:UD obw_m0.0<8,8,1>:UD {align1};
603
604
605 mov (8) msg_reg1.0<1>:UD vme_wb1.0<8,8,1>:UD {align1};
606 mov (8) msg_reg2.0<1>:ud vme_wb2.0<8,8,1>:ud {align1};
607 mov (8) msg_reg3.0<1>:ud vme_wb3.0<8,8,1>:ud {align1};
608 mov (8) msg_reg4.0<1>:ud vme_wb4.0<8,8,1>:ud {align1};
609 /* bind index 3, write 2 oword (32 bytes), msg type: 8(OWord Block Write) */
610 send (16)
611 msg_ind
612 obw_wb
613 null
614 data_port(
615 OBW_CACHE_TYPE,
616 OBW_MESSAGE_TYPE,
617 OBW_CONTROL_2,
618 OBW_BIND_IDX,
619 OBW_WRITE_COMMIT_CATEGORY,
620 OBW_HEADER_PRESENT
621 )
622 mlen 2
623 rlen obw_wb_length
624 {align1};
625
626 /* Write FME/BME RefID */
627 add (1) obw_m0.8<1>:UD obw_m0.8<0,1,0>:UD 0x08:UD {align1};
628 mov (8) msg_reg0.0<1>:UD obw_m0<8,8,1>:UD {align1};
629
630 mov (8) msg_reg1.0<1>:UD vme_wb6.0<8,8,1>:UD {align1};
631
632 /* bind index 3, write 2 oword (32bytes), msg type: 8(OWord Block Write) */
633 send (16)
634 msg_ind
635 obw_wb
636 null
637 data_port(
638 OBW_CACHE_TYPE,
639 OBW_MESSAGE_TYPE,
640 OBW_CONTROL_2,
641 OBW_BIND_IDX,
642 OBW_WRITE_COMMIT_CATEGORY,
643 OBW_HEADER_PRESENT
644 )
645 mlen 2
646 rlen obw_wb_length
647 {align1};
648
649 /* Issue message fence so that the previous write message is committed */
650 send (16)
651 mb_ind
652 mb_wb.0<1>:ud
653 NULL
654 data_port(
655 OBR_CACHE_TYPE,
656 OBR_MESSAGE_FENCE,
657 OBR_MF_COMMIT,
658 OBR_BIND_IDX,
659 OBR_WRITE_COMMIT_CATEGORY,
660 OBR_HEADER_PRESENT
661 )
662 mlen 1
663 rlen 1
664 {align1};
665
666 __EXIT:
667 /*
668 * kill thread
669 */
670 mov (8) ts_msg_reg0<1>:UD r0<8,8,1>:UD {align1};
671 send (16) ts_msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};
672
673
674 nop ;
675 nop ;
676
677 word_imedian:
678 cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.4<0,1,0>:w {align1};
679 (f0.0) jmpi (1) cmp_a_ge_b;
680 cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
681 (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
682 (f0.0) jmpi (1) cmp_end;
683 cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
684 (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
685 (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
686 jmpi (1) cmp_end;
687 cmp_a_ge_b:
688 cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
689 (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
690 (f0.0) jmpi (1) cmp_end;
691 cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
692 (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
693 (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
694 cmp_end:
695 RETURN {align1};
696
697 nop;
698 nop;
699 ref_boundary_check:
700
701 /* The left/up coordinate of reference window */
702 add (2) TEMP_VAR0.0<1>:w INPUT_ARG0.8<2,2,1>:w INPUT_ARG0.0<2,2,1>:w {align1};
703 /* The right/bottom coordinate of reference window */
704 add (1) TEMP_VAR0.16<1>:w TEMP_VAR0.0<0,1,0>:w 48:w {align1};
705 add (1) TEMP_VAR0.18<1>:w TEMP_VAR0.2<0,1,0>:w 40:w {align1};
706
707 /* Firstly the MV range is checked */
708 mul (2) TEMP_VAR1.16<1>:w INPUT_ARG1.16<2,2,1>:w -1:w {align1};
709 add (2) TEMP_VAR1.0<1>:w INPUT_ARG0.8<2,2,1>:w TEMP_VAR1.16<2,2,1>:w {align1};
710 add (2) TEMP_VAR1.4<1>:w INPUT_ARG0.8<2,2,1>:w INPUT_ARG1.16<2,2,1>:w {align1};
711
712 cmp.l.f0.0 (1) null:w TEMP_VAR0.0<0,1,0>:w TEMP_VAR1.0<0,1,0>:w {align1};
713 (f0.0) mov (1) TEMP_VAR0.0<1>:w TEMP_VAR1.0<0,1,0>:w {align1};
714 cmp.g.f0.0 (1) null:w TEMP_VAR0.16<0,1,0>:w TEMP_VAR1.4<0,1,0>:w {align1};
715 (f0.0) add (1) TEMP_VAR0.0<1>:w TEMP_VAR1.4<0,1,0>:w -48:w {align1};
716 cmp.l.f0.0 (1) null:w TEMP_VAR0.2<0,1,0>:w TEMP_VAR1.2<0,1,0>:w {align1};
717 (f0.0) mov (1) TEMP_VAR0.2<1>:w TEMP_VAR1.2<0,1,0>:w {align1};
718 cmp.g.f0.0 (1) null:w TEMP_VAR0.18<0,1,0>:w TEMP_VAR1.6<0,1,0>:w {align1};
719 (f0.0) add (1) TEMP_VAR0.2<1>:w TEMP_VAR1.6<0,1,0>:w -40:w {align1};
720
721 x_left_cmp:
722 cmp.l.f0.0 (1) null:w TEMP_VAR0.0<0,1,0>:w 0:w {align1};
723 (-f0.0) jmpi (1) x_right_cmp;
724 (f0.0) mov (1) TEMP_VAR0.0<1>:w 0:w {align1};
725 jmpi (1) y_top_cmp;
726 x_right_cmp:
727 cmp.g.f0.0 (1) null:w TEMP_VAR0.16<0,1,0>:w INPUT_ARG1.0<0,1,0>:w {align1};
728 (-f0.0) jmpi (1) y_top_cmp;
729 (f0.0) add (1) TEMP_VAR0.0<1>:w INPUT_ARG1.0<0,1,0>:w -48:w {align1};
730 y_top_cmp:
731 cmp.l.f0.0 (1) null:w TEMP_VAR0.2<0,1,0>:w 0:w {align1};
732 (-f0.0) jmpi (1) y_bottom_cmp;
733 (f0.0) mov (1) TEMP_VAR0.2<1>:w 0:w {align1};
734 jmpi (1) y_bottom_end;
735 y_bottom_cmp:
736 cmp.g.f0.0 (1) null:w TEMP_VAR0.18<0,1,0>:w INPUT_ARG1.2<0,1,0>:w {align1};
737 (f0.0) add (1) TEMP_VAR0.2<1>:w INPUT_ARG1.2<0,1,0>:w -40:w {align1};
738
739 y_bottom_end:
740 mul (2) TEMP_VAR1.0<1>:w INPUT_ARG0.8<2,2,1>:w -1:w {align1};
741 add (2) RET_ARG<1>:w TEMP_VAR0.0<2,2,1>:w TEMP_VAR1.0<2,2,1>:w {align1};
742 RETURN {align1};
743 nop;
744 nop;
745
746 vme_run_again:
747
748 asr (2) mb_ref_win.0<1>:w mb_mvp_ref.0<2,2,1>:w 2:w {align1};
749 mov (2) tmp_reg0.0<1>:w mb_ref_win.0<2,2,1>:w {align1};
750 add (2) mb_ref_win.8<1>:w mb_ref_win.0<2,2,1>:w 3:w {align1};
751 and (2) mb_ref_win.16<1>:uw mb_ref_win.8<2,2,1>:uw 0xFFFC:uw {align1};
752
753 cmp.l.f0.0 (1) null:w tmp_reg0.0<0,1,0>:w 0:w {align1};
754 (f0.0) mul (1) tmp_reg0.0<1>:w tmp_reg0.0<0,1,0>:w -1:w {align1};
755 cmp.l.f0.0 (1) null:w tmp_reg0.2<0,1,0>:w 0:w {align1};
756 (f0.0) mul (1) tmp_reg0.2<1>:w tmp_reg0.2<0,1,0>:w -1:w {align1};
757
758 cmp.ge.f0.0 (1) null:w tmp_reg0.0<0,1,0>:w 4:w {align1};
759 (f0.0) jmpi (1) vme_start;
760 cmp.ge.f0.0 (1) null:w tmp_reg0.2<0,1,0>:w 4:w {align1};
761 (f0.0) jmpi (1) vme_start;
762
763 jmpi (1) vme_done;
764
765 vme_start:
766 mov (8) tmp_vme_wb0.0<1>:ud vme_wb0.0<8,8,1>:ud {align1};
767 mov (8) tmp_vme_wb1.0<1>:ud vme_wb1.0<8,8,1>:ud {align1};
768
769 /* Calibrate the ref window for MPEG2 */
770 mov (1) vme_m0.0<1>:W -16:W {align1};
771 mov (1) vme_m0.2<1>:W -12:W {align1};
772 mov (1) INPUT_ARG0.8<1>:ud vme_m0.8<0,1,0>:ud {align1};
773 add (2) INPUT_ARG0.0<1>:w vme_m0.0<2,2,1>:w mb_ref_win.16<2,2,1>:w {align1};
774 mov (8) INPUT_ARG1.0<1>:ud pic_ref.0<8,8,1>:ud {align1};
775
776 SAVE_RET {align1};
777 jmpi (1) ref_boundary_check;
778 mov (2) vme_m0.0<1>:w RET_ARG<2,2,1>:w {align1};
779
780 /* IME search */
781 mov (1) vme_m0.12<1>:UD SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR:UD {align1}; /* 16x16 Source, harr */
782 mov (1) vme_m0.22<1>:UW REF_REGION_SIZE {align1}; /* Reference Width&Height, 48x40 */
783
784 mov (1) vme_m0.4<1>:UD vme_m0.0<0,1,0>:UD {align1};
785
786 mov (8) vme_msg_0.0<1>:UD vme_m0.0<8,8,1>:UD {align1};
787
788 mov (8) vme_m1.0<1>:ud 0x0:UD {align1};
789
790 mov (1) vme_m1.0<1>:UD ADAPTIVE_SEARCH_ENABLE:ud {align1} ;
791 /* the Max MV number is passed by constant buffer */
792 mov (1) vme_m1.4<1>:UB r4.28<0,1,0>:UB {align1};
793 mov (1) vme_m1.8<1>:UD START_CENTER + SEARCH_PATH_LEN:UD {align1};
794 mov (8) vme_msg_1.0<1>:UD vme_m1.0<8,8,1>:UD {align1};
795
796 /* Setup the Cost center */
797 /* currently four 8x8 share the same cost center */
798 mov (4) vme_m3.0<2>:ud mv_cc_ref.0<0,1,0>:ud {align1};
799 mov (4) vme_m3.4<2>:ud mv_cc_ref.0<0,1,0>:ud {align1};
800
801 mov (8) vme_msg_3<1>:UD vme_m3.0<8,8,1>:UD {align1};
802 mov (8) vme_msg_2<1>:UD vme_m2.0<8,8,1>:UD {align1};
803
804 /* M4/M5 search path */
805 mov (1) vme_msg_4.0<1>:UD 0x01010101:UD {align1};
806 mov (1) vme_msg_4.4<1>:UD 0x10010101:UD {align1};
807 mov (1) vme_msg_4.8<1>:UD 0x0F0F0F0F:UD {align1};
808 mov (1) vme_msg_4.12<1>:UD 0x100F0F0F:UD {align1};
809 mov (1) vme_msg_4.16<1>:UD 0x01010101:UD {align1};
810 mov (1) vme_msg_4.20<1>:UD 0x10010101:UD {align1};
811 mov (1) vme_msg_4.24<1>:UD 0x0F0F0F0F:UD {align1};
812 mov (1) vme_msg_4.28<1>:UD 0x100F0F0F:UD {align1};
813
814 mov (1) vme_msg_5.0<1>:UD 0x01010101:UD {align1};
815 mov (1) vme_msg_5.4<1>:UD 0x10010101:UD {align1};
816 mov (1) vme_msg_5.8<1>:UD 0x0F0F0F0F:UD {align1};
817 mov (1) vme_msg_5.12<1>:UD 0x000F0F0F:UD {align1};
818
819 mov (4) vme_msg_5.16<1>:UD 0x0:UD {align1};
820
821 send (8)
822 vme_msg_ind
823 vme_wb<1>:UD
824 null
825 vme(
826 BIND_IDX_VME,
827 0,
828 0,
829 VME_IME_MESSAGE_TYPE
830 )
831 mlen ime_vme_msg_length
832 rlen vme_wb_length {align1};
833
834 /* Set Macroblock-shape/mode for FBR */
835
836 mov (1) vme_m2.20<1>:UD 0x0:UD {align1};
837 mov (1) vme_m2.21<1>:UB vme_wb.25<0,1,0>:UB {align1};
838 mov (1) vme_m2.22<1>:UB vme_wb.26<0,1,0>:UB {align1};
839
840 and (1) tmp_reg0.0<1>:UW vme_wb.0<0,1,0>:UW 0x03:UW {align1};
841 mov (1) vme_m2.20<1>:UB tmp_reg0.0<0,1,0>:UB {align1};
842
843 /* Send FBR message into CRE */
844
845 mov (8) vme_msg_4.0<1>:UD vme_wb1.0<8,8,1>:UD {align1};
846 mov (8) vme_msg_5.0<1>:ud vme_wb2.0<8,8,1>:ud {align1};
847 mov (8) vme_msg_6.0<1>:ud vme_wb3.0<8,8,1>:ud {align1};
848 mov (8) vme_msg_7.0<1>:ud vme_wb4.0<8,8,1>:ud {align1};
849
850 mov (1) vme_m0.12<1>:UD INTER_SAD_HAAR + SUB_PEL_MODE_HALF + FBR_BME_DISABLE:UD {align1}; /* 16x16 Source, 1/2 pixel, harr, BME disable */
851 /* Bilinear filter */
852 mov (1) tmp_reg0.0<1>:uw 0x04:uw {align1};
853 add (1) vme_m1.30<1>:ub vme_m1.30<0,1,0>:ub tmp_reg0.0<0,1,0>:ub {align1};
854
855 mov (8) vme_msg_0.0<1>:UD vme_m0.0<8,8,1>:UD {align1};
856 mov (8) vme_msg_1.0<1>:UD vme_m1.0<8,8,1>:UD {align1};
857
858 mov (8) vme_msg_2.0<1>:UD vme_m2.0<8,8,1>:UD {align1};
859 mov (8) vme_msg_3.0<1>:UD vme_m3.0<8,8,1>:UD {align1};
860
861 /* after verification it will be passed by using payload */
862 send (8)
863 vme_msg_ind
864 vme_wb<1>:UD
865 null
866 cre(
867 BIND_IDX_VME,
868 VME_FBR_MESSAGE_TYPE
869 )
870 mlen fbr_vme_msg_length
871 rlen vme_wb_length
872 {align1};
873
874 cmp.l.f0.0 (1) null:uw vme_wb0.8<0,1,0>:uw tmp_vme_wb0.8<0,1,0>:uw {align1};
875 (f0.0) jmpi (1) vme_done;
876 mov (8) vme_wb0.0<1>:ud tmp_vme_wb0.0<8,8,1>:ud {align1};
877 mov (8) vme_wb1.0<1>:ud tmp_vme_wb1.0<8,8,1>:ud {align1};
878
879 vme_done:
880 jmpi (1) vme_mv_output;
881 nop;
882 nop;
883 nop;
884