Debian Codegraph @

examples/bio_nsg/bio_450cells/components/mechanisms/modfiles/Kv2like.mod

raw
1 : Kv2-like channel
2 : Adapted from model implemented in Keren et al. 2005
3 : Adjusted parameters to be similar to guangxitoxin-sensitive current in mouse CA1 pyramids from Liu and Bean 2014
4
5
6 NEURON {
7 SUFFIX Kv2like
8 USEION k READ ek WRITE ik
9 RANGE gbar, g, ik
10 }
11
12 UNITS {
13 (S) = (siemens)
14 (mV) = (millivolt)
15 (mA) = (milliamp)
16 }
17
18 PARAMETER {
19 gbar = 0.00001 (S/cm2)
20 }
21
22 ASSIGNED {
23 v (mV)
24 ek (mV)
25 ik (mA/cm2)
26 g (S/cm2)
27 celsius (degC)
28 mInf
29 mAlpha
30 mBeta
31 mTau
32 hInf
33 h1Tau
34 h2Tau
35 }
36
37 STATE {
38 m
39 h1
40 h2
41 }
42
43 BREAKPOINT {
44 SOLVE states METHOD cnexp
45 g = gbar * m * m * (0.5 * h1 + 0.5 * h2)
46 ik = g * (v - ek)
47 }
48
49 DERIVATIVE states {
50 rates()
51 m' = (mInf - m) / mTau
52 h1' = (hInf - h1) / h1Tau
53 h2' = (hInf - h2) / h2Tau
54 }
55
56 INITIAL{
57 rates()
58 m = mInf
59 h1 = hInf
60 h2 = hInf
61 }
62
63 PROCEDURE rates() {
64 LOCAL qt
65 qt = 2.3^((celsius-21)/10)
66 UNITSOFF
67 mAlpha = 0.12 * vtrap( -(v - 43), 11.0)
68 mBeta = 0.02 * exp(-(v + 1.27) / 120)
69 mInf = mAlpha / (mAlpha + mBeta)
70 mTau = 2.5 * (1 / (qt * (mAlpha + mBeta)))
71
72 hInf = 1/(1 + exp((v + 58) / 11))
73 h1Tau = (360 + (1010 + 23.7 * (v + 54)) * exp(-((v + 75) / 48)^2)) / qt
74 h2Tau = (2350 + 1380 * exp(-0.011 * v) - 210 * exp(-0.03 * v)) / qt
75 UNITSON
76 }
77
78 FUNCTION vtrap(x, y) { : Traps for 0 in denominator of rate equations
79 UNITSOFF
80 if (fabs(x / y) < 1e-6) {
81 vtrap = y * (1 - x / y / 2)
82 } else {
83 vtrap = x / (exp(x / y) - 1)
84 }
85 UNITSON
86 }