Debian Codegraph @

packages/seacas/applications/numbers/nu_cgcal2.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE CGCAL2(CRD,IX,MAT,MASS,VOL,DENS,VOLM,CG,ZITOT,XXX,
8 * XG,XI,XINI,AJ,NNODES,NDIM,NQUAD,VOLMN,IELM,NELBLK,
9 * AXI,NUMNP)
10
11 DIMENSION CRD(NUMNP,*), IX(NNODES,*), MAT(6,*), MASS(*),
12 * DENS(*), VOLM(*), CG(*), ZITOT(*),VOLMN(4,*),IELM(4,*),
13 * XXX(NDIM+1,NQUAD,*),XG(NDIM,*), XI(NDIM,*), XINI(*),
14 * AJ(2,*)
15 DIMENSION ZI(6), ZMOM(3)
16 DIMENSION CCC(2,4)
17
18 LOGICAL AXI
19 REAL MASS, MASSE
20 PI = ATAN2(0.0, -1.0)
21
22 C ... VOLMN(1,*) = MINIMUM VOLUME (AREAS FOR 2-D)
23 C VOLMN(2,*) = MAXIMUM VOLUME
24 C VOLMN(3,*) = TOTAL VOLUME
25
26 DO 10 I=1, NELBLK
27 VOLMN(1,I) = 1.0E30
28 VOLMN(2,I) = 0.0
29 VOLMN(3,I) = 0.0
30 IELM (3,I) = 0
31 MASS(I) = 0.0
32 VOLM(I) = 0.0
33 10 CONTINUE
34 DO 20 I=1,3
35 ZITOT(I) = 0.0
36 ZITOT(I+3) = 0.0
37 ZMOM(I) = 0.0
38 20 CONTINUE
39 ZMAS = 0.0
40 VOL = 0.0
41
42 C ... GET QUADRATURE POINT LOCATIONS, EVALUATE SHAPE FUNCTIONS
43
44 CALL QUAD(XXX, XI, XG, NDIM, NNODES, NQUAD, WT)
45
46 DO 110 IBLK = 1, NELBLK
47 IF (MAT(5,IBLK) .NE. 1) GOTO 110
48 IELBEG = MAT(3,IBLK)
49 IELEND = MAT(4,IBLK)
50 MIEL = IBLK
51 DO 100 IEL = IELBEG, IELEND
52
53 C ... CALCULATE AREA, VOLUME, AND MOMENTS OF INERTIA OF ELEMENT
54
55 DO 30 I=1,3
56 ZI(I) = 0.0
57 ZI(I+3) = 0.0
58 CG(I) = 0.0
59 30 CONTINUE
60 VOLUME = 0.0
61
62 DO 40 I=1,4
63 CCC(1,I) = CRD(IX(I,IEL),1)
64 CCC(2,I) = CRD(IX(I,IEL),2)
65 40 CONTINUE
66 DO 80 NG=1,NQUAD
67 DET = 0.0
68 DO 60 J=1,2
69 XINI(J) = 0.0
70 DO 50 K=1,2
71 AJ(K,J) = 0.0
72 50 CONTINUE
73 60 CONTINUE
74
75 DO 70 I=1,4
76 XINI(1) = XINI(1)+XXX(1,I,NG) * CCC(1,I)
77 AJ(1,1) = AJ(1,1)+XXX(2,I,NG) * CCC(1,I)
78 AJ(2,1) = AJ(2,1)+XXX(3,I,NG) * CCC(1,I)
79
80 XINI(2) = XINI(2)+XXX(1,I,NG) * CCC(2,I)
81 AJ(1,2) = AJ(1,2)+XXX(2,I,NG) * CCC(2,I)
82 AJ(2,2) = AJ(2,2)+XXX(3,I,NG) * CCC(2,I)
83 70 CONTINUE
84
85 DET = ( AJ(1,1)*AJ(2,2) - AJ(2,1)*AJ(1,2) ) * WT
86 DETW = DET * DENS(MIEL)
87
88 IF (AXI) THEN
89
90 C ... CG(1) IS THE VOLUME FOR AXI 2-D, VOLUME IS ACTUALLY C/S AREA
91
92 CG(1) = CG(1) + DET * XINI(1)
93 CG(2) = CG(2) + DETW * XINI(1) * XINI(2)
94 ZI(2) = ZI(2) + DETW * XINI(1)**3
95 ZI(1) = ZI(1) + DETW * XINI(1)*XINI(2)**2
96 VOLUME = VOLUME + DET
97 ELSE
98 CG(1) = CG(1) + DETW * XINI(1)
99 CG(2) = CG(2) + DETW * XINI(2)
100 ZI(1) = ZI(1) + DETW * XINI(2)**2
101 ZI(2) = ZI(2) + DETW * XINI(1)**2
102 ZI(3) = ZI(3) + DETW * XINI(1)*XINI(2)
103 VOLUME = VOLUME + DET
104 END IF
105
106 80 CONTINUE
107
108 C ... DETERMINE MIN/MAX ELEMENT VOLUMES FOR EACH MATERIAL AND
109 C COUNT NUMBER OF ELEMENTS FOR EACH MATERIAL
110
111 IELM(3,MIEL) = IELM(3,MIEL) + 1
112 VOLMN(3,MIEL) = VOLMN(3,MIEL) + VOLUME
113 IF (VOLUME .LT. VOLMN(1,MIEL)) THEN
114 VOLMN(1,MIEL) = VOLUME
115 IELM(1,MIEL) = IEL
116 ELSE IF (VOLUME .GT. VOLMN(2,MIEL)) THEN
117 VOLMN(2,MIEL) = VOLUME
118 IELM(2,MIEL) = IEL
119 ENDIF
120
121 IF (AXI) THEN
122 VOLUME = 2. * PI * CG(1)
123 ZI(2) = ZI(2) * 2. * PI
124 ZI(1) = ZI(1) * 2. * PI + ZI(2) / 2.0
125 ZI(3) = ZI(1)
126 END IF
127 DO 90 I=1,3
128 ZITOT(I) = ZITOT(I) + ZI(I)
129 90 CONTINUE
130 MASSE = VOLUME * DENS(MIEL)
131 MASS(MIEL)= MASS(MIEL) + MASSE
132 VOLM(MIEL)= VOLM(MIEL) + VOLUME
133 VOL = VOL + VOLUME
134 ZMAS = ZMAS + MASSE
135 IF (AXI) THEN
136 CG(1) = 0.0
137 ZMOM(2) = ZMOM(2) + CG(2) * 2. * PI
138 ELSE
139 ZMOM(1) = ZMOM(1) + CG(1)
140 ZMOM(2) = ZMOM(2) + CG(2)
141 END IF
142 100 CONTINUE
143 110 CONTINUE
144 FIX = SIGN(0.5, ZMAS) + SIGN(0.5, -ZMAS)
145 DO 120 I=1,3
146 CG(I) = ZMOM(I) / (ZMAS + FIX)
147 120 CONTINUE
148 IF (AXI) THEN
149 ZITOT(1) = ZITOT(1) - ZMAS * CG(2)**2
150 ZITOT(3) = ZITOT(3) - ZMAS * CG(2)**2
151 ELSE
152 ZITOT(1) = ZITOT(1) - ZMAS * CG(2)**2
153 ZITOT(2) = ZITOT(2) - ZMAS * CG(1)**2
154 ZITOT(4) = ZITOT(3) - ZMAS * CG(1) * CG(2)
155 ZITOT(3) = ZITOT(1) + ZITOT(2)
156 END IF
157
158 RETURN
159 END