Debian Codegraph @

examples/bio_nsg/bio_450cells/Ih.mod

raw
1 : Reference: Kole,Hallermann,and Stuart, J. Neurosci. 2006
2
3 NEURON {
4 SUFFIX Ih
5 NONSPECIFIC_CURRENT ihcn
6 RANGE gbar, g, ihcn
7 }
8
9 UNITS {
10 (S) = (siemens)
11 (mV) = (millivolt)
12 (mA) = (milliamp)
13 }
14
15 PARAMETER {
16 gbar = 0.00001 (S/cm2)
17 ehcn = -45.0 (mV)
18 }
19
20 ASSIGNED {
21 v (mV)
22 ihcn (mA/cm2)
23 g (S/cm2)
24 mInf
25 mTau
26 mAlpha
27 mBeta
28 }
29
30 STATE {
31 m
32 }
33
34 BREAKPOINT {
35 SOLVE states METHOD cnexp
36 g = gbar*m
37 ihcn = g*(v-ehcn)
38 }
39
40 DERIVATIVE states {
41 rates()
42 m' = (mInf-m)/mTau
43 }
44
45 INITIAL{
46 rates()
47 m = mInf
48 }
49
50 PROCEDURE rates(){
51 UNITSOFF
52 : if(v == -154.9){
53 : v = v + 0.0001
54 : }
55 :mAlpha = 0.001*6.43*(v+154.9)/(exp((v+154.9)/11.9)-1)
56 mAlpha = 0.001 * 6.43 * vtrap(v + 154.9, 11.9)
57 mBeta = 0.001*193*exp(v/33.1)
58 mInf = mAlpha/(mAlpha + mBeta)
59 mTau = 1/(mAlpha + mBeta)
60 UNITSON
61 }
62
63 FUNCTION vtrap(x, y) { : Traps for 0 in denominator of rate equations
64 UNITSOFF
65 if (fabs(x / y) < 1e-6) {
66 vtrap = y * (1 - x / y / 2)
67 } else {
68 vtrap = x / (exp(x / y) - 1)
69 }
70 UNITSON
71 }