Debian Codegraph @

examples/bio_nsg/bio_450cells/stp4syn.mod

raw
1 COMMENT
2 A model (# 4 using terminology of Jung Hoon Lee) of a short-term synaptic plasticity.
3 The magnitude of the peak conductance is found by
4 solving Eqs (3,4) in Hennig, 2013. "Theoretical models of synaptic short term plasticity. Frontiers in computational neuroscience, 7, p.45."
5
6 State variables:
7
8 n = fraction of available vesicles
9 p = release probability
10
11 After each spike the magnitude of the peak conductance changes by the factor w*Pmax, where
12 w is the static synaptic weight and Pmax is the dynamically changing factor that could be interpreted as a probability of a transmitter release by the presynaptic terminal.
13
14 The post_synaptic dynamics of individual synaptic events is modeled by a single exponential synapse with the time constant tau_1
15
16 Implemented by Sergey L. Gratiy
17
18 ENDCOMMENT
19
20
21
22
23 NEURON {
24 POINT_PROCESS stp4syn
25 RANGE e, i, tau_r, p0, tau_1,tau_f
26 NONSPECIFIC_CURRENT i
27 }
28
29 UNITS {
30 (nA) = (nanoamp)
31 (mV) = (millivolt)
32 (umho) = (micromho)
33 }
34
35 PARAMETER {
36 : e = synaptic reversal potential
37 e = 0 (mV)
38 : tau_r = recovery time constant
39 tau_r = 100 (ms)
40 : p0 = baseline level of release probability
41 p0 = 0.3
42 : tau_f = facilitation time constant
43 tau_f = 1000 (ms) < 0, 1e9 >
44 : tau_1 = baseline level of release probability
45 tau_1 = 10 (ms)
46 }
47
48 ASSIGNED {
49 v (mV)
50 i (nA)
51 }
52
53 STATE {
54 n
55 p
56 g
57 }
58
59 INITIAL {
60 n=1
61 p=1
62 g=0
63 }
64
65 BREAKPOINT {
66 SOLVE state METHOD cnexp
67 i = g*(v - e)
68 }
69
70 DERIVATIVE state {
71 n' = (1-n)/tau_r
72 g' = -g/tau_1
73 p' = 0
74 }
75
76 NET_RECEIVE(weight (umho)) {
77 g = g + weight*n*p0
78 n = n - n*p0
79 p = p + p0*(1-p)
80
81 }
82
83