Debian Codegraph @

m4/intmax_t.m4

raw
1 # intmax_t.m4 serial 9
2 dnl Copyright (C) 1997-2004, 2006-2007, 2009-2024 Free Software Foundation,
3 dnl Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7
8 dnl From Paul Eggert.
9
10 AC_PREREQ([2.53])
11
12 # Define intmax_t to 'long' or 'long long'
13 # if it is not already defined in <stdint.h> or <inttypes.h>.
14
15 AC_DEFUN([gl_AC_TYPE_INTMAX_T],
16 [
17 dnl For simplicity, we assume that a header file defines 'intmax_t' if and
18 dnl only if it defines 'uintmax_t'.
19 AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
20 AC_REQUIRE([gl_AC_HEADER_STDINT_H])
21 if test $gl_cv_header_inttypes_h = no && test $gl_cv_header_stdint_h = no; then
22 AC_DEFINE_UNQUOTED([intmax_t], [long long],
23 [Define to long or long long if <inttypes.h> and <stdint.h> don't define.])
24 else
25 AC_DEFINE([HAVE_INTMAX_T], [1],
26 [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
27 fi
28 ])
29
30 dnl An alternative would be to explicitly test for 'intmax_t'.
31
32 AC_DEFUN([gt_AC_TYPE_INTMAX_T],
33 [
34 AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
35 AC_REQUIRE([gl_AC_HEADER_STDINT_H])
36 AC_CACHE_CHECK([for intmax_t], [gt_cv_c_intmax_t],
37 [AC_COMPILE_IFELSE(
38 [AC_LANG_PROGRAM(
39 [[
40 #include <stddef.h>
41 #include <stdlib.h>
42 #if HAVE_STDINT_H_WITH_UINTMAX
43 #include <stdint.h>
44 #endif
45 #if HAVE_INTTYPES_H_WITH_UINTMAX
46 #include <inttypes.h>
47 #endif
48 ]],
49 [[intmax_t x = -1; return !x;]])],
50 [gt_cv_c_intmax_t=yes],
51 [gt_cv_c_intmax_t=no])])
52 if test $gt_cv_c_intmax_t = yes; then
53 AC_DEFINE([HAVE_INTMAX_T], [1],
54 [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
55 else
56 AC_DEFINE_UNQUOTED([intmax_t], [long long],
57 [Define to long or long long if <stdint.h> and <inttypes.h> don't define.])
58 fi
59 ])