Debian Codegraph @

m4/stddef_h.m4

raw
1 # stddef_h.m4 serial 14
2 dnl Copyright (C) 2009-2024 Free Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
6
7 dnl A placeholder for <stddef.h>, for platforms that have issues.
8
9 AC_DEFUN_ONCE([gl_STDDEF_H],
10 [
11 AC_REQUIRE([gl_STDDEF_H_DEFAULTS])
12 AC_REQUIRE([gt_TYPE_WCHAR_T])
13
14 dnl Persuade OpenBSD <stddef.h> to declare max_align_t.
15 AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
16
17 GL_GENERATE_STDDEF_H=false
18
19 dnl Test whether the type max_align_t exists and whether its alignment
20 dnl "is as great as is supported by the implementation in all contexts".
21 AC_CACHE_CHECK([for good max_align_t],
22 [gl_cv_type_max_align_t],
23 [AC_COMPILE_IFELSE(
24 [AC_LANG_PROGRAM(
25 [[/* On FreeBSD 12.0/x86, max_align_t defined by <stddef.h> has
26 the correct alignment with the default (wrong) definition of
27 _Alignof, but a wrong alignment as soon as we activate an
28 ISO C compliant _Alignof definition. */
29 #if ((defined __GNUC__ && 4 <= __GNUC__) || defined __clang__) && !defined __cplusplus
30 #define _Alignof(type) __builtin_offsetof (struct { char __a; type __b; }, __b)
31 #endif
32 #include <stddef.h>
33 unsigned int s = sizeof (max_align_t);
34 #if defined __GNUC__ || defined __clang__ || defined __IBM__ALIGNOF__
35 int check1[2 * (__alignof__ (double) <= __alignof__ (max_align_t)) - 1];
36 int check2[2 * (__alignof__ (long double) <= __alignof__ (max_align_t)) - 1];
37 #endif
38 typedef struct { char a; max_align_t b; } max_helper;
39 typedef struct { char a; long b; } long_helper;
40 typedef struct { char a; double b; } double_helper;
41 typedef struct { char a; long double b; } long_double_helper;
42 int check3[2 * (offsetof (long_helper, b) <= offsetof (max_helper, b)) - 1];
43 int check4[2 * (offsetof (double_helper, b) <= offsetof (max_helper, b)) - 1];
44 int check5[2 * (offsetof (long_double_helper, b) <= offsetof (max_helper, b)) - 1];
45 ]])],
46 [gl_cv_type_max_align_t=yes],
47 [gl_cv_type_max_align_t=no])
48 ])
49 if test $gl_cv_type_max_align_t = no; then
50 HAVE_MAX_ALIGN_T=0
51 GL_GENERATE_STDDEF_H=true
52 fi
53
54 if test $gt_cv_c_wchar_t = no; then
55 HAVE_WCHAR_T=0
56 GL_GENERATE_STDDEF_H=true
57 fi
58
59 AC_CACHE_CHECK([whether NULL can be used in arbitrary expressions],
60 [gl_cv_decl_null_works],
61 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
62 int test[2 * (sizeof NULL == sizeof (void *)) -1];
63 ]])],
64 [gl_cv_decl_null_works=yes],
65 [gl_cv_decl_null_works=no])])
66 if test $gl_cv_decl_null_works = no; then
67 REPLACE_NULL=1
68 GL_GENERATE_STDDEF_H=true
69 fi
70
71 AC_CACHE_CHECK([for unreachable],
72 [gl_cv_func_unreachable],
73 [AC_LINK_IFELSE(
74 [AC_LANG_PROGRAM(
75 [[#include <stddef.h>
76 ]],
77 [[unreachable ();
78 ]])],
79 [gl_cv_func_unreachable=yes],
80 [gl_cv_func_unreachable=no])
81 ])
82 if test $gl_cv_func_unreachable = no; then
83 GL_GENERATE_STDDEF_H=true
84 fi
85
86 if $GL_GENERATE_STDDEF_H; then
87 gl_NEXT_HEADERS([stddef.h])
88 fi
89 ])
90
91 # gl_STDDEF_MODULE_INDICATOR([modulename])
92 # sets the shell variable that indicates the presence of the given module
93 # to a C preprocessor expression that will evaluate to 1.
94 # This macro invocation must not occur in macros that are AC_REQUIREd.
95 AC_DEFUN([gl_STDDEF_MODULE_INDICATOR],
96 [
97 dnl Ensure to expand the default settings once only.
98 gl_STDDEF_H_REQUIRE_DEFAULTS
99 gl_MODULE_INDICATOR_SET_VARIABLE([$1])
100 ])
101
102 # Initializes the default values for AC_SUBSTed shell variables.
103 # This macro must not be AC_REQUIREd. It must only be invoked, and only
104 # outside of macros or in macros that are not AC_REQUIREd.
105 AC_DEFUN([gl_STDDEF_H_REQUIRE_DEFAULTS],
106 [
107 m4_defun(GL_MODULE_INDICATOR_PREFIX[_STDDEF_H_MODULE_INDICATOR_DEFAULTS], [
108 ])
109 m4_require(GL_MODULE_INDICATOR_PREFIX[_STDDEF_H_MODULE_INDICATOR_DEFAULTS])
110 AC_REQUIRE([gl_STDDEF_H_DEFAULTS])
111 ])
112
113 AC_DEFUN([gl_STDDEF_H_DEFAULTS],
114 [
115 dnl Assume proper GNU behavior unless another module says otherwise.
116 REPLACE_NULL=0; AC_SUBST([REPLACE_NULL])
117 HAVE_MAX_ALIGN_T=1; AC_SUBST([HAVE_MAX_ALIGN_T])
118 HAVE_WCHAR_T=1; AC_SUBST([HAVE_WCHAR_T])
119 ])