| 1 |
# po.m4 serial 22 (gettext-0.19) |
| 2 |
dnl Copyright (C) 1995-2014 Free Software Foundation, Inc. |
| 3 |
dnl This file is free software; the Free Software Foundation |
| 4 |
dnl gives unlimited permission to copy and/or distribute it, |
| 5 |
dnl with or without modifications, as long as this notice is preserved. |
| 6 |
dnl |
| 7 |
dnl This file can can be used in projects which are not available under |
| 8 |
dnl the GNU General Public License or the GNU Library General Public |
| 9 |
dnl License but which still want to provide support for the GNU gettext |
| 10 |
dnl functionality. |
| 11 |
dnl Please note that the actual code of the GNU gettext library is covered |
| 12 |
dnl by the GNU Library General Public License, and the rest of the GNU |
| 13 |
dnl gettext package package is covered by the GNU General Public License. |
| 14 |
dnl They are *not* in the public domain. |
| 15 |
|
| 16 |
dnl Authors: |
| 17 |
dnl Ulrich Drepper <[email protected]>, 1995-2000. |
| 18 |
dnl Bruno Haible <[email protected]>, 2000-2003. |
| 19 |
|
| 20 |
AC_PREREQ([2.60]) |
| 21 |
|
| 22 |
dnl Checks for all prerequisites of the po subdirectory. |
| 23 |
AC_DEFUN([AM_PO_SUBDIRS], |
| 24 |
[ |
| 25 |
AC_REQUIRE([AC_PROG_MAKE_SET])dnl |
| 26 |
AC_REQUIRE([AC_PROG_INSTALL])dnl |
| 27 |
AC_REQUIRE([AC_PROG_MKDIR_P])dnl |
| 28 |
AC_REQUIRE([AC_PROG_SED])dnl |
| 29 |
AC_REQUIRE([AM_NLS])dnl |
| 30 |
|
| 31 |
dnl Release version of the gettext macros. This is used to ensure that |
| 32 |
dnl the gettext macros and po/Makefile.in.in are in sync. |
| 33 |
AC_SUBST([GETTEXT_MACRO_VERSION], [0.19]) |
| 34 |
|
| 35 |
dnl Perform the following tests also if --disable-nls has been given, |
| 36 |
dnl because they are needed for "make dist" to work. |
| 37 |
|
| 38 |
dnl Search for GNU msgfmt in the PATH. |
| 39 |
dnl The first test excludes Solaris msgfmt and early GNU msgfmt versions. |
| 40 |
dnl The second test excludes FreeBSD msgfmt. |
| 41 |
AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt, |
| 42 |
[$ac_dir/$ac_word --statistics /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 && |
| 43 |
(if $ac_dir/$ac_word --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)], |
| 44 |
:) |
| 45 |
AC_PATH_PROG([GMSGFMT], [gmsgfmt], [$MSGFMT]) |
| 46 |
|
| 47 |
dnl Test whether it is GNU msgfmt >= 0.15. |
| 48 |
changequote(,)dnl |
| 49 |
case `$MSGFMT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in |
| 50 |
'' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) MSGFMT_015=: ;; |
| 51 |
*) MSGFMT_015=$MSGFMT ;; |
| 52 |
esac |
| 53 |
changequote([,])dnl |
| 54 |
AC_SUBST([MSGFMT_015]) |
| 55 |
changequote(,)dnl |
| 56 |
case `$GMSGFMT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in |
| 57 |
'' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) GMSGFMT_015=: ;; |
| 58 |
*) GMSGFMT_015=$GMSGFMT ;; |
| 59 |
esac |
| 60 |
changequote([,])dnl |
| 61 |
AC_SUBST([GMSGFMT_015]) |
| 62 |
|
| 63 |
dnl Search for GNU xgettext 0.12 or newer in the PATH. |
| 64 |
dnl The first test excludes Solaris xgettext and early GNU xgettext versions. |
| 65 |
dnl The second test excludes FreeBSD xgettext. |
| 66 |
AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext, |
| 67 |
[$ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 && |
| 68 |
(if $ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)], |
| 69 |
:) |
| 70 |
dnl Remove leftover from FreeBSD xgettext call. |
| 71 |
rm -f messages.po |
| 72 |
|
| 73 |
dnl Test whether it is GNU xgettext >= 0.15. |
| 74 |
changequote(,)dnl |
| 75 |
case `$XGETTEXT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in |
| 76 |
'' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) XGETTEXT_015=: ;; |
| 77 |
*) XGETTEXT_015=$XGETTEXT ;; |
| 78 |
esac |
| 79 |
changequote([,])dnl |
| 80 |
AC_SUBST([XGETTEXT_015]) |
| 81 |
|
| 82 |
dnl Search for GNU msgmerge 0.11 or newer in the PATH. |
| 83 |
AM_PATH_PROG_WITH_TEST(MSGMERGE, msgmerge, |
| 84 |
[$ac_dir/$ac_word --update -q /dev/null /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1], :) |
| 85 |
|
| 86 |
dnl Installation directories. |
| 87 |
dnl Autoconf >= 2.60 defines localedir. For older versions of autoconf, we |
| 88 |
dnl have to define it here, so that it can be used in po/Makefile. |
| 89 |
test -n "$localedir" || localedir='${datadir}/locale' |
| 90 |
AC_SUBST([localedir]) |
| 91 |
|
| 92 |
dnl Support for AM_XGETTEXT_OPTION. |
| 93 |
test -n "${XGETTEXT_EXTRA_OPTIONS+set}" || XGETTEXT_EXTRA_OPTIONS= |
| 94 |
AC_SUBST([XGETTEXT_EXTRA_OPTIONS]) |
| 95 |
|
| 96 |
AC_CONFIG_COMMANDS([po-directories], [[ |
| 97 |
for ac_file in $CONFIG_FILES; do |
| 98 |
# Support "outfile[:infile[:infile...]]" |
| 99 |
case "$ac_file" in |
| 100 |
*:*) ac_file=`echo "$ac_file"|sed 's%:.*%%'` ;; |
| 101 |
esac |
| 102 |
# PO directories have a Makefile.in generated from Makefile.in.in. |
| 103 |
case "$ac_file" in */Makefile.in) |
| 104 |
# Adjust a relative srcdir. |
| 105 |
ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'` |
| 106 |
ac_dir_suffix=/`echo "$ac_dir"|sed 's%^\./%%'` |
| 107 |
ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'` |
| 108 |
# In autoconf-2.13 it is called $ac_given_srcdir. |
| 109 |
# In autoconf-2.50 it is called $srcdir. |
| 110 |
test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir" |
| 111 |
case "$ac_given_srcdir" in |
| 112 |
.) top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;; |
| 113 |
/*) top_srcdir="$ac_given_srcdir" ;; |
| 114 |
*) top_srcdir="$ac_dots$ac_given_srcdir" ;; |
| 115 |
esac |
| 116 |
# Treat a directory as a PO directory if and only if it has a |
| 117 |
# POTFILES.in file. This allows packages to have multiple PO |
| 118 |
# directories under different names or in different locations. |
| 119 |
if test -f "$ac_given_srcdir/$ac_dir/POTFILES.in"; then |
| 120 |
rm -f "$ac_dir/POTFILES" |
| 121 |
test -n "$as_me" && echo "$as_me: creating $ac_dir/POTFILES" || echo "creating $ac_dir/POTFILES" |
| 122 |
gt_tab=`printf '\t'` |
| 123 |
cat "$ac_given_srcdir/$ac_dir/POTFILES.in" | sed -e "/^#/d" -e "/^[ ${gt_tab}]*\$/d" -e "s,.*, $top_srcdir/& \\\\," | sed -e "\$s/\(.*\) \\\\/\1/" > "$ac_dir/POTFILES" |
| 124 |
POMAKEFILEDEPS="POTFILES.in" |
| 125 |
# ALL_LINGUAS, POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES depend |
| 126 |
# on $ac_dir but don't depend on user-specified configuration |
| 127 |
# parameters. |
| 128 |
if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then |
| 129 |
# The LINGUAS file contains the set of available languages. |
| 130 |
if test -n "$OBSOLETE_ALL_LINGUAS"; then |
| 131 |
test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete" |
| 132 |
fi |
| 133 |
ALL_LINGUAS_=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"` |
| 134 |
# Hide the ALL_LINGUAS assignment from automake < 1.5. |
| 135 |
eval 'ALL_LINGUAS''=$ALL_LINGUAS_' |
| 136 |
POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS" |
| 137 |
else |
| 138 |
# The set of available languages was given in configure.in. |
| 139 |
# Hide the ALL_LINGUAS assignment from automake < 1.5. |
| 140 |
eval 'ALL_LINGUAS''=$OBSOLETE_ALL_LINGUAS' |
| 141 |
fi |
| 142 |
# Compute POFILES |
| 143 |
# as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po) |
| 144 |
# Compute UPDATEPOFILES |
| 145 |
# as $(foreach lang, $(ALL_LINGUAS), $(lang).po-update) |
| 146 |
# Compute DUMMYPOFILES |
| 147 |
# as $(foreach lang, $(ALL_LINGUAS), $(lang).nop) |
| 148 |
# Compute GMOFILES |
| 149 |
# as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo) |
| 150 |
case "$ac_given_srcdir" in |
| 151 |
.) srcdirpre= ;; |
| 152 |
*) srcdirpre='$(srcdir)/' ;; |
| 153 |
esac |
| 154 |
POFILES= |
| 155 |
UPDATEPOFILES= |
| 156 |
DUMMYPOFILES= |
| 157 |
GMOFILES= |
| 158 |
for lang in $ALL_LINGUAS; do |
| 159 |
POFILES="$POFILES $srcdirpre$lang.po" |
| 160 |
UPDATEPOFILES="$UPDATEPOFILES $lang.po-update" |
| 161 |
DUMMYPOFILES="$DUMMYPOFILES $lang.nop" |
| 162 |
GMOFILES="$GMOFILES $srcdirpre$lang.gmo" |
| 163 |
done |
| 164 |
# CATALOGS depends on both $ac_dir and the user's LINGUAS |
| 165 |
# environment variable. |
| 166 |
INST_LINGUAS= |
| 167 |
if test -n "$ALL_LINGUAS"; then |
| 168 |
for presentlang in $ALL_LINGUAS; do |
| 169 |
useit=no |
| 170 |
if test "%UNSET%" != "$LINGUAS"; then |
| 171 |
desiredlanguages="$LINGUAS" |
| 172 |
else |
| 173 |
desiredlanguages="$ALL_LINGUAS" |
| 174 |
fi |
| 175 |
for desiredlang in $desiredlanguages; do |
| 176 |
# Use the presentlang catalog if desiredlang is |
| 177 |
# a. equal to presentlang, or |
| 178 |
# b. a variant of presentlang (because in this case, |
| 179 |
# presentlang can be used as a fallback for messages |
| 180 |
# which are not translated in the desiredlang catalog). |
| 181 |
case "$desiredlang" in |
| 182 |
"$presentlang"*) useit=yes;; |
| 183 |
esac |
| 184 |
done |
| 185 |
if test $useit = yes; then |
| 186 |
INST_LINGUAS="$INST_LINGUAS $presentlang" |
| 187 |
fi |
| 188 |
done |
| 189 |
fi |
| 190 |
CATALOGS= |
| 191 |
if test -n "$INST_LINGUAS"; then |
| 192 |
for lang in $INST_LINGUAS; do |
| 193 |
CATALOGS="$CATALOGS $lang.gmo" |
| 194 |
done |
| 195 |
fi |
| 196 |
test -n "$as_me" && echo "$as_me: creating $ac_dir/Makefile" || echo "creating $ac_dir/Makefile" |
| 197 |
sed -e "/^POTFILES =/r $ac_dir/POTFILES" -e "/^# Makevars/r $ac_given_srcdir/$ac_dir/Makevars" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@POMAKEFILEDEPS@|$POMAKEFILEDEPS|g" "$ac_dir/Makefile.in" > "$ac_dir/Makefile" |
| 198 |
for f in "$ac_given_srcdir/$ac_dir"/Rules-*; do |
| 199 |
if test -f "$f"; then |
| 200 |
case "$f" in |
| 201 |
*.orig | *.bak | *~) ;; |
| 202 |
*) cat "$f" >> "$ac_dir/Makefile" ;; |
| 203 |
esac |
| 204 |
fi |
| 205 |
done |
| 206 |
fi |
| 207 |
;; |
| 208 |
esac |
| 209 |
done]], |
| 210 |
[# Capture the value of obsolete ALL_LINGUAS because we need it to compute |
| 211 |
# POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES, CATALOGS. But hide it |
| 212 |
# from automake < 1.5. |
| 213 |
eval 'OBSOLETE_ALL_LINGUAS''="$ALL_LINGUAS"' |
| 214 |
# Capture the value of LINGUAS because we need it to compute CATALOGS. |
| 215 |
LINGUAS="${LINGUAS-%UNSET%}" |
| 216 |
]) |
| 217 |
]) |
| 218 |
|
| 219 |
dnl Postprocesses a Makefile in a directory containing PO files. |
| 220 |
AC_DEFUN([AM_POSTPROCESS_PO_MAKEFILE], |
| 221 |
[ |
| 222 |
# When this code is run, in config.status, two variables have already been |
| 223 |
# set: |
| 224 |
# - OBSOLETE_ALL_LINGUAS is the value of LINGUAS set in configure.in, |
| 225 |
# - LINGUAS is the value of the environment variable LINGUAS at configure |
| 226 |
# time. |
| 227 |
|
| 228 |
changequote(,)dnl |
| 229 |
# Adjust a relative srcdir. |
| 230 |
ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'` |
| 231 |
ac_dir_suffix=/`echo "$ac_dir"|sed 's%^\./%%'` |
| 232 |
ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'` |
| 233 |
# In autoconf-2.13 it is called $ac_given_srcdir. |
| 234 |
# In autoconf-2.50 it is called $srcdir. |
| 235 |
test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir" |
| 236 |
case "$ac_given_srcdir" in |
| 237 |
.) top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;; |
| 238 |
/*) top_srcdir="$ac_given_srcdir" ;; |
| 239 |
*) top_srcdir="$ac_dots$ac_given_srcdir" ;; |
| 240 |
esac |
| 241 |
|
| 242 |
# Find a way to echo strings without interpreting backslash. |
| 243 |
if test "X`(echo '\t') 2>/dev/null`" = 'X\t'; then |
| 244 |
gt_echo='echo' |
| 245 |
else |
| 246 |
if test "X`(printf '%s\n' '\t') 2>/dev/null`" = 'X\t'; then |
| 247 |
gt_echo='printf %s\n' |
| 248 |
else |
| 249 |
echo_func () { |
| 250 |
cat <<EOT |
| 251 |
$* |
| 252 |
EOT |
| 253 |
} |
| 254 |
gt_echo='echo_func' |
| 255 |
fi |
| 256 |
fi |
| 257 |
|
| 258 |
# A sed script that extracts the value of VARIABLE from a Makefile. |
| 259 |
tab=`printf '\t'` |
| 260 |
sed_x_variable=' |
| 261 |
# Test if the hold space is empty. |
| 262 |
x |
| 263 |
s/P/P/ |
| 264 |
x |
| 265 |
ta |
| 266 |
# Yes it was empty. Look if we have the expected variable definition. |
| 267 |
/^['"${tab}"' ]*VARIABLE['"${tab}"' ]*=/{ |
| 268 |
# Seen the first line of the variable definition. |
| 269 |
s/^['"${tab}"' ]*VARIABLE['"${tab}"' ]*=// |
| 270 |
ba |
| 271 |
} |
| 272 |
bd |
| 273 |
:a |
| 274 |
# Here we are processing a line from the variable definition. |
| 275 |
# Remove comment, more precisely replace it with a space. |
| 276 |
s/#.*$/ / |
| 277 |
# See if the line ends in a backslash. |
| 278 |
tb |
| 279 |
:b |
| 280 |
s/\\$// |
| 281 |
# Print the line, without the trailing backslash. |
| 282 |
p |
| 283 |
tc |
| 284 |
# There was no trailing backslash. The end of the variable definition is |
| 285 |
# reached. Clear the hold space. |
| 286 |
s/^.*$// |
| 287 |
x |
| 288 |
bd |
| 289 |
:c |
| 290 |
# A trailing backslash means that the variable definition continues in the |
| 291 |
# next line. Put a nonempty string into the hold space to indicate this. |
| 292 |
s/^.*$/P/ |
| 293 |
x |
| 294 |
:d |
| 295 |
' |
| 296 |
changequote([,])dnl |
| 297 |
|
| 298 |
# Set POTFILES to the value of the Makefile variable POTFILES. |
| 299 |
sed_x_POTFILES=`$gt_echo "$sed_x_variable" | sed -e '/^ *#/d' -e 's/VARIABLE/POTFILES/g'` |
| 300 |
POTFILES=`sed -n -e "$sed_x_POTFILES" < "$ac_file"` |
| 301 |
# Compute POTFILES_DEPS as |
| 302 |
# $(foreach file, $(POTFILES), $(top_srcdir)/$(file)) |
| 303 |
POTFILES_DEPS= |
| 304 |
for file in $POTFILES; do |
| 305 |
POTFILES_DEPS="$POTFILES_DEPS "'$(top_srcdir)/'"$file" |
| 306 |
done |
| 307 |
POMAKEFILEDEPS="" |
| 308 |
|
| 309 |
if test -n "$OBSOLETE_ALL_LINGUAS"; then |
| 310 |
test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete" |
| 311 |
fi |
| 312 |
if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then |
| 313 |
# The LINGUAS file contains the set of available languages. |
| 314 |
ALL_LINGUAS_=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"` |
| 315 |
POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS" |
| 316 |
else |
| 317 |
# Set ALL_LINGUAS to the value of the Makefile variable LINGUAS. |
| 318 |
sed_x_LINGUAS=`$gt_echo "$sed_x_variable" | sed -e '/^ *#/d' -e 's/VARIABLE/LINGUAS/g'` |
| 319 |
ALL_LINGUAS_=`sed -n -e "$sed_x_LINGUAS" < "$ac_file"` |
| 320 |
fi |
| 321 |
# Hide the ALL_LINGUAS assignment from automake < 1.5. |
| 322 |
eval 'ALL_LINGUAS''=$ALL_LINGUAS_' |
| 323 |
# Compute POFILES |
| 324 |
# as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po) |
| 325 |
# Compute UPDATEPOFILES |
| 326 |
# as $(foreach lang, $(ALL_LINGUAS), $(lang).po-update) |
| 327 |
# Compute DUMMYPOFILES |
| 328 |
# as $(foreach lang, $(ALL_LINGUAS), $(lang).nop) |
| 329 |
# Compute GMOFILES |
| 330 |
# as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo) |
| 331 |
# Compute PROPERTIESFILES |
| 332 |
# as $(foreach lang, $(ALL_LINGUAS), $(top_srcdir)/$(DOMAIN)_$(lang).properties) |
| 333 |
# Compute CLASSFILES |
| 334 |
# as $(foreach lang, $(ALL_LINGUAS), $(top_srcdir)/$(DOMAIN)_$(lang).class) |
| 335 |
# Compute QMFILES |
| 336 |
# as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).qm) |
| 337 |
# Compute MSGFILES |
| 338 |
# as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang)).msg) |
| 339 |
# Compute RESOURCESDLLFILES |
| 340 |
# as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang))/$(DOMAIN).resources.dll) |
| 341 |
case "$ac_given_srcdir" in |
| 342 |
.) srcdirpre= ;; |
| 343 |
*) srcdirpre='$(srcdir)/' ;; |
| 344 |
esac |
| 345 |
POFILES= |
| 346 |
UPDATEPOFILES= |
| 347 |
DUMMYPOFILES= |
| 348 |
GMOFILES= |
| 349 |
PROPERTIESFILES= |
| 350 |
CLASSFILES= |
| 351 |
QMFILES= |
| 352 |
MSGFILES= |
| 353 |
RESOURCESDLLFILES= |
| 354 |
for lang in $ALL_LINGUAS; do |
| 355 |
POFILES="$POFILES $srcdirpre$lang.po" |
| 356 |
UPDATEPOFILES="$UPDATEPOFILES $lang.po-update" |
| 357 |
DUMMYPOFILES="$DUMMYPOFILES $lang.nop" |
| 358 |
GMOFILES="$GMOFILES $srcdirpre$lang.gmo" |
| 359 |
PROPERTIESFILES="$PROPERTIESFILES \$(top_srcdir)/\$(DOMAIN)_$lang.properties" |
| 360 |
CLASSFILES="$CLASSFILES \$(top_srcdir)/\$(DOMAIN)_$lang.class" |
| 361 |
QMFILES="$QMFILES $srcdirpre$lang.qm" |
| 362 |
frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'` |
| 363 |
MSGFILES="$MSGFILES $srcdirpre$frobbedlang.msg" |
| 364 |
frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'` |
| 365 |
RESOURCESDLLFILES="$RESOURCESDLLFILES $srcdirpre$frobbedlang/\$(DOMAIN).resources.dll" |
| 366 |
done |
| 367 |
# CATALOGS depends on both $ac_dir and the user's LINGUAS |
| 368 |
# environment variable. |
| 369 |
INST_LINGUAS= |
| 370 |
if test -n "$ALL_LINGUAS"; then |
| 371 |
for presentlang in $ALL_LINGUAS; do |
| 372 |
useit=no |
| 373 |
if test "%UNSET%" != "$LINGUAS"; then |
| 374 |
desiredlanguages="$LINGUAS" |
| 375 |
else |
| 376 |
desiredlanguages="$ALL_LINGUAS" |
| 377 |
fi |
| 378 |
for desiredlang in $desiredlanguages; do |
| 379 |
# Use the presentlang catalog if desiredlang is |
| 380 |
# a. equal to presentlang, or |
| 381 |
# b. a variant of presentlang (because in this case, |
| 382 |
# presentlang can be used as a fallback for messages |
| 383 |
# which are not translated in the desiredlang catalog). |
| 384 |
case "$desiredlang" in |
| 385 |
"$presentlang"*) useit=yes;; |
| 386 |
esac |
| 387 |
done |
| 388 |
if test $useit = yes; then |
| 389 |
INST_LINGUAS="$INST_LINGUAS $presentlang" |
| 390 |
fi |
| 391 |
done |
| 392 |
fi |
| 393 |
CATALOGS= |
| 394 |
JAVACATALOGS= |
| 395 |
QTCATALOGS= |
| 396 |
TCLCATALOGS= |
| 397 |
CSHARPCATALOGS= |
| 398 |
if test -n "$INST_LINGUAS"; then |
| 399 |
for lang in $INST_LINGUAS; do |
| 400 |
CATALOGS="$CATALOGS $lang.gmo" |
| 401 |
JAVACATALOGS="$JAVACATALOGS \$(DOMAIN)_$lang.properties" |
| 402 |
QTCATALOGS="$QTCATALOGS $lang.qm" |
| 403 |
frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'` |
| 404 |
TCLCATALOGS="$TCLCATALOGS $frobbedlang.msg" |
| 405 |
frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'` |
| 406 |
CSHARPCATALOGS="$CSHARPCATALOGS $frobbedlang/\$(DOMAIN).resources.dll" |
| 407 |
done |
| 408 |
fi |
| 409 |
|
| 410 |
sed -e "s|@POTFILES_DEPS@|$POTFILES_DEPS|g" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@PROPERTIESFILES@|$PROPERTIESFILES|g" -e "s|@CLASSFILES@|$CLASSFILES|g" -e "s|@QMFILES@|$QMFILES|g" -e "s|@MSGFILES@|$MSGFILES|g" -e "s|@RESOURCESDLLFILES@|$RESOURCESDLLFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@JAVACATALOGS@|$JAVACATALOGS|g" -e "s|@QTCATALOGS@|$QTCATALOGS|g" -e "s|@TCLCATALOGS@|$TCLCATALOGS|g" -e "s|@CSHARPCATALOGS@|$CSHARPCATALOGS|g" -e 's,^#distdir:,distdir:,' < "$ac_file" > "$ac_file.tmp" |
| 411 |
tab=`printf '\t'` |
| 412 |
if grep -l '@TCLCATALOGS@' "$ac_file" > /dev/null; then |
| 413 |
# Add dependencies that cannot be formulated as a simple suffix rule. |
| 414 |
for lang in $ALL_LINGUAS; do |
| 415 |
frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'` |
| 416 |
cat >> "$ac_file.tmp" <<EOF |
| 417 |
$frobbedlang.msg: $lang.po |
| 418 |
${tab}@echo "\$(MSGFMT) -c --tcl -d \$(srcdir) -l $lang $srcdirpre$lang.po"; \ |
| 419 |
${tab}\$(MSGFMT) -c --tcl -d "\$(srcdir)" -l $lang $srcdirpre$lang.po || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; } |
| 420 |
EOF |
| 421 |
done |
| 422 |
fi |
| 423 |
if grep -l '@CSHARPCATALOGS@' "$ac_file" > /dev/null; then |
| 424 |
# Add dependencies that cannot be formulated as a simple suffix rule. |
| 425 |
for lang in $ALL_LINGUAS; do |
| 426 |
frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'` |
| 427 |
cat >> "$ac_file.tmp" <<EOF |
| 428 |
$frobbedlang/\$(DOMAIN).resources.dll: $lang.po |
| 429 |
${tab}@echo "\$(MSGFMT) -c --csharp -d \$(srcdir) -l $lang $srcdirpre$lang.po -r \$(DOMAIN)"; \ |
| 430 |
${tab}\$(MSGFMT) -c --csharp -d "\$(srcdir)" -l $lang $srcdirpre$lang.po -r "\$(DOMAIN)" || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; } |
| 431 |
EOF |
| 432 |
done |
| 433 |
fi |
| 434 |
if test -n "$POMAKEFILEDEPS"; then |
| 435 |
cat >> "$ac_file.tmp" <<EOF |
| 436 |
Makefile: $POMAKEFILEDEPS |
| 437 |
EOF |
| 438 |
fi |
| 439 |
mv "$ac_file.tmp" "$ac_file" |
| 440 |
]) |
| 441 |
|
| 442 |
dnl Initializes the accumulator used by AM_XGETTEXT_OPTION. |
| 443 |
AC_DEFUN([AM_XGETTEXT_OPTION_INIT], |
| 444 |
[ |
| 445 |
XGETTEXT_EXTRA_OPTIONS= |
| 446 |
]) |
| 447 |
|
| 448 |
dnl Registers an option to be passed to xgettext in the po subdirectory. |
| 449 |
AC_DEFUN([AM_XGETTEXT_OPTION], |
| 450 |
[ |
| 451 |
AC_REQUIRE([AM_XGETTEXT_OPTION_INIT]) |
| 452 |
XGETTEXT_EXTRA_OPTIONS="$XGETTEXT_EXTRA_OPTIONS $1" |
| 453 |
]) |