Debian Codegraph @

src/shaders/h264/ildb/save_Left_UV_8x2T_Mbaff.asm

raw
1 /*
2 * Copyright © <2010>, Intel Corporation.
3 *
4 * Permission is hereby granted, free of charge, to any person obtaining a
5 * copy of this software and associated documentation files (the
6 * "Software"), to deal in the Software without restriction, including
7 * without limitation the rights to use, copy, modify, merge, publish,
8 * distribute, sub license, and/or sell copies of the Software, and to
9 * permit persons to whom the Software is furnished to do so, subject to
10 * the following conditions:
11 *
12 * The above copyright notice and this permission notice (including the
13 * next paragraph) shall be included in all copies or substantial portions
14 * of the Software.
15 *
16 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
17 * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
18 * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
19 * IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
20 * ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
21 * TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
22 * SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
23 *
24 * This file was originally licensed under the following license
25 *
26 * Licensed under the Apache License, Version 2.0 (the "License");
27 * you may not use this file except in compliance with the License.
28 * You may obtain a copy of the License at
29 *
30 * http://www.apache.org/licenses/LICENSE-2.0
31 *
32 * Unless required by applicable law or agreed to in writing, software
33 * distributed under the License is distributed on an "AS IS" BASIS,
34 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
35 * See the License for the specific language governing permissions and
36 * limitations under the License.
37 *
38 */
39 // Module name: save_Left_UV_8x2T.asm
40 //
41 // Transpose 8x2 to 2x8 UV data and write to memory
42 //
43 //----------------------------------------------------------------
44 // Symbols need to be defined before including this module
45 //
46 // Left MB region:
47 // PREV_MB_UW: Base=ryy ElementSize=2 SrcRegion=REGION(8,1) Type=uw
48
49 // Binding table index:
50 // BI_SRC_UV: Binding table index of UV surface (NV12)
51 //
52 // Temp buffer:
53 // BUF_W: BUF_W Base=rxx ElementSize=1 SrcRegion=REGION(8,1) Type=uw
54 //
55 //
56 #if defined(_DEBUG)
57 mov (1) EntrySignatureC:w 0xDDD6:w
58 #endif
59
60 and.z.f0.0 (1) null:w r[ECM_AddrReg, BitFlags]:ub FieldModeCurrentMbFlag:w
61
62 and.nz.f0.1 (1) NULLREGW BitFields:w BotFieldFlag:w
63
64 // Transpose U/V, save them to MRFs in NV12 format
65 mov (1) MSGSRC.0:ud ORIX_LEFT:w { NoDDClr } // Block origin
66 asr (1) MSGSRC.1:ud ORIY_LEFT:w 1:w { NoDDClr, NoDDChk } // NV12 U+V block origin y = half of Y comp
67 mov (1) MSGSRC.2:ud 0x00070003:ud { NoDDChk } // NV12 U+V block width and height (4x8)
68
69
70 // 16x2 UV src in GRF (each pix is specified as yx)
71 // +-----------------------+-----------------------+-----------------------+-----------------------+
72 // |71 71 61 61 51 51 41 41 31 31 21 21 11 11 01 01 70 70 60 60 50 50 40 40 30 30 20 20 10 10 00 00|
73 // +-----------------------+-----------------------+-----------------------+-----------------------+
74 //
75 // First step (8) <1> <=== <8;4,1>:w
76 // +-----------------------+-----------------------+-----------------------+-----------------------+
77 // |71 71 61 61 51 51 41 41 70 70 60 60 50 50 40 40 31 31 21 21 11 11 01 01 30 30 20 20 10 10 00 00|
78 // +-----------------------+-----------------------+-----------------------+-----------------------+
79 mov (8) BUF_W(0,0)<1> PREV_MB_UW(0,0)<8;4,1> { NoDDClr }
80 mov (8) BUF_W(0,8)<1> PREV_MB_UW(0,4)<8;4,1> { NoDDChk }
81
82 // Second step (8) <1> <=== <1;2,4>
83 // +-----------------------+-----------------------+-----------------------+-----------------------+
84 // |71 71 70 70 61 61 60 60 51 51 50 50 41 41 40 40 31 31 30 30 21 21 20 20 11 11 10 10 01 01 00 00|
85 // +-----------------------+-----------------------+-----------------------+-----------------------+
86 mov (8) MSGPAYLOADW(0,0)<1> BUF_W(0,0)<1;2,4>
87 mov (8) MSGPAYLOADW(0,8)<1> BUF_W(0,8)<1;2,4>
88
89 // Transposed U+V in NV12 in 4x8 is ready for writting to dataport.
90
91 // Set message descriptor
92
93 (f0.0) if (1) ELSE_UV_8X2T
94
95 // Frame picture
96 mov (1) MSGDSC MSG_LEN(1)+DWBWMSGDSC+BI_DEST_UV:ud // Write 1 GRF to DEST_UV
97
98 (f0.1) add (1) MSGSRC.1:d MSGSRC.1:d 8:w // Add vertical offset 8 for bot MB in MBAFF mode
99
100 ELSE_UV_8X2T:
101 else (1) ENDIF_UV_8X2T
102
103 // Field picture
104 (f0.1) mov (1) MSGDSC MSG_LEN(1)+DWBWMSGDSC+ENMSGDSCBF+BI_DEST_UV:ud // Write 1 GRF to DEST_UV bottom field
105 (-f0.1) mov (1) MSGDSC MSG_LEN(1)+DWBWMSGDSC+ENMSGDSCTF+BI_DEST_UV:ud // Write 1 GRF to DEST_UV top field
106
107 asr (1) MSGSRC.1:d MSGSRC.1:d 1:w // Reduce y by half in field access mode
108
109 endif
110 ENDIF_UV_8X2T:
111
112 send (8) null:ud MSGHDR MSGSRC<8;8,1>:ud DAPWRITE MSGDSC