Debian Codegraph @

src/shaders/h264/ildb/saveNV12_16x4T.asm

raw
1 /*
2 * Copyright © <2010>, Intel Corporation.
3 *
4 * Permission is hereby granted, free of charge, to any person obtaining a
5 * copy of this software and associated documentation files (the
6 * "Software"), to deal in the Software without restriction, including
7 * without limitation the rights to use, copy, modify, merge, publish,
8 * distribute, sub license, and/or sell copies of the Software, and to
9 * permit persons to whom the Software is furnished to do so, subject to
10 * the following conditions:
11 *
12 * The above copyright notice and this permission notice (including the
13 * next paragraph) shall be included in all copies or substantial portions
14 * of the Software.
15 *
16 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
17 * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
18 * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
19 * IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
20 * ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
21 * TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
22 * SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
23 *
24 * This file was originally licensed under the following license
25 *
26 * Licensed under the Apache License, Version 2.0 (the "License");
27 * you may not use this file except in compliance with the License.
28 * You may obtain a copy of the License at
29 *
30 * http://www.apache.org/licenses/LICENSE-2.0
31 *
32 * Unless required by applicable law or agreed to in writing, software
33 * distributed under the License is distributed on an "AS IS" BASIS,
34 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
35 * See the License for the specific language governing permissions and
36 * limitations under the License.
37 *
38 */
39 // Module name: saveNV12_16x4T.asm
40 //
41 // Transpose 16x4 to 4x16 YNV12 data and write to memory
42 //
43 //----------------------------------------------------------------
44 // Symbols need to be defined before including this module
45 //
46 // Left MB region:
47 // PREV_MB_YB: Base=rxx ElementSize=1 SrcRegion=REGION(16,1) Type=ub
48 // PREV_MB_UW: Base=ryy ElementSize=2 SrcRegion=REGION(8,1) Type=uw
49
50 // Binding table index:
51 // BI_SRC_Y: Binding table index of Y surface
52 // BI_SRC_UV: Binding table index of UV surface (NV12)
53 //
54 // Temp buffer:
55 // BUF_B: BUF_B Base=rxx ElementSize=1 SrcRegion=REGION(16,1) Type=ub
56 // BUF_W: BUF_W Base=rxx ElementSize=1 SrcRegion=REGION(8,1) Type=uw
57 //
58 //
59 #if defined(_DEBUG)
60 mov (1) EntrySignatureC:w 0xDDD6:w
61 #endif
62
63 mov (2) MSGSRC.0<1>:ud ORIX_LEFT<2;2,1>:w // Block origin
64 mov (1) MSGSRC.2<1>:ud 0x000F0003:ud // 4x16
65
66 // Transpose Y, save them to MRFs
67
68 // 16x4 Y src in GRF (each pix is specified as yx)
69 // +-----------------------+-----------------------+-----------------------+-----------------------+
70 // |f1 e1 d1 c1 b1 a1 91 81 71 61 51 41 31 21 11 01 f0 e0 d0 c0 b0 a0 90 80 70 60 50 40 30 20 10 00|
71 // +-----------------------+-----------------------+-----------------------+-----------------------+
72 // |f3 e3 d3 c3 b3 a3 93 83 73 63 53 43 33 23 13 03 f2 e2 d2 c2 b2 a2 92 82 72 62 52 42 32 22 12 02|
73 // +-----------------------+-----------------------+-----------------------+-----------------------+
74 //
75 // First step (16) <1> <=== <16;4,1>
76 // +-----------------------+-----------------------+-----------------------+-----------------------+
77 // |73 63 53 43 72 62 52 42 71 61 51 41 70 60 50 40 33 23 13 03 32 22 12 02 31 21 11 01 30 20 10 00|
78 // +-----------------------+-----------------------+-----------------------+-----------------------+
79 // |f3 e3 d3 c3 f2 e2 d2 c2 f1 e1 d1 c1 f0 e0 d0 c0 b3 a3 93 83 b2 a2 92 82 b1 a1 91 81 b0 a0 90 80|
80 // +-----------------------+-----------------------+-----------------------+-----------------------+
81
82 // The first step
83 mov (16) BUF_B(0,0)<1> PREV_MB_YB(0,0)<16;4,1>
84 mov (16) BUF_B(0,16)<1> PREV_MB_YB(0,4)<16;4,1>
85 mov (16) BUF_B(1,0)<1> PREV_MB_YB(0,8)<16;4,1>
86 mov (16) BUF_B(1,16)<1> PREV_MB_YB(0,12)<16;4,1>
87
88 //
89 // Second step (16) <1> <=== <1;4,4>
90 // +-----------------------+-----------------------+-----------------------+-----------------------+
91 // |73 72 71 70 63 62 61 60 53 52 51 50 43 42 41 40 33 32 31 30 23 22 21 20 13 12 11 10 03 02 01 00|
92 // +-----------------------+-----------------------+-----------------------+-----------------------+
93 // |f3 f2 f1 f0 e3 e2 e1 e0 d3 d2 d1 d0 c3 c2 c1 c0 b3 b2 b1 b0 a3 a2 a1 a0 93 92 91 90 83 82 81 80|
94 // +-----------------------+-----------------------+-----------------------+-----------------------+
95 //
96 // The second step
97 // mov (16) MSGPAYLOADB(0,0)<1> BUF_B(0,0)<32;8,4> // Read 2 rows, write 1 row
98 // mov (16) MSGPAYLOADB(0,16)<1> BUF_B(0,1)<32;8,4>
99 // mov (16) MSGPAYLOADB(1,0)<1> BUF_B(0,2)<32;8,4>
100 // mov (16) MSGPAYLOADB(1,16)<1> BUF_B(0,3)<32;8,4>
101
102 mov (16) MSGPAYLOADB(0,0)<1> BUF_B(0,0)<1;4,4>
103 mov (16) MSGPAYLOADB(0,16)<1> BUF_B(0,16)<1;4,4>
104 mov (16) MSGPAYLOADB(1,0)<1> BUF_B(1,0)<1;4,4>
105 mov (16) MSGPAYLOADB(1,16)<1> BUF_B(1,16)<1;4,4>
106
107 // Transposed Y in 4x16 is ready for writting to dataport.
108 //
109 send (8) NULLREG MSGHDR MSGSRC<8;8,1>:ud DAPWRITE MSG_LEN(2)+DWBWMSGDSC+BI_DEST_Y // Write 2 GRFs
110
111
112
113 /////////////////////////////////////////////////////////////////////////////////////////////////////
114
115 // Transpose U/V, save them to MRFs in NV12 format
116 asr (1) MSGSRC.1:ud MSGSRC.1:ud 1:w // NV12 U+V block origin y = half of Y comp
117 mov (1) MSGSRC.2<1>:ud 0x00070003:ud // NV12 U+V block width and height (4x8)
118
119
120 // 16x2 UV src in GRF (each pix is specified as yx)
121 // +-----------------------+-----------------------+-----------------------+-----------------------+
122 // |71 71 61 61 51 51 41 41 31 31 21 21 11 11 01 01 70 70 60 60 50 50 40 40 30 30 20 20 10 10 00 00|
123 // +-----------------------+-----------------------+-----------------------+-----------------------+
124 //
125 // First step (8) <1> <=== <8;4,1>:w
126 // +-----------------------+-----------------------+-----------------------+-----------------------+
127 // |71 71 61 61 51 51 41 41 70 70 60 60 50 50 40 40 31 31 21 21 11 11 01 01 30 30 20 20 10 10 00 00|
128 // +-----------------------+-----------------------+-----------------------+-----------------------+
129 mov (8) BUF_W(0,0)<1> PREV_MB_UW(0,0)<8;4,1>
130 mov (8) BUF_W(0,8)<1> PREV_MB_UW(0,4)<8;4,1>
131
132 // Second step (8) <1> <=== <1;2,4>
133 // +-----------------------+-----------------------+-----------------------+-----------------------+
134 // |71 71 70 70 61 61 60 60 51 51 50 50 41 41 40 40 31 31 30 30 21 21 20 20 11 11 10 10 01 01 00 00|
135 // +-----------------------+-----------------------+-----------------------+-----------------------+
136 mov (8) MSGPAYLOADW(0,0)<1> BUF_W(0,0)<1;2,4>
137 mov (8) MSGPAYLOADW(0,8)<1> BUF_W(0,8)<1;2,4>
138
139 // Transposed U+V in NV12 in 4x8 is ready for writting to dataport.
140
141 send (8) NULLREG MSGHDR MSGSRC<8;8,1>:ud DAPWRITE MSG_LEN(1)+DWBWMSGDSC+BI_DEST_UV // Write 1 GRF
142
143