Debian Codegraph @

packages/seacas/applications/numbers/nu_con2d.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE CON2D (CRD, NDIM, NUMNP, IX, NNODES, NUMEL, MAT,
9 * NELBLK, SELECT, ASPECT, SKEW, TAPER, AREA,
10 * SUMRY, ISUMRY, DEBUG)
11 C=======================================================================
12
13 C *** CON2D *** Calculate state of mesh -- Aspect ratio, Skewness,
14 C and Taper
15
16 C (Greg Sjaardema, 16 April, 1989)
17
18 C Based on article by John Robinson, "CRE Method of element testing
19 C and the Jacobian shape parameters," Eng. Comput., 1987, Vol. 4,
20 C June, pp 113 - 118
21
22 C -- ARRAYS:
23 C CRD(NUMNP, NDIM) - IN -
24 C IX(NNODES, NUMEL) - IN -
25 C MAT(5, NELBLK) - IN -
26 C SELECT(NUMEL) - IN -
27 C ASPECT(NUMEL) - OUT- Aspect ratio (1.0 <= AR <= infinity)
28 C SKEW(NUMEL) - OUT- Skewness of mesh, degrees (0 <= skew <= ?)
29 C TAPER(NUMEL) - OUT- Taper of mesh, combination of X and Y taper
30 C AREA(NUMEL) - OUT- Area of element
31
32 C -- SCALARS:
33 C NDIM - Number of spatial dimensions
34 C NUMNP - Number of nodal points
35 C NNODES - Number of nodes per element
36 C NUMEL - Number of elements
37 C NELBLK - Number of material/element blocks
38
39 C E2 E4
40 C +----------+ +-----------+ +---------+ |
41 C | | F3 / / / \
42 C | | / A / / \
43 C +----------+ +-----------+ +---------------+
44
45 C AR = E2/F3 SKEW = SIN(A) TAPER Y
46
47 C=======================================================================
48
49 REAL CRD(NUMNP, NDIM), ASPECT(*), SKEW(*), TAPER(*), AREA(*)
50 INTEGER IX(NNODES, NUMEL), MAT(6, NELBLK), ISUMRY(2,4,NELBLK)
51 REAL SUMRY(4,4,NELBLK)
52 LOGICAL SELECT(*), DEBUG, ISABRT
53 include 'nu_io.blk'
54
55 CALL INIREA (NUMEL, 0.0, ASPECT)
56 CALL INIREA (NUMEL, 0.0, SKEW)
57 CALL INIREA (NUMEL, 0.0, TAPER)
58 CALL INIREA (NUMEL, 0.0, AREA)
59
60 DO 40 IBLK = 1, NELBLK
61 IF (MAT(5, IBLK) .EQ. 1) THEN
62 IELBEG = MAT(3, IBLK)
63 IELEND = MAT(4, IBLK)
64 IF (ISABRT()) RETURN
65 DO 30 IEL = IELBEG, IELEND
66 c .. if doesn't vectorize, remove next line and do select on summary only
67 IF (SELECT(IEL)) THEN
68 X1 = CRD(IX(1,IEL), 1)
69 X2 = CRD(IX(2,IEL), 1)
70 X3 = CRD(IX(3,IEL), 1)
71 X4 = CRD(IX(4,IEL), 1)
72
73 Y1 = CRD(IX(1,IEL), 2)
74 Y2 = CRD(IX(2,IEL), 2)
75 Y3 = CRD(IX(3,IEL), 2)
76 Y4 = CRD(IX(4,IEL), 2)
77
78 C ... Make centroid of element the center of coordinate system
79
80 XS = (X1 + X2 + X3 + X4) / 4.0
81 YS = (Y1 + Y2 + Y3 + Y4) / 4.0
82
83 X1 = X1 - XS
84 X2 = X2 - XS
85 X3 = X3 - XS
86 X4 = X4 - XS
87
88 Y1 = Y1 - YS
89 Y2 = Y2 - YS
90 Y3 = Y3 - YS
91 Y4 = Y4 - YS
92
93 C ... Rotate element such that center of side 2-3 and 4-1 define X axis
94
95 AMAG = SQRT((X2+X3-X4-X1)**2 + (Y2+Y3-Y4-Y1)**2)
96 C = (X2 + X3 - X4 - X1) / AMAG
97 S = (Y2 + Y3 - Y4 - Y1) / AMAG
98
99 XT = C * X1 + S * Y1
100 Y1 = -S * X1 + C * Y1
101 X1 = XT
102
103 XT = C * X2 + S * Y2
104 Y2 = -S * X2 + C * Y2
105 X2 = XT
106
107 XT = C * X3 + S * Y3
108 Y3 = -S * X3 + C * Y3
109 X3 = XT
110
111 XT = C * X4 + S * Y4
112 Y4 = -S * X4 + C * Y4
113 X4 = XT
114
115 C ... Calculate ``Shape function'' parameters - E1, F1, F2 = 0.0
116
117 E2 = -X1 + X2 + X3 - X4
118 E3 = -X1 - X2 + X3 + X4
119 E4 = X1 - X2 + X3 - X4
120
121 F3 = -Y1 - Y2 + Y3 + Y4
122 F4 = Y1 - Y2 + Y3 - Y4
123
124 ASPECT(IEL) = MAX (E2 / F3, F3 / E2)
125 SKEW(IEL) = ABS(E3/F3) / SQRT((E3/F3)**2 + 1.0)
126 TAPER(IEL) = SQRT((F4 / F3)**2 + (E4 / E2)**2)
127 AREA(IEL) = E2 * F3 / 4.0
128
129 END IF
130 30 CONTINUE
131 END IF
132 40 CONTINUE
133 DO 50 IO=IOMIN, IOMAX
134 WRITE (IO, 60)
135 50 CONTINUE
136 60 FORMAT (/' Shape Parameters for Selected Elements',/
137 * /2X,'Mat Minimum Elem Maximum Elem Average ',
138 * ' Std. Dev.'/)
139
140 DO 100 ITMP = 1, NELBLK
141 IBLK = MAT(6, ITMP)
142 IF (MAT(5, IBLK) .EQ. 1) THEN
143 IELBEG = MAT(3, IBLK)
144 IELEND = MAT(4, IBLK)
145 NUMLST = IELEND - IELBEG + 1
146 C ... Determine mins, maxs, averages, and std. dev. for selected block/elem
147
148 CALL SUMMRY (' ', NUMLST, SELECT(IELBEG), ASPECT(IELBEG),
149 * SUMRY(1,1,IBLK), ISUMRY(1,1,IBLK),IELBEG-1)
150 CALL SUMMRY (' ', NUMLST, SELECT(IELBEG), SKEW(IELBEG),
151 * SUMRY(1,2,IBLK), ISUMRY(1,2,IBLK),IELBEG-1)
152 CALL SUMMRY (' ', NUMLST, SELECT(IELBEG), TAPER(IELBEG),
153 * SUMRY(1,3,IBLK), ISUMRY(1,3,IBLK),IELBEG-1)
154 CALL SUMMRY (' ', NUMLST, SELECT(IELBEG), AREA(IELBEG),
155 * SUMRY(1,4,IBLK), ISUMRY(1,4,IBLK),IELBEG-1)
156
157 DO 70 IO= IOMIN, IOMAX
158 WRITE (IO, 80) MAT(1,IBLK),
159 * SUMRY(1,1,IBLK), ISUMRY(1,1,IBLK),
160 * SUMRY(2,1,IBLK), ISUMRY(2,1,IBLK),
161 * SUMRY(3,1,IBLK), SUMRY(4,1,IBLK), 'Aspect',
162 * SUMRY(1,2,IBLK), ISUMRY(1,2,IBLK),
163 * SUMRY(2,2,IBLK), ISUMRY(2,2,IBLK),
164 * SUMRY(3,2,IBLK), SUMRY(4,2,IBLK), 'Skewness',
165 * SUMRY(1,3,IBLK), ISUMRY(1,3,IBLK),
166 * SUMRY(2,3,IBLK), ISUMRY(2,3,IBLK),
167 * SUMRY(3,3,IBLK), SUMRY(4,3,IBLK), 'Taper',
168 * SUMRY(1,4,IBLK), ISUMRY(1,4,IBLK),
169 * SUMRY(2,4,IBLK), ISUMRY(2,4,IBLK),
170 * SUMRY(3,4,IBLK), SUMRY(4,4,IBLK), 'Area'
171
172 WRITE (IO, 90)
173 70 CONTINUE
174 80 FORMAT (I5,(T8,2(1PE15.8,I6,2X),2(1PE15.8,2X),3X,A8))
175 90 FORMAT (' ------------------')
176 END IF
177 100 CONTINUE
178 END